SL/Controller/RequirementSpec.pm

   1 package SL::Controller::RequirementSpec;
   2
   3 use strict;
   4 use utf8;
   5
   6 use parent qw(SL::Controller::Base);
   7
   8 use SL::ClientJS;
   9 use SL::Controller::Helper::GetModels;
  10 use SL::Controller::Helper::Paginated;
  11 use SL::Controller::Helper::Sorted;
  12 use SL::Controller::Helper::ParseFilter;
  13 use SL::Controller::Helper::ReportGenerator;
  14 use SL::Controller::Helper::RequirementSpec;
  15 use SL::DB::Customer;
  16 use SL::DB::Project;
  17 use SL::DB::RequirementSpecComplexity;
  18 use SL::DB::RequirementSpecRisk;
  19 use SL::DB::RequirementSpecStatus;
  20 use SL::DB::RequirementSpecType;
  21 use SL::DB::RequirementSpec;
  22 use SL::Helper::Flash;
  23 use SL::Locale::String;
  24 use SL::Template::LaTeX;
  25
  26 use Rose::Object::MakeMethods::Generic
  27 (
  28   scalar                  => [ qw(requirement_spec_item customers types statuses db_args flat_filter is_template visible_item visible_section) ],
  29   'scalar --get_set_init' => [ qw(requirement_spec complexities risks projects copy_source js) ],
  30 );
  31
  32 __PACKAGE__->run_before('setup');
  33 __PACKAGE__->run_before('load_select_options',  only => [ qw(new ajax_edit create update list) ]);
  34
  35
  36 __PACKAGE__->get_models_url_params('flat_filter');
  37 __PACKAGE__->make_paginated(
  38   MODEL         => 'RequirementSpec',
  39   PAGINATE_ARGS => 'db_args',
  40   ONLY          => [ qw(list) ],
  41 );
  42
  43 __PACKAGE__->make_sorted(
  44   MODEL         => 'RequirementSpec',
  45   ONLY          => [ qw(list) ],
  46
  47   DEFAULT_BY    => 'customer',
  48   DEFAULT_DIR   => 1,
  49
  50   customer      => t8('Customer'),
  51   title         => t8('Title'),
  52   type          => t8('Requirement Spec Type'),
  53   status        => t8('Requirement Spec Status'),
  54   projectnumber => t8('Project Number'),
  55   version       => t8('Version'),
  56   mtime         => t8('Last modification'),
  57 );
  58
  59 #
  60 # actions
  61 #
  62
  63
  64 sub action_list {
  65   my ($self) = @_;
  66
  67   $self->setup_db_args_from_filter;
  68   $self->flat_filter({ map { $_->{key} => $_->{value} } $::form->flatten_variables('filter') });
  69
  70   $self->prepare_report;
  71
  72   my $requirement_specs = $self->get_models(%{ $self->db_args });
  73
  74   $self->report_generator_list_objects(report => $self->{report}, objects => $requirement_specs);
  75 }
  76
  77 sub action_new {
  78   my ($self) = @_;
  79
  80   $self->requirement_spec(SL::DB::RequirementSpec->new);
  81
  82   if ($self->copy_source) {
  83     $self->requirement_spec->$_($self->copy_source->$_) for qw(type_id status_id customer_id title hourly_rate)
  84   }
  85
  86   $self->render('requirement_spec/new', title => t8('Create a new requirement spec'));
  87 }
  88
  89 sub action_ajax_edit {
  90   my ($self) = @_;
  91
  92   $self->render('requirement_spec/_form', { layout => 0 }, submit_as => 'ajax');
  93 }
  94
  95 sub action_ajax_show_time_and_cost_estimate {
  96   my ($self) = @_;
  97
  98   $self->render('requirement_spec/_show_time_and_cost_estimate', { layout => 0 });
  99 }
 100
 101 sub action_ajax_cancel_time_and_cost_estimate {
 102   my ($self) = @_;
 103
 104   my $html   = $self->render('requirement_spec/_show_time_and_cost_estimate', { output => 0 });
 105
 106   $self->js
 107    ->replaceWith('#time_cost_estimate', $html)
 108    ->render($self);
 109 }
 110
 111 sub action_ajax_edit_time_and_cost_estimate {
 112   my ($self) = @_;
 113
 114   my $html   = $self->render('requirement_spec/_edit_time_and_cost_estimate', { output => 0 });
 115
 116   $self->js
 117    ->replaceWith('#time_cost_estimate', $html)
 118    ->render($self);
 119 }
 120
 121 sub action_ajax_save_time_and_cost_estimate {
 122   my ($self) = @_;
 123
 124   $self->requirement_spec->db->do_transaction(sub {
 125     # Make Emacs happy
 126     1;
 127     foreach my $attributes (@{ $::form->{requirement_spec_items} || [] }) {
 128       SL::DB::RequirementSpecItem
 129         ->new(id => delete $attributes->{id})
 130         ->load
 131         ->update_attributes(%{ $attributes });
 132     }
 133
 134     1;
 135   });
 136
 137   my $html = $self->render('requirement_spec/_show_time_and_cost_estimate', { output => 0 });
 138   $self->js->replaceWith('#time_cost_estimate', $html);
 139
 140   if ($self->visible_section) {
 141     $html = $self->render('requirement_spec_item/_section', { output => 0 }, requirement_spec_item => $self->visible_section);
 142     $self->js->html('#column-content', $html);
 143   }
 144
 145   $self->js->render($self);
 146 }
 147
 148 sub action_show {
 149   my ($self) = @_;
 150
 151   my $item = $::form->{requirement_spec_item_id} ? SL::DB::RequirementSpecItem->new(id => $::form->{requirement_spec_item_id})->load : @{ $self->requirement_spec->sections }[0];
 152   $self->requirement_spec_item($item);
 153
 154   $self->render('requirement_spec/show', title => t8('Show requirement spec'));
 155 }
 156
 157 sub action_create {
 158   my ($self) = @_;
 159
 160   $self->requirement_spec(SL::DB::RequirementSpec->new);
 161   $self->create_or_update;
 162 }
 163
 164 sub action_update {
 165   my ($self) = @_;
 166   $self->create_or_update;
 167 }
 168
 169 sub action_destroy {
 170   my ($self) = @_;
 171
 172   if (eval { $self->requirement_spec->delete; 1; }) {
 173     flash_later('info',  t8('The requirement spec has been deleted.'));
 174   } else {
 175     flash_later('error', t8('The requirement spec is in use and cannot be deleted.'));
 176   }
 177
 178   $self->redirect_to(action => 'list');
 179 }
 180
 181 sub action_revert_to {
 182   my ($self, %params) = @_;
 183
 184   return $self->js->error(t8('Cannot revert a versioned copy.'))->render($self) if $self->requirement_spec->working_copy_id;
 185
 186   my $versioned_copy = SL::DB::RequirementSpec->new(id => $::form->{versioned_copy_id})->load;
 187
 188   $self->requirement_spec->copy_from(
 189     $versioned_copy,
 190     version_id => $versioned_copy->version_id,
 191   );
 192
 193   flash_later('info', t8('The requirement spec has been reverted to version #1.', $self->requirement_spec->version->version_number));
 194   $self->js->redirect_to($self->url_for(action => 'show', id => $self->requirement_spec->id))->render($self);
 195 }
 196
 197 sub action_create_pdf {
 198   my ($self, %params) = @_;
 199
 200   my %result = SL::Template::LaTeX->parse_and_create_pdf('requirement_spec.tex', SELF => $self, rspec => $self->requirement_spec);
 201
 202   $::form->error(t8('Conversion to PDF failed: #1', $result{error})) if $result{error};
 203
 204   my $attachment_name  =  $self->requirement_spec->type->description . ' ' . ($self->requirement_spec->working_copy_id || $self->requirement_spec->id);
 205   $attachment_name    .=  ' (v' . $self->requirement_spec->version->version_number . ')' if $self->requirement_spec->version;
 206   $attachment_name    .=  '.pdf';
 207   $attachment_name     =~ s/[^\wäöüÄÖÜß \-\+\(\)\[\]\{\}\.,]+/_/g;
 208
 209   $self->send_file($result{file_name}, type => 'application/pdf', name => $attachment_name);
 210   unlink $result{file_name};
 211 }
 212
 213 #
 214 # filters
 215 #
 216
 217 sub setup {
 218   my ($self) = @_;
 219
 220   $::auth->assert('sales_quotation_edit');
 221   $::request->{layout}->use_stylesheet("${_}.css") for qw(jquery.contextMenu requirement_spec);
 222   $::request->{layout}->use_javascript("${_}.js") for qw(jquery.jstree jquery/jquery.contextMenu client_js requirement_spec);
 223   $self->is_template($::form->{is_template} ? 1 : 0);
 224   $self->init_visible_section;
 225
 226   return 1;
 227 }
 228
 229 sub init_complexities {
 230   my ($self) = @_;
 231   return SL::DB::Manager::RequirementSpecComplexity->get_all_sorted;
 232 }
 233
 234 sub init_risks {
 235   my ($self) = @_;
 236   return SL::DB::Manager::RequirementSpecRisk->get_all_sorted;
 237 }
 238
 239 sub init_projects {
 240   my ($self) = @_;
 241   $self->projects(SL::DB::Manager::Project->get_all_sorted);
 242 }
 243
 244 sub init_requirement_spec {
 245   my ($self) = @_;
 246   $self->requirement_spec(SL::DB::RequirementSpec->new(id => $::form->{id})->load || die "No such requirement spec") if $::form->{id};
 247 }
 248
 249 sub init_copy_source {
 250   my ($self) = @_;
 251   $self->copy_source(SL::DB::RequirementSpec->new(id => $::form->{copy_source_id})->load) if $::form->{copy_source_id};
 252 }
 253
 254 sub init_js {
 255   my ($self) = @_;
 256   $self->js(SL::ClientJS->new);
 257 }
 258
 259 sub load_select_options {
 260   my ($self) = @_;
 261
 262   my @filter = ('!obsolete' => 1);
 263   @filter    = ( or => [ @filter, id => $self->requirement_spec->customer_id ] ) if $self->requirement_spec && $self->requirement_spec->customer_id;
 264
 265   $self->customers(SL::DB::Manager::Customer->get_all_sorted(where => \@filter));
 266   $self->statuses( SL::DB::Manager::RequirementSpecStatus->get_all_sorted);
 267   $self->types(    SL::DB::Manager::RequirementSpecType->get_all_sorted);
 268 }
 269
 270 #
 271 # helpers
 272 #
 273
 274 sub create_or_update {
 275   my $self   = shift;
 276   my $is_new = !$self->requirement_spec->id;
 277   my $params = delete($::form->{requirement_spec}) || { };
 278   my $title  = $is_new ? t8('Create a new requirement spec') : t8('Edit requirement spec');
 279
 280   $self->requirement_spec->assign_attributes(%{ $params });
 281
 282   my @errors = $self->requirement_spec->validate;
 283
 284   if (@errors) {
 285     return $self->js->error(@errors)->render($self) if $::request->is_ajax;
 286
 287     flash('error', @errors);
 288     $self->render('requirement_spec/new', title => $title);
 289     return;
 290   }
 291
 292   my $db = $self->requirement_spec->db;
 293   if (!$db->do_transaction(sub {
 294     if ($self->copy_source) {
 295       $self->requirement_spec($self->copy_source->create_copy(%{ $params }));
 296     } else {
 297       $self->requirement_spec->save;
 298     }
 299   })) {
 300     $::lxdebug->message(LXDebug::WARN(), "Error: " . $db->error);
 301     @errors = ($::locale->text('Saving failed. Error message from the database: #1'), $db->error);
 302     return $self->js->error(@errors)->render($self) if $::request->is_ajax;
 303
 304     $self->requirement_spec->id(undef) if $is_new;
 305     flash('error', @errors);
 306     return $self->render('requirement_spec/new', title => $title);
 307   }
 308
 309   if ($::request->is_ajax) {
 310     my $html = $self->render('requirement_spec/_header', { output => 0 });
 311     return $self->invalidate_version
 312       ->replaceWith('#requirement-spec-header', $html)
 313       ->flash('info', t8('The requirement spec has been saved.'))
 314       ->render($self);
 315   }
 316
 317   flash_later('info', $is_new ? t8('The requirement spec has been created.') : t8('The requirement spec has been saved.'));
 318   $self->redirect_to(action => 'show', id => $self->requirement_spec->id);
 319 }
 320
 321 sub setup_db_args_from_filter {
 322   my ($self) = @_;
 323
 324   $self->{filter} = {};
 325   my %args = parse_filter(
 326     $::form->{filter},
 327     with_objects => [ 'customer', 'type', 'status', 'project' ],
 328     launder_to   => $self->{filter},
 329   );
 330
 331   $args{where} = [
 332     and => [
 333       @{ $args{where} || [] },
 334       working_copy_id => undef,
 335       is_template     => $self->is_template
 336     ]];
 337
 338   $self->db_args(\%args);
 339 }
 340
 341 sub prepare_report {
 342   my ($self)      = @_;
 343
 344   my $callback    = $self->get_callback;
 345
 346   my $report      = SL::ReportGenerator->new(\%::myconfig, $::form);
 347   $self->{report} = $report;
 348
 349   my @columns     = qw(title customer status type projectnumber mtime version);
 350   my @sortable    = qw(title customer status type projectnumber mtime);
 351
 352   my %column_defs = (
 353     title         => { obj_link => sub { $self->url_for(action => 'show', id => $_[0]->id, callback => $callback) } },
 354     customer      => { raw_data => sub { $self->presenter->customer($_[0]->customer, display => 'table-cell', callback => $callback) },
 355                        sub      => sub { $_[0]->customer->name } },
 356     projectnumber => { raw_data => sub { $self->presenter->project($_[0]->project, display => 'table-cell', callback => $callback) },
 357                        sub      => sub { $_[0]->project_id ? $_[0]->project->projectnumber : '' } },
 358     status        => { sub      => sub { $_[0]->status->description } },
 359     type          => { sub      => sub { $_[0]->type->description } },
 360     version       => { sub      => sub { $_[0]->version_id ? $_[0]->version->version_number : t8('Working copy without version') } },
 361     mtime         => { sub      => sub { $_[0]->mtime->to_kivitendo(precision => 'minute') } },
 362   );
 363
 364   map { $column_defs{$_}->{text} ||= $::locale->text( $self->get_sort_spec->{$_}->{title} ) } keys %column_defs;
 365
 366   $report->set_options(
 367     std_column_visibility => 1,
 368     controller_class      => 'RequirementSpec',
 369     output_format         => 'HTML',
 370     raw_top_info_text     => $self->render('requirement_spec/report_top',    { output => 0 }),
 371     raw_bottom_info_text  => $self->render('requirement_spec/report_bottom', { output => 0 }),
 372     title                 => $::locale->text('Requirement Specs'),
 373     allow_pdf_export      => 1,
 374     allow_csv_export      => 1,
 375   );
 376   $report->set_columns(%column_defs);
 377   $report->set_column_order(@columns);
 378   $report->set_export_options(qw(list filter));
 379   $report->set_options_from_form;
 380   $self->set_report_generator_sort_options(report => $report, sortable_columns => \@sortable);
 381
 382   $self->disable_pagination if $report->{options}{output_format} =~ /^(pdf|csv)$/i;
 383 }
 384
 385 sub invalidate_version {
 386   my ($self) = @_;
 387
 388   my $rspec  = SL::DB::RequirementSpec->new(id => $self->requirement_spec->id)->load;
 389   $rspec->invalidate_version;
 390
 391   my $html = $self->render('requirement_spec/_version', { output => 0 }, requirement_spec => $rspec);
 392   return $self->js->html('#requirement_spec_version', $html);
 393 }
 394
 395
 396 1;