SL/Controller/RequirementSpec.pm

   1 package SL::Controller::RequirementSpec;
   2
   3 use strict;
   4 use utf8;
   5
   6 use parent qw(SL::Controller::Base);
   7
   8 use SL::ClientJS;
   9 use SL::Controller::Helper::GetModels;
  10 use SL::Controller::Helper::Paginated;
  11 use SL::Controller::Helper::Sorted;
  12 use SL::Controller::Helper::ParseFilter;
  13 use SL::Controller::Helper::ReportGenerator;
  14 use SL::Controller::Helper::RequirementSpec;
  15 use SL::DB::Customer;
  16 use SL::DB::Project;
  17 use SL::DB::RequirementSpecComplexity;
  18 use SL::DB::RequirementSpecRisk;
  19 use SL::DB::RequirementSpecStatus;
  20 use SL::DB::RequirementSpecType;
  21 use SL::DB::RequirementSpec;
  22 use SL::Helper::Flash;
  23 use SL::Locale::String;
  24 use SL::Template::LaTeX;
  25
  26 use Rose::Object::MakeMethods::Generic
  27 (
  28   scalar                  => [ qw(requirement_spec_item customers types statuses db_args flat_filter visible_item visible_section) ],
  29   'scalar --get_set_init' => [ qw(requirement_spec complexities risks projects copy_source js) ],
  30 );
  31
  32 __PACKAGE__->run_before('setup');
  33 __PACKAGE__->run_before('load_select_options',  only => [ qw(new ajax_edit create update list) ]);
  34
  35
  36 __PACKAGE__->get_models_url_params('flat_filter');
  37 __PACKAGE__->make_paginated(
  38   MODEL         => 'RequirementSpec',
  39   PAGINATE_ARGS => 'db_args',
  40   ONLY          => [ qw(list) ],
  41 );
  42
  43 __PACKAGE__->make_sorted(
  44   MODEL         => 'RequirementSpec',
  45   ONLY          => [ qw(list) ],
  46
  47   DEFAULT_BY    => 'customer',
  48   DEFAULT_DIR   => 1,
  49
  50   customer      => t8('Customer'),
  51   title         => t8('Title'),
  52   type          => t8('Requirement Spec Type'),
  53   status        => t8('Requirement Spec Status'),
  54   projectnumber => t8('Project Number'),
  55   version       => t8('Version'),
  56   mtime         => t8('Last modification'),
  57 );
  58
  59 #
  60 # actions
  61 #
  62
  63
  64 sub action_list {
  65   my ($self) = @_;
  66
  67   $self->setup_db_args_from_filter;
  68   $self->flat_filter({ map { $_->{key} => $_->{value} } $::form->flatten_variables('filter') });
  69
  70   $self->prepare_report;
  71
  72   my $requirement_specs = $self->get_models(%{ $self->db_args });
  73
  74   $self->report_generator_list_objects(report => $self->{report}, objects => $requirement_specs);
  75 }
  76
  77 sub action_new {
  78   my ($self) = @_;
  79
  80   $self->requirement_spec(SL::DB::RequirementSpec->new(is_template => $::form->{is_template}));
  81
  82   if ($self->copy_source) {
  83     $self->requirement_spec->$_($self->copy_source->$_) for qw(type_id status_id customer_id title hourly_rate)
  84   }
  85
  86   $self->render('requirement_spec/new', title => $self->requirement_spec->is_template ? t8('Create a new requirement spec template') : t8('Create a new requirement spec'));
  87 }
  88
  89 sub action_ajax_edit {
  90   my ($self) = @_;
  91
  92   $self->render('requirement_spec/_form', { layout => 0 }, submit_as => 'ajax');
  93 }
  94
  95 sub action_ajax_show_time_and_cost_estimate {
  96   my ($self) = @_;
  97
  98   $self->render('requirement_spec/_show_time_and_cost_estimate', { layout => 0 });
  99 }
 100
 101 sub action_ajax_cancel_time_and_cost_estimate {
 102   my ($self) = @_;
 103
 104   my $html   = $self->render('requirement_spec/_show_time_and_cost_estimate', { output => 0 });
 105
 106   $self->js
 107    ->replaceWith('#time_cost_estimate', $html)
 108    ->render($self);
 109 }
 110
 111 sub action_ajax_edit_time_and_cost_estimate {
 112   my ($self) = @_;
 113
 114   my $html   = $self->render('requirement_spec/_edit_time_and_cost_estimate', { output => 0 });
 115
 116   $self->js
 117    ->replaceWith('#time_cost_estimate', $html)
 118    ->render($self);
 119 }
 120
 121 sub action_ajax_save_time_and_cost_estimate {
 122   my ($self) = @_;
 123
 124   $self->requirement_spec->db->do_transaction(sub {
 125     # Make Emacs happy
 126     1;
 127     foreach my $attributes (@{ $::form->{requirement_spec_items} || [] }) {
 128       SL::DB::RequirementSpecItem
 129         ->new(id => delete $attributes->{id})
 130         ->load
 131         ->update_attributes(%{ $attributes });
 132     }
 133
 134     1;
 135   });
 136
 137   my $html = $self->render('requirement_spec/_show_time_and_cost_estimate', { output => 0 });
 138   $self->js->replaceWith('#time_cost_estimate', $html);
 139
 140   if ($self->visible_section) {
 141     $html = $self->render('requirement_spec_item/_section', { output => 0 }, requirement_spec_item => $self->visible_section);
 142     $self->js->html('#column-content', $html);
 143   }
 144
 145   $self->js->render($self);
 146 }
 147
 148 sub action_show {
 149   my ($self) = @_;
 150
 151   my $title  = $self->requirement_spec->is_template ? t8('Show requirement spec template') : t8('Show requirement spec');
 152   my $item   = $::form->{requirement_spec_item_id} ? SL::DB::RequirementSpecItem->new(id => $::form->{requirement_spec_item_id})->load : @{ $self->requirement_spec->sections }[0];
 153   $self->requirement_spec_item($item);
 154
 155   $self->render('requirement_spec/show', title => $title);
 156 }
 157
 158 sub action_create {
 159   my ($self) = @_;
 160
 161   $self->requirement_spec(SL::DB::RequirementSpec->new);
 162   $self->create_or_update;
 163 }
 164
 165 sub action_update {
 166   my ($self) = @_;
 167   $self->create_or_update;
 168 }
 169
 170 sub action_destroy {
 171   my ($self) = @_;
 172
 173   if (eval { $self->requirement_spec->delete; 1; }) {
 174     flash_later('info',  t8('The requirement spec has been deleted.'));
 175   } else {
 176     flash_later('error', t8('The requirement spec is in use and cannot be deleted.'));
 177   }
 178
 179   $self->redirect_to(action => 'list');
 180 }
 181
 182 sub action_revert_to {
 183   my ($self, %params) = @_;
 184
 185   return $self->js->error(t8('Cannot revert a versioned copy.'))->render($self) if $self->requirement_spec->working_copy_id;
 186
 187   my $versioned_copy = SL::DB::RequirementSpec->new(id => $::form->{versioned_copy_id})->load;
 188
 189   $self->requirement_spec->copy_from(
 190     $versioned_copy,
 191     version_id => $versioned_copy->version_id,
 192   );
 193
 194   flash_later('info', t8('The requirement spec has been reverted to version #1.', $self->requirement_spec->version->version_number));
 195   $self->js->redirect_to($self->url_for(action => 'show', id => $self->requirement_spec->id))->render($self);
 196 }
 197
 198 sub action_create_pdf {
 199   my ($self, %params) = @_;
 200
 201   my %result = SL::Template::LaTeX->parse_and_create_pdf('requirement_spec.tex', SELF => $self, rspec => $self->requirement_spec);
 202
 203   $::form->error(t8('Conversion to PDF failed: #1', $result{error})) if $result{error};
 204
 205   my $attachment_name  =  $self->requirement_spec->type->description . ' ' . ($self->requirement_spec->working_copy_id || $self->requirement_spec->id);
 206   $attachment_name    .=  ' (v' . $self->requirement_spec->version->version_number . ')' if $self->requirement_spec->version;
 207   $attachment_name    .=  '.pdf';
 208   $attachment_name     =~ s/[^\wäöüÄÖÜß \-\+\(\)\[\]\{\}\.,]+/_/g;
 209
 210   $self->send_file($result{file_name}, type => 'application/pdf', name => $attachment_name);
 211   unlink $result{file_name};
 212 }
 213
 214 sub action_select_template_to_paste {
 215   my ($self) = @_;
 216
 217   my @templates = grep { @{ $_->sections } || @{ $_->text_blocks } } @{ SL::DB::Manager::RequirementSpec->get_all(where => [ is_template => 1 ], sort_by => 'lower(title)') };
 218   $self->render('requirement_spec/select_template_to_paste', { layout => 0 }, TEMPLATES => \@templates);
 219 }
 220
 221 #
 222 # filters
 223 #
 224
 225 sub setup {
 226   my ($self) = @_;
 227
 228   $::auth->assert('sales_quotation_edit');
 229   $::request->{layout}->use_stylesheet("${_}.css") for qw(jquery.contextMenu requirement_spec);
 230   $::request->{layout}->use_javascript("${_}.js") for qw(jquery.jstree jquery/jquery.contextMenu client_js requirement_spec);
 231   $self->init_visible_section;
 232
 233   return 1;
 234 }
 235
 236 sub init_complexities {
 237   my ($self) = @_;
 238   return SL::DB::Manager::RequirementSpecComplexity->get_all_sorted;
 239 }
 240
 241 sub init_risks {
 242   my ($self) = @_;
 243   return SL::DB::Manager::RequirementSpecRisk->get_all_sorted;
 244 }
 245
 246 sub init_projects {
 247   my ($self) = @_;
 248   $self->projects(SL::DB::Manager::Project->get_all_sorted);
 249 }
 250
 251 sub init_requirement_spec {
 252   my ($self) = @_;
 253   $self->requirement_spec(SL::DB::RequirementSpec->new(id => $::form->{id})->load || die "No such requirement spec") if $::form->{id};
 254 }
 255
 256 sub init_copy_source {
 257   my ($self) = @_;
 258   $self->copy_source(SL::DB::RequirementSpec->new(id => $::form->{copy_source_id})->load) if $::form->{copy_source_id};
 259 }
 260
 261 sub init_js {
 262   my ($self) = @_;
 263   $self->js(SL::ClientJS->new);
 264 }
 265
 266 sub load_select_options {
 267   my ($self) = @_;
 268
 269   my @filter = ('!obsolete' => 1);
 270   @filter    = ( or => [ @filter, id => $self->requirement_spec->customer_id ] ) if $self->requirement_spec && $self->requirement_spec->customer_id;
 271
 272   $self->customers(SL::DB::Manager::Customer->get_all_sorted(where => \@filter));
 273   $self->statuses( SL::DB::Manager::RequirementSpecStatus->get_all_sorted);
 274   $self->types(    SL::DB::Manager::RequirementSpecType->get_all_sorted);
 275 }
 276
 277 #
 278 # helpers
 279 #
 280
 281 sub create_or_update {
 282   my $self   = shift;
 283   my $is_new = !$self->requirement_spec->id;
 284   my $params = delete($::form->{requirement_spec}) || { };
 285
 286   $self->requirement_spec->assign_attributes(%{ $params });
 287
 288   my $title  = $is_new && $self->requirement_spec->is_template ? t8('Create a new requirement spec template')
 289              : $is_new                                         ? t8('Create a new requirement spec')
 290              :            $self->requirement_spec->is_template ? t8('Edit requirement spec template')
 291              :                                                   t8('Edit requirement spec');
 292
 293   my @errors = $self->requirement_spec->validate;
 294
 295   if (@errors) {
 296     return $self->js->error(@errors)->render($self) if $::request->is_ajax;
 297
 298     flash('error', @errors);
 299     $self->render('requirement_spec/new', title => $title);
 300     return;
 301   }
 302
 303   my $db = $self->requirement_spec->db;
 304   if (!$db->do_transaction(sub {
 305     if ($self->copy_source) {
 306       $self->requirement_spec($self->copy_source->create_copy(%{ $params }));
 307     } else {
 308       $self->requirement_spec->save;
 309     }
 310   })) {
 311     $::lxdebug->message(LXDebug::WARN(), "Error: " . $db->error);
 312     @errors = ($::locale->text('Saving failed. Error message from the database: #1'), $db->error);
 313     return $self->js->error(@errors)->render($self) if $::request->is_ajax;
 314
 315     $self->requirement_spec->id(undef) if $is_new;
 316     flash('error', @errors);
 317     return $self->render('requirement_spec/new', title => $title);
 318   }
 319
 320   my $info = $self->requirement_spec->is_template ? t8('The requirement spec template has been saved.') : t8('The requirement spec has been saved.');
 321
 322   if ($::request->is_ajax) {
 323     my $html = $self->render('requirement_spec/_header', { output => 0 });
 324     return $self->invalidate_version
 325       ->replaceWith('#requirement-spec-header', $html)
 326       ->flash('info', $info)
 327       ->render($self);
 328   }
 329
 330   flash_later('info', $info);
 331   $self->redirect_to(action => 'show', id => $self->requirement_spec->id);
 332 }
 333
 334 sub setup_db_args_from_filter {
 335   my ($self) = @_;
 336
 337   $self->{filter} = {};
 338   my %args = parse_filter(
 339     $::form->{filter},
 340     with_objects => [ 'customer', 'type', 'status', 'project' ],
 341     launder_to   => $self->{filter},
 342   );
 343
 344   $args{where} = [
 345     and => [
 346       @{ $args{where} || [] },
 347       working_copy_id => undef,
 348       is_template     => $::form->{is_template} ? 1 : 0,
 349     ]];
 350
 351   $self->db_args(\%args);
 352 }
 353
 354 sub prepare_report {
 355   my ($self)      = @_;
 356
 357   my $callback    = $self->get_callback;
 358
 359   my $is_template = $::form->{is_template};
 360   my $report      = SL::ReportGenerator->new(\%::myconfig, $::form);
 361   $self->{report} = $report;
 362
 363   my @columns     = $is_template ? qw(title mtime) : qw(title customer status type projectnumber mtime version);
 364   my @sortable    = $is_template ? qw(title mtime) : qw(title customer status type projectnumber mtime);
 365
 366   my %column_defs = (
 367     title         => { obj_link => sub { $self->url_for(action => 'show', id => $_[0]->id, callback => $callback) } },
 368     mtime         => { sub      => sub { ($_[0]->mtime || $_[0]->itime)->to_kivitendo(precision => 'minute') } },
 369   );
 370
 371   if (!$is_template) {
 372     %column_defs = (
 373       %column_defs,
 374       customer      => { raw_data => sub { $self->presenter->customer($_[0]->customer, display => 'table-cell', callback => $callback) },
 375                          sub      => sub { $_[0]->customer->name } },
 376       projectnumber => { raw_data => sub { $self->presenter->project($_[0]->project, display => 'table-cell', callback => $callback) },
 377                          sub      => sub { $_[0]->project_id ? $_[0]->project->projectnumber : '' } },
 378       status        => { sub      => sub { $_[0]->status->description } },
 379       type          => { sub      => sub { $_[0]->type->description } },
 380       version       => { sub      => sub { $_[0]->version_id ? $_[0]->version->version_number : t8('Working copy without version') } },
 381     );
 382   }
 383
 384   map { $column_defs{$_}->{text} ||= $::locale->text( $self->get_sort_spec->{$_}->{title} ) } keys %column_defs;
 385
 386   $report->set_options(
 387     std_column_visibility => 1,
 388     controller_class      => 'RequirementSpec',
 389     output_format         => 'HTML',
 390     raw_top_info_text     => $self->render('requirement_spec/report_top',    { output => 0 }, is_template => $is_template),
 391     raw_bottom_info_text  => $self->render('requirement_spec/report_bottom', { output => 0 }),
 392     title                 => $is_template ? t8('Requirement Spec Templates') : t8('Requirement Specs'),
 393     allow_pdf_export      => 1,
 394     allow_csv_export      => 1,
 395   );
 396   $report->set_columns(%column_defs);
 397   $report->set_column_order(@columns);
 398   $report->set_export_options(qw(list filter));
 399   $report->set_options_from_form;
 400   $self->set_report_generator_sort_options(report => $report, sortable_columns => \@sortable);
 401
 402   $self->disable_pagination if $report->{options}{output_format} =~ /^(pdf|csv)$/i;
 403 }
 404
 405 sub invalidate_version {
 406   my ($self) = @_;
 407
 408   my $rspec  = SL::DB::RequirementSpec->new(id => $self->requirement_spec->id)->load;
 409   return $self->js if $rspec->is_template;
 410
 411   $rspec->invalidate_version;
 412
 413   my $html = $self->render('requirement_spec/_version', { output => 0 }, requirement_spec => $rspec);
 414   return $self->js->html('#requirement_spec_version', $html);
 415 }
 416
 417 1;