SL/Controller/RequirementSpec.pm

   1 package SL::Controller::RequirementSpec;
   2
   3 use strict;
   4 use utf8;
   5
   6 use parent qw(SL::Controller::Base);
   7
   8 use File::Spec ();
   9
  10 use SL::ClientJS;
  11 use SL::Common ();
  12 use SL::Controller::Helper::GetModels;
  13 use SL::Controller::Helper::Filtered;
  14 use SL::Controller::Helper::Paginated;
  15 use SL::Controller::Helper::Sorted;
  16 use SL::Controller::Helper::ParseFilter;
  17 use SL::Controller::Helper::ReportGenerator;
  18 use SL::Controller::Helper::RequirementSpec;
  19 use SL::DB::Customer;
  20 use SL::DB::Project;
  21 use SL::DB::RequirementSpecComplexity;
  22 use SL::DB::RequirementSpecRisk;
  23 use SL::DB::RequirementSpecStatus;
  24 use SL::DB::RequirementSpecType;
  25 use SL::DB::RequirementSpec;
  26 use SL::Helper::Flash;
  27 use SL::Locale::String;
  28 use SL::Template::LaTeX;
  29
  30 use Rose::Object::MakeMethods::Generic
  31 (
  32   scalar                  => [ qw(requirement_spec_item customers types statuses visible_item visible_section) ],
  33   'scalar --get_set_init' => [ qw(requirement_spec complexities risks projects copy_source js current_text_block_output_position) ],
  34 );
  35
  36 __PACKAGE__->run_before('setup');
  37 __PACKAGE__->run_before('load_select_options',  only => [ qw(new ajax_edit create update list) ]);
  38
  39 __PACKAGE__->make_filtered(
  40   MODEL      => 'RequirementSpec',
  41   LAUNDER_TO => 'filter'
  42 );
  43 __PACKAGE__->make_paginated(
  44   MODEL => 'RequirementSpec',
  45   ONLY  => [ qw(list) ],
  46 );
  47 __PACKAGE__->make_sorted(
  48   MODEL         => 'RequirementSpec',
  49   ONLY          => [ qw(list) ],
  50
  51   DEFAULT_BY    => 'customer',
  52   DEFAULT_DIR   => 1,
  53
  54   customer      => t8('Customer'),
  55   title         => t8('Title'),
  56   type          => t8('Requirement Spec Type'),
  57   status        => t8('Requirement Spec Status'),
  58   projectnumber => t8('Project Number'),
  59   version       => t8('Version'),
  60   mtime         => t8('Last modification'),
  61 );
  62
  63 #
  64 # actions
  65 #
  66
  67
  68 sub action_list {
  69   my ($self) = @_;
  70
  71   my $requirement_specs = $self->get_models(
  72     query => [
  73       and => [
  74         working_copy_id => undef,
  75         is_template     => $::form->{is_template} ? 1 : 0,
  76       ]],
  77     with_objects => [ 'customer', 'type', 'status', 'project' ],
  78   );
  79
  80   $self->prepare_report;
  81   $self->report_generator_list_objects(report => $self->{report}, objects => $requirement_specs);
  82 }
  83
  84 sub action_new {
  85   my ($self) = @_;
  86
  87   $self->requirement_spec(SL::DB::RequirementSpec->new(is_template => $::form->{is_template}));
  88
  89   if ($self->copy_source) {
  90     $self->requirement_spec->$_($self->copy_source->$_) for qw(type_id status_id customer_id title hourly_rate)
  91   }
  92
  93   $self->render('requirement_spec/new', title => $self->requirement_spec->is_template ? t8('Create a new requirement spec template') : t8('Create a new requirement spec'));
  94 }
  95
  96 sub action_ajax_show_basic_settings {
  97   my ($self) = @_;
  98
  99   $self->render('requirement_spec/_show_basic_settings', { layout => 0 });
 100 }
 101
 102 sub action_ajax_edit {
 103   my ($self) = @_;
 104
 105   my $html   = $self->render('requirement_spec/_form', { output => 0 }, submit_as => 'ajax');
 106
 107   $self->js
 108     ->hide('#basic_settings')
 109     ->after('#basic_settings', $html)
 110     ->render($self);
 111 }
 112
 113 sub action_ajax_show_time_and_cost_estimate {
 114   my ($self) = @_;
 115
 116   $self->render('requirement_spec/_show_time_and_cost_estimate', { layout => 0 });
 117 }
 118
 119 sub action_ajax_edit_time_and_cost_estimate {
 120   my ($self) = @_;
 121
 122   my $html   = $self->render('requirement_spec/_edit_time_and_cost_estimate', { output => 0 });
 123   my $first  = ($self->requirement_spec->sections_sorted || [])->[0];
 124   $first     = ($first->children_sorted || [])->[0] if $first;
 125
 126   $self->js
 127    ->hide('#time_cost_estimate')
 128    ->after('#time_cost_estimate', $html)
 129    ->on('#time_cost_estimate INPUT[type=text]', 'keydown', 'kivi.requirement_spec.time_cost_estimate_input_key_down')
 130    ->action_if($first && $first->id, 'focus', '#time_and_cost_estimate_form_complexity_id_' . $first->id)
 131    ->render($self);
 132 }
 133
 134 sub action_ajax_save_time_and_cost_estimate {
 135   my ($self) = @_;
 136
 137   $self->requirement_spec->db->do_transaction(sub {
 138     # Make Emacs happy
 139     1;
 140     foreach my $attributes (@{ $::form->{requirement_spec_items} || [] }) {
 141       SL::DB::RequirementSpecItem
 142         ->new(id => delete $attributes->{id})
 143         ->load
 144         ->update_attributes(%{ $attributes });
 145     }
 146
 147     1;
 148   });
 149
 150   $self->requirement_spec(SL::DB::RequirementSpec->new(id => $self->requirement_spec->id)->load);
 151
 152   my $html = $self->render('requirement_spec/_show_time_and_cost_estimate', { output => 0 });
 153   $self->js->replaceWith('#time_cost_estimate', $html)
 154            ->remove('#time_cost_estimate_form_container');
 155
 156   if ($self->visible_section) {
 157     $html = $self->render('requirement_spec_item/_section', { output => 0 }, requirement_spec_item => $self->visible_section);
 158     $self->js->html('#column-content', $html);
 159   }
 160
 161   $self->js->render($self);
 162 }
 163
 164 sub action_show {
 165   my ($self) = @_;
 166
 167   my $title  = $self->requirement_spec->is_template ? t8('Show requirement spec template') : t8('Show requirement spec');
 168   my $item   = $::form->{requirement_spec_item_id} ? SL::DB::RequirementSpecItem->new(id => $::form->{requirement_spec_item_id})->load : @{ $self->requirement_spec->sections }[0];
 169   $self->requirement_spec_item($item);
 170
 171   $self->render('requirement_spec/show', title => $title);
 172 }
 173
 174 sub action_create {
 175   my ($self) = @_;
 176
 177   $self->requirement_spec(SL::DB::RequirementSpec->new);
 178   $self->create_or_update;
 179 }
 180
 181 sub action_update {
 182   my ($self) = @_;
 183   $self->create_or_update;
 184 }
 185
 186 sub action_destroy {
 187   my ($self) = @_;
 188
 189   if (eval { $self->requirement_spec->delete; 1; }) {
 190     flash_later('info',  t8('The requirement spec has been deleted.'));
 191   } else {
 192     flash_later('error', t8('The requirement spec is in use and cannot be deleted.'));
 193   }
 194
 195   $self->redirect_to(action => 'list');
 196 }
 197
 198 sub action_revert_to {
 199   my ($self, %params) = @_;
 200
 201   return $self->js->error(t8('Cannot revert a versioned copy.'))->render($self) if $self->requirement_spec->working_copy_id;
 202
 203   my $versioned_copy = SL::DB::RequirementSpec->new(id => $::form->{versioned_copy_id})->load;
 204
 205   $self->requirement_spec->copy_from($versioned_copy);
 206   my $version = $versioned_copy->versions->[0];
 207   $version->update_attributes(working_copy_id => $self->requirement_spec->id);
 208
 209   flash_later('info', t8('The requirement spec has been reverted to version #1.', $self->requirement_spec->version->version_number));
 210   $self->js->redirect_to($self->url_for(action => 'show', id => $self->requirement_spec->id))->render($self);
 211 }
 212
 213 sub action_create_pdf {
 214   my ($self, %params) = @_;
 215
 216   my $base_name       = $self->requirement_spec->type->template_file_name || 'requirement_spec';
 217   my @pictures        = $self->prepare_pictures_for_printing;
 218   my %result          = SL::Template::LaTeX->parse_and_create_pdf("${base_name}.tex", SELF => $self, rspec => $self->requirement_spec);
 219
 220   unlink @pictures unless ($::lx_office_conf{debug} || {})->{keep_temp_files};
 221
 222   $::form->error(t8('Conversion to PDF failed: #1', $result{error})) if $result{error};
 223
 224   my $attachment_name  =  $self->requirement_spec->type->description . ' ' . ($self->requirement_spec->working_copy_id || $self->requirement_spec->id);
 225   $attachment_name    .=  ' (v' . $self->requirement_spec->version->version_number . ')' if $self->requirement_spec->version;
 226   $attachment_name    .=  '.pdf';
 227   $attachment_name     =~ s/[^\wäöüÄÖÜß \-\+\(\)\[\]\{\}\.,]+/_/g;
 228
 229   $self->send_file($result{file_name}, type => 'application/pdf', name => $attachment_name);
 230   unlink $result{file_name};
 231 }
 232
 233 sub action_select_template_to_paste {
 234   my ($self) = @_;
 235
 236   my @templates = grep { @{ $_->sections } || @{ $_->text_blocks } } @{ SL::DB::Manager::RequirementSpec->get_all(where => [ is_template => 1 ], sort_by => 'lower(title)') };
 237   $self->render('requirement_spec/select_template_to_paste', { layout => 0 }, TEMPLATES => \@templates);
 238 }
 239
 240 sub action_paste_template {
 241   my ($self, %params) = @_;
 242
 243   my $template = SL::DB::RequirementSpec->new(id => $::form->{template_id})->load;
 244   my %result   = $self->requirement_spec->paste_template($template);
 245
 246   return $self->js->error($self->requirement_spec->error)->render($self) if !%result;
 247
 248   $self->render_pasted_text_block($_) for sort { $a->position <=> $b->position } @{ $result{text_blocks} };
 249   $self->render_pasted_section($_)    for sort { $a->position <=> $b->position } @{ $result{sections}    };
 250
 251   if (@{ $result{sections} } && (($::form->{current_content_type} || 'sections') eq 'sections') && !$::form->{current_content_id}) {
 252     $self->render_first_pasted_section_as_list($result{sections}->[0]);
 253   }
 254
 255   $self->invalidate_version->render($self);
 256 }
 257
 258 #
 259 # filters
 260 #
 261
 262 sub setup {
 263   my ($self) = @_;
 264
 265   $::auth->assert('sales_quotation_edit');
 266   $::request->{layout}->use_stylesheet("${_}.css") for qw(jquery.contextMenu requirement_spec);
 267   $::request->{layout}->use_javascript("${_}.js")  for qw(jquery.jstree jquery/jquery.contextMenu jquery/jquery.hotkeys requirement_spec);
 268   $self->init_visible_section;
 269
 270   return 1;
 271 }
 272
 273 sub init_complexities {
 274   my ($self) = @_;
 275   return SL::DB::Manager::RequirementSpecComplexity->get_all_sorted;
 276 }
 277
 278 sub init_risks {
 279   my ($self) = @_;
 280   return SL::DB::Manager::RequirementSpecRisk->get_all_sorted;
 281 }
 282
 283 sub init_projects {
 284   my ($self) = @_;
 285   $self->projects(SL::DB::Manager::Project->get_all_sorted);
 286 }
 287
 288 sub init_requirement_spec {
 289   my ($self) = @_;
 290   $self->requirement_spec(SL::DB::RequirementSpec->new(id => $::form->{id})->load || die "No such requirement spec") if $::form->{id};
 291 }
 292
 293 sub init_copy_source {
 294   my ($self) = @_;
 295   $self->copy_source(SL::DB::RequirementSpec->new(id => $::form->{copy_source_id})->load) if $::form->{copy_source_id};
 296 }
 297
 298 sub init_js {
 299   my ($self) = @_;
 300   $self->js(SL::ClientJS->new);
 301 }
 302
 303 sub init_current_text_block_output_position {
 304   my ($self) = @_;
 305   $self->current_text_block_output_position($::form->{current_content_type} !~ m/^(?:text-blocks|tb)-(front|back)/ ? -1 : $1 eq 'front' ? 0 : 1);
 306 }
 307
 308 sub load_select_options {
 309   my ($self) = @_;
 310
 311   my @filter = ('!obsolete' => 1);
 312   @filter    = ( or => [ @filter, id => $self->requirement_spec->customer_id ] ) if $self->requirement_spec && $self->requirement_spec->customer_id;
 313
 314   $self->customers(SL::DB::Manager::Customer->get_all_sorted(where => \@filter));
 315   $self->statuses( SL::DB::Manager::RequirementSpecStatus->get_all_sorted);
 316   $self->types(    SL::DB::Manager::RequirementSpecType->get_all_sorted);
 317 }
 318
 319 #
 320 # helpers
 321 #
 322
 323 sub create_or_update {
 324   my $self   = shift;
 325   my $is_new = !$self->requirement_spec->id;
 326   my $params = delete($::form->{requirement_spec}) || { };
 327
 328   $self->requirement_spec->assign_attributes(%{ $params });
 329
 330   my $title  = $is_new && $self->requirement_spec->is_template ? t8('Create a new requirement spec template')
 331              : $is_new                                         ? t8('Create a new requirement spec')
 332              :            $self->requirement_spec->is_template ? t8('Edit requirement spec template')
 333              :                                                   t8('Edit requirement spec');
 334
 335   my @errors = $self->requirement_spec->validate;
 336
 337   if (@errors) {
 338     return $self->js->error(@errors)->render($self) if $::request->is_ajax;
 339
 340     flash('error', @errors);
 341     $self->render('requirement_spec/new', title => $title);
 342     return;
 343   }
 344
 345   my $db = $self->requirement_spec->db;
 346   if (!$db->do_transaction(sub {
 347     if ($self->copy_source) {
 348       $self->requirement_spec($self->copy_source->create_copy(%{ $params }));
 349     } else {
 350       $self->requirement_spec->save;
 351     }
 352   })) {
 353     $::lxdebug->message(LXDebug::WARN(), "Error: " . $db->error);
 354     @errors = ($::locale->text('Saving failed. Error message from the database: #1', $db->error));
 355     return $self->js->error(@errors)->render($self) if $::request->is_ajax;
 356
 357     $self->requirement_spec->id(undef) if $is_new;
 358     flash('error', @errors);
 359     return $self->render('requirement_spec/new', title => $title);
 360   }
 361
 362   my $info = $self->requirement_spec->is_template ? t8('The requirement spec template has been saved.') : t8('The requirement spec has been saved.');
 363
 364   if ($::request->is_ajax) {
 365     my $header_html = $self->render('requirement_spec/_header', { output => 0 });
 366     my $basics_html = $self->render('requirement_spec/_show_basic_settings', { output => 0 });
 367     return $self->invalidate_version
 368       ->replaceWith('#requirement-spec-header', $header_html)
 369       ->replaceWith('#basic_settings',          $basics_html)
 370       ->remove('#basic_settings_form')
 371       ->flash('info', $info)
 372       ->render($self);
 373   }
 374
 375   flash_later('info', $info);
 376   $self->redirect_to(action => 'show', id => $self->requirement_spec->id);
 377 }
 378
 379 sub prepare_report {
 380   my ($self)      = @_;
 381
 382   my $callback    = $self->get_callback;
 383
 384   my $is_template = $::form->{is_template};
 385   my $report      = SL::ReportGenerator->new(\%::myconfig, $::form);
 386   $self->{report} = $report;
 387
 388   my @columns     = $is_template ? qw(title mtime) : qw(title customer status type projectnumber mtime version);
 389   my @sortable    = $is_template ? qw(title mtime) : qw(title customer status type projectnumber mtime);
 390
 391   my %column_defs = (
 392     title         => { obj_link => sub { $self->url_for(action => 'show', id => $_[0]->id, callback => $callback) } },
 393     mtime         => { sub      => sub { ($_[0]->mtime || $_[0]->itime)->to_kivitendo(precision => 'minute') } },
 394   );
 395
 396   if (!$is_template) {
 397     %column_defs = (
 398       %column_defs,
 399       customer      => { raw_data => sub { $self->presenter->customer($_[0]->customer, display => 'table-cell', callback => $callback) },
 400                          sub      => sub { $_[0]->customer->name } },
 401       projectnumber => { raw_data => sub { $self->presenter->project($_[0]->project, display => 'table-cell', callback => $callback) },
 402                          sub      => sub { $_[0]->project_id ? $_[0]->project->projectnumber : '' } },
 403       status        => { sub      => sub { $_[0]->status->description } },
 404       type          => { sub      => sub { $_[0]->type->description } },
 405       version       => { sub      => sub { $_[0]->version ? $_[0]->version->version_number : t8('Working copy without version') } },
 406     );
 407   }
 408
 409   map { $column_defs{$_}->{text} ||= $::locale->text( $self->get_sort_spec->{$_}->{title} ) } keys %column_defs;
 410
 411   $report->set_options(
 412     std_column_visibility => 1,
 413     controller_class      => 'RequirementSpec',
 414     output_format         => 'HTML',
 415     raw_top_info_text     => $self->render('requirement_spec/report_top',    { output => 0 }, is_template => $is_template),
 416     raw_bottom_info_text  => $self->render('requirement_spec/report_bottom', { output => 0 }),
 417     title                 => $is_template ? t8('Requirement Spec Templates') : t8('Requirement Specs'),
 418     allow_pdf_export      => 1,
 419     allow_csv_export      => 1,
 420   );
 421   $report->set_columns(%column_defs);
 422   $report->set_column_order(@columns);
 423   $report->set_export_options(qw(list filter));
 424   $report->set_options_from_form;
 425   $self->set_report_generator_sort_options(report => $report, sortable_columns => \@sortable);
 426
 427   $self->disable_pagination if $report->{options}{output_format} =~ /^(pdf|csv)$/i;
 428 }
 429
 430 sub invalidate_version {
 431   my ($self) = @_;
 432
 433   my $rspec  = SL::DB::RequirementSpec->new(id => $self->requirement_spec->id)->load;
 434   return $self->js if $rspec->is_template;
 435
 436   $rspec->invalidate_version;
 437
 438   my $html = $self->render('requirement_spec/_version', { output => 0 }, requirement_spec => $rspec);
 439   return $self->js->html('#requirement_spec_version', $html);
 440 }
 441
 442 sub render_pasted_text_block {
 443   my ($self, $text_block, %params) = @_;
 444
 445   if ($self->current_text_block_output_position == $text_block->output_position) {
 446     my $html = $self->render('requirement_spec_text_block/_text_block', { output => 0 }, text_block => $text_block);
 447     $self->js
 448       ->appendTo($html, '#text-block-list')
 449       ->hide('#text-block-list-empty');
 450   }
 451
 452   my $node       = $self->presenter->requirement_spec_text_block_jstree_data($text_block);
 453   my $front_back = $text_block->output_position == 0 ? 'front' : 'back';
 454   $self->js
 455     ->jstree->create_node('#tree', "#tb-${front_back}", 'last', $node)
 456     ->jstree->open_node(  '#tree', "#tb-${front_back}");
 457 }
 458
 459 sub render_pasted_section {
 460   my ($self, $item, $parent_id) = @_;
 461
 462   my $node = $self->presenter->requirement_spec_item_jstree_data($item);
 463   $self->js
 464     ->jstree->create_node('#tree', $parent_id ? "#fb-${parent_id}" : '#sections', 'last', $node)
 465     ->jstree->open_node(  '#tree', $parent_id ? "#fb-${parent_id}" : '#sections');
 466
 467   $self->render_pasted_section($_, $item->id) for @{ $item->children_sorted };
 468 }
 469
 470 sub render_first_pasted_section_as_list {
 471   my ($self, $section, %params) = @_;
 472
 473   my $html = $self->render('requirement_spec_item/_section', { output => 0 }, requirement_spec_item => $section);
 474   $self->js
 475     ->html('#column-content', $html)
 476     ->val( '#current_content_type', $section->item_type)
 477     ->val( '#current_content_id',   $section->id)
 478     ->jstree->select_node('#tree', '#fb-' . $section->id);
 479 }
 480
 481 sub prepare_pictures_for_printing {
 482   my ($self) = @_;
 483
 484   my @files;
 485   my $userspath = File::Spec->rel2abs($::lx_office_conf{paths}->{userspath});
 486   my $target    =  "${userspath}/kivitendo-print-requirement-spec-picture-" . Common::unique_id() . '-';
 487
 488   foreach my $picture (map { @{ $_->pictures } } @{ $self->requirement_spec->text_blocks }) {
 489     my $output_file_name        = $target . $picture->id . '.' . $picture->get_default_file_name_extension;
 490     $picture->{print_file_name} = File::Spec->abs2rel($output_file_name, $userspath);
 491     my $out                     = IO::File->new($output_file_name, 'w') || die("Could not create file " . $output_file_name);
 492     $out->binmode;
 493     $out->print($picture->picture_content);
 494     $out->close;
 495
 496     push @files, $output_file_name;
 497   }
 498
 499   return @files;
 500 }
 501
 502 1;