SL/Controller/RequirementSpec.pm

   1 package SL::Controller::RequirementSpec;
   2
   3 use strict;
   4
   5 use parent qw(SL::Controller::Base);
   6
   7 use SL::ClientJS;
   8 use SL::Controller::Helper::GetModels;
   9 use SL::Controller::Helper::Paginated;
  10 use SL::Controller::Helper::Sorted;
  11 use SL::Controller::Helper::ParseFilter;
  12 use SL::Controller::Helper::ReportGenerator;
  13 use SL::Controller::Helper::RequirementSpec;
  14 use SL::DB::Customer;
  15 use SL::DB::Project;
  16 use SL::DB::RequirementSpecComplexity;
  17 use SL::DB::RequirementSpecRisk;
  18 use SL::DB::RequirementSpecStatus;
  19 use SL::DB::RequirementSpecType;
  20 use SL::DB::RequirementSpec;
  21 use SL::Helper::Flash;
  22 use SL::Locale::String;
  23
  24 use Rose::Object::MakeMethods::Generic
  25 (
  26   scalar                  => [ qw(requirement_spec_item customers types statuses db_args flat_filter is_template visible_item visible_section) ],
  27   'scalar --get_set_init' => [ qw(requirement_spec complexities risks projects copy_source js) ],
  28 );
  29
  30 __PACKAGE__->run_before('setup');
  31 __PACKAGE__->run_before('load_select_options',  only => [ qw(new ajax_edit create update list) ]);
  32
  33
  34 __PACKAGE__->get_models_url_params('flat_filter');
  35 __PACKAGE__->make_paginated(
  36   MODEL         => 'RequirementSpec',
  37   PAGINATE_ARGS => 'db_args',
  38   ONLY          => [ qw(list) ],
  39 );
  40
  41 __PACKAGE__->make_sorted(
  42   MODEL         => 'RequirementSpec',
  43   ONLY          => [ qw(list) ],
  44
  45   DEFAULT_BY    => 'customer',
  46   DEFAULT_DIR   => 1,
  47
  48   customer      => t8('Customer'),
  49   title         => t8('Title'),
  50   type          => t8('Requirement Spec Type'),
  51   status        => t8('Requirement Spec Status'),
  52   projectnumber => t8('Project Number'),
  53   version       => t8('Version'),
  54   mtime         => t8('Last modification'),
  55 );
  56
  57 #
  58 # actions
  59 #
  60
  61
  62 sub action_list {
  63   my ($self) = @_;
  64
  65   $self->setup_db_args_from_filter;
  66   $self->flat_filter({ map { $_->{key} => $_->{value} } $::form->flatten_variables('filter') });
  67
  68   $self->prepare_report;
  69
  70   my $requirement_specs = $self->get_models(%{ $self->db_args });
  71
  72   $self->report_generator_list_objects(report => $self->{report}, objects => $requirement_specs);
  73 }
  74
  75 sub action_new {
  76   my ($self) = @_;
  77
  78   $self->requirement_spec(SL::DB::RequirementSpec->new);
  79
  80   if ($self->copy_source) {
  81     $self->requirement_spec->$_($self->copy_source->$_) for qw(type_id status_id customer_id title hourly_rate)
  82   }
  83
  84   $self->render('requirement_spec/new', title => t8('Create a new requirement spec'));
  85 }
  86
  87 sub action_ajax_edit {
  88   my ($self) = @_;
  89
  90   $self->render('requirement_spec/_form', { layout => 0 }, submit_as => 'ajax');
  91 }
  92
  93 sub action_ajax_show_time_and_cost_estimate {
  94   my ($self) = @_;
  95
  96   $self->render('requirement_spec/_show_time_and_cost_estimate', { layout => 0 });
  97 }
  98
  99 sub action_ajax_cancel_time_and_cost_estimate {
 100   my ($self) = @_;
 101
 102   my $html   = $self->render('requirement_spec/_show_time_and_cost_estimate', { output => 0 });
 103
 104   $self->js
 105    ->replaceWith('#time_cost_estimate', $html)
 106    ->render($self);
 107 }
 108
 109 sub action_ajax_edit_time_and_cost_estimate {
 110   my ($self) = @_;
 111
 112   my $html   = $self->render('requirement_spec/_edit_time_and_cost_estimate', { output => 0 });
 113
 114   $self->js
 115    ->replaceWith('#time_cost_estimate', $html)
 116    ->render($self);
 117 }
 118
 119 sub action_ajax_save_time_and_cost_estimate {
 120   my ($self) = @_;
 121
 122   $self->requirement_spec->db->do_transaction(sub {
 123     # Make Emacs happy
 124     1;
 125     foreach my $attributes (@{ $::form->{requirement_spec_items} || [] }) {
 126       SL::DB::RequirementSpecItem
 127         ->new(id => delete $attributes->{id})
 128         ->load
 129         ->update_attributes(%{ $attributes });
 130     }
 131
 132     1;
 133   });
 134
 135   my $html = $self->render('requirement_spec/_show_time_and_cost_estimate', { output => 0 });
 136   $self->js->replaceWith('#time_cost_estimate', $html);
 137
 138   if ($self->visible_section) {
 139     $html = $self->render('requirement_spec_item/_section', { output => 0 }, requirement_spec_item => $self->visible_section);
 140     $self->js->html('#column-content', $html);
 141   }
 142
 143   $self->js->render($self);
 144 }
 145
 146 sub action_show {
 147   my ($self) = @_;
 148
 149   my $item = $::form->{requirement_spec_item_id} ? SL::DB::RequirementSpecItem->new(id => $::form->{requirement_spec_item_id})->load : @{ $self->requirement_spec->sections }[0];
 150   $self->requirement_spec_item($item);
 151
 152   $self->render('requirement_spec/show', title => t8('Show requirement spec'));
 153 }
 154
 155 sub action_create {
 156   my ($self) = @_;
 157
 158   $self->requirement_spec(SL::DB::RequirementSpec->new);
 159   $self->create_or_update;
 160 }
 161
 162 sub action_update {
 163   my ($self) = @_;
 164   $self->create_or_update;
 165 }
 166
 167 sub action_destroy {
 168   my ($self) = @_;
 169
 170   if (eval { $self->requirement_spec->delete; 1; }) {
 171     flash_later('info',  t8('The requirement spec has been deleted.'));
 172   } else {
 173     flash_later('error', t8('The requirement spec is in use and cannot be deleted.'));
 174   }
 175
 176   $self->redirect_to(action => 'list');
 177 }
 178
 179 #
 180 # filters
 181 #
 182
 183 sub setup {
 184   my ($self) = @_;
 185
 186   $::auth->assert('sales_quotation_edit');
 187   $::request->{layout}->use_stylesheet("${_}.css") for qw(jquery.contextMenu requirement_spec);
 188   $::request->{layout}->use_javascript("${_}.js") for qw(jquery.jstree jquery/jquery.contextMenu client_js requirement_spec);
 189   $self->is_template($::form->{is_template} ? 1 : 0);
 190   $self->init_visible_section;
 191
 192   return 1;
 193 }
 194
 195 sub init_complexities {
 196   my ($self) = @_;
 197   return SL::DB::Manager::RequirementSpecComplexity->get_all_sorted;
 198 }
 199
 200 sub init_risks {
 201   my ($self) = @_;
 202   return SL::DB::Manager::RequirementSpecRisk->get_all_sorted;
 203 }
 204
 205 sub init_projects {
 206   my ($self) = @_;
 207   $self->projects(SL::DB::Manager::Project->get_all_sorted);
 208 }
 209
 210 sub init_requirement_spec {
 211   my ($self) = @_;
 212   $self->requirement_spec(SL::DB::RequirementSpec->new(id => $::form->{id})->load || die "No such requirement spec") if $::form->{id};
 213 }
 214
 215 sub init_copy_source {
 216   my ($self) = @_;
 217   $self->copy_source(SL::DB::RequirementSpec->new(id => $::form->{copy_source_id})->load) if $::form->{copy_source_id};
 218 }
 219
 220 sub init_js {
 221   my ($self) = @_;
 222   $self->js(SL::ClientJS->new);
 223 }
 224
 225 sub load_select_options {
 226   my ($self) = @_;
 227
 228   my @filter = ('!obsolete' => 1);
 229   @filter    = ( or => [ @filter, id => $self->requirement_spec->customer_id ] ) if $self->requirement_spec && $self->requirement_spec->customer_id;
 230
 231   $self->customers(SL::DB::Manager::Customer->get_all_sorted(where => \@filter));
 232   $self->statuses( SL::DB::Manager::RequirementSpecStatus->get_all_sorted);
 233   $self->types(    SL::DB::Manager::RequirementSpecType->get_all_sorted);
 234 }
 235
 236 #
 237 # helpers
 238 #
 239
 240 sub create_or_update {
 241   my $self   = shift;
 242   my $is_new = !$self->requirement_spec->id;
 243   my $params = delete($::form->{requirement_spec}) || { };
 244   my $title  = $is_new ? t8('Create a new requirement spec') : t8('Edit requirement spec');
 245
 246   $self->requirement_spec->assign_attributes(%{ $params });
 247
 248   my @errors = $self->requirement_spec->validate;
 249
 250   if (@errors) {
 251     return $self->js->error(@errors)->render($self) if $::request->is_ajax;
 252
 253     flash('error', @errors);
 254     $self->render('requirement_spec/new', title => $title);
 255     return;
 256   }
 257
 258   my $db = $self->requirement_spec->db;
 259   if (!$db->do_transaction(sub {
 260     if ($self->copy_source) {
 261       $self->requirement_spec($self->copy_source->create_copy(%{ $params }));
 262     } else {
 263       $self->requirement_spec->save;
 264     }
 265   })) {
 266     $::lxdebug->message(LXDebug::WARN(), "Error: " . $db->error);
 267     @errors = ($::locale->text('Saving failed. Error message from the database: #1'), $db->error);
 268     return $self->js->error(@errors)->render($self) if $::request->is_ajax;
 269
 270     $self->requirement_spec->id(undef) if $is_new;
 271     flash('error', @errors);
 272     return $self->render('requirement_spec/new', title => $title);
 273   }
 274
 275   if ($::request->is_ajax) {
 276     my $html = $self->render('requirement_spec/_header', { output => 0 });
 277     return $self->invalidate_version
 278       ->replaceWith('#requirement-spec-header', $html)
 279       ->flash('info', t8('The requirement spec has been saved.'))
 280       ->render($self);
 281   }
 282
 283   flash_later('info', $is_new ? t8('The requirement spec has been created.') : t8('The requirement spec has been saved.'));
 284   $self->redirect_to(action => 'show', id => $self->requirement_spec->id);
 285 }
 286
 287 sub setup_db_args_from_filter {
 288   my ($self) = @_;
 289
 290   $self->{filter} = {};
 291   my %args = parse_filter(
 292     $::form->{filter},
 293     with_objects => [ 'customer', 'type', 'status', 'project' ],
 294     launder_to   => $self->{filter},
 295   );
 296
 297   $args{where} = [
 298     and => [
 299       @{ $args{where} || [] },
 300       working_copy_id => undef,
 301       is_template     => $self->is_template
 302     ]];
 303
 304   $self->db_args(\%args);
 305 }
 306
 307 sub prepare_report {
 308   my ($self)      = @_;
 309
 310   my $callback    = $self->get_callback;
 311
 312   my $report      = SL::ReportGenerator->new(\%::myconfig, $::form);
 313   $self->{report} = $report;
 314
 315   my @columns     = qw(title customer status type projectnumber mtime version);
 316   my @sortable    = qw(title customer status type projectnumber mtime);
 317
 318   my %column_defs = (
 319     title         => { obj_link => sub { $self->url_for(action => 'show', id => $_[0]->id, callback => $callback) } },
 320     customer      => { raw_data => sub { $self->presenter->customer($_[0]->customer, display => 'table-cell', callback => $callback) },
 321                        sub      => sub { $_[0]->customer->name } },
 322     projectnumber => { raw_data => sub { $self->presenter->project($_[0]->project, display => 'table-cell', callback => $callback) },
 323                        sub      => sub { $_[0]->project_id ? $_[0]->project->projectnumber : '' } },
 324     status        => { sub      => sub { $_[0]->status->description } },
 325     type          => { sub      => sub { $_[0]->type->description } },
 326     version       => { sub      => sub { $_[0]->version_id ? $_[0]->version->version_number : t8('Working copy without version') } },
 327     mtime         => { sub      => sub { $_[0]->mtime->to_kivitendo(precision => 'minute') } },
 328   );
 329
 330   map { $column_defs{$_}->{text} ||= $::locale->text( $self->get_sort_spec->{$_}->{title} ) } keys %column_defs;
 331
 332   $report->set_options(
 333     std_column_visibility => 1,
 334     controller_class      => 'RequirementSpec',
 335     output_format         => 'HTML',
 336     raw_top_info_text     => $self->render('requirement_spec/report_top',    { output => 0 }),
 337     raw_bottom_info_text  => $self->render('requirement_spec/report_bottom', { output => 0 }),
 338     title                 => $::locale->text('Requirement Specs'),
 339     allow_pdf_export      => 1,
 340     allow_csv_export      => 1,
 341   );
 342   $report->set_columns(%column_defs);
 343   $report->set_column_order(@columns);
 344   $report->set_export_options(qw(list filter));
 345   $report->set_options_from_form;
 346   $self->set_report_generator_sort_options(report => $report, sortable_columns => \@sortable);
 347
 348   $self->disable_pagination if $report->{options}{output_format} =~ /^(pdf|csv)$/i;
 349 }
 350
 351 sub invalidate_version {
 352   my ($self) = @_;
 353
 354   my $rspec  = SL::DB::RequirementSpec->new(id => $self->requirement_spec->id)->load;
 355   $rspec->invalidate_version;
 356
 357   my $html = $self->render('requirement_spec/_version', { output => 0 }, requirement_spec => $rspec);
 358   return $self->js->html('#requirement_spec_version', $html);
 359 }
 360
 361
 362 1;