SL/Controller/RequirementSpec.pm

   1 package SL::Controller::RequirementSpec;
   2
   3 use strict;
   4
   5 use parent qw(SL::Controller::Base);
   6
   7 use SL::ClientJS;
   8 use SL::Controller::Helper::GetModels;
   9 use SL::Controller::Helper::Paginated;
  10 use SL::Controller::Helper::Sorted;
  11 use SL::Controller::Helper::ParseFilter;
  12 use SL::Controller::Helper::ReportGenerator;
  13 use SL::Controller::Helper::RequirementSpec;
  14 use SL::DB::Customer;
  15 use SL::DB::Project;
  16 use SL::DB::RequirementSpecComplexity;
  17 use SL::DB::RequirementSpecRisk;
  18 use SL::DB::RequirementSpecStatus;
  19 use SL::DB::RequirementSpecType;
  20 use SL::DB::RequirementSpec;
  21 use SL::Helper::Flash;
  22 use SL::Locale::String;
  23
  24 use Rose::Object::MakeMethods::Generic
  25 (
  26   scalar                  => [ qw(requirement_spec_item customers types statuses db_args flat_filter is_template visible_item visible_section) ],
  27   'scalar --get_set_init' => [ qw(requirement_spec complexities risks projects copy_source) ],
  28 );
  29
  30 __PACKAGE__->run_before('setup');
  31 __PACKAGE__->run_before('load_select_options',  only => [ qw(new ajax_edit create update list) ]);
  32
  33
  34 __PACKAGE__->get_models_url_params('flat_filter');
  35 __PACKAGE__->make_paginated(
  36   MODEL         => 'RequirementSpec',
  37   PAGINATE_ARGS => 'db_args',
  38   ONLY          => [ qw(list) ],
  39 );
  40
  41 __PACKAGE__->make_sorted(
  42   MODEL         => 'RequirementSpec',
  43   ONLY          => [ qw(list) ],
  44
  45   DEFAULT_BY    => 'customer',
  46   DEFAULT_DIR   => 1,
  47
  48   customer      => t8('Customer'),
  49   title         => t8('Title'),
  50   type          => t8('Requirement Spec Type'),
  51   status        => t8('Requirement Spec Status'),
  52   projectnumber => t8('Project Number'),
  53   version       => t8('Version'),
  54   mtime         => t8('Last modification'),
  55 );
  56
  57 #
  58 # actions
  59 #
  60
  61
  62 sub action_list {
  63   my ($self) = @_;
  64
  65   $self->setup_db_args_from_filter;
  66   $self->flat_filter({ map { $_->{key} => $_->{value} } $::form->flatten_variables('filter') });
  67
  68   $self->prepare_report;
  69
  70   my $requirement_specs = $self->get_models(%{ $self->db_args });
  71
  72   $self->report_generator_list_objects(report => $self->{report}, objects => $requirement_specs);
  73 }
  74
  75 sub action_new {
  76   my ($self) = @_;
  77
  78   $self->requirement_spec(SL::DB::RequirementSpec->new);
  79
  80   if ($self->copy_source) {
  81     $self->requirement_spec->$_($self->copy_source->$_) for qw(type_id status_id customer_id title hourly_rate)
  82   }
  83
  84   $self->render('requirement_spec/new', title => t8('Create a new requirement spec'));
  85 }
  86
  87 sub action_ajax_edit {
  88   my ($self) = @_;
  89
  90   $self->render('requirement_spec/_form', { layout => 0 }, submit_as => 'ajax');
  91 }
  92
  93 sub action_ajax_show_time_and_cost_estimate {
  94   my ($self) = @_;
  95
  96   $self->render('requirement_spec/_show_time_and_cost_estimate', { layout => 0 });
  97 }
  98
  99 sub action_ajax_cancel_time_and_cost_estimate {
 100   my ($self) = @_;
 101
 102   my $html   = $self->render('requirement_spec/_show_time_and_cost_estimate', { output => 0 });
 103
 104   SL::ClientJS->new
 105     ->replaceWith('#time_cost_estimate', $html)
 106     ->render($self);
 107 }
 108
 109 sub action_ajax_edit_time_and_cost_estimate {
 110   my ($self) = @_;
 111
 112   my $html   = $self->render('requirement_spec/_edit_time_and_cost_estimate', { output => 0 });
 113
 114   SL::ClientJS->new
 115     ->replaceWith('#time_cost_estimate', $html)
 116     ->render($self);
 117 }
 118
 119 sub action_ajax_save_time_and_cost_estimate {
 120   my ($self) = @_;
 121
 122   $self->requirement_spec->db->do_transaction(sub {
 123     # Make Emacs happy
 124     1;
 125     foreach my $attributes (@{ $::form->{requirement_spec_items} || [] }) {
 126       SL::DB::RequirementSpecItem
 127         ->new(id => delete $attributes->{id})
 128         ->load
 129         ->update_attributes(%{ $attributes });
 130     }
 131
 132     1;
 133   });
 134
 135   my $html = $self->render('requirement_spec/_show_time_and_cost_estimate', { output => 0 });
 136   my $js   = SL::ClientJS->new->replaceWith('#time_cost_estimate', $html);
 137
 138   if ($self->visible_section) {
 139     $html = $self->render('requirement_spec_item/_section', { output => 0 }, requirement_spec_item => $self->visible_section);
 140     $js->html('#column-content', $html);
 141   }
 142
 143   $js->render($self);
 144 }
 145
 146 sub action_show {
 147   my ($self) = @_;
 148
 149   my $item = $::form->{requirement_spec_item_id} ? SL::DB::RequirementSpecItem->new(id => $::form->{requirement_spec_item_id})->load : @{ $self->requirement_spec->sections }[0];
 150   $self->requirement_spec_item($item);
 151
 152   $self->render('requirement_spec/show', title => t8('Show requirement spec'));
 153 }
 154
 155 sub action_create {
 156   my ($self) = @_;
 157
 158   $self->requirement_spec(SL::DB::RequirementSpec->new);
 159   $self->create_or_update;
 160 }
 161
 162 sub action_update {
 163   my ($self) = @_;
 164   $self->create_or_update;
 165 }
 166
 167 sub action_destroy {
 168   my ($self) = @_;
 169
 170   if (eval { $self->requirement_spec->delete; 1; }) {
 171     flash_later('info',  t8('The requirement spec has been deleted.'));
 172   } else {
 173     flash_later('error', t8('The requirement spec is in use and cannot be deleted.'));
 174   }
 175
 176   $self->redirect_to(action => 'list');
 177 }
 178
 179 sub action_reorder {
 180   my ($self) = @_;
 181
 182   SL::DB::RequirementSpec->reorder_list(@{ $::form->{requirement_spec_id} || [] });
 183
 184   $self->render('1;', { type => 'js', inline => 1 });
 185 }
 186
 187 #
 188 # filters
 189 #
 190
 191 sub setup {
 192   my ($self) = @_;
 193
 194   $::auth->assert('sales_quotation_edit');
 195   $::request->{layout}->use_stylesheet("${_}.css") for qw(jquery.contextMenu requirement_spec);
 196   $::request->{layout}->use_javascript("${_}.js") for qw(jquery.jstree jquery/jquery.contextMenu client_js requirement_spec);
 197   $self->is_template($::form->{is_template} ? 1 : 0);
 198   $self->init_visible_section;
 199
 200   return 1;
 201 }
 202
 203 sub init_complexities {
 204   my ($self) = @_;
 205   return SL::DB::Manager::RequirementSpecComplexity->get_all_sorted;
 206 }
 207
 208 sub init_risks {
 209   my ($self) = @_;
 210   return SL::DB::Manager::RequirementSpecRisk->get_all_sorted;
 211 }
 212
 213 sub init_projects {
 214   my ($self) = @_;
 215   $self->projects(SL::DB::Manager::Project->get_all_sorted);
 216 }
 217
 218 sub init_requirement_spec {
 219   my ($self) = @_;
 220   $self->requirement_spec(SL::DB::RequirementSpec->new(id => $::form->{id})->load || die "No such requirement spec") if $::form->{id};
 221 }
 222
 223 sub init_copy_source {
 224   my ($self) = @_;
 225   $self->copy_source(SL::DB::RequirementSpec->new(id => $::form->{copy_source_id})->load) if $::form->{copy_source_id};
 226 }
 227
 228 sub load_select_options {
 229   my ($self) = @_;
 230
 231   my @filter = ('!obsolete' => 1);
 232   @filter    = ( or => [ @filter, id => $self->requirement_spec->customer_id ] ) if $self->requirement_spec && $self->requirement_spec->customer_id;
 233
 234   $self->customers(SL::DB::Manager::Customer->get_all_sorted(where => \@filter));
 235   $self->statuses( SL::DB::Manager::RequirementSpecStatus->get_all_sorted);
 236   $self->types(    SL::DB::Manager::RequirementSpecType->get_all_sorted);
 237 }
 238
 239 #
 240 # helpers
 241 #
 242
 243 sub create_or_update {
 244   my $self   = shift;
 245   my $is_new = !$self->requirement_spec->id;
 246   my $params = delete($::form->{requirement_spec}) || { };
 247   my $title  = $is_new ? t8('Create a new requirement spec') : t8('Edit requirement spec');
 248
 249   $self->requirement_spec->assign_attributes(%{ $params });
 250
 251   my @errors = $self->requirement_spec->validate;
 252
 253   if (@errors) {
 254     return SL::ClientJS->new->error(@errors)->render($self) if $::request->is_ajax;
 255
 256     flash('error', @errors);
 257     $self->render('requirement_spec/new', title => $title);
 258     return;
 259   }
 260
 261   my $db = $self->requirement_spec->db;
 262   if (!$db->do_transaction(sub {
 263     if ($self->copy_source) {
 264       $self->requirement_spec($self->copy_source->create_copy(%{ $params }));
 265     } else {
 266       $self->requirement_spec->save;
 267     }
 268   })) {
 269     $::lxdebug->message(LXDebug::WARN(), "Error: " . $db->error);
 270     @errors = ($::locale->text('Saving failed. Error message from the database: #1'), $db->error);
 271     return SL::ClientJS->new->error(@errors)->render($self) if $::request->is_ajax;
 272
 273     $self->requirement_spec->id(undef) if $is_new;
 274     flash('error', @errors);
 275     return $self->render('requirement_spec/new', title => $title);
 276   }
 277
 278   if ($::request->is_ajax) {
 279     my $html = $self->render('requirement_spec/_header', { output => 0 });
 280     return SL::ClientJS->new
 281       ->replaceWith('#requirement-spec-header', $html)
 282       ->flash('info', t8('The requirement spec has been saved.'))
 283       ->render($self);
 284   }
 285
 286   flash_later('info', $is_new ? t8('The requirement spec has been created.') : t8('The requirement spec has been saved.'));
 287   $self->redirect_to(action => 'show', id => $self->requirement_spec->id);
 288 }
 289
 290 sub setup_db_args_from_filter {
 291   my ($self) = @_;
 292
 293   $self->{filter} = {};
 294   my %args = parse_filter(
 295     $::form->{filter},
 296     with_objects => [ 'customer', 'type', 'status', 'project' ],
 297     launder_to   => $self->{filter},
 298   );
 299
 300   $args{where} = [
 301     and => [
 302       @{ $args{where} || [] },
 303       working_copy_id => undef,
 304       is_template     => $self->is_template
 305     ]];
 306
 307   $self->db_args(\%args);
 308 }
 309
 310 sub prepare_report {
 311   my ($self)      = @_;
 312
 313   my $callback    = $self->get_callback;
 314
 315   my $report      = SL::ReportGenerator->new(\%::myconfig, $::form);
 316   $self->{report} = $report;
 317
 318   my @columns     = qw(title customer status type projectnumber mtime version);
 319   my @sortable    = qw(title customer status type projectnumber mtime);
 320
 321   my %column_defs = (
 322     title         => { obj_link => sub { $self->url_for(action => 'show', id => $_[0]->id, callback => $callback) } },
 323     customer      => { raw_data => sub { $self->presenter->customer($_[0]->customer, display => 'table-cell', callback => $callback) },
 324                        sub      => sub { $_[0]->customer->name } },
 325     projectnumber => { raw_data => sub { $self->presenter->project($_[0]->project, display => 'table-cell', callback => $callback) },
 326                        sub      => sub { $_[0]->project_id ? $_[0]->project->projectnumber : '' } },
 327     status        => { sub      => sub { $_[0]->status->description } },
 328     type          => { sub      => sub { $_[0]->type->description } },
 329     version       => { sub      => sub { $_[0]->version_id ? $_[0]->version->version_number : t8('Working copy without version') } },
 330     mtime         => { sub      => sub { $_[0]->mtime->to_kivitendo(precision => 'minute') } },
 331   );
 332
 333   map { $column_defs{$_}->{text} ||= $::locale->text( $self->get_sort_spec->{$_}->{title} ) } keys %column_defs;
 334
 335   $report->set_options(
 336     std_column_visibility => 1,
 337     controller_class      => 'RequirementSpec',
 338     output_format         => 'HTML',
 339     raw_top_info_text     => $self->render('requirement_spec/report_top',    { output => 0 }),
 340     raw_bottom_info_text  => $self->render('requirement_spec/report_bottom', { output => 0 }),
 341     title                 => $::locale->text('Requirement Specs'),
 342     allow_pdf_export      => 1,
 343     allow_csv_export      => 1,
 344   );
 345   $report->set_columns(%column_defs);
 346   $report->set_column_order(@columns);
 347   $report->set_export_options(qw(list filter));
 348   $report->set_options_from_form;
 349   $self->set_report_generator_sort_options(report => $report, sortable_columns => \@sortable);
 350
 351   $self->disable_pagination if $report->{options}{output_format} =~ /^(pdf|csv)$/i;
 352 }
 353
 354 1;