SL/Controller/RequirementSpec.pm

   1 package SL::Controller::RequirementSpec;
   2
   3 use strict;
   4 use utf8;
   5
   6 use parent qw(SL::Controller::Base);
   7
   8 use File::Spec ();
   9
  10 use SL::Common ();
  11 use SL::Controller::Helper::GetModels;
  12 use SL::Controller::Helper::ReportGenerator;
  13 use SL::Controller::Helper::RequirementSpec;
  14 use SL::DB::Customer;
  15 use SL::DB::Project;
  16 use SL::DB::ProjectStatus;
  17 use SL::DB::ProjectType;
  18 use SL::DB::RequirementSpecComplexity;
  19 use SL::DB::RequirementSpecRisk;
  20 use SL::DB::RequirementSpecStatus;
  21 use SL::DB::RequirementSpecType;
  22 use SL::DB::RequirementSpec;
  23 use SL::Helper::CreatePDF qw();
  24 use SL::Helper::Flash;
  25 use SL::Locale::String;
  26 use SL::Template::LaTeX;
  27
  28 use Rose::Object::MakeMethods::Generic
  29 (
  30   scalar                  => [ qw(requirement_spec_item visible_item visible_section) ],
  31   'scalar --get_set_init' => [ qw(requirement_spec customers types statuses complexities risks projects project_types project_statuses default_project_type default_project_status copy_source
  32                                   current_text_block_output_position models time_based_units html_template cvar_configs includeable_cvar_configs include_cvars) ],
  33 );
  34
  35 __PACKAGE__->run_before('setup');
  36 __PACKAGE__->run_before('set_default_filter_args', only => [ qw(list) ]);
  37
  38 my %sort_columns = (
  39   customer      => t8('Customer'),
  40   title         => t8('Title'),
  41   type          => t8('Requirement Spec Type'),
  42   status        => t8('Requirement Spec Status'),
  43   projectnumber => t8('Project Number'),
  44   version       => t8('Version'),
  45   mtime         => t8('Last modification'),
  46 );
  47
  48 #
  49 # actions
  50 #
  51
  52
  53 sub action_list {
  54   my ($self) = @_;
  55
  56   $self->prepare_report;
  57   $self->report_generator_list_objects(report => $self->{report}, objects => $self->models->get);
  58 }
  59
  60 sub action_new {
  61   my ($self) = @_;
  62
  63   $self->requirement_spec(SL::DB::RequirementSpec->new(is_template => $::form->{is_template}));
  64
  65   if ($self->copy_source) {
  66     $self->requirement_spec->$_($self->copy_source->$_) for qw(type_id status_id customer_id title hourly_rate is_template)
  67   }
  68
  69   $self->_setup_form_action_bar;
  70
  71   $self->render('requirement_spec/new', title => $self->requirement_spec->is_template ? t8('Create a new requirement spec template') : t8('Create a new requirement spec'));
  72 }
  73
  74 sub action_ajax_show_basic_settings {
  75   my ($self) = @_;
  76
  77   $self->render('requirement_spec/_show_basic_settings', { layout => 0 });
  78 }
  79
  80 sub action_ajax_edit {
  81   my ($self) = @_;
  82
  83   my $html   = $self->render('requirement_spec/_form', { output => 0 }, submit_as => 'ajax');
  84
  85   $self->js
  86     ->hide('#basic_settings')
  87     ->after('#basic_settings', $html)
  88     ->render;
  89 }
  90
  91 sub action_ajax_edit_project_link {
  92   my ($self) = @_;
  93
  94   my $html   = $self->render('requirement_spec/_project_link_form', { output => 0 }, submit_as => 'ajax');
  95
  96   $self->js
  97     ->hide('#basic_settings')
  98     ->after('#basic_settings', $html)
  99     ->render;
 100 }
 101
 102 sub action_ajax_show_time_and_cost_estimate {
 103   my ($self) = @_;
 104
 105   $self->render('requirement_spec/_show_time_and_cost_estimate', { layout => 0 });
 106 }
 107
 108 sub action_ajax_edit_time_and_cost_estimate {
 109   my ($self) = @_;
 110
 111   my $html   = $self->render('requirement_spec/_edit_time_and_cost_estimate', { output => 0 });
 112   my $first  = ($self->requirement_spec->sections_sorted || [])->[0];
 113   $first     = ($first->children_sorted || [])->[0] if $first;
 114
 115   $self->js
 116    ->hide('#time_cost_estimate')
 117    ->after('#time_cost_estimate', $html)
 118    ->on('#time_cost_estimate INPUT[type=text]', 'keydown', 'kivi.requirement_spec.time_cost_estimate_input_key_down')
 119    ->action_if($first && $first->id, 'focus', '#time_and_cost_estimate_form_complexity_id_' . $first->id)
 120    ->render;
 121 }
 122
 123 sub action_ajax_save_time_and_cost_estimate {
 124   my ($self) = @_;
 125
 126   $self->requirement_spec->db->with_transaction(sub {
 127     # Make Emacs happy
 128     1;
 129     foreach my $attributes (@{ $::form->{requirement_spec_items} || [] }) {
 130       SL::DB::RequirementSpecItem
 131         ->new(id => delete $attributes->{id})
 132         ->load
 133         ->update_attributes(%{ $attributes });
 134     }
 135
 136     1;
 137   });
 138
 139   $self->requirement_spec(SL::DB::RequirementSpec->new(id => $self->requirement_spec->id)->load);
 140
 141   my $html = $self->render('requirement_spec/_show_time_and_cost_estimate', { output => 0 }, initially_hidden => !!$::form->{keep_open});
 142   $self->js->replaceWith('#time_cost_estimate', $html);
 143
 144   return $self->js->render if $::form->{keep_open};
 145
 146   $self->js->remove('#time_cost_estimate_form_container');
 147
 148   if ($self->visible_section) {
 149     $html = $self->render('requirement_spec_item/_section', { output => 0 }, requirement_spec_item => $self->visible_section);
 150     $self->js->html('#column-content', $html);
 151   }
 152
 153   $self->js->render;
 154 }
 155
 156 sub action_show {
 157   my ($self) = @_;
 158
 159   my $title  = $self->requirement_spec->is_template ? t8('Show requirement spec template') : t8('Show requirement spec');
 160   my $item   = $::form->{requirement_spec_item_id} ? SL::DB::RequirementSpecItem->new(id => $::form->{requirement_spec_item_id})->load : @{ $self->requirement_spec->sections_sorted }[0];
 161   $self->requirement_spec_item($item);
 162
 163   $self->render('requirement_spec/show', title => $title);
 164 }
 165
 166 sub action_create {
 167   my ($self) = @_;
 168
 169   $self->requirement_spec(SL::DB::RequirementSpec->new);
 170   $self->create_or_update;
 171 }
 172
 173 sub action_update {
 174   my ($self) = @_;
 175   $self->create_or_update;
 176 }
 177
 178 sub action_update_project_link {
 179   my $self   = shift;
 180   my $action = delete($::form->{project_link_action}) || 'keep';
 181
 182   return $self->update_project_link_none_keep_existing($action) if $action =~ m{none|keep|existing};
 183   return $self->update_project_link_new($action)                if $action eq 'new';
 184   return $self->update_project_link_create($action)             if $action eq 'create';
 185
 186   die "Unknown project link action '$action'";
 187 }
 188
 189 sub action_destroy {
 190   my ($self) = @_;
 191
 192   if (eval { $self->requirement_spec->delete; 1; }) {
 193     flash_later('info',  t8('The requirement spec has been deleted.'));
 194   } else {
 195     flash_later('error', t8('The requirement spec is in use and cannot be deleted.'));
 196   }
 197
 198   $self->redirect_to(action => 'list');
 199 }
 200
 201 sub action_revert_to {
 202   my ($self, %params) = @_;
 203
 204   return $self->js->error(t8('Cannot revert a versioned copy.'))->render if $self->requirement_spec->working_copy_id;
 205
 206   my $versioned_copy = SL::DB::RequirementSpec->new(id => $::form->{versioned_copy_id})->load;
 207
 208   $self->requirement_spec->copy_from($versioned_copy);
 209   my $version = $versioned_copy->versions->[0];
 210   $version->update_attributes(working_copy_id => $self->requirement_spec->id);
 211
 212   flash_later('info', t8('The requirement spec has been reverted to version #1.', $versioned_copy->version->version_number));
 213   $self->js->redirect_to($self->url_for(action => 'show', id => $self->requirement_spec->id))->render;
 214 }
 215
 216 sub action_create_pdf {
 217   my ($self, %params) = @_;
 218
 219   my $base_name       = $self->requirement_spec->type->template_file_name || 'requirement_spec';
 220   my @pictures        = $self->prepare_pictures_for_printing;
 221   my %result          = SL::Template::LaTeX->parse_and_create_pdf("${base_name}.tex", SELF => $self, rspec => $self->requirement_spec);
 222
 223   unlink @pictures unless ($::lx_office_conf{debug} || {})->{keep_temp_files};
 224
 225   $::form->error(t8('Conversion to PDF failed: #1', $result{error})) if $result{error};
 226
 227   my $attachment_name  =  $self->requirement_spec->type->description . ' ' . ($self->requirement_spec->working_copy_id || $self->requirement_spec->id);
 228   $attachment_name    .=  ' (v' . $self->requirement_spec->version->version_number . ')' if $self->requirement_spec->version;
 229   $attachment_name    .=  '.pdf';
 230   $attachment_name     =~ s/[^\wäöüÄÖÜß \-\+\(\)\[\]\{\}\.,]+/_/g;
 231
 232   $self->send_file($result{file_name}, type => 'application/pdf', name => $attachment_name);
 233   unlink $result{file_name};
 234 }
 235
 236 sub action_create_html {
 237   my ($self, %params) = @_;
 238
 239   my $base_name       = $self->requirement_spec->type->template_file_name || 'requirement_spec';
 240   my @pictures        = $self->prepare_pictures_for_printing;
 241   my $content         = SL::Helper::CreatePDF->create_parsed_file(
 242     template      => "${base_name}.html",
 243     format        => 'html',
 244     template_type => 'HTML',
 245     variables     => {
 246       SELF        => $self,
 247       rspec       => $self->requirement_spec,
 248     });
 249
 250   # $content is now a scalar of bytes, but $self->render() expects a
 251   # scalar of characters.
 252   $content = Encode::decode('utf-8', $content);
 253
 254   $self->render(\$content, { layout => 0, process => 0 });
 255 }
 256
 257 sub action_select_template_to_paste {
 258   my ($self) = @_;
 259
 260   my @templates = @{ SL::DB::Manager::RequirementSpec->get_all(
 261     where   => [ is_template => 1, SL::DB::Manager::RequirementSpec->not_empty_filter ],
 262     sort_by => 'lower(requirement_specs.title)',
 263   ) };
 264   $self->render('requirement_spec/select_template_to_paste', { layout => 0 }, TEMPLATES => \@templates);
 265 }
 266
 267 sub action_paste_template {
 268   my ($self, %params) = @_;
 269
 270   my $template = SL::DB::RequirementSpec->new(id => $::form->{template_id})->load;
 271   my %result   = $self->requirement_spec->paste_template($template);
 272
 273   return $self->js->error($self->requirement_spec->error)->render if !%result;
 274
 275   $self->render_pasted_text_block($_) for sort { $a->position <=> $b->position } @{ $result{text_blocks} };
 276   $self->render_pasted_section($_)    for sort { $a->position <=> $b->position } @{ $result{sections}    };
 277
 278   if (@{ $result{sections} } && (($::form->{current_content_type} || 'sections') eq 'sections') && !$::form->{current_content_id}) {
 279     $self->render_first_pasted_section_as_list($result{sections}->[0]);
 280   }
 281
 282   my $parts_list = $self->render('requirement_spec_part/show', { output => 0 });
 283   $self->js
 284     ->replaceWith('#additional_parts_list_container', $parts_list)
 285     ->show(       '#additional_parts_list_container')
 286     ->remove(     '#additional_parts_form_container');
 287
 288   $self->invalidate_version->render;
 289 }
 290
 291 sub action_renumber_sections {
 292   my ($self)  = @_;
 293
 294   my %numbers = map { ($_ => 1)                                                                         } qw(section function_block);
 295   my %formats = map { my $method = "${_}_number_format"; ($_ => $self->requirement_spec->type->$method) } qw(section function_block);
 296   my @items   = @{ $self->requirement_spec->sections_sorted };
 297
 298   $self->requirement_spec->db->with_transaction(sub {
 299     while (@items) {
 300       my $item = shift @items;
 301       my $type = $item->parent_id ? 'function_block' : 'section';
 302
 303       $item->update_attributes(fb_number => SL::PrefixedNumber->new(number => $formats{$type} || 0)->set_to($numbers{$type}));
 304
 305       $numbers{$type}++;
 306
 307       unshift @items, @{ $item->children_sorted };
 308     }
 309
 310     $self->requirement_spec->invalidate_version unless $self->requirement_spec->is_template;
 311
 312     1;
 313   });
 314
 315   $self->redirect_to(action => 'show', id => $self->requirement_spec->id);
 316 }
 317
 318 #
 319 # filters
 320 #
 321
 322 sub setup {
 323   my ($self) = @_;
 324
 325   $::auth->assert('requirement_spec_edit');
 326   $::request->{layout}->use_stylesheet("${_}.css") for qw(jquery.contextMenu requirement_spec);
 327   $::request->{layout}->use_javascript("${_}.js")  for qw(jquery.jstree jquery/jquery.contextMenu jquery/jquery.hotkeys requirement_spec ckeditor/ckeditor ckeditor/adapters/jquery kivi.Part.js autocomplete_customer);
 328   $self->init_visible_section;
 329
 330   return 1;
 331 }
 332
 333 sub init_complexities           { SL::DB::Manager::RequirementSpecComplexity->get_all_sorted  }
 334 sub init_default_project_status { SL::DB::Manager::ProjectStatus->find_by(name => 'planning') }
 335 sub init_default_project_type   { SL::DB::ProjectType->new(id => 1)->load                     }
 336 sub init_project_statuses       { SL::DB::Manager::ProjectStatus->get_all_sorted              }
 337 sub init_project_types          { SL::DB::Manager::ProjectType->get_all_sorted                }
 338 sub init_projects               { SL::DB::Manager::Project->get_all_sorted                    }
 339 sub init_risks                  { SL::DB::Manager::RequirementSpecRisk->get_all_sorted        }
 340 sub init_statuses               { SL::DB::Manager::RequirementSpecStatus->get_all_sorted      }
 341 sub init_time_based_units       { SL::DB::Manager::Unit->time_based_units                     }
 342 sub init_types                  { SL::DB::Manager::RequirementSpecType->get_all_sorted        }
 343 sub init_cvar_configs           { SL::DB::Manager::CustomVariableConfig->get_all_sorted(where => [ module => 'RequirementSpecs' ]) }
 344
 345 sub init_customers {
 346   my ($self) = @_;
 347
 348   my @filter = ('!obsolete' => 1);
 349   @filter    = ( or => [ @filter, id => $self->requirement_spec->customer_id ] ) if $self->requirement_spec && $self->requirement_spec->customer_id;
 350
 351   return SL::DB::Manager::Customer->get_all_sorted(where => \@filter);
 352 }
 353
 354 sub init_requirement_spec {
 355   my ($self) = @_;
 356   $self->requirement_spec(SL::DB::RequirementSpec->new(id => $::form->{id})->load || die "No such requirement spec") if $::form->{id};
 357 }
 358
 359 sub init_copy_source {
 360   my ($self) = @_;
 361   $self->copy_source(SL::DB::RequirementSpec->new(id => $::form->{copy_source_id})->load) if $::form->{copy_source_id};
 362 }
 363
 364 sub init_current_text_block_output_position {
 365   my ($self) = @_;
 366   $self->current_text_block_output_position($::form->{current_content_type} !~ m/^(?:text-blocks|tb)-(front|back)/ ? -1 : $1 eq 'front' ? 0 : 1);
 367 }
 368
 369 sub init_includeable_cvar_configs {
 370   my ($self) = @_;
 371   return [ grep { $_->includeable } @{ $self->cvar_configs } ];
 372 }
 373
 374 sub init_include_cvars {
 375   my ($self) = @_;
 376   return $::form->{include_cvars} if $::form->{include_cvars} && (ref($::form->{include_cvars}) eq 'HASH');
 377   return { map { ($_->name => ($_->includeable && $_->included_by_default)) } @{ $self->cvar_configs } };
 378 }
 379
 380 #
 381 # helpers
 382 #
 383
 384 sub create_or_update {
 385   my $self   = shift;
 386   my $is_new = !$self->requirement_spec->id;
 387   my $params = delete($::form->{requirement_spec}) || { };
 388   my $cvars  = delete($::form->{cvars})            || { };
 389
 390   # Forcefully make it clear to Rose which custom_variables exist (or don't), so that the ones added with »add_custom_variables« are visible when calling »custom_variables«.
 391   if ($is_new) {
 392     $params->{custom_variables} = [];
 393   } else {
 394     $self->requirement_spec->custom_variables;
 395   }
 396
 397   $self->requirement_spec->assign_attributes(%{ $params });
 398
 399   foreach my $var (@{ $self->requirement_spec->cvars_by_config }) {
 400     my $value = $cvars->{ $var->config->name };
 401     $value    = $::form->parse_amount(\%::myconfig, $value) if $var->config->type eq 'number';
 402
 403     $var->value($value);
 404   }
 405
 406   my $title  = $is_new && $self->requirement_spec->is_template ? t8('Create a new requirement spec template')
 407              : $is_new                                         ? t8('Create a new requirement spec')
 408              :            $self->requirement_spec->is_template ? t8('Edit requirement spec template')
 409              :                                                   t8('Edit requirement spec');
 410
 411   my @errors = $self->requirement_spec->validate;
 412
 413   if (@errors) {
 414     return $self->js->error(@errors)->render if $::request->is_ajax;
 415
 416     flash('error', @errors);
 417     $self->render('requirement_spec/new', title => $title);
 418     return;
 419   }
 420
 421   my $db = $self->requirement_spec->db;
 422   if (!$db->with_transaction(sub {
 423     if ($self->copy_source) {
 424       $self->requirement_spec($self->copy_source->create_copy(%{ $params }));
 425     } else {
 426       $self->requirement_spec->save(cascade => 1);
 427     }
 428     1;
 429   })) {
 430     $::lxdebug->message(LXDebug::WARN(), "Error: " . $db->error);
 431     @errors = ($::locale->text('Saving failed. Error message from the database: #1', $db->error));
 432     return $self->js->error(@errors)->render if $::request->is_ajax;
 433
 434     $self->requirement_spec->id(undef) if $is_new;
 435     flash('error', @errors);
 436     return $self->render('requirement_spec/new', title => $title);
 437   }
 438
 439   my $info = $self->requirement_spec->is_template ? t8('The requirement spec template has been saved.') : t8('The requirement spec has been saved.');
 440
 441   if ($::request->is_ajax) {
 442     my $header_html = $self->render('requirement_spec/_header', { output => 0 });
 443     my $basics_html = $self->render('requirement_spec/_show_basic_settings', { output => 0 });
 444     return $self->invalidate_version
 445       ->replaceWith('#requirement-spec-header', $header_html)
 446       ->replaceWith('#basic_settings',          $basics_html)
 447       ->remove('#basic_settings_form')
 448       ->flash('info', $info)
 449       ->render;
 450   }
 451
 452   flash_later('info', $info);
 453   $self->redirect_to(action => 'show', id => $self->requirement_spec->id);
 454 }
 455
 456 sub prepare_report {
 457   my ($self)      = @_;
 458
 459   my $is_template = $::form->{is_template};
 460   my $report      = SL::ReportGenerator->new(\%::myconfig, $::form);
 461
 462   $self->models->disable_plugin('paginated') if $report->{options}{output_format} =~ /^(pdf|csv)$/i;
 463   $self->models->finalize; # for filter laundering
 464   my $callback    = $self->models->get_callback;
 465
 466   $self->{report} = $report;
 467
 468   my @columns     = $is_template ? qw(title mtime) : qw(title customer status type projectnumber mtime version);
 469   my @sortable    = $is_template ? qw(title mtime) : qw(title customer status type projectnumber mtime);
 470
 471   my %column_defs = (
 472     title         => { obj_link => sub { $self->url_for(action => 'show', id => $_[0]->id, callback => $callback) } },
 473     mtime         => { sub      => sub { ($_[0]->mtime || $_[0]->itime)->to_kivitendo(precision => 'minute') } },
 474   );
 475
 476   if (!$is_template) {
 477     %column_defs = (
 478       %column_defs,
 479       customer      => { raw_data => sub { $self->presenter->customer($_[0]->customer, display => 'table-cell', callback => $callback) },
 480                          sub      => sub { $_[0]->customer->name } },
 481       projectnumber => { raw_data => sub { $self->presenter->project($_[0]->project, display => 'table-cell', callback => $callback) },
 482                          sub      => sub { $_[0]->project_id ? $_[0]->project->projectnumber : '' } },
 483       status        => { sub      => sub { $_[0]->status->description } },
 484       type          => { sub      => sub { $_[0]->type->description } },
 485       version       => { sub      => sub { $_[0]->version ? $_[0]->version->version_number : t8('Working copy without version') } },
 486     );
 487   }
 488
 489   $column_defs{$_}->{text} ||= $::locale->text( $self->models->get_sort_spec->{$_}->{title} ) for keys %column_defs;
 490
 491   if (!$is_template) {
 492     my %cvar_column_defs = map {
 493       my $cfg = $_;
 494       (('cvar_' . $cfg->name) => {
 495         sub     => sub { my $var = $_[0]->cvar_by_name($cfg->name); $var ? $var->value_as_text : '' },
 496         text    => $cfg->description,
 497         visible => $self->include_cvars->{ $cfg->name } ? 1 : 0,
 498       })
 499     } @{ $self->includeable_cvar_configs };
 500
 501     push @columns, map { 'cvar_' . $_->name } @{ $self->includeable_cvar_configs };
 502     %column_defs = (%column_defs, %cvar_column_defs);
 503   }
 504
 505   $report->set_options(
 506     std_column_visibility => 1,
 507     controller_class      => 'RequirementSpec',
 508     output_format         => 'HTML',
 509     raw_top_info_text     => $self->render('requirement_spec/report_top',    { output => 0 }, is_template => $is_template),
 510     raw_bottom_info_text  => $self->render('requirement_spec/report_bottom', { output => 0 }, models => $self->models),
 511     title                 => $is_template ? t8('Requirement Spec Templates') : t8('Requirement Specs'),
 512     allow_pdf_export      => 1,
 513     allow_csv_export      => 1,
 514   );
 515   $report->set_columns(%column_defs);
 516   $report->set_column_order(@columns);
 517   $report->set_export_options(qw(list filter));
 518   $report->set_options_from_form;
 519   $self->models->set_report_generator_sort_options(report => $report, sortable_columns => \@sortable);
 520 }
 521
 522 sub invalidate_version {
 523   my ($self) = @_;
 524
 525   my $rspec  = SL::DB::RequirementSpec->new(id => $self->requirement_spec->id)->load;
 526   return $self->js if $rspec->is_template;
 527
 528   $rspec->invalidate_version;
 529
 530   my $html = $self->render('requirement_spec/_version', { output => 0 }, requirement_spec => $rspec);
 531   return $self->js->html('#requirement_spec_version', $html);
 532 }
 533
 534 sub render_pasted_text_block {
 535   my ($self, $text_block, %params) = @_;
 536
 537   if ($self->current_text_block_output_position == $text_block->output_position) {
 538     my $html = $self->render('requirement_spec_text_block/_text_block', { output => 0 }, text_block => $text_block);
 539     $self->js
 540       ->appendTo($html, '#text-block-list')
 541       ->hide('#text-block-list-empty');
 542   }
 543
 544   my $node       = $self->presenter->requirement_spec_text_block_jstree_data($text_block);
 545   my $front_back = $text_block->output_position == 0 ? 'front' : 'back';
 546   $self->js
 547     ->jstree->create_node('#tree', "#tb-${front_back}", 'last', $node)
 548     ->jstree->open_node(  '#tree', "#tb-${front_back}");
 549 }
 550
 551 sub set_default_filter_args {
 552   my ($self) = @_;
 553
 554   if (!$::form->{filter} && !$::form->{is_template}) {
 555     $::form->{filter} = {
 556       status_id => [ map { $_->{id} } grep { $_->name ne 'done' } @{ $self->statuses } ],
 557     };
 558   }
 559
 560   return 1;
 561 }
 562
 563 sub render_pasted_section {
 564   my ($self, $item, $parent_id) = @_;
 565
 566   my $node = $self->presenter->requirement_spec_item_jstree_data($item);
 567   $self->js
 568     ->jstree->create_node('#tree', $parent_id ? "#fb-${parent_id}" : '#sections', 'last', $node)
 569     ->jstree->open_node(  '#tree', $parent_id ? "#fb-${parent_id}" : '#sections');
 570
 571   $self->render_pasted_section($_, $item->id) for @{ $item->children_sorted };
 572 }
 573
 574 sub render_first_pasted_section_as_list {
 575   my ($self, $section, %params) = @_;
 576
 577   my $html = $self->render('requirement_spec_item/_section', { output => 0 }, requirement_spec_item => $section);
 578   $self->js
 579     ->html('#column-content', $html)
 580     ->val( '#current_content_type', $section->item_type)
 581     ->val( '#current_content_id',   $section->id)
 582     ->jstree->select_node('#tree', '#fb-' . $section->id);
 583 }
 584
 585 sub prepare_pictures_for_printing {
 586   my ($self) = @_;
 587
 588   my @files;
 589   my $userspath = File::Spec->rel2abs($::lx_office_conf{paths}->{userspath});
 590   my $target    =  "${userspath}/kivitendo-print-requirement-spec-picture-" . Common::unique_id() . '-';
 591
 592   foreach my $picture (map { @{ $_->pictures } } @{ $self->requirement_spec->text_blocks }) {
 593     my $output_file_name        = $target . $picture->id . '.' . $picture->get_default_file_name_extension;
 594     $picture->{print_file_name} = File::Spec->abs2rel($output_file_name, $userspath);
 595     my $out                     = IO::File->new($output_file_name, 'w') || die("Could not create file " . $output_file_name);
 596     $out->binmode;
 597     $out->print($picture->picture_content);
 598     $out->close;
 599
 600     push @files, $output_file_name;
 601   }
 602
 603   return @files;
 604 }
 605
 606 sub update_project_link_none_keep_existing {
 607   my ($self, $action) = @_;
 608
 609   $self->requirement_spec->update_attributes(project_id => undef)                     if $action eq 'none';
 610   $self->requirement_spec->update_attributes(project_id => $::form->{new_project_id}) if $action eq 'existing';
 611
 612   return $self->invalidate_version
 613     ->replaceWith('#basic_settings', $self->render('requirement_spec/_show_basic_settings', { output => 0 }))
 614     ->remove('#project_link_form')
 615     ->flash('info', t8('The project link has been updated.'))
 616     ->render;
 617 }
 618
 619 sub update_project_link_new {
 620   my ($self) = @_;
 621
 622   return $self->js
 623     ->replaceWith('#project_link_form', $self->render('requirement_spec/_new_project_form', { output => 0 }))
 624     ->render;
 625 }
 626
 627 sub update_project_link_create {
 628   my ($self)  = @_;
 629   my $params  = delete($::form->{project}) || {};
 630   my $project = SL::DB::Project->new(
 631     %{ $params },
 632     valid  => 1,
 633     active => 1,
 634   );
 635
 636   my @errors = $project->validate;
 637
 638   return $self->js->error(@errors)->render if @errors;
 639
 640   my $db = $self->requirement_spec->db;
 641   if (!$db->with_transaction(sub {
 642     $project->save;
 643     $self->requirement_spec->update_attributes(project_id => $project->id);
 644
 645   })) {
 646     $::lxdebug->message(LXDebug::WARN(), "Error: " . $db->error);
 647     return $self->js->error(t8('Saving failed. Error message from the database: #1', $db->error))->render;
 648   }
 649
 650   return $self->invalidate_version
 651     ->replaceWith('#basic_settings', $self->render('requirement_spec/_show_basic_settings', { output => 0 }))
 652     ->remove('#project_link_form')
 653     ->flash('info', t8('The project has been created.'))
 654     ->flash('info', t8('The project link has been updated.'))
 655     ->render;
 656 }
 657
 658 sub init_models {
 659   my ($self) = @_;
 660
 661   SL::Controller::Helper::GetModels->new(
 662     controller   => $self,
 663     sorted       => {
 664       _default     => {
 665         by           => 'customer',
 666         dir          => 1,
 667       },
 668       %sort_columns,
 669     },
 670     query => [
 671       and => [
 672         working_copy_id => undef,
 673         is_template     => $::form->{is_template} ? 1 : 0,
 674       ],
 675     ],
 676     with_objects => [ 'customer', 'type', 'status', 'project' ],
 677   );
 678 }
 679
 680 sub init_html_template {
 681   my ($self)    = @_;
 682   my $base_name = $self->requirement_spec->type->template_file_name || 'requirement_spec';
 683   my $template  = SL::Helper::CreatePDF->find_template(name => $base_name, extension => 'html');
 684   return !!$template;
 685 }
 686
 687 sub _setup_form_action_bar {
 688   my ($self) = @_;
 689
 690   for my $bar ($::request->layout->get('actionbar')) {
 691     $bar->add(
 692       action => [
 693         t8('Save'),
 694         submit    => [ '#basic_settings_form', { action => 'RequirementSpec/' . ($self->requirement_spec->id ? 'update' : 'create') } ],
 695         accesskey => 'enter',
 696       ],
 697
 698       link => [
 699         t8('Abort'),
 700         link => $self->url_for(action => 'list', is_template => $self->requirement_spec->is_template),
 701       ],
 702     );
 703   }
 704 }
 705
 706 1;