SL/Controller/RequirementSpec.pm

   1 package SL::Controller::RequirementSpec;
   2
   3 use strict;
   4 use utf8;
   5
   6 use parent qw(SL::Controller::Base);
   7
   8 use File::Spec ();
   9
  10 use SL::ClientJS;
  11 use SL::Common ();
  12 use SL::Controller::Helper::GetModels;
  13 use SL::Controller::Helper::Filtered;
  14 use SL::Controller::Helper::Paginated;
  15 use SL::Controller::Helper::Sorted;
  16 use SL::Controller::Helper::ParseFilter;
  17 use SL::Controller::Helper::ReportGenerator;
  18 use SL::Controller::Helper::RequirementSpec;
  19 use SL::DB::Customer;
  20 use SL::DB::Project;
  21 use SL::DB::RequirementSpecComplexity;
  22 use SL::DB::RequirementSpecRisk;
  23 use SL::DB::RequirementSpecStatus;
  24 use SL::DB::RequirementSpecType;
  25 use SL::DB::RequirementSpec;
  26 use SL::Helper::Flash;
  27 use SL::Locale::String;
  28 use SL::Template::LaTeX;
  29
  30 use Rose::Object::MakeMethods::Generic
  31 (
  32   scalar                  => [ qw(requirement_spec_item customers types statuses visible_item visible_section) ],
  33   'scalar --get_set_init' => [ qw(requirement_spec complexities risks projects copy_source js current_text_block_output_position) ],
  34 );
  35
  36 __PACKAGE__->run_before('setup');
  37 __PACKAGE__->run_before('load_select_options',  only => [ qw(new ajax_edit create update list) ]);
  38
  39 __PACKAGE__->make_filtered(
  40   MODEL      => 'RequirementSpec',
  41   LAUNDER_TO => 'filter'
  42 );
  43 __PACKAGE__->make_paginated(
  44   MODEL => 'RequirementSpec',
  45   ONLY  => [ qw(list) ],
  46 );
  47 __PACKAGE__->make_sorted(
  48   MODEL         => 'RequirementSpec',
  49   ONLY          => [ qw(list) ],
  50
  51   DEFAULT_BY    => 'customer',
  52   DEFAULT_DIR   => 1,
  53
  54   customer      => t8('Customer'),
  55   title         => t8('Title'),
  56   type          => t8('Requirement Spec Type'),
  57   status        => t8('Requirement Spec Status'),
  58   projectnumber => t8('Project Number'),
  59   version       => t8('Version'),
  60   mtime         => t8('Last modification'),
  61 );
  62
  63 #
  64 # actions
  65 #
  66
  67
  68 sub action_list {
  69   my ($self) = @_;
  70
  71   my $requirement_specs = $self->get_models(
  72     query => [
  73       and => [
  74         working_copy_id => undef,
  75         is_template     => $::form->{is_template} ? 1 : 0,
  76       ]],
  77     with_objects => [ 'customer', 'type', 'status', 'project' ],
  78   );
  79
  80   $self->prepare_report;
  81   $self->report_generator_list_objects(report => $self->{report}, objects => $requirement_specs);
  82 }
  83
  84 sub action_new {
  85   my ($self) = @_;
  86
  87   $self->requirement_spec(SL::DB::RequirementSpec->new(is_template => $::form->{is_template}));
  88
  89   if ($self->copy_source) {
  90     $self->requirement_spec->$_($self->copy_source->$_) for qw(type_id status_id customer_id title hourly_rate)
  91   }
  92
  93   $self->render('requirement_spec/new', title => $self->requirement_spec->is_template ? t8('Create a new requirement spec template') : t8('Create a new requirement spec'));
  94 }
  95
  96 sub action_ajax_show_basic_settings {
  97   my ($self) = @_;
  98
  99   $self->render('requirement_spec/_show_basic_settings', { layout => 0 });
 100 }
 101
 102 sub action_ajax_edit {
 103   my ($self) = @_;
 104
 105   my $html   = $self->render('requirement_spec/_form', { output => 0 }, submit_as => 'ajax');
 106
 107   $self->js
 108     ->hide('#basic_settings')
 109     ->after('#basic_settings', $html)
 110     ->render($self);
 111 }
 112
 113 sub action_ajax_show_time_and_cost_estimate {
 114   my ($self) = @_;
 115
 116   $self->render('requirement_spec/_show_time_and_cost_estimate', { layout => 0 });
 117 }
 118
 119 sub action_ajax_edit_time_and_cost_estimate {
 120   my ($self) = @_;
 121
 122   my $html   = $self->render('requirement_spec/_edit_time_and_cost_estimate', { output => 0 });
 123
 124   $self->js
 125    ->hide('#time_cost_estimate')
 126    ->after('#time_cost_estimate', $html)
 127    ->on('#time_cost_estimate INPUT[type=text]', 'keydown', 'kivi.requirement_spec.time_cost_estimate_input_key_down')
 128    ->render($self);
 129 }
 130
 131 sub action_ajax_save_time_and_cost_estimate {
 132   my ($self) = @_;
 133
 134   $self->requirement_spec->db->do_transaction(sub {
 135     # Make Emacs happy
 136     1;
 137     foreach my $attributes (@{ $::form->{requirement_spec_items} || [] }) {
 138       SL::DB::RequirementSpecItem
 139         ->new(id => delete $attributes->{id})
 140         ->load
 141         ->update_attributes(%{ $attributes });
 142     }
 143
 144     1;
 145   });
 146
 147   $self->requirement_spec(SL::DB::RequirementSpec->new(id => $self->requirement_spec->id)->load);
 148
 149   my $html = $self->render('requirement_spec/_show_time_and_cost_estimate', { output => 0 });
 150   $self->js->replaceWith('#time_cost_estimate', $html)
 151            ->remove('#time_cost_estimate_form_container');
 152
 153   if ($self->visible_section) {
 154     $html = $self->render('requirement_spec_item/_section', { output => 0 }, requirement_spec_item => $self->visible_section);
 155     $self->js->html('#column-content', $html);
 156   }
 157
 158   $self->js->render($self);
 159 }
 160
 161 sub action_show {
 162   my ($self) = @_;
 163
 164   my $title  = $self->requirement_spec->is_template ? t8('Show requirement spec template') : t8('Show requirement spec');
 165   my $item   = $::form->{requirement_spec_item_id} ? SL::DB::RequirementSpecItem->new(id => $::form->{requirement_spec_item_id})->load : @{ $self->requirement_spec->sections }[0];
 166   $self->requirement_spec_item($item);
 167
 168   $self->render('requirement_spec/show', title => $title);
 169 }
 170
 171 sub action_create {
 172   my ($self) = @_;
 173
 174   $self->requirement_spec(SL::DB::RequirementSpec->new);
 175   $self->create_or_update;
 176 }
 177
 178 sub action_update {
 179   my ($self) = @_;
 180   $self->create_or_update;
 181 }
 182
 183 sub action_destroy {
 184   my ($self) = @_;
 185
 186   if (eval { $self->requirement_spec->delete; 1; }) {
 187     flash_later('info',  t8('The requirement spec has been deleted.'));
 188   } else {
 189     flash_later('error', t8('The requirement spec is in use and cannot be deleted.'));
 190   }
 191
 192   $self->redirect_to(action => 'list');
 193 }
 194
 195 sub action_revert_to {
 196   my ($self, %params) = @_;
 197
 198   return $self->js->error(t8('Cannot revert a versioned copy.'))->render($self) if $self->requirement_spec->working_copy_id;
 199
 200   my $versioned_copy = SL::DB::RequirementSpec->new(id => $::form->{versioned_copy_id})->load;
 201
 202   $self->requirement_spec->copy_from($versioned_copy);
 203   my $version = $versioned_copy->versions->[0];
 204   $version->update_attributes(working_copy_id => $self->requirement_spec->id);
 205
 206   flash_later('info', t8('The requirement spec has been reverted to version #1.', $self->requirement_spec->version->version_number));
 207   $self->js->redirect_to($self->url_for(action => 'show', id => $self->requirement_spec->id))->render($self);
 208 }
 209
 210 sub action_create_pdf {
 211   my ($self, %params) = @_;
 212
 213   my $base_name       = $self->requirement_spec->type->template_file_name || 'requirement_spec';
 214   my @pictures        = $self->prepare_pictures_for_printing;
 215   my %result          = SL::Template::LaTeX->parse_and_create_pdf("${base_name}.tex", SELF => $self, rspec => $self->requirement_spec);
 216
 217   unlink @pictures unless ($::lx_office_conf{debug} || {})->{keep_temp_files};
 218
 219   $::form->error(t8('Conversion to PDF failed: #1', $result{error})) if $result{error};
 220
 221   my $attachment_name  =  $self->requirement_spec->type->description . ' ' . ($self->requirement_spec->working_copy_id || $self->requirement_spec->id);
 222   $attachment_name    .=  ' (v' . $self->requirement_spec->version->version_number . ')' if $self->requirement_spec->version;
 223   $attachment_name    .=  '.pdf';
 224   $attachment_name     =~ s/[^\wäöüÄÖÜß \-\+\(\)\[\]\{\}\.,]+/_/g;
 225
 226   $self->send_file($result{file_name}, type => 'application/pdf', name => $attachment_name);
 227   unlink $result{file_name};
 228 }
 229
 230 sub action_select_template_to_paste {
 231   my ($self) = @_;
 232
 233   my @templates = grep { @{ $_->sections } || @{ $_->text_blocks } } @{ SL::DB::Manager::RequirementSpec->get_all(where => [ is_template => 1 ], sort_by => 'lower(title)') };
 234   $self->render('requirement_spec/select_template_to_paste', { layout => 0 }, TEMPLATES => \@templates);
 235 }
 236
 237 sub action_paste_template {
 238   my ($self, %params) = @_;
 239
 240   my $template = SL::DB::RequirementSpec->new(id => $::form->{template_id})->load;
 241   my %result   = $self->requirement_spec->paste_template($template);
 242
 243   return $self->js->error($self->requirement_spec->error)->render($self) if !%result;
 244
 245   $self->render_pasted_text_block($_) for sort { $a->position <=> $b->position } @{ $result{text_blocks} };
 246   $self->render_pasted_section($_)    for sort { $a->position <=> $b->position } @{ $result{sections}    };
 247
 248   if (@{ $result{sections} } && (($::form->{current_content_type} || 'sections') eq 'sections') && !$::form->{current_content_id}) {
 249     $self->render_first_pasted_section_as_list($result{sections}->[0]);
 250   }
 251
 252   $self->invalidate_version->render($self);
 253 }
 254
 255 #
 256 # filters
 257 #
 258
 259 sub setup {
 260   my ($self) = @_;
 261
 262   $::auth->assert('sales_quotation_edit');
 263   $::request->{layout}->use_stylesheet("${_}.css") for qw(jquery.contextMenu requirement_spec);
 264   $::request->{layout}->use_javascript("${_}.js") for qw(jquery.jstree jquery/jquery.contextMenu requirement_spec);
 265   $self->init_visible_section;
 266
 267   return 1;
 268 }
 269
 270 sub init_complexities {
 271   my ($self) = @_;
 272   return SL::DB::Manager::RequirementSpecComplexity->get_all_sorted;
 273 }
 274
 275 sub init_risks {
 276   my ($self) = @_;
 277   return SL::DB::Manager::RequirementSpecRisk->get_all_sorted;
 278 }
 279
 280 sub init_projects {
 281   my ($self) = @_;
 282   $self->projects(SL::DB::Manager::Project->get_all_sorted);
 283 }
 284
 285 sub init_requirement_spec {
 286   my ($self) = @_;
 287   $self->requirement_spec(SL::DB::RequirementSpec->new(id => $::form->{id})->load || die "No such requirement spec") if $::form->{id};
 288 }
 289
 290 sub init_copy_source {
 291   my ($self) = @_;
 292   $self->copy_source(SL::DB::RequirementSpec->new(id => $::form->{copy_source_id})->load) if $::form->{copy_source_id};
 293 }
 294
 295 sub init_js {
 296   my ($self) = @_;
 297   $self->js(SL::ClientJS->new);
 298 }
 299
 300 sub init_current_text_block_output_position {
 301   my ($self) = @_;
 302   $self->current_text_block_output_position($::form->{current_content_type} !~ m/^(?:text-blocks|tb)-(front|back)/ ? -1 : $1 eq 'front' ? 0 : 1);
 303 }
 304
 305 sub load_select_options {
 306   my ($self) = @_;
 307
 308   my @filter = ('!obsolete' => 1);
 309   @filter    = ( or => [ @filter, id => $self->requirement_spec->customer_id ] ) if $self->requirement_spec && $self->requirement_spec->customer_id;
 310
 311   $self->customers(SL::DB::Manager::Customer->get_all_sorted(where => \@filter));
 312   $self->statuses( SL::DB::Manager::RequirementSpecStatus->get_all_sorted);
 313   $self->types(    SL::DB::Manager::RequirementSpecType->get_all_sorted);
 314 }
 315
 316 #
 317 # helpers
 318 #
 319
 320 sub create_or_update {
 321   my $self   = shift;
 322   my $is_new = !$self->requirement_spec->id;
 323   my $params = delete($::form->{requirement_spec}) || { };
 324
 325   $self->requirement_spec->assign_attributes(%{ $params });
 326
 327   my $title  = $is_new && $self->requirement_spec->is_template ? t8('Create a new requirement spec template')
 328              : $is_new                                         ? t8('Create a new requirement spec')
 329              :            $self->requirement_spec->is_template ? t8('Edit requirement spec template')
 330              :                                                   t8('Edit requirement spec');
 331
 332   my @errors = $self->requirement_spec->validate;
 333
 334   if (@errors) {
 335     return $self->js->error(@errors)->render($self) if $::request->is_ajax;
 336
 337     flash('error', @errors);
 338     $self->render('requirement_spec/new', title => $title);
 339     return;
 340   }
 341
 342   my $db = $self->requirement_spec->db;
 343   if (!$db->do_transaction(sub {
 344     if ($self->copy_source) {
 345       $self->requirement_spec($self->copy_source->create_copy(%{ $params }));
 346     } else {
 347       $self->requirement_spec->save;
 348     }
 349   })) {
 350     $::lxdebug->message(LXDebug::WARN(), "Error: " . $db->error);
 351     @errors = ($::locale->text('Saving failed. Error message from the database: #1'), $db->error);
 352     return $self->js->error(@errors)->render($self) if $::request->is_ajax;
 353
 354     $self->requirement_spec->id(undef) if $is_new;
 355     flash('error', @errors);
 356     return $self->render('requirement_spec/new', title => $title);
 357   }
 358
 359   my $info = $self->requirement_spec->is_template ? t8('The requirement spec template has been saved.') : t8('The requirement spec has been saved.');
 360
 361   if ($::request->is_ajax) {
 362     my $header_html = $self->render('requirement_spec/_header', { output => 0 });
 363     my $basics_html = $self->render('requirement_spec/_show_basic_settings', { output => 0 });
 364     return $self->invalidate_version
 365       ->replaceWith('#requirement-spec-header', $header_html)
 366       ->replaceWith('#basic_settings',          $basics_html)
 367       ->remove('#basic_settings_form')
 368       ->flash('info', $info)
 369       ->render($self);
 370   }
 371
 372   flash_later('info', $info);
 373   $self->redirect_to(action => 'show', id => $self->requirement_spec->id);
 374 }
 375
 376 sub prepare_report {
 377   my ($self)      = @_;
 378
 379   my $callback    = $self->get_callback;
 380
 381   my $is_template = $::form->{is_template};
 382   my $report      = SL::ReportGenerator->new(\%::myconfig, $::form);
 383   $self->{report} = $report;
 384
 385   my @columns     = $is_template ? qw(title mtime) : qw(title customer status type projectnumber mtime version);
 386   my @sortable    = $is_template ? qw(title mtime) : qw(title customer status type projectnumber mtime);
 387
 388   my %column_defs = (
 389     title         => { obj_link => sub { $self->url_for(action => 'show', id => $_[0]->id, callback => $callback) } },
 390     mtime         => { sub      => sub { ($_[0]->mtime || $_[0]->itime)->to_kivitendo(precision => 'minute') } },
 391   );
 392
 393   if (!$is_template) {
 394     %column_defs = (
 395       %column_defs,
 396       customer      => { raw_data => sub { $self->presenter->customer($_[0]->customer, display => 'table-cell', callback => $callback) },
 397                          sub      => sub { $_[0]->customer->name } },
 398       projectnumber => { raw_data => sub { $self->presenter->project($_[0]->project, display => 'table-cell', callback => $callback) },
 399                          sub      => sub { $_[0]->project_id ? $_[0]->project->projectnumber : '' } },
 400       status        => { sub      => sub { $_[0]->status->description } },
 401       type          => { sub      => sub { $_[0]->type->description } },
 402       version       => { sub      => sub { $_[0]->version ? $_[0]->version->version_number : t8('Working copy without version') } },
 403     );
 404   }
 405
 406   map { $column_defs{$_}->{text} ||= $::locale->text( $self->get_sort_spec->{$_}->{title} ) } keys %column_defs;
 407
 408   $report->set_options(
 409     std_column_visibility => 1,
 410     controller_class      => 'RequirementSpec',
 411     output_format         => 'HTML',
 412     raw_top_info_text     => $self->render('requirement_spec/report_top',    { output => 0 }, is_template => $is_template),
 413     raw_bottom_info_text  => $self->render('requirement_spec/report_bottom', { output => 0 }),
 414     title                 => $is_template ? t8('Requirement Spec Templates') : t8('Requirement Specs'),
 415     allow_pdf_export      => 1,
 416     allow_csv_export      => 1,
 417   );
 418   $report->set_columns(%column_defs);
 419   $report->set_column_order(@columns);
 420   $report->set_export_options(qw(list filter));
 421   $report->set_options_from_form;
 422   $self->set_report_generator_sort_options(report => $report, sortable_columns => \@sortable);
 423
 424   $self->disable_pagination if $report->{options}{output_format} =~ /^(pdf|csv)$/i;
 425 }
 426
 427 sub invalidate_version {
 428   my ($self) = @_;
 429
 430   my $rspec  = SL::DB::RequirementSpec->new(id => $self->requirement_spec->id)->load;
 431   return $self->js if $rspec->is_template;
 432
 433   $rspec->invalidate_version;
 434
 435   my $html = $self->render('requirement_spec/_version', { output => 0 }, requirement_spec => $rspec);
 436   return $self->js->html('#requirement_spec_version', $html);
 437 }
 438
 439 sub render_pasted_text_block {
 440   my ($self, $text_block, %params) = @_;
 441
 442   if ($self->current_text_block_output_position == $text_block->output_position) {
 443     my $html = $self->render('requirement_spec_text_block/_text_block', { output => 0 }, text_block => $text_block);
 444     $self->js
 445       ->appendTo($html, '#text-block-list')
 446       ->hide('#text-block-list-empty');
 447   }
 448
 449   my $node       = $self->presenter->requirement_spec_text_block_jstree_data($text_block);
 450   my $front_back = $text_block->output_position == 0 ? 'front' : 'back';
 451   $self->js
 452     ->jstree->create_node('#tree', "#tb-${front_back}", 'last', $node)
 453     ->jstree->open_node(  '#tree', "#tb-${front_back}");
 454 }
 455
 456 sub render_pasted_section {
 457   my ($self, $item, $parent_id) = @_;
 458
 459   my $node = $self->presenter->requirement_spec_item_jstree_data($item);
 460   $self->js
 461     ->jstree->create_node('#tree', $parent_id ? "#fb-${parent_id}" : '#sections', 'last', $node)
 462     ->jstree->open_node(  '#tree', $parent_id ? "#fb-${parent_id}" : '#sections');
 463
 464   $self->render_pasted_section($_, $item->id) for @{ $item->children_sorted };
 465 }
 466
 467 sub render_first_pasted_section_as_list {
 468   my ($self, $section, %params) = @_;
 469
 470   my $html = $self->render('requirement_spec_item/_section', { output => 0 }, requirement_spec_item => $section);
 471   $self->js
 472     ->html('#column-content', $html)
 473     ->val( '#current_content_type', $section->item_type)
 474     ->val( '#current_content_id',   $section->id)
 475     ->jstree->select_node('#tree', '#fb-' . $section->id);
 476 }
 477
 478 sub prepare_pictures_for_printing {
 479   my ($self) = @_;
 480
 481   my @files;
 482   my $userspath = File::Spec->rel2abs($::lx_office_conf{paths}->{userspath});
 483   my $target    =  "${userspath}/kivitendo-print-requirement-spec-picture-" . Common::unique_id() . '-';
 484
 485   foreach my $picture (map { @{ $_->pictures } } @{ $self->requirement_spec->text_blocks }) {
 486     my $output_file_name        = $target . $picture->id . '.' . $picture->get_default_file_name_extension;
 487     $picture->{print_file_name} = File::Spec->abs2rel($output_file_name, $userspath);
 488     my $out                     = IO::File->new($output_file_name, 'w') || die("Could not create file " . $output_file_name);
 489     $out->binmode;
 490     $out->print($picture->picture_content);
 491     $out->close;
 492
 493     push @files, $output_file_name;
 494   }
 495
 496   return @files;
 497 }
 498
 499 1;