SL/Controller/RequirementSpec.pm

   1 package SL::Controller::RequirementSpec;
   2
   3 use strict;
   4 use utf8;
   5
   6 use parent qw(SL::Controller::Base);
   7
   8 use SL::ClientJS;
   9 use SL::Controller::Helper::GetModels;
  10 use SL::Controller::Helper::Paginated;
  11 use SL::Controller::Helper::Sorted;
  12 use SL::Controller::Helper::ParseFilter;
  13 use SL::Controller::Helper::ReportGenerator;
  14 use SL::Controller::Helper::RequirementSpec;
  15 use SL::DB::Customer;
  16 use SL::DB::Project;
  17 use SL::DB::RequirementSpecComplexity;
  18 use SL::DB::RequirementSpecRisk;
  19 use SL::DB::RequirementSpecStatus;
  20 use SL::DB::RequirementSpecType;
  21 use SL::DB::RequirementSpec;
  22 use SL::Helper::Flash;
  23 use SL::Locale::String;
  24 use SL::Template::LaTeX;
  25
  26 use Rose::Object::MakeMethods::Generic
  27 (
  28   scalar                  => [ qw(requirement_spec_item customers types statuses db_args flat_filter visible_item visible_section) ],
  29   'scalar --get_set_init' => [ qw(requirement_spec complexities risks projects copy_source js current_text_block_output_position) ],
  30 );
  31
  32 __PACKAGE__->run_before('setup');
  33 __PACKAGE__->run_before('load_select_options',  only => [ qw(new ajax_edit create update list) ]);
  34
  35
  36 __PACKAGE__->get_models_url_params('flat_filter');
  37 __PACKAGE__->make_paginated(
  38   MODEL         => 'RequirementSpec',
  39   PAGINATE_ARGS => 'db_args',
  40   ONLY          => [ qw(list) ],
  41 );
  42
  43 __PACKAGE__->make_sorted(
  44   MODEL         => 'RequirementSpec',
  45   ONLY          => [ qw(list) ],
  46
  47   DEFAULT_BY    => 'customer',
  48   DEFAULT_DIR   => 1,
  49
  50   customer      => t8('Customer'),
  51   title         => t8('Title'),
  52   type          => t8('Requirement Spec Type'),
  53   status        => t8('Requirement Spec Status'),
  54   projectnumber => t8('Project Number'),
  55   version       => t8('Version'),
  56   mtime         => t8('Last modification'),
  57 );
  58
  59 #
  60 # actions
  61 #
  62
  63
  64 sub action_list {
  65   my ($self) = @_;
  66
  67   $self->setup_db_args_from_filter;
  68   $self->flat_filter({ map { $_->{key} => $_->{value} } $::form->flatten_variables('filter') });
  69
  70   $self->prepare_report;
  71
  72   my $requirement_specs = $self->get_models(%{ $self->db_args });
  73
  74   $self->report_generator_list_objects(report => $self->{report}, objects => $requirement_specs);
  75 }
  76
  77 sub action_new {
  78   my ($self) = @_;
  79
  80   $self->requirement_spec(SL::DB::RequirementSpec->new(is_template => $::form->{is_template}));
  81
  82   if ($self->copy_source) {
  83     $self->requirement_spec->$_($self->copy_source->$_) for qw(type_id status_id customer_id title hourly_rate)
  84   }
  85
  86   $self->render('requirement_spec/new', title => $self->requirement_spec->is_template ? t8('Create a new requirement spec template') : t8('Create a new requirement spec'));
  87 }
  88
  89 sub action_ajax_edit {
  90   my ($self) = @_;
  91
  92   $self->render('requirement_spec/_form', { layout => 0 }, submit_as => 'ajax');
  93 }
  94
  95 sub action_ajax_show_time_and_cost_estimate {
  96   my ($self) = @_;
  97
  98   $self->render('requirement_spec/_show_time_and_cost_estimate', { layout => 0 });
  99 }
 100
 101 sub action_ajax_cancel_time_and_cost_estimate {
 102   my ($self) = @_;
 103
 104   my $html   = $self->render('requirement_spec/_show_time_and_cost_estimate', { output => 0 });
 105
 106   $self->js
 107    ->replaceWith('#time_cost_estimate', $html)
 108    ->render($self);
 109 }
 110
 111 sub action_ajax_edit_time_and_cost_estimate {
 112   my ($self) = @_;
 113
 114   my $html   = $self->render('requirement_spec/_edit_time_and_cost_estimate', { output => 0 });
 115
 116   $self->js
 117    ->replaceWith('#time_cost_estimate', $html)
 118    ->render($self);
 119 }
 120
 121 sub action_ajax_save_time_and_cost_estimate {
 122   my ($self) = @_;
 123
 124   $self->requirement_spec->db->do_transaction(sub {
 125     # Make Emacs happy
 126     1;
 127     foreach my $attributes (@{ $::form->{requirement_spec_items} || [] }) {
 128       SL::DB::RequirementSpecItem
 129         ->new(id => delete $attributes->{id})
 130         ->load
 131         ->update_attributes(%{ $attributes });
 132     }
 133
 134     1;
 135   });
 136
 137   $self->requirement_spec(SL::DB::RequirementSpec->new(id => $self->requirement_spec->id)->load);
 138
 139   my $html = $self->render('requirement_spec/_show_time_and_cost_estimate', { output => 0 });
 140   $self->js->replaceWith('#time_cost_estimate', $html);
 141
 142   if ($self->visible_section) {
 143     $html = $self->render('requirement_spec_item/_section', { output => 0 }, requirement_spec_item => $self->visible_section);
 144     $self->js->html('#column-content', $html);
 145   }
 146
 147   $self->js->render($self);
 148 }
 149
 150 sub action_show {
 151   my ($self) = @_;
 152
 153   my $title  = $self->requirement_spec->is_template ? t8('Show requirement spec template') : t8('Show requirement spec');
 154   my $item   = $::form->{requirement_spec_item_id} ? SL::DB::RequirementSpecItem->new(id => $::form->{requirement_spec_item_id})->load : @{ $self->requirement_spec->sections }[0];
 155   $self->requirement_spec_item($item);
 156
 157   $self->render('requirement_spec/show', title => $title);
 158 }
 159
 160 sub action_create {
 161   my ($self) = @_;
 162
 163   $self->requirement_spec(SL::DB::RequirementSpec->new);
 164   $self->create_or_update;
 165 }
 166
 167 sub action_update {
 168   my ($self) = @_;
 169   $self->create_or_update;
 170 }
 171
 172 sub action_destroy {
 173   my ($self) = @_;
 174
 175   if (eval { $self->requirement_spec->delete; 1; }) {
 176     flash_later('info',  t8('The requirement spec has been deleted.'));
 177   } else {
 178     flash_later('error', t8('The requirement spec is in use and cannot be deleted.'));
 179   }
 180
 181   $self->redirect_to(action => 'list');
 182 }
 183
 184 sub action_revert_to {
 185   my ($self, %params) = @_;
 186
 187   return $self->js->error(t8('Cannot revert a versioned copy.'))->render($self) if $self->requirement_spec->working_copy_id;
 188
 189   my $versioned_copy = SL::DB::RequirementSpec->new(id => $::form->{versioned_copy_id})->load;
 190
 191   $self->requirement_spec->copy_from(
 192     $versioned_copy,
 193     version_id => $versioned_copy->version_id,
 194   );
 195
 196   flash_later('info', t8('The requirement spec has been reverted to version #1.', $self->requirement_spec->version->version_number));
 197   $self->js->redirect_to($self->url_for(action => 'show', id => $self->requirement_spec->id))->render($self);
 198 }
 199
 200 sub action_create_pdf {
 201   my ($self, %params) = @_;
 202
 203   my %result = SL::Template::LaTeX->parse_and_create_pdf('requirement_spec.tex', SELF => $self, rspec => $self->requirement_spec);
 204
 205   $::form->error(t8('Conversion to PDF failed: #1', $result{error})) if $result{error};
 206
 207   my $attachment_name  =  $self->requirement_spec->type->description . ' ' . ($self->requirement_spec->working_copy_id || $self->requirement_spec->id);
 208   $attachment_name    .=  ' (v' . $self->requirement_spec->version->version_number . ')' if $self->requirement_spec->version;
 209   $attachment_name    .=  '.pdf';
 210   $attachment_name     =~ s/[^\wäöüÄÖÜß \-\+\(\)\[\]\{\}\.,]+/_/g;
 211
 212   $self->send_file($result{file_name}, type => 'application/pdf', name => $attachment_name);
 213   unlink $result{file_name};
 214 }
 215
 216 sub action_select_template_to_paste {
 217   my ($self) = @_;
 218
 219   my @templates = grep { @{ $_->sections } || @{ $_->text_blocks } } @{ SL::DB::Manager::RequirementSpec->get_all(where => [ is_template => 1 ], sort_by => 'lower(title)') };
 220   $self->render('requirement_spec/select_template_to_paste', { layout => 0 }, TEMPLATES => \@templates);
 221 }
 222
 223 sub action_paste_template {
 224   my ($self, %params) = @_;
 225
 226   my $template = SL::DB::RequirementSpec->new(id => $::form->{template_id})->load;
 227   my %result   = $self->requirement_spec->paste_template($template);
 228
 229   return $self->js->error($self->requirement_spec->error)->render($self) if !%result;
 230
 231   $self->render_pasted_text_block($_) for sort { $a->position <=> $b->position } @{ $result{text_blocks} };
 232   $self->render_pasted_section($_)    for sort { $a->position <=> $b->position } @{ $result{sections}    };
 233
 234   if (@{ $result{sections} } && (($::form->{current_content_type} || 'sections') eq 'sections') && !$::form->{current_content_id}) {
 235     $self->render_first_pasted_section_as_list($result{sections}->[0]);
 236   }
 237
 238   $self->invalidate_version->render($self);
 239 }
 240
 241 #
 242 # filters
 243 #
 244
 245 sub setup {
 246   my ($self) = @_;
 247
 248   $::auth->assert('sales_quotation_edit');
 249   $::request->{layout}->use_stylesheet("${_}.css") for qw(jquery.contextMenu requirement_spec);
 250   $::request->{layout}->use_javascript("${_}.js") for qw(jquery.jstree jquery/jquery.contextMenu client_js requirement_spec);
 251   $self->init_visible_section;
 252
 253   return 1;
 254 }
 255
 256 sub init_complexities {
 257   my ($self) = @_;
 258   return SL::DB::Manager::RequirementSpecComplexity->get_all_sorted;
 259 }
 260
 261 sub init_risks {
 262   my ($self) = @_;
 263   return SL::DB::Manager::RequirementSpecRisk->get_all_sorted;
 264 }
 265
 266 sub init_projects {
 267   my ($self) = @_;
 268   $self->projects(SL::DB::Manager::Project->get_all_sorted);
 269 }
 270
 271 sub init_requirement_spec {
 272   my ($self) = @_;
 273   $self->requirement_spec(SL::DB::RequirementSpec->new(id => $::form->{id})->load || die "No such requirement spec") if $::form->{id};
 274 }
 275
 276 sub init_copy_source {
 277   my ($self) = @_;
 278   $self->copy_source(SL::DB::RequirementSpec->new(id => $::form->{copy_source_id})->load) if $::form->{copy_source_id};
 279 }
 280
 281 sub init_js {
 282   my ($self) = @_;
 283   $self->js(SL::ClientJS->new);
 284 }
 285
 286 sub init_current_text_block_output_position {
 287   my ($self) = @_;
 288   $self->current_text_block_output_position($::form->{current_content_type} !~ m/^(?:text-blocks|tb)-(front|back)/ ? -1 : $1 eq 'front' ? 0 : 1);
 289 }
 290
 291 sub load_select_options {
 292   my ($self) = @_;
 293
 294   my @filter = ('!obsolete' => 1);
 295   @filter    = ( or => [ @filter, id => $self->requirement_spec->customer_id ] ) if $self->requirement_spec && $self->requirement_spec->customer_id;
 296
 297   $self->customers(SL::DB::Manager::Customer->get_all_sorted(where => \@filter));
 298   $self->statuses( SL::DB::Manager::RequirementSpecStatus->get_all_sorted);
 299   $self->types(    SL::DB::Manager::RequirementSpecType->get_all_sorted);
 300 }
 301
 302 #
 303 # helpers
 304 #
 305
 306 sub create_or_update {
 307   my $self   = shift;
 308   my $is_new = !$self->requirement_spec->id;
 309   my $params = delete($::form->{requirement_spec}) || { };
 310
 311   $self->requirement_spec->assign_attributes(%{ $params });
 312
 313   my $title  = $is_new && $self->requirement_spec->is_template ? t8('Create a new requirement spec template')
 314              : $is_new                                         ? t8('Create a new requirement spec')
 315              :            $self->requirement_spec->is_template ? t8('Edit requirement spec template')
 316              :                                                   t8('Edit requirement spec');
 317
 318   my @errors = $self->requirement_spec->validate;
 319
 320   if (@errors) {
 321     return $self->js->error(@errors)->render($self) if $::request->is_ajax;
 322
 323     flash('error', @errors);
 324     $self->render('requirement_spec/new', title => $title);
 325     return;
 326   }
 327
 328   my $db = $self->requirement_spec->db;
 329   if (!$db->do_transaction(sub {
 330     if ($self->copy_source) {
 331       $self->requirement_spec($self->copy_source->create_copy(%{ $params }));
 332     } else {
 333       $self->requirement_spec->save;
 334     }
 335   })) {
 336     $::lxdebug->message(LXDebug::WARN(), "Error: " . $db->error);
 337     @errors = ($::locale->text('Saving failed. Error message from the database: #1'), $db->error);
 338     return $self->js->error(@errors)->render($self) if $::request->is_ajax;
 339
 340     $self->requirement_spec->id(undef) if $is_new;
 341     flash('error', @errors);
 342     return $self->render('requirement_spec/new', title => $title);
 343   }
 344
 345   my $info = $self->requirement_spec->is_template ? t8('The requirement spec template has been saved.') : t8('The requirement spec has been saved.');
 346
 347   if ($::request->is_ajax) {
 348     my $html = $self->render('requirement_spec/_header', { output => 0 });
 349     return $self->invalidate_version
 350       ->replaceWith('#requirement-spec-header', $html)
 351       ->flash('info', $info)
 352       ->render($self);
 353   }
 354
 355   flash_later('info', $info);
 356   $self->redirect_to(action => 'show', id => $self->requirement_spec->id);
 357 }
 358
 359 sub setup_db_args_from_filter {
 360   my ($self) = @_;
 361
 362   $self->{filter} = {};
 363   my %args = parse_filter(
 364     $::form->{filter},
 365     with_objects => [ 'customer', 'type', 'status', 'project' ],
 366     launder_to   => $self->{filter},
 367   );
 368
 369   $args{where} = [
 370     and => [
 371       @{ $args{where} || [] },
 372       working_copy_id => undef,
 373       is_template     => $::form->{is_template} ? 1 : 0,
 374     ]];
 375
 376   $self->db_args(\%args);
 377 }
 378
 379 sub prepare_report {
 380   my ($self)      = @_;
 381
 382   my $callback    = $self->get_callback;
 383
 384   my $is_template = $::form->{is_template};
 385   my $report      = SL::ReportGenerator->new(\%::myconfig, $::form);
 386   $self->{report} = $report;
 387
 388   my @columns     = $is_template ? qw(title mtime) : qw(title customer status type projectnumber mtime version);
 389   my @sortable    = $is_template ? qw(title mtime) : qw(title customer status type projectnumber mtime);
 390
 391   my %column_defs = (
 392     title         => { obj_link => sub { $self->url_for(action => 'show', id => $_[0]->id, callback => $callback) } },
 393     mtime         => { sub      => sub { ($_[0]->mtime || $_[0]->itime)->to_kivitendo(precision => 'minute') } },
 394   );
 395
 396   if (!$is_template) {
 397     %column_defs = (
 398       %column_defs,
 399       customer      => { raw_data => sub { $self->presenter->customer($_[0]->customer, display => 'table-cell', callback => $callback) },
 400                          sub      => sub { $_[0]->customer->name } },
 401       projectnumber => { raw_data => sub { $self->presenter->project($_[0]->project, display => 'table-cell', callback => $callback) },
 402                          sub      => sub { $_[0]->project_id ? $_[0]->project->projectnumber : '' } },
 403       status        => { sub      => sub { $_[0]->status->description } },
 404       type          => { sub      => sub { $_[0]->type->description } },
 405       version       => { sub      => sub { $_[0]->version_id ? $_[0]->version->version_number : t8('Working copy without version') } },
 406     );
 407   }
 408
 409   map { $column_defs{$_}->{text} ||= $::locale->text( $self->get_sort_spec->{$_}->{title} ) } keys %column_defs;
 410
 411   $report->set_options(
 412     std_column_visibility => 1,
 413     controller_class      => 'RequirementSpec',
 414     output_format         => 'HTML',
 415     raw_top_info_text     => $self->render('requirement_spec/report_top',    { output => 0 }, is_template => $is_template),
 416     raw_bottom_info_text  => $self->render('requirement_spec/report_bottom', { output => 0 }),
 417     title                 => $is_template ? t8('Requirement Spec Templates') : t8('Requirement Specs'),
 418     allow_pdf_export      => 1,
 419     allow_csv_export      => 1,
 420   );
 421   $report->set_columns(%column_defs);
 422   $report->set_column_order(@columns);
 423   $report->set_export_options(qw(list filter));
 424   $report->set_options_from_form;
 425   $self->set_report_generator_sort_options(report => $report, sortable_columns => \@sortable);
 426
 427   $self->disable_pagination if $report->{options}{output_format} =~ /^(pdf|csv)$/i;
 428 }
 429
 430 sub invalidate_version {
 431   my ($self) = @_;
 432
 433   my $rspec  = SL::DB::RequirementSpec->new(id => $self->requirement_spec->id)->load;
 434   return $self->js if $rspec->is_template;
 435
 436   $rspec->invalidate_version;
 437
 438   my $html = $self->render('requirement_spec/_version', { output => 0 }, requirement_spec => $rspec);
 439   return $self->js->html('#requirement_spec_version', $html);
 440 }
 441
 442 sub render_pasted_text_block {
 443   my ($self, $text_block, %params) = @_;
 444
 445   if ($self->current_text_block_output_position == $text_block->output_position) {
 446     my $html = $self->render('requirement_spec_text_block/_text_block', { output => 0 }, text_block => $text_block);
 447     $self->js
 448       ->appendTo($html, '#text-block-list')
 449       ->hide('#text-block-list-empty');
 450   }
 451
 452   my $node       = $self->presenter->requirement_spec_text_block_jstree_data($text_block);
 453   my $front_back = $text_block->output_position == 0 ? 'front' : 'back';
 454   $self->js
 455     ->jstree->create_node('#tree', "#tb-${front_back}", 'last', $node)
 456     ->jstree->open_node(  '#tree', "#tb-${front_back}");
 457 }
 458
 459 sub render_pasted_section {
 460   my ($self, $item, $parent_id) = @_;
 461
 462   my $node = $self->presenter->requirement_spec_item_jstree_data($item);
 463   $self->js
 464     ->jstree->create_node('#tree', $parent_id ? "#fb-${parent_id}" : '#sections', 'last', $node)
 465     ->jstree->open_node(  '#tree', $parent_id ? "#fb-${parent_id}" : '#sections');
 466
 467   $self->render_pasted_section($_, $item->id) for @{ $item->children_sorted };
 468 }
 469
 470 sub render_first_pasted_section_as_list {
 471   my ($self, $section, %params) = @_;
 472
 473   my $html = $self->render('requirement_spec_item/_section', { output => 0 }, requirement_spec_item => $section);
 474   $self->js
 475     ->html('#column-content', $html)
 476     ->val( '#current_content_type', $section->item_type)
 477     ->val( '#current_content_id',   $section->id)
 478     ->jstree->select_node('#tree', '#fb-' . $section->id);
 479 }
 480
 481 1;