SL/Controller/RequirementSpec.pm

   1 package SL::Controller::RequirementSpec;
   2
   3 use strict;
   4 use utf8;
   5
   6 use parent qw(SL::Controller::Base);
   7
   8 use File::Spec ();
   9
  10 use SL::ClientJS;
  11 use SL::Common ();
  12 use SL::Controller::Helper::GetModels;
  13 use SL::Controller::Helper::ReportGenerator;
  14 use SL::Controller::Helper::RequirementSpec;
  15 use SL::DB::Customer;
  16 use SL::DB::Project;
  17 use SL::DB::ProjectStatus;
  18 use SL::DB::ProjectType;
  19 use SL::DB::RequirementSpecComplexity;
  20 use SL::DB::RequirementSpecRisk;
  21 use SL::DB::RequirementSpecStatus;
  22 use SL::DB::RequirementSpecType;
  23 use SL::DB::RequirementSpec;
  24 use SL::Helper::Flash;
  25 use SL::Locale::String;
  26 use SL::Template::LaTeX;
  27
  28 use Rose::Object::MakeMethods::Generic
  29 (
  30   scalar                  => [ qw(requirement_spec_item visible_item visible_section) ],
  31   'scalar --get_set_init' => [ qw(requirement_spec customers types statuses complexities risks projects project_types project_statuses default_project_type default_project_status copy_source js
  32                                   current_text_block_output_position models) ],
  33 );
  34
  35 __PACKAGE__->run_before('setup');
  36 __PACKAGE__->run_before('set_default_filter_args', only => [ qw(list) ]);
  37
  38 my %sort_columns = (
  39   customer      => t8('Customer'),
  40   title         => t8('Title'),
  41   type          => t8('Requirement Spec Type'),
  42   status        => t8('Requirement Spec Status'),
  43   projectnumber => t8('Project Number'),
  44   version       => t8('Version'),
  45   mtime         => t8('Last modification'),
  46 );
  47
  48 #
  49 # actions
  50 #
  51
  52
  53 sub action_list {
  54   my ($self) = @_;
  55
  56   $self->prepare_report;
  57   $self->report_generator_list_objects(report => $self->{report}, objects => $self->models->get);
  58 }
  59
  60 sub action_new {
  61   my ($self) = @_;
  62
  63   $self->requirement_spec(SL::DB::RequirementSpec->new(is_template => $::form->{is_template}));
  64
  65   if ($self->copy_source) {
  66     $self->requirement_spec->$_($self->copy_source->$_) for qw(type_id status_id customer_id title hourly_rate is_template)
  67   }
  68
  69   $self->render('requirement_spec/new', title => $self->requirement_spec->is_template ? t8('Create a new requirement spec template') : t8('Create a new requirement spec'));
  70 }
  71
  72 sub action_ajax_show_basic_settings {
  73   my ($self) = @_;
  74
  75   $self->render('requirement_spec/_show_basic_settings', { layout => 0 });
  76 }
  77
  78 sub action_ajax_edit {
  79   my ($self) = @_;
  80
  81   my $html   = $self->render('requirement_spec/_form', { output => 0 }, submit_as => 'ajax');
  82
  83   $self->js
  84     ->hide('#basic_settings')
  85     ->after('#basic_settings', $html)
  86     ->render($self);
  87 }
  88
  89 sub action_ajax_edit_project_link {
  90   my ($self) = @_;
  91
  92   my $html   = $self->render('requirement_spec/_project_link_form', { output => 0 }, submit_as => 'ajax');
  93
  94   $self->js
  95     ->hide('#basic_settings')
  96     ->after('#basic_settings', $html)
  97     ->render($self);
  98 }
  99
 100 sub action_ajax_show_time_and_cost_estimate {
 101   my ($self) = @_;
 102
 103   $self->render('requirement_spec/_show_time_and_cost_estimate', { layout => 0 });
 104 }
 105
 106 sub action_ajax_edit_time_and_cost_estimate {
 107   my ($self) = @_;
 108
 109   my $html   = $self->render('requirement_spec/_edit_time_and_cost_estimate', { output => 0 });
 110   my $first  = ($self->requirement_spec->sections_sorted || [])->[0];
 111   $first     = ($first->children_sorted || [])->[0] if $first;
 112
 113   $self->js
 114    ->hide('#time_cost_estimate')
 115    ->after('#time_cost_estimate', $html)
 116    ->on('#time_cost_estimate INPUT[type=text]', 'keydown', 'kivi.requirement_spec.time_cost_estimate_input_key_down')
 117    ->action_if($first && $first->id, 'focus', '#time_and_cost_estimate_form_complexity_id_' . $first->id)
 118    ->render($self);
 119 }
 120
 121 sub action_ajax_save_time_and_cost_estimate {
 122   my ($self) = @_;
 123
 124   $self->requirement_spec->db->do_transaction(sub {
 125     # Make Emacs happy
 126     1;
 127     foreach my $attributes (@{ $::form->{requirement_spec_items} || [] }) {
 128       SL::DB::RequirementSpecItem
 129         ->new(id => delete $attributes->{id})
 130         ->load
 131         ->update_attributes(%{ $attributes });
 132     }
 133
 134     1;
 135   });
 136
 137   $self->requirement_spec(SL::DB::RequirementSpec->new(id => $self->requirement_spec->id)->load);
 138
 139   my $html = $self->render('requirement_spec/_show_time_and_cost_estimate', { output => 0 }, initially_hidden => !!$::form->{keep_open});
 140   $self->js->replaceWith('#time_cost_estimate', $html);
 141
 142   return $self->js->render($self) if $::form->{keep_open};
 143
 144   $self->js->remove('#time_cost_estimate_form_container');
 145
 146   if ($self->visible_section) {
 147     $html = $self->render('requirement_spec_item/_section', { output => 0 }, requirement_spec_item => $self->visible_section);
 148     $self->js->html('#column-content', $html);
 149   }
 150
 151   $self->js->render($self);
 152 }
 153
 154 sub action_show {
 155   my ($self) = @_;
 156
 157   my $title  = $self->requirement_spec->is_template ? t8('Show requirement spec template') : t8('Show requirement spec');
 158   my $item   = $::form->{requirement_spec_item_id} ? SL::DB::RequirementSpecItem->new(id => $::form->{requirement_spec_item_id})->load : @{ $self->requirement_spec->sections_sorted }[0];
 159   $self->requirement_spec_item($item);
 160
 161   $self->render('requirement_spec/show', title => $title);
 162 }
 163
 164 sub action_create {
 165   my ($self) = @_;
 166
 167   $self->requirement_spec(SL::DB::RequirementSpec->new);
 168   $self->create_or_update;
 169 }
 170
 171 sub action_update {
 172   my ($self) = @_;
 173   $self->create_or_update;
 174 }
 175
 176 sub action_update_project_link {
 177   my $self   = shift;
 178   my $action = delete($::form->{project_link_action}) || 'keep';
 179
 180   return $self->update_project_link_none_keep_existing($action) if $action =~ m{none|keep|existing};
 181   return $self->update_project_link_new($action)                if $action eq 'new';
 182   return $self->update_project_link_create($action)             if $action eq 'create';
 183
 184   die "Unknown project link action '$action'";
 185 }
 186
 187 sub action_destroy {
 188   my ($self) = @_;
 189
 190   if (eval { $self->requirement_spec->delete; 1; }) {
 191     flash_later('info',  t8('The requirement spec has been deleted.'));
 192   } else {
 193     flash_later('error', t8('The requirement spec is in use and cannot be deleted.'));
 194   }
 195
 196   $self->redirect_to(action => 'list');
 197 }
 198
 199 sub action_revert_to {
 200   my ($self, %params) = @_;
 201
 202   return $self->js->error(t8('Cannot revert a versioned copy.'))->render($self) if $self->requirement_spec->working_copy_id;
 203
 204   my $versioned_copy = SL::DB::RequirementSpec->new(id => $::form->{versioned_copy_id})->load;
 205
 206   $self->requirement_spec->copy_from($versioned_copy);
 207   my $version = $versioned_copy->versions->[0];
 208   $version->update_attributes(working_copy_id => $self->requirement_spec->id);
 209
 210   flash_later('info', t8('The requirement spec has been reverted to version #1.', $self->requirement_spec->version->version_number));
 211   $self->js->redirect_to($self->url_for(action => 'show', id => $self->requirement_spec->id))->render($self);
 212 }
 213
 214 sub action_create_pdf {
 215   my ($self, %params) = @_;
 216
 217   my $base_name       = $self->requirement_spec->type->template_file_name || 'requirement_spec';
 218   my @pictures        = $self->prepare_pictures_for_printing;
 219   my %result          = SL::Template::LaTeX->parse_and_create_pdf("${base_name}.tex", SELF => $self, rspec => $self->requirement_spec);
 220
 221   unlink @pictures unless ($::lx_office_conf{debug} || {})->{keep_temp_files};
 222
 223   $::form->error(t8('Conversion to PDF failed: #1', $result{error})) if $result{error};
 224
 225   my $attachment_name  =  $self->requirement_spec->type->description . ' ' . ($self->requirement_spec->working_copy_id || $self->requirement_spec->id);
 226   $attachment_name    .=  ' (v' . $self->requirement_spec->version->version_number . ')' if $self->requirement_spec->version;
 227   $attachment_name    .=  '.pdf';
 228   $attachment_name     =~ s/[^\wäöüÄÖÜß \-\+\(\)\[\]\{\}\.,]+/_/g;
 229
 230   $self->send_file($result{file_name}, type => 'application/pdf', name => $attachment_name);
 231   unlink $result{file_name};
 232 }
 233
 234 sub action_select_template_to_paste {
 235   my ($self) = @_;
 236
 237   my @templates = @{ SL::DB::Manager::RequirementSpec->get_all(
 238     where   => [ is_template => 1, SL::DB::Manager::RequirementSpec->not_empty_filter ],
 239     sort_by => 'lower(requirement_specs.title)',
 240   ) };
 241   $self->render('requirement_spec/select_template_to_paste', { layout => 0 }, TEMPLATES => \@templates);
 242 }
 243
 244 sub action_paste_template {
 245   my ($self, %params) = @_;
 246
 247   my $template = SL::DB::RequirementSpec->new(id => $::form->{template_id})->load;
 248   my %result   = $self->requirement_spec->paste_template($template);
 249
 250   return $self->js->error($self->requirement_spec->error)->render($self) if !%result;
 251
 252   $self->render_pasted_text_block($_) for sort { $a->position <=> $b->position } @{ $result{text_blocks} };
 253   $self->render_pasted_section($_)    for sort { $a->position <=> $b->position } @{ $result{sections}    };
 254
 255   if (@{ $result{sections} } && (($::form->{current_content_type} || 'sections') eq 'sections') && !$::form->{current_content_id}) {
 256     $self->render_first_pasted_section_as_list($result{sections}->[0]);
 257   }
 258
 259   my $parts_list = $self->render('requirement_spec_part/show', { output => 0 });
 260   $self->js
 261     ->replaceWith('#additional_parts_list_container', $parts_list)
 262     ->show(       '#additional_parts_list_container')
 263     ->remove(     '#additional_parts_form_container');
 264
 265   $self->invalidate_version->render($self);
 266 }
 267
 268 #
 269 # filters
 270 #
 271
 272 sub setup {
 273   my ($self) = @_;
 274
 275   $::auth->assert('requirement_spec_edit');
 276   $::request->{layout}->use_stylesheet("${_}.css") for qw(jquery.contextMenu requirement_spec);
 277   $::request->{layout}->use_javascript("${_}.js")  for qw(jquery.jstree jquery/jquery.contextMenu jquery/jquery.hotkeys requirement_spec ckeditor/ckeditor ckeditor/adapters/jquery);
 278   $self->init_visible_section;
 279
 280   return 1;
 281 }
 282
 283 sub init_js                     { SL::ClientJS->new                                           }
 284 sub init_complexities           { SL::DB::Manager::RequirementSpecComplexity->get_all_sorted  }
 285 sub init_default_project_status { SL::DB::Manager::ProjectStatus->find_by(name => 'planning') }
 286 sub init_default_project_type   { SL::DB::ProjectType->new(id => 1)->load                     }
 287 sub init_project_statuses       { SL::DB::Manager::ProjectStatus->get_all_sorted              }
 288 sub init_project_types          { SL::DB::Manager::ProjectType->get_all_sorted                }
 289 sub init_projects               { SL::DB::Manager::Project->get_all_sorted                    }
 290 sub init_risks                  { SL::DB::Manager::RequirementSpecRisk->get_all_sorted        }
 291 sub init_statuses               { SL::DB::Manager::RequirementSpecStatus->get_all_sorted      }
 292 sub init_types                  { SL::DB::Manager::RequirementSpecType->get_all_sorted        }
 293
 294 sub init_customers {
 295   my ($self) = @_;
 296
 297   my @filter = ('!obsolete' => 1);
 298   @filter    = ( or => [ @filter, id => $self->requirement_spec->customer_id ] ) if $self->requirement_spec && $self->requirement_spec->customer_id;
 299
 300   return SL::DB::Manager::Customer->get_all_sorted(where => \@filter);
 301 }
 302
 303 sub init_requirement_spec {
 304   my ($self) = @_;
 305   $self->requirement_spec(SL::DB::RequirementSpec->new(id => $::form->{id})->load || die "No such requirement spec") if $::form->{id};
 306 }
 307
 308 sub init_copy_source {
 309   my ($self) = @_;
 310   $self->copy_source(SL::DB::RequirementSpec->new(id => $::form->{copy_source_id})->load) if $::form->{copy_source_id};
 311 }
 312
 313 sub init_current_text_block_output_position {
 314   my ($self) = @_;
 315   $self->current_text_block_output_position($::form->{current_content_type} !~ m/^(?:text-blocks|tb)-(front|back)/ ? -1 : $1 eq 'front' ? 0 : 1);
 316 }
 317
 318 #
 319 # helpers
 320 #
 321
 322 sub create_or_update {
 323   my $self   = shift;
 324   my $is_new = !$self->requirement_spec->id;
 325   my $params = delete($::form->{requirement_spec}) || { };
 326
 327   $self->requirement_spec->assign_attributes(%{ $params });
 328
 329   my $title  = $is_new && $self->requirement_spec->is_template ? t8('Create a new requirement spec template')
 330              : $is_new                                         ? t8('Create a new requirement spec')
 331              :            $self->requirement_spec->is_template ? t8('Edit requirement spec template')
 332              :                                                   t8('Edit requirement spec');
 333
 334   my @errors = $self->requirement_spec->validate;
 335
 336   if (@errors) {
 337     return $self->js->error(@errors)->render($self) if $::request->is_ajax;
 338
 339     flash('error', @errors);
 340     $self->render('requirement_spec/new', title => $title);
 341     return;
 342   }
 343
 344   my $db = $self->requirement_spec->db;
 345   if (!$db->do_transaction(sub {
 346     if ($self->copy_source) {
 347       $self->requirement_spec($self->copy_source->create_copy(%{ $params }));
 348     } else {
 349       $self->requirement_spec->save;
 350     }
 351   })) {
 352     $::lxdebug->message(LXDebug::WARN(), "Error: " . $db->error);
 353     @errors = ($::locale->text('Saving failed. Error message from the database: #1', $db->error));
 354     return $self->js->error(@errors)->render($self) if $::request->is_ajax;
 355
 356     $self->requirement_spec->id(undef) if $is_new;
 357     flash('error', @errors);
 358     return $self->render('requirement_spec/new', title => $title);
 359   }
 360
 361   my $info = $self->requirement_spec->is_template ? t8('The requirement spec template has been saved.') : t8('The requirement spec has been saved.');
 362
 363   if ($::request->is_ajax) {
 364     my $header_html = $self->render('requirement_spec/_header', { output => 0 });
 365     my $basics_html = $self->render('requirement_spec/_show_basic_settings', { output => 0 });
 366     return $self->invalidate_version
 367       ->replaceWith('#requirement-spec-header', $header_html)
 368       ->replaceWith('#basic_settings',          $basics_html)
 369       ->remove('#basic_settings_form')
 370       ->flash('info', $info)
 371       ->render($self);
 372   }
 373
 374   flash_later('info', $info);
 375   $self->redirect_to(action => 'show', id => $self->requirement_spec->id);
 376 }
 377
 378 sub prepare_report {
 379   my ($self)      = @_;
 380
 381   my $is_template = $::form->{is_template};
 382   my $report      = SL::ReportGenerator->new(\%::myconfig, $::form);
 383
 384   $self->models->disable_plugin('paginated') if $report->{options}{output_format} =~ /^(pdf|csv)$/i;
 385   $self->models->finalize; # for filter laundering
 386   my $callback    = $self->models->get_callback;
 387
 388   $self->{report} = $report;
 389
 390   my @columns     = $is_template ? qw(title mtime) : qw(title customer status type projectnumber mtime version);
 391   my @sortable    = $is_template ? qw(title mtime) : qw(title customer status type projectnumber mtime);
 392
 393   my %column_defs = (
 394     title         => { obj_link => sub { $self->url_for(action => 'show', id => $_[0]->id, callback => $callback) } },
 395     mtime         => { sub      => sub { ($_[0]->mtime || $_[0]->itime)->to_kivitendo(precision => 'minute') } },
 396   );
 397
 398   if (!$is_template) {
 399     %column_defs = (
 400       %column_defs,
 401       customer      => { raw_data => sub { $self->presenter->customer($_[0]->customer, display => 'table-cell', callback => $callback) },
 402                          sub      => sub { $_[0]->customer->name } },
 403       projectnumber => { raw_data => sub { $self->presenter->project($_[0]->project, display => 'table-cell', callback => $callback) },
 404                          sub      => sub { $_[0]->project_id ? $_[0]->project->projectnumber : '' } },
 405       status        => { sub      => sub { $_[0]->status->description } },
 406       type          => { sub      => sub { $_[0]->type->description } },
 407       version       => { sub      => sub { $_[0]->version ? $_[0]->version->version_number : t8('Working copy without version') } },
 408     );
 409   }
 410
 411   map { $column_defs{$_}->{text} ||= $::locale->text( $self->models->get_sort_spec->{$_}->{title} ) } keys %column_defs;
 412
 413   $report->set_options(
 414     std_column_visibility => 1,
 415     controller_class      => 'RequirementSpec',
 416     output_format         => 'HTML',
 417     raw_top_info_text     => $self->render('requirement_spec/report_top',    { output => 0 }, is_template => $is_template),
 418     raw_bottom_info_text  => $self->render('requirement_spec/report_bottom', { output => 0 }, models => $self->models),
 419     title                 => $is_template ? t8('Requirement Spec Templates') : t8('Requirement Specs'),
 420     allow_pdf_export      => 1,
 421     allow_csv_export      => 1,
 422   );
 423   $report->set_columns(%column_defs);
 424   $report->set_column_order(@columns);
 425   $report->set_export_options(qw(list filter));
 426   $report->set_options_from_form;
 427   $self->models->set_report_generator_sort_options(report => $report, sortable_columns => \@sortable);
 428 }
 429
 430 sub invalidate_version {
 431   my ($self) = @_;
 432
 433   my $rspec  = SL::DB::RequirementSpec->new(id => $self->requirement_spec->id)->load;
 434   return $self->js if $rspec->is_template;
 435
 436   $rspec->invalidate_version;
 437
 438   my $html = $self->render('requirement_spec/_version', { output => 0 }, requirement_spec => $rspec);
 439   return $self->js->html('#requirement_spec_version', $html);
 440 }
 441
 442 sub render_pasted_text_block {
 443   my ($self, $text_block, %params) = @_;
 444
 445   if ($self->current_text_block_output_position == $text_block->output_position) {
 446     my $html = $self->render('requirement_spec_text_block/_text_block', { output => 0 }, text_block => $text_block);
 447     $self->js
 448       ->appendTo($html, '#text-block-list')
 449       ->hide('#text-block-list-empty');
 450   }
 451
 452   my $node       = $self->presenter->requirement_spec_text_block_jstree_data($text_block);
 453   my $front_back = $text_block->output_position == 0 ? 'front' : 'back';
 454   $self->js
 455     ->jstree->create_node('#tree', "#tb-${front_back}", 'last', $node)
 456     ->jstree->open_node(  '#tree', "#tb-${front_back}");
 457 }
 458
 459 sub set_default_filter_args {
 460   my ($self) = @_;
 461
 462   if (!$::form->{filter} && !$::form->{is_template}) {
 463     $::form->{filter} = {
 464       status_id => [ map { $_->{id} } grep { $_->name ne 'done' } @{ $self->statuses } ],
 465     };
 466   }
 467
 468   return 1;
 469 }
 470
 471 sub render_pasted_section {
 472   my ($self, $item, $parent_id) = @_;
 473
 474   my $node = $self->presenter->requirement_spec_item_jstree_data($item);
 475   $self->js
 476     ->jstree->create_node('#tree', $parent_id ? "#fb-${parent_id}" : '#sections', 'last', $node)
 477     ->jstree->open_node(  '#tree', $parent_id ? "#fb-${parent_id}" : '#sections');
 478
 479   $self->render_pasted_section($_, $item->id) for @{ $item->children_sorted };
 480 }
 481
 482 sub render_first_pasted_section_as_list {
 483   my ($self, $section, %params) = @_;
 484
 485   my $html = $self->render('requirement_spec_item/_section', { output => 0 }, requirement_spec_item => $section);
 486   $self->js
 487     ->html('#column-content', $html)
 488     ->val( '#current_content_type', $section->item_type)
 489     ->val( '#current_content_id',   $section->id)
 490     ->jstree->select_node('#tree', '#fb-' . $section->id);
 491 }
 492
 493 sub prepare_pictures_for_printing {
 494   my ($self) = @_;
 495
 496   my @files;
 497   my $userspath = File::Spec->rel2abs($::lx_office_conf{paths}->{userspath});
 498   my $target    =  "${userspath}/kivitendo-print-requirement-spec-picture-" . Common::unique_id() . '-';
 499
 500   foreach my $picture (map { @{ $_->pictures } } @{ $self->requirement_spec->text_blocks }) {
 501     my $output_file_name        = $target . $picture->id . '.' . $picture->get_default_file_name_extension;
 502     $picture->{print_file_name} = File::Spec->abs2rel($output_file_name, $userspath);
 503     my $out                     = IO::File->new($output_file_name, 'w') || die("Could not create file " . $output_file_name);
 504     $out->binmode;
 505     $out->print($picture->picture_content);
 506     $out->close;
 507
 508     push @files, $output_file_name;
 509   }
 510
 511   return @files;
 512 }
 513
 514 sub update_project_link_none_keep_existing {
 515   my ($self, $action) = @_;
 516
 517   $self->requirement_spec->update_attributes(project_id => undef)                     if $action eq 'none';
 518   $self->requirement_spec->update_attributes(project_id => $::form->{new_project_id}) if $action eq 'existing';
 519
 520   return $self->invalidate_version
 521     ->replaceWith('#basic_settings', $self->render('requirement_spec/_show_basic_settings', { output => 0 }))
 522     ->remove('#project_link_form')
 523     ->flash('info', t8('The project link has been updated.'))
 524     ->render($self);
 525 }
 526
 527 sub update_project_link_new {
 528   my ($self) = @_;
 529
 530   return $self->js
 531     ->replaceWith('#project_link_form', $self->render('requirement_spec/_new_project_form', { output => 0 }))
 532     ->render($self);
 533 }
 534
 535 sub update_project_link_create {
 536   my ($self)  = @_;
 537   my $params  = delete($::form->{project}) || {};
 538   my $project = SL::DB::Project->new(
 539     %{ $params },
 540     valid  => 1,
 541     active => 1,
 542   );
 543
 544   my @errors = $project->validate;
 545
 546   return $self->js->error(@errors)->render($self) if @errors;
 547
 548   my $db = $self->requirement_spec->db;
 549   if (!$db->do_transaction(sub {
 550     $project->save;
 551     $self->requirement_spec->update_attributes(project_id => $project->id);
 552
 553   })) {
 554     $::lxdebug->message(LXDebug::WARN(), "Error: " . $db->error);
 555     return $self->js->error(t8('Saving failed. Error message from the database: #1', $db->error))->render($self);
 556   }
 557
 558   return $self->invalidate_version
 559     ->replaceWith('#basic_settings', $self->render('requirement_spec/_show_basic_settings', { output => 0 }))
 560     ->remove('#project_link_form')
 561     ->flash('info', t8('The project has been created.'))
 562     ->flash('info', t8('The project link has been updated.'))
 563     ->render($self);
 564 }
 565
 566 sub init_models {
 567   my ($self) = @_;
 568
 569   SL::Controller::Helper::GetModels->new(
 570     controller   => $self,
 571     sorted       => {
 572       _default     => {
 573         by           => 'customer',
 574         dir          => 1,
 575       },
 576       %sort_columns,
 577     },
 578     query => [
 579       and => [
 580         working_copy_id => undef,
 581         is_template     => $::form->{is_template} ? 1 : 0,
 582       ],
 583     ],
 584     with_objects => [ 'customer', 'type', 'status', 'project' ],
 585   );
 586 }
 587
 588 1;