SL/Controller/RequirementSpec.pm

   1 package SL::Controller::RequirementSpec;
   2
   3 use strict;
   4 use utf8;
   5
   6 use parent qw(SL::Controller::Base);
   7
   8 use SL::ClientJS;
   9 use SL::Controller::Helper::GetModels;
  10 use SL::Controller::Helper::Paginated;
  11 use SL::Controller::Helper::Sorted;
  12 use SL::Controller::Helper::ParseFilter;
  13 use SL::Controller::Helper::ReportGenerator;
  14 use SL::Controller::Helper::RequirementSpec;
  15 use SL::DB::Customer;
  16 use SL::DB::Project;
  17 use SL::DB::RequirementSpecComplexity;
  18 use SL::DB::RequirementSpecRisk;
  19 use SL::DB::RequirementSpecStatus;
  20 use SL::DB::RequirementSpecType;
  21 use SL::DB::RequirementSpec;
  22 use SL::Helper::Flash;
  23 use SL::Locale::String;
  24 use SL::Template::LaTeX;
  25
  26 use Rose::Object::MakeMethods::Generic
  27 (
  28   scalar                  => [ qw(requirement_spec_item customers types statuses db_args flat_filter visible_item visible_section) ],
  29   'scalar --get_set_init' => [ qw(requirement_spec complexities risks projects copy_source js current_text_block_output_position) ],
  30 );
  31
  32 __PACKAGE__->run_before('setup');
  33 __PACKAGE__->run_before('load_select_options',  only => [ qw(new ajax_edit create update list) ]);
  34
  35
  36 __PACKAGE__->get_models_url_params('flat_filter');
  37 __PACKAGE__->make_paginated(
  38   MODEL         => 'RequirementSpec',
  39   PAGINATE_ARGS => 'db_args',
  40   ONLY          => [ qw(list) ],
  41 );
  42
  43 __PACKAGE__->make_sorted(
  44   MODEL         => 'RequirementSpec',
  45   ONLY          => [ qw(list) ],
  46
  47   DEFAULT_BY    => 'customer',
  48   DEFAULT_DIR   => 1,
  49
  50   customer      => t8('Customer'),
  51   title         => t8('Title'),
  52   type          => t8('Requirement Spec Type'),
  53   status        => t8('Requirement Spec Status'),
  54   projectnumber => t8('Project Number'),
  55   version       => t8('Version'),
  56   mtime         => t8('Last modification'),
  57 );
  58
  59 #
  60 # actions
  61 #
  62
  63
  64 sub action_list {
  65   my ($self) = @_;
  66
  67   $self->setup_db_args_from_filter;
  68   $self->flat_filter({ map { $_->{key} => $_->{value} } $::form->flatten_variables('filter') });
  69
  70   $self->prepare_report;
  71
  72   my $requirement_specs = $self->get_models(%{ $self->db_args });
  73
  74   $self->report_generator_list_objects(report => $self->{report}, objects => $requirement_specs);
  75 }
  76
  77 sub action_new {
  78   my ($self) = @_;
  79
  80   $self->requirement_spec(SL::DB::RequirementSpec->new(is_template => $::form->{is_template}));
  81
  82   if ($self->copy_source) {
  83     $self->requirement_spec->$_($self->copy_source->$_) for qw(type_id status_id customer_id title hourly_rate)
  84   }
  85
  86   $self->render('requirement_spec/new', title => $self->requirement_spec->is_template ? t8('Create a new requirement spec template') : t8('Create a new requirement spec'));
  87 }
  88
  89 sub action_ajax_show_basic_settings {
  90   my ($self) = @_;
  91
  92   $self->render('requirement_spec/_show_basic_settings', { layout => 0 });
  93 }
  94
  95 sub action_ajax_edit {
  96   my ($self) = @_;
  97
  98   my $html   = $self->render('requirement_spec/_form', { output => 0 }, submit_as => 'ajax');
  99
 100   $self->js
 101     ->hide('#basic_settings')
 102     ->after('#basic_settings', $html)
 103     ->render($self);
 104 }
 105
 106 sub action_ajax_show_time_and_cost_estimate {
 107   my ($self) = @_;
 108
 109   $self->render('requirement_spec/_show_time_and_cost_estimate', { layout => 0 });
 110 }
 111
 112 sub action_ajax_cancel_time_and_cost_estimate {
 113   my ($self) = @_;
 114
 115   my $html   = $self->render('requirement_spec/_show_time_and_cost_estimate', { output => 0 });
 116
 117   $self->js
 118    ->replaceWith('#time_cost_estimate', $html)
 119    ->render($self);
 120 }
 121
 122 sub action_ajax_edit_time_and_cost_estimate {
 123   my ($self) = @_;
 124
 125   my $html   = $self->render('requirement_spec/_edit_time_and_cost_estimate', { output => 0 });
 126
 127   $self->js
 128    ->replaceWith('#time_cost_estimate', $html)
 129    ->on('#time_cost_estimate INPUT[type=text]', 'keydown', 'kivi.requirement_spec.time_cost_estimate_input_key_down')
 130    ->render($self);
 131 }
 132
 133 sub action_ajax_save_time_and_cost_estimate {
 134   my ($self) = @_;
 135
 136   $self->requirement_spec->db->do_transaction(sub {
 137     # Make Emacs happy
 138     1;
 139     foreach my $attributes (@{ $::form->{requirement_spec_items} || [] }) {
 140       SL::DB::RequirementSpecItem
 141         ->new(id => delete $attributes->{id})
 142         ->load
 143         ->update_attributes(%{ $attributes });
 144     }
 145
 146     1;
 147   });
 148
 149   $self->requirement_spec(SL::DB::RequirementSpec->new(id => $self->requirement_spec->id)->load);
 150
 151   my $html = $self->render('requirement_spec/_show_time_and_cost_estimate', { output => 0 });
 152   $self->js->replaceWith('#time_cost_estimate', $html);
 153
 154   if ($self->visible_section) {
 155     $html = $self->render('requirement_spec_item/_section', { output => 0 }, requirement_spec_item => $self->visible_section);
 156     $self->js->html('#column-content', $html);
 157   }
 158
 159   $self->js->render($self);
 160 }
 161
 162 sub action_show {
 163   my ($self) = @_;
 164
 165   my $title  = $self->requirement_spec->is_template ? t8('Show requirement spec template') : t8('Show requirement spec');
 166   my $item   = $::form->{requirement_spec_item_id} ? SL::DB::RequirementSpecItem->new(id => $::form->{requirement_spec_item_id})->load : @{ $self->requirement_spec->sections }[0];
 167   $self->requirement_spec_item($item);
 168
 169   $self->render('requirement_spec/show', title => $title);
 170 }
 171
 172 sub action_create {
 173   my ($self) = @_;
 174
 175   $self->requirement_spec(SL::DB::RequirementSpec->new);
 176   $self->create_or_update;
 177 }
 178
 179 sub action_update {
 180   my ($self) = @_;
 181   $self->create_or_update;
 182 }
 183
 184 sub action_destroy {
 185   my ($self) = @_;
 186
 187   if (eval { $self->requirement_spec->delete; 1; }) {
 188     flash_later('info',  t8('The requirement spec has been deleted.'));
 189   } else {
 190     flash_later('error', t8('The requirement spec is in use and cannot be deleted.'));
 191   }
 192
 193   $self->redirect_to(action => 'list');
 194 }
 195
 196 sub action_revert_to {
 197   my ($self, %params) = @_;
 198
 199   return $self->js->error(t8('Cannot revert a versioned copy.'))->render($self) if $self->requirement_spec->working_copy_id;
 200
 201   my $versioned_copy = SL::DB::RequirementSpec->new(id => $::form->{versioned_copy_id})->load;
 202
 203   $self->requirement_spec->copy_from(
 204     $versioned_copy,
 205     version_id => $versioned_copy->version_id,
 206   );
 207
 208   flash_later('info', t8('The requirement spec has been reverted to version #1.', $self->requirement_spec->version->version_number));
 209   $self->js->redirect_to($self->url_for(action => 'show', id => $self->requirement_spec->id))->render($self);
 210 }
 211
 212 sub action_create_pdf {
 213   my ($self, %params) = @_;
 214
 215   my %result = SL::Template::LaTeX->parse_and_create_pdf('requirement_spec.tex', SELF => $self, rspec => $self->requirement_spec);
 216
 217   $::form->error(t8('Conversion to PDF failed: #1', $result{error})) if $result{error};
 218
 219   my $attachment_name  =  $self->requirement_spec->type->description . ' ' . ($self->requirement_spec->working_copy_id || $self->requirement_spec->id);
 220   $attachment_name    .=  ' (v' . $self->requirement_spec->version->version_number . ')' if $self->requirement_spec->version;
 221   $attachment_name    .=  '.pdf';
 222   $attachment_name     =~ s/[^\wäöüÄÖÜß \-\+\(\)\[\]\{\}\.,]+/_/g;
 223
 224   $self->send_file($result{file_name}, type => 'application/pdf', name => $attachment_name);
 225   unlink $result{file_name};
 226 }
 227
 228 sub action_select_template_to_paste {
 229   my ($self) = @_;
 230
 231   my @templates = grep { @{ $_->sections } || @{ $_->text_blocks } } @{ SL::DB::Manager::RequirementSpec->get_all(where => [ is_template => 1 ], sort_by => 'lower(title)') };
 232   $self->render('requirement_spec/select_template_to_paste', { layout => 0 }, TEMPLATES => \@templates);
 233 }
 234
 235 sub action_paste_template {
 236   my ($self, %params) = @_;
 237
 238   my $template = SL::DB::RequirementSpec->new(id => $::form->{template_id})->load;
 239   my %result   = $self->requirement_spec->paste_template($template);
 240
 241   return $self->js->error($self->requirement_spec->error)->render($self) if !%result;
 242
 243   $self->render_pasted_text_block($_) for sort { $a->position <=> $b->position } @{ $result{text_blocks} };
 244   $self->render_pasted_section($_)    for sort { $a->position <=> $b->position } @{ $result{sections}    };
 245
 246   if (@{ $result{sections} } && (($::form->{current_content_type} || 'sections') eq 'sections') && !$::form->{current_content_id}) {
 247     $self->render_first_pasted_section_as_list($result{sections}->[0]);
 248   }
 249
 250   $self->invalidate_version->render($self);
 251 }
 252
 253 #
 254 # filters
 255 #
 256
 257 sub setup {
 258   my ($self) = @_;
 259
 260   $::auth->assert('sales_quotation_edit');
 261   $::request->{layout}->use_stylesheet("${_}.css") for qw(jquery.contextMenu requirement_spec);
 262   $::request->{layout}->use_javascript("${_}.js") for qw(jquery.jstree jquery/jquery.contextMenu client_js requirement_spec);
 263   $self->init_visible_section;
 264
 265   return 1;
 266 }
 267
 268 sub init_complexities {
 269   my ($self) = @_;
 270   return SL::DB::Manager::RequirementSpecComplexity->get_all_sorted;
 271 }
 272
 273 sub init_risks {
 274   my ($self) = @_;
 275   return SL::DB::Manager::RequirementSpecRisk->get_all_sorted;
 276 }
 277
 278 sub init_projects {
 279   my ($self) = @_;
 280   $self->projects(SL::DB::Manager::Project->get_all_sorted);
 281 }
 282
 283 sub init_requirement_spec {
 284   my ($self) = @_;
 285   $self->requirement_spec(SL::DB::RequirementSpec->new(id => $::form->{id})->load || die "No such requirement spec") if $::form->{id};
 286 }
 287
 288 sub init_copy_source {
 289   my ($self) = @_;
 290   $self->copy_source(SL::DB::RequirementSpec->new(id => $::form->{copy_source_id})->load) if $::form->{copy_source_id};
 291 }
 292
 293 sub init_js {
 294   my ($self) = @_;
 295   $self->js(SL::ClientJS->new);
 296 }
 297
 298 sub init_current_text_block_output_position {
 299   my ($self) = @_;
 300   $self->current_text_block_output_position($::form->{current_content_type} !~ m/^(?:text-blocks|tb)-(front|back)/ ? -1 : $1 eq 'front' ? 0 : 1);
 301 }
 302
 303 sub load_select_options {
 304   my ($self) = @_;
 305
 306   my @filter = ('!obsolete' => 1);
 307   @filter    = ( or => [ @filter, id => $self->requirement_spec->customer_id ] ) if $self->requirement_spec && $self->requirement_spec->customer_id;
 308
 309   $self->customers(SL::DB::Manager::Customer->get_all_sorted(where => \@filter));
 310   $self->statuses( SL::DB::Manager::RequirementSpecStatus->get_all_sorted);
 311   $self->types(    SL::DB::Manager::RequirementSpecType->get_all_sorted);
 312 }
 313
 314 #
 315 # helpers
 316 #
 317
 318 sub create_or_update {
 319   my $self   = shift;
 320   my $is_new = !$self->requirement_spec->id;
 321   my $params = delete($::form->{requirement_spec}) || { };
 322
 323   $self->requirement_spec->assign_attributes(%{ $params });
 324
 325   my $title  = $is_new && $self->requirement_spec->is_template ? t8('Create a new requirement spec template')
 326              : $is_new                                         ? t8('Create a new requirement spec')
 327              :            $self->requirement_spec->is_template ? t8('Edit requirement spec template')
 328              :                                                   t8('Edit requirement spec');
 329
 330   my @errors = $self->requirement_spec->validate;
 331
 332   if (@errors) {
 333     return $self->js->error(@errors)->render($self) if $::request->is_ajax;
 334
 335     flash('error', @errors);
 336     $self->render('requirement_spec/new', title => $title);
 337     return;
 338   }
 339
 340   my $db = $self->requirement_spec->db;
 341   if (!$db->do_transaction(sub {
 342     if ($self->copy_source) {
 343       $self->requirement_spec($self->copy_source->create_copy(%{ $params }));
 344     } else {
 345       $self->requirement_spec->save;
 346     }
 347   })) {
 348     $::lxdebug->message(LXDebug::WARN(), "Error: " . $db->error);
 349     @errors = ($::locale->text('Saving failed. Error message from the database: #1'), $db->error);
 350     return $self->js->error(@errors)->render($self) if $::request->is_ajax;
 351
 352     $self->requirement_spec->id(undef) if $is_new;
 353     flash('error', @errors);
 354     return $self->render('requirement_spec/new', title => $title);
 355   }
 356
 357   my $info = $self->requirement_spec->is_template ? t8('The requirement spec template has been saved.') : t8('The requirement spec has been saved.');
 358
 359   if ($::request->is_ajax) {
 360     my $header_html = $self->render('requirement_spec/_header', { output => 0 });
 361     my $basics_html = $self->render('requirement_spec/_show_basic_settings', { output => 0 });
 362     return $self->invalidate_version
 363       ->replaceWith('#requirement-spec-header', $header_html)
 364       ->replaceWith('#basic_settings',          $basics_html)
 365       ->remove('#basic_settings_form')
 366       ->flash('info', $info)
 367       ->render($self);
 368   }
 369
 370   flash_later('info', $info);
 371   $self->redirect_to(action => 'show', id => $self->requirement_spec->id);
 372 }
 373
 374 sub setup_db_args_from_filter {
 375   my ($self) = @_;
 376
 377   $self->{filter} = {};
 378   my %args = parse_filter(
 379     $::form->{filter},
 380     with_objects => [ 'customer', 'type', 'status', 'project' ],
 381     launder_to   => $self->{filter},
 382   );
 383
 384   $args{where} = [
 385     and => [
 386       @{ $args{where} || [] },
 387       working_copy_id => undef,
 388       is_template     => $::form->{is_template} ? 1 : 0,
 389     ]];
 390
 391   $self->db_args(\%args);
 392 }
 393
 394 sub prepare_report {
 395   my ($self)      = @_;
 396
 397   my $callback    = $self->get_callback;
 398
 399   my $is_template = $::form->{is_template};
 400   my $report      = SL::ReportGenerator->new(\%::myconfig, $::form);
 401   $self->{report} = $report;
 402
 403   my @columns     = $is_template ? qw(title mtime) : qw(title customer status type projectnumber mtime version);
 404   my @sortable    = $is_template ? qw(title mtime) : qw(title customer status type projectnumber mtime);
 405
 406   my %column_defs = (
 407     title         => { obj_link => sub { $self->url_for(action => 'show', id => $_[0]->id, callback => $callback) } },
 408     mtime         => { sub      => sub { ($_[0]->mtime || $_[0]->itime)->to_kivitendo(precision => 'minute') } },
 409   );
 410
 411   if (!$is_template) {
 412     %column_defs = (
 413       %column_defs,
 414       customer      => { raw_data => sub { $self->presenter->customer($_[0]->customer, display => 'table-cell', callback => $callback) },
 415                          sub      => sub { $_[0]->customer->name } },
 416       projectnumber => { raw_data => sub { $self->presenter->project($_[0]->project, display => 'table-cell', callback => $callback) },
 417                          sub      => sub { $_[0]->project_id ? $_[0]->project->projectnumber : '' } },
 418       status        => { sub      => sub { $_[0]->status->description } },
 419       type          => { sub      => sub { $_[0]->type->description } },
 420       version       => { sub      => sub { $_[0]->version_id ? $_[0]->version->version_number : t8('Working copy without version') } },
 421     );
 422   }
 423
 424   map { $column_defs{$_}->{text} ||= $::locale->text( $self->get_sort_spec->{$_}->{title} ) } keys %column_defs;
 425
 426   $report->set_options(
 427     std_column_visibility => 1,
 428     controller_class      => 'RequirementSpec',
 429     output_format         => 'HTML',
 430     raw_top_info_text     => $self->render('requirement_spec/report_top',    { output => 0 }, is_template => $is_template),
 431     raw_bottom_info_text  => $self->render('requirement_spec/report_bottom', { output => 0 }),
 432     title                 => $is_template ? t8('Requirement Spec Templates') : t8('Requirement Specs'),
 433     allow_pdf_export      => 1,
 434     allow_csv_export      => 1,
 435   );
 436   $report->set_columns(%column_defs);
 437   $report->set_column_order(@columns);
 438   $report->set_export_options(qw(list filter));
 439   $report->set_options_from_form;
 440   $self->set_report_generator_sort_options(report => $report, sortable_columns => \@sortable);
 441
 442   $self->disable_pagination if $report->{options}{output_format} =~ /^(pdf|csv)$/i;
 443 }
 444
 445 sub invalidate_version {
 446   my ($self) = @_;
 447
 448   my $rspec  = SL::DB::RequirementSpec->new(id => $self->requirement_spec->id)->load;
 449   return $self->js if $rspec->is_template;
 450
 451   $rspec->invalidate_version;
 452
 453   my $html = $self->render('requirement_spec/_version', { output => 0 }, requirement_spec => $rspec);
 454   return $self->js->html('#requirement_spec_version', $html);
 455 }
 456
 457 sub render_pasted_text_block {
 458   my ($self, $text_block, %params) = @_;
 459
 460   if ($self->current_text_block_output_position == $text_block->output_position) {
 461     my $html = $self->render('requirement_spec_text_block/_text_block', { output => 0 }, text_block => $text_block);
 462     $self->js
 463       ->appendTo($html, '#text-block-list')
 464       ->hide('#text-block-list-empty');
 465   }
 466
 467   my $node       = $self->presenter->requirement_spec_text_block_jstree_data($text_block);
 468   my $front_back = $text_block->output_position == 0 ? 'front' : 'back';
 469   $self->js
 470     ->jstree->create_node('#tree', "#tb-${front_back}", 'last', $node)
 471     ->jstree->open_node(  '#tree', "#tb-${front_back}");
 472 }
 473
 474 sub render_pasted_section {
 475   my ($self, $item, $parent_id) = @_;
 476
 477   my $node = $self->presenter->requirement_spec_item_jstree_data($item);
 478   $self->js
 479     ->jstree->create_node('#tree', $parent_id ? "#fb-${parent_id}" : '#sections', 'last', $node)
 480     ->jstree->open_node(  '#tree', $parent_id ? "#fb-${parent_id}" : '#sections');
 481
 482   $self->render_pasted_section($_, $item->id) for @{ $item->children_sorted };
 483 }
 484
 485 sub render_first_pasted_section_as_list {
 486   my ($self, $section, %params) = @_;
 487
 488   my $html = $self->render('requirement_spec_item/_section', { output => 0 }, requirement_spec_item => $section);
 489   $self->js
 490     ->html('#column-content', $html)
 491     ->val( '#current_content_type', $section->item_type)
 492     ->val( '#current_content_id',   $section->id)
 493     ->jstree->select_node('#tree', '#fb-' . $section->id);
 494 }
 495
 496 1;