SL/Controller/RequirementSpec.pm

   1 package SL::Controller::RequirementSpec;
   2
   3 use strict;
   4
   5 use parent qw(SL::Controller::Base);
   6
   7 use SL::ClientJS;
   8 use SL::Controller::Helper::GetModels;
   9 use SL::Controller::Helper::Paginated;
  10 use SL::Controller::Helper::Sorted;
  11 use SL::Controller::Helper::ParseFilter;
  12 use SL::Controller::Helper::ReportGenerator;
  13 use SL::Controller::Helper::RequirementSpec;
  14 use SL::DB::Customer;
  15 use SL::DB::Project;
  16 use SL::DB::RequirementSpecComplexity;
  17 use SL::DB::RequirementSpecRisk;
  18 use SL::DB::RequirementSpecStatus;
  19 use SL::DB::RequirementSpecType;
  20 use SL::DB::RequirementSpec;
  21 use SL::Helper::Flash;
  22 use SL::Locale::String;
  23
  24 use Rose::Object::MakeMethods::Generic
  25 (
  26   scalar                  => [ qw(requirement_spec_item customers types statuses db_args flat_filter is_template visible_item visible_section) ],
  27   'scalar --get_set_init' => [ qw(requirement_spec complexities risks projects) ],
  28 );
  29
  30 __PACKAGE__->run_before('setup');
  31 __PACKAGE__->run_before('load_select_options',  only => [ qw(new ajax_edit create update list) ]);
  32
  33 __PACKAGE__->get_models_url_params('flat_filter');
  34 __PACKAGE__->make_paginated(
  35   MODEL         => 'RequirementSpec',
  36   PAGINATE_ARGS => 'db_args',
  37   ONLY          => [ qw(list) ],
  38 );
  39
  40 __PACKAGE__->make_sorted(
  41   MODEL         => 'RequirementSpec',
  42   ONLY          => [ qw(list) ],
  43
  44   DEFAULT_BY    => 'customer',
  45   DEFAULT_DIR   => 1,
  46
  47   customer      => t8('Customer'),
  48   title         => t8('Title'),
  49   type          => t8('Requirement Spec Type'),
  50   status        => t8('Requirement Spec Status'),
  51   projectnumber => t8('Project Number'),
  52 );
  53
  54 #
  55 # actions
  56 #
  57
  58
  59 sub action_list {
  60   my ($self) = @_;
  61
  62   $self->setup_db_args_from_filter;
  63   $self->flat_filter({ map { $_->{key} => $_->{value} } $::form->flatten_variables('filter') });
  64
  65   $self->prepare_report;
  66
  67   my $requirement_specs = $self->get_models(%{ $self->db_args });
  68
  69   $self->report_generator_list_objects(report => $self->{report}, objects => $requirement_specs);
  70 }
  71
  72 sub action_new {
  73   my ($self) = @_;
  74
  75   $self->requirement_spec(SL::DB::RequirementSpec->new);
  76   $self->render('requirement_spec/new', title => t8('Create a new requirement spec'));
  77 }
  78
  79 sub action_ajax_edit {
  80   my ($self) = @_;
  81
  82   $self->render('requirement_spec/_form', { layout => 0 }, submit_as => 'ajax');
  83 }
  84
  85 sub action_ajax_show_time_and_cost_estimate {
  86   my ($self) = @_;
  87
  88   $self->render('requirement_spec/_show_time_and_cost_estimate', { layout => 0 });
  89 }
  90
  91 sub action_ajax_cancel_time_and_cost_estimate {
  92   my ($self) = @_;
  93
  94   my $html   = $self->render('requirement_spec/_show_time_and_cost_estimate', { output => 0 });
  95
  96   SL::ClientJS->new
  97     ->replaceWith('#time_cost_estimate', $html)
  98     ->render($self);
  99 }
 100
 101 sub action_ajax_edit_time_and_cost_estimate {
 102   my ($self) = @_;
 103
 104   my $html   = $self->render('requirement_spec/_edit_time_and_cost_estimate', { output => 0 });
 105
 106   SL::ClientJS->new
 107     ->replaceWith('#time_cost_estimate', $html)
 108     ->render($self);
 109 }
 110
 111 sub action_ajax_save_time_and_cost_estimate {
 112   my ($self) = @_;
 113
 114   $self->requirement_spec->db->do_transaction(sub {
 115     # Make Emacs happy
 116     1;
 117     foreach my $attributes (@{ $::form->{requirement_spec_items} || [] }) {
 118       SL::DB::RequirementSpecItem
 119         ->new(id => delete $attributes->{id})
 120         ->load
 121         ->update_attributes(%{ $attributes });
 122     }
 123
 124     1;
 125   });
 126
 127   my $html = $self->render('requirement_spec/_show_time_and_cost_estimate', { output => 0 });
 128   my $js   = SL::ClientJS->new->replaceWith('#time_cost_estimate', $html);
 129
 130   if ($self->visible_section) {
 131     $html = $self->render('requirement_spec_item/_section', { output => 0 }, requirement_spec_item => $self->visible_section);
 132     $js->html('#column-content', $html);
 133   }
 134
 135   $js->render($self);
 136 }
 137
 138 sub action_show {
 139   my ($self) = @_;
 140
 141   my $item = $::form->{requirement_spec_item_id} ? SL::DB::RequirementSpecItem->new(id => $::form->{requirement_spec_item_id})->load : @{ $self->requirement_spec->sections }[0];
 142   $self->requirement_spec_item($item);
 143
 144   $self->render('requirement_spec/show', title => t8('Show requirement spec'));
 145 }
 146
 147 sub action_create {
 148   my ($self) = @_;
 149
 150   $self->requirement_spec(SL::DB::RequirementSpec->new);
 151   $self->create_or_update;
 152 }
 153
 154 sub action_update {
 155   my ($self) = @_;
 156   $self->create_or_update;
 157 }
 158
 159 sub action_destroy {
 160   my ($self) = @_;
 161
 162   if (eval { $self->requirement_spec->delete; 1; }) {
 163     flash_later('info',  t8('The requirement spec has been deleted.'));
 164   } else {
 165     flash_later('error', t8('The requirement spec is in use and cannot be deleted.'));
 166   }
 167
 168   $self->redirect_to(action => 'list');
 169 }
 170
 171 sub action_reorder {
 172   my ($self) = @_;
 173
 174   SL::DB::RequirementSpec->reorder_list(@{ $::form->{requirement_spec_id} || [] });
 175
 176   $self->render('1;', { type => 'js', inline => 1 });
 177 }
 178
 179 #
 180 # filters
 181 #
 182
 183 sub setup {
 184   my ($self) = @_;
 185
 186   $::auth->assert('config');
 187   $::request->{layout}->use_stylesheet("${_}.css") for qw(jquery.contextMenu requirement_spec);
 188   $::request->{layout}->use_javascript("${_}.js") for qw(jquery.jstree jquery/jquery.contextMenu client_js requirement_spec);
 189   $self->is_template($::form->{is_template} ? 1 : 0);
 190   $self->init_visible_section;
 191
 192   return 1;
 193 }
 194
 195 sub init_complexities {
 196   my ($self) = @_;
 197   return SL::DB::Manager::RequirementSpecComplexity->get_all_sorted;
 198 }
 199
 200 sub init_risks {
 201   my ($self) = @_;
 202   return SL::DB::Manager::RequirementSpecRisk->get_all_sorted;
 203 }
 204
 205 sub init_projects {
 206   my ($self) = @_;
 207   $self->projects(SL::DB::Manager::Project->get_all_sorted);
 208 }
 209
 210 sub init_requirement_spec {
 211   my ($self) = @_;
 212   $self->requirement_spec(SL::DB::RequirementSpec->new(id => $::form->{id})->load || die "No such requirement spec") if $::form->{id};
 213 }
 214
 215 sub load_select_options {
 216   my ($self) = @_;
 217
 218   my @filter = ('!obsolete' => 1);
 219   @filter    = ( or => [ @filter, id => $self->requirement_spec->customer_id ] ) if $self->requirement_spec && $self->requirement_spec->customer_id;
 220
 221   $self->customers(SL::DB::Manager::Customer->get_all_sorted(where => \@filter));
 222   $self->statuses( SL::DB::Manager::RequirementSpecStatus->get_all_sorted);
 223   $self->types(    SL::DB::Manager::RequirementSpecType->get_all_sorted);
 224 }
 225
 226 #
 227 # helpers
 228 #
 229
 230 sub create_or_update {
 231   my $self   = shift;
 232   my $is_new = !$self->requirement_spec->id;
 233   my $params = delete($::form->{requirement_spec}) || { };
 234   my $title  = $is_new ? t8('Create a new requirement spec') : t8('Edit requirement spec');
 235
 236   $self->requirement_spec->assign_attributes(%{ $params });
 237
 238   my @errors = $self->requirement_spec->validate;
 239
 240   if (@errors) {
 241     return SL::ClientJS->new->error(@errors)->render($self) if $::request->is_ajax;
 242
 243     flash('error', @errors);
 244     $self->render('requirement_spec/new', title => $title);
 245     return;
 246   }
 247
 248   $self->requirement_spec->save;
 249
 250   if ($::request->is_ajax) {
 251     my $html = $self->render('requirement_spec/_header', { output => 0 });
 252     return SL::ClientJS->new
 253       ->replaceWith('#requirement-spec-header', $html)
 254       ->flash('info', t8('The requirement spec has been saved.'))
 255       ->render($self);
 256   }
 257
 258   flash_later('info', $is_new ? t8('The requirement spec has been created.') : t8('The requirement spec has been saved.'));
 259   $self->redirect_to(action => 'show', id => $self->requirement_spec->id);
 260 }
 261
 262 sub setup_db_args_from_filter {
 263   my ($self) = @_;
 264
 265   $self->{filter} = {};
 266   my %args = parse_filter(
 267     $::form->{filter},
 268     with_objects => [ 'customer', 'type', 'status', 'project' ],
 269     launder_to   => $self->{filter},
 270   );
 271
 272   $args{where} = [
 273     and => [
 274       @{ $args{where} || [] },
 275       is_template => $self->is_template
 276     ]];
 277
 278   $self->db_args(\%args);
 279 }
 280
 281 sub prepare_report {
 282   my ($self)      = @_;
 283
 284   my $callback    = $self->get_callback;
 285
 286   my $report      = SL::ReportGenerator->new(\%::myconfig, $::form);
 287   $self->{report} = $report;
 288
 289   my @columns     = qw(title customer status type projectnumber);
 290   my @sortable    = qw(title customer status type projectnumber);
 291
 292   my %column_defs = (
 293     title         => { obj_link => sub { $self->url_for(action => 'show', id => $_[0]->id, callback => $callback) } },
 294     customer      => { raw_data => sub { $self->presenter->customer($_[0]->customer, display => 'table-cell', callback => $callback) },
 295                        sub      => sub { $_[0]->customer->name } },
 296     projectnumber => { raw_data => sub { $self->presenter->project($_[0]->project, display => 'table-cell', callback => $callback) },
 297                        sub      => sub { $_[0]->project_id ? $_[0]->project->projectnumber : '' } },
 298     status        => { sub      => sub { $_[0]->status->description } },
 299     type          => { sub      => sub { $_[0]->type->description } },
 300   );
 301
 302   map { $column_defs{$_}->{text} ||= $::locale->text( $self->get_sort_spec->{$_}->{title} ) } keys %column_defs;
 303
 304   $report->set_options(
 305     std_column_visibility => 1,
 306     controller_class      => 'RequirementSpec',
 307     output_format         => 'HTML',
 308     raw_top_info_text     => $self->render('requirement_spec/report_top',    { output => 0 }),
 309     raw_bottom_info_text  => $self->render('requirement_spec/report_bottom', { output => 0 }),
 310     title                 => $::locale->text('Requirement Specs'),
 311     allow_pdf_export      => 1,
 312     allow_csv_export      => 1,
 313   );
 314   $report->set_columns(%column_defs);
 315   $report->set_column_order(@columns);
 316   $report->set_export_options(qw(list filter));
 317   $report->set_options_from_form;
 318   $self->set_report_generator_sort_options(report => $report, sortable_columns => \@sortable);
 319
 320   $self->disable_pagination if $report->{options}{output_format} =~ /^(pdf|csv)$/i;
 321 }
 322
 323 1;