SL/Controller/RequirementSpecItem.pm

   1 package SL::Controller::RequirementSpecItem;
   2
   3 use strict;
   4
   5 use parent qw(SL::Controller::Base);
   6
   7 use Carp;
   8 use List::MoreUtils qw(apply);
   9 use List::Util qw(first);
  10 use Time::HiRes ();
  11
  12 use SL::Clipboard;
  13 use SL::Controller::Helper::RequirementSpec;
  14 use SL::DB::RequirementSpec;
  15 use SL::DB::RequirementSpecComplexity;
  16 use SL::DB::RequirementSpecItem;
  17 use SL::DB::RequirementSpecRisk;
  18 use SL::Helper::Flash;
  19 use SL::JSON;
  20 use SL::Locale::String;
  21
  22 use Rose::Object::MakeMethods::Generic
  23 (
  24   scalar                  => [ qw(item visible_item visible_section clicked_item sections) ],
  25   'scalar --get_set_init' => [ qw(complexities risks js) ],
  26 );
  27
  28 __PACKAGE__->run_before('check_auth');
  29 __PACKAGE__->run_before('load_requirement_spec_item', only => [ qw(dragged_and_dropped ajax_update ajax_edit ajax_delete ajax_flag ajax_copy) ]);
  30 __PACKAGE__->run_before('init_visible_section');
  31
  32 #
  33 # actions
  34 #
  35
  36 sub action_ajax_list {
  37   my ($self) = @_;
  38
  39   if (!$::form->{clicked_id}) {
  40     # Clicked on "sections" in the tree. Do nothing.
  41     return $self->render($self->js);
  42   }
  43
  44   my $clicked_item = SL::DB::RequirementSpecItem->new(id => $::form->{clicked_id})->load;
  45   $self->item($clicked_item->section);
  46
  47   if (!$self->visible_section || ($self->visible_section->id != $self->item->id)) {
  48     $self->render_list($self->item, $clicked_item);
  49   } else {
  50     $self->select_node($clicked_item);
  51   }
  52
  53   $self->render($self->js);
  54 }
  55
  56 sub insert_new_item_in_section_view {
  57   my ($self) = @_;
  58
  59   $self->js->hide('#section-list-empty');
  60
  61   my $new_type  = $self->item->item_type;
  62   my $id_prefix = $new_type eq 'sub-function-block' ? 'sub-' : '';
  63   my $template  = 'requirement_spec_item/_' . (apply { s/-/_/g; $_ } $new_type);
  64   my $html      = "" . $self->render($template, { output => 0 }, requirement_spec_item => $self->item);
  65   my $next_item = $self->item->get_next_in_list;
  66
  67   if ($next_item) {
  68     $self->js->insertBefore($html, '#' . $id_prefix . 'function-block-' . $next_item->id);
  69   } else {
  70     my $parent_is_section = $self->item->parent->item_type eq 'section';
  71     $self->js->appendTo($html, $parent_is_section ? '#section-list' : '#sub-function-block-container-' . $self->item->parent_id);
  72     $self->js->show('#sub-function-block-container-' . $self->item->parent_id) if !$parent_is_section;
  73   }
  74
  75   $self->replace_bottom($self->item->parent) if $new_type eq 'sub-function-block';
  76 }
  77
  78 sub action_dragged_and_dropped {
  79   my ($self)              = @_;
  80
  81   my $position            = $::form->{position} =~ m/^ (?: before | after | last ) $/x ? $::form->{position}                                             : die "Unknown 'position' parameter";
  82   my $dropped_item        = $::form->{dropped_id}                                  ? SL::DB::RequirementSpecItem->new(id => $::form->{dropped_id})->load : undef;
  83
  84   my $old_visible_section = $self->visible_section ? $self->visible_section : undef;
  85   my $old_parent_id       = $self->item->parent_id;
  86   my $old_type            = $self->item->item_type;
  87
  88   $self->item->db->do_transaction(sub {
  89     $self->item->remove_from_list;
  90     $self->item->parent_id($position =~ m/before|after/ ? $dropped_item->parent_id : $dropped_item->id);
  91     $self->item->add_to_list(position => $position, reference => $::form->{dropped_id} || undef);
  92   });
  93
  94   $self->item(SL::DB::RequirementSpecItem->new(id => $self->item->id)->load);
  95   my $new_section         = $self->item->section;
  96   my $new_type            = $self->item->item_type;
  97   my $new_visible_section = SL::DB::RequirementSpecItem->new(id => $self->visible_item->id)->load->section;
  98
  99   return $self->invalidate_version->render($self) if !$old_visible_section || ($new_type eq 'section');
 100
 101   # From here on $old_visible_section is definitely set.
 102
 103   my $old_parent  = SL::DB::RequirementSpecItem->new(id => $old_parent_id)->load;
 104   my $old_section = $old_parent->section;
 105
 106   # $::lxdebug->message(0, "old sec ID " . $old_section->id . " new " . $new_section->id . " old visible " . $old_visible_section->id . " new visible " . $new_visible_section->id
 107   #                       . " PARENT: old " . $old_parent->id . " new " . $self->item->parent_id . '/' . $self->item->parent->id);
 108
 109   if ($old_visible_section->id != $new_visible_section->id) {
 110     # The currently visible item has been dragged to a different section.
 111     $self->invalidate_version;
 112     return $self->render_list($new_section, $self->item)
 113       ->render($self);
 114   }
 115
 116   if ($old_visible_section->id == $old_section->id) {
 117     my $id_prefix = $old_type eq 'sub-function-block' ? 'sub-' : '';
 118     $self->js->remove('#' . $id_prefix . 'function-block-' . $self->item->id);
 119
 120     if ($old_type eq 'sub-function-block') {
 121       $self->replace_bottom($old_parent) ;
 122       $self->js->hide('#sub-function-block-container-' . $old_parent->id) if 0 == scalar(@{ $old_parent->children });
 123
 124     } elsif (0 == scalar(@{ $old_section->children })) {
 125       $self->js->show('#section-list-empty');
 126     }
 127   }
 128
 129   if ($old_visible_section->id == $new_section->id) {
 130     $self->insert_new_item_in_section_view($self->js);
 131   }
 132
 133   # $::lxdebug->dump(0, "js", $self->js->to_array);
 134
 135   $self->invalidate_version->render($self);
 136 }
 137
 138 sub action_ajax_add_section {
 139   my ($self, %params) = @_;
 140
 141   die "Missing parameter 'requirement_spec_id'" if !$::form->{requirement_spec_id};
 142
 143   $self->item(SL::DB::RequirementSpecItem->new(requirement_spec_id => $::form->{requirement_spec_id}, item_type => 'section'));
 144
 145   my $insert_after = $::form->{id} ? SL::DB::RequirementSpecItem->new(id => $::form->{id})->load->section->id : undef;
 146   my $html         = $self->render('requirement_spec_item/_section_form', { output => 0 }, id_base => 'new_section', insert_after => $insert_after);
 147
 148   $self->js
 149     ->remove('#new_section_form')
 150     ->hide('#column-content > *')
 151     ->appendTo($html, '#column-content')
 152     ->focus('#new_section_title')
 153     ->render($self);
 154 }
 155
 156 sub action_ajax_add_function_block {
 157   my ($self, %params) = @_;
 158
 159   return $self->add_function_block('function-block');
 160 }
 161
 162 sub action_ajax_add_sub_function_block {
 163   my ($self, %params) = @_;
 164
 165   return $self->add_function_block('sub-function-block');
 166 }
 167
 168 sub action_ajax_create {
 169   my ($self, %params) = @_;
 170
 171   my $prefix          = $::form->{form_prefix} || die "Missing parameter 'form_prefix'";
 172   my $attributes      = $::form->{$prefix}     || die "Missing parameter group '${prefix}'";
 173   my $insert_after    = delete $attributes->{insert_after};
 174
 175   my @errors = $self->item(SL::DB::RequirementSpecItem->new(%{ $attributes }))->validate;
 176   return $self->js->error(@errors)->render($self) if @errors;
 177
 178   $self->item->save;
 179   $self->item->add_to_list(position => 'after', reference => $insert_after) if $insert_after;
 180
 181   my $type = $self->item->item_type;
 182
 183   if ($type eq 'section') {
 184     my $node = $self->presenter->requirement_spec_item_jstree_data($self->item);
 185     $self->invalidate_version;
 186     return $self->render_list($self->item)
 187       ->jstree->create_node('#tree', $insert_after ? ('#fb-' . $insert_after, 'after') : ('#sections', 'last'), $node)
 188       ->jstree->select_node('#tree', '#fb-' . $self->item->id)
 189       ->render($self);
 190   }
 191
 192   my $template = 'requirement_spec_item/_' . (apply { s/-/_/g; $_ } $type);
 193   my $html     = $self->render($template, { output => 0 }, requirement_spec_item => $self->item, id_prefix => $type eq 'function-block' ? '' : 'sub-');
 194   my $node     = $self->presenter->requirement_spec_item_jstree_data($self->item);
 195
 196   $self->js
 197     ->replaceWith('#' . $prefix . '_form', $html)
 198     ->hide('#section-list-empty')
 199     ->jstree->create_node('#tree', $insert_after ? ('#fb-' . $insert_after, 'after') : ('#fb-' . $self->item->parent_id, 'last'), $node)
 200     ->jstree->select_node('#tree', '#fb-' . $self->item->id);
 201
 202   $self->replace_bottom($self->item->parent) if $type eq 'sub-function-block';
 203
 204   $self->invalidate_version->render($self);
 205 }
 206
 207 sub action_ajax_edit {
 208   my ($self, %params) = @_;
 209
 210   $self->item(SL::DB::RequirementSpecItem->new(id => $::form->{id})->load);
 211
 212   if (!$self->is_item_visible) {
 213     # Show section/item to edit if it is not visible.
 214
 215     my $html = $self->render('requirement_spec_item/_section', { output => 0 }, requirement_spec_item => $self->item->section);
 216     $self->js->html('#column-content', $html);
 217   }
 218
 219   if ($self->item->item_type =~ m/section/) {
 220     # Edit the section header, not an item.
 221     my $html = $self->render('requirement_spec_item/_section_form', { output => 0 });
 222
 223     $self->js
 224       ->hide('#section-header-' . $self->item->id)
 225       ->remove("#edit_section_form")
 226       ->insertAfter($html, '#section-header-' . $self->item->id)
 227       ->jstree->select_node('#tree', '#fb-' . $self->item->id)
 228       ->focus("#edit_section_title")
 229       ->val('#current_content_type', 'section')
 230       ->val('#current_content_id',   $self->item->id)
 231       ->render($self);
 232     return;
 233   }
 234
 235   # Edit a function block or a sub function block
 236   my @dependencies          = $self->create_dependencies;
 237   my @selected_dependencies = map { $_->id } @{ $self->item->dependencies };
 238
 239   my $html                  = $self->render('requirement_spec_item/_function_block_form', { output => 0 }, DEPENDENCIES => \@dependencies, SELECTED_DEPENDENCIES => \@selected_dependencies);
 240   my $id_base               = 'edit_function_block_' . $self->item->id;
 241   my $content_top_id        = '#' . $self->item->item_type . '-content-top-' . $self->item->id;
 242
 243   $self->js
 244     ->hide($content_top_id)
 245     ->remove("#${id_base}_form")
 246     ->insertAfter($html, $content_top_id)
 247     ->jstree->select_node('#tree', '#fb-' . $self->item->id)
 248     ->focus("#${id_base}_description")
 249     ->val('#current_content_type', $self->item->item_type)
 250     ->val('#current_content_id', $self->item->id)
 251     ->render($self);
 252 }
 253
 254 sub action_ajax_update {
 255   my ($self, %params) = @_;
 256
 257   my $prefix     = $::form->{form_prefix} || die "Missing parameter 'form_prefix'";
 258   my $attributes = $::form->{$prefix}     || {};
 259
 260   foreach (qw(requirement_spec_id parent_id position)) {
 261     delete $attributes->{$_} if !defined $attributes->{$_};
 262   }
 263
 264   my @errors = $self->item->assign_attributes(%{ $attributes })->validate;
 265   return $self->js->error(@errors)->render($self) if @errors;
 266
 267   $self->item->save;
 268
 269   my $type = $self->item->item_type;
 270
 271   if ($type eq 'section') {
 272     # Updated section, now update section header.
 273
 274     my $html = $self->render('requirement_spec_item/_section_header', { output => 0 }, requirement_spec_item => $self->item);
 275
 276     return $self->invalidate_version
 277       ->remove('#edit_section_form')
 278       ->html('#section-header-' . $self->item->id, $html)
 279       ->show('#section-header-' . $self->item->id)
 280       ->jstree->rename_node('#tree', '#fb-' . $self->item->id, $::request->presenter->requirement_spec_item_tree_node_title($self->item))
 281       ->render($self);
 282   }
 283
 284   # Updated function block or sub function block. Update (sub)
 285   # function block and potentially the bottom of the parent function
 286   # block.
 287
 288   my $id_prefix    = $type eq 'function-block' ? '' : 'sub-';
 289   my $html_top     = $self->render('requirement_spec_item/_function_block_content_top',    { output => 0 }, requirement_spec_item => $self->item, id_prefix => $id_prefix);
 290   $id_prefix      .= 'function-block-content-';
 291
 292   $self->js
 293     ->remove('#' . $prefix . '_form')
 294     ->replaceWith('#' . $id_prefix . 'top-' . $self->item->id, $html_top)
 295     ->jstree->rename_node('#tree', '#fb-' . $self->item->id, $::request->presenter->requirement_spec_item_tree_node_title($self->item));
 296
 297   $self->replace_bottom($self->item, id_prefix => $id_prefix);
 298   $self->replace_bottom($self->item->parent) if $type eq 'sub-function-block';
 299
 300   $self->invalidate_version->render($self);
 301 }
 302
 303 sub action_ajax_delete {
 304   my ($self) = @_;
 305
 306   my $full_list = $self->item->get_full_list;
 307
 308   $self->item->delete;
 309
 310   if ($self->visible_section && ($self->visible_section->id == $self->item->id)) {
 311     # Currently visible section is deleted.
 312
 313     my $new_section = first { $_->id != $self->item->id } @{ $self->item->requirement_spec->sections };
 314     if ($new_section) {
 315       $self->render_list($new_section);
 316
 317     } else {
 318       my $html = $self->render('requirement_spec_item/_no_section', { output => 0 });
 319       $self->js
 320         ->html('#column-content',      $html)
 321         ->val('#current_content_type', '')
 322         ->val('#current_content_id',   '')
 323     }
 324
 325   } elsif ($self->is_item_visible) {
 326     # Item in currently visible section is deleted.
 327
 328     my $type = $self->item->item_type;
 329     $self->js->remove('#edit_function_block_' . $self->item->id . '_form')
 330              ->remove('#' . $type . '-' . $self->item->id);
 331
 332     $self->replace_bottom($self->item->parent_id) if $type eq 'sub-function-block';
 333
 334     if (1 == scalar @{ $full_list }) {
 335       if ($type eq 'function-block') {
 336         $self->js->show('#section-list-empty');
 337       } elsif ($type eq 'sub-function-block') {
 338         $self->js->hide('#sub-function-block-container-' . $self->item->parent_id);
 339       }
 340     }
 341   }
 342
 343   $self->invalidate_version
 344     ->jstree->delete_node('#tree', '#fb-' . $self->item->id)
 345     ->render($self);
 346 }
 347
 348 sub action_ajax_flag {
 349   my ($self) = @_;
 350
 351   $self->item->update_attributes(is_flagged => !$self->item->is_flagged);
 352
 353   $self->js
 354    ->action_if($self->is_item_visible, 'toggleClass', '#' . $self->item->item_type . '-' . $self->item->id, 'flagged')
 355    ->toggleClass('#fb-' . $self->item->id, 'flagged')
 356    ->render($self);
 357 }
 358
 359 sub action_ajax_copy {
 360   my ($self, %params) = @_;
 361
 362   SL::Clipboard->new->copy($self->item);
 363   $self->render($self->js);
 364 }
 365
 366 sub determine_paste_position {
 367   my ($self) = @_;
 368
 369   if ($self->item->item_type eq 'section') {
 370     # Sections are always pasted either directly after the
 371     # clicked-upon section or at the very end.
 372     return $self->clicked_item ? (undef, $self->clicked_item->section->id) : ();
 373
 374   } elsif ($self->item->item_type eq 'function-block') {
 375     # A function block:
 376     # - paste on section list: insert into last section as last element
 377     # - paste on section: insert into that section as last element
 378     # - paste on function block: insert after clicked-upon element
 379     # - paste on sub function block: insert after parent function block of clicked-upon element
 380     return !$self->clicked_item                                ? ( $self->sections->[-1]->id,              undef                          )
 381          :  $self->clicked_item->item_type eq 'section'        ? ( $self->clicked_item->id,                undef                          )
 382          :  $self->clicked_item->item_type eq 'function-block' ? ( $self->clicked_item->parent_id,         $self->clicked_item->id        )
 383          :                                                       ( $self->clicked_item->parent->parent_id, $self->clicked_item->parent_id );
 384
 385   } else {                      # sub-function-block
 386     # A sub function block:
 387     # - paste on section list: promote to function block and insert into last section as last element
 388     # - paste on section: promote to function block and insert into that section as last element
 389     # - paste on function block: insert as last element in clicked-upon element
 390     # - paste on sub function block: insert after clicked-upon element
 391
 392     # Promote sub function blocks to function blocks when pasting on a
 393     # section or the section list.
 394     $self->item->item_type('function-block') if !$self->clicked_item || ($self->clicked_item->item_type eq 'section');
 395
 396     return !$self->clicked_item                                ? ( $self->sections->[-1]->id,      undef                   )
 397          :  $self->clicked_item->item_type eq 'section'        ? ( $self->clicked_item->id,        undef                   )
 398          :  $self->clicked_item->item_type eq 'function-block' ? ( $self->clicked_item->id,        undef                   )
 399          :                                                       ( $self->clicked_item->parent_id, $self->clicked_item->id );
 400   }
 401 }
 402
 403 sub assign_requirement_spec_id_rec {
 404   my ($self, $item) = @_;
 405
 406   $item->requirement_spec_id($::form->{requirement_spec_id});
 407   $self->assign_requirement_spec_id_rec($_) for @{ $item->children || [] };
 408
 409   return $item;
 410 }
 411
 412 sub create_and_insert_node_rec {
 413   my ($self, $item, $new_parent_id, $insert_after) = @_;
 414
 415   my $node = $self->presenter->requirement_spec_item_jstree_data($item);
 416   $self->js->jstree->create_node('#tree', $insert_after ? ('#fb-' . $insert_after, 'after') : $new_parent_id ? ('#fb-' . $new_parent_id, 'last') : ('#sections', 'last'), $node);
 417
 418   $self->create_and_insert_node_rec($_, $item->id) for @{ $item->children || [] };
 419
 420   $self->js->jstree->open_node('#tree', '#fb-' . $item->id);
 421 }
 422
 423 sub action_ajax_paste {
 424   my ($self, %params) = @_;
 425
 426   my $copied = SL::Clipboard->new->get_entry(qr/^RequirementSpecItem$/);
 427
 428   if (!$copied) {
 429     return $self->js->error(t8("The clipboard does not contain anything that can be pasted here."))
 430                     ->render($self);
 431   }
 432
 433   $self->item($self->assign_requirement_spec_id_rec($copied->to_object));
 434   my $req_spec = SL::DB::RequirementSpec->new(id => $::form->{requirement_spec_id})->load;
 435   $self->sections($req_spec->sections);
 436
 437   if (($self->item->item_type ne 'section') && !@{ $self->sections }) {
 438     return $self->js->error(t8("You cannot paste function blocks or sub function blocks if there is no section."))
 439                     ->render($self);
 440   }
 441
 442   $self->clicked_item($::form->{id} ? SL::DB::RequirementSpecItem->new(id => $::form->{id})->load : undef);
 443
 444   my ($new_parent_id, $insert_after) = $self->determine_paste_position;
 445
 446   # Store result in database.
 447   $self->item->update_attributes(requirement_spec_id => $::form->{requirement_spec_id}, parent_id => $new_parent_id);
 448   $self->item->add_to_list(position => 'after', reference => $insert_after) if $insert_after;
 449
 450   # Update the tree: create the node for all pasted objects.
 451   $self->create_and_insert_node_rec($self->item, $new_parent_id, $insert_after);
 452
 453   # Pasting the very first section?
 454   if (!@{ $self->sections }) {
 455     my $html = $self->render('requirement_spec_item/_section', { output => 0 }, requirement_spec_item => $self->item);
 456     $self->js->html('#column-content', $html)
 457              ->jstree->select_node('#tree', '#fb-' . $self->item->id)
 458   }
 459
 460   # Update the current view if required.
 461   $self->insert_new_item_in_section_view($self->js) if $self->is_item_visible;
 462
 463   $self->invalidate_version->render($self);
 464 }
 465
 466 #
 467 # filters
 468 #
 469
 470 sub check_auth {
 471   my ($self) = @_;
 472   $::auth->assert('sales_quotation_edit');
 473 }
 474
 475 sub load_requirement_spec_item {
 476   my ($self) = @_;
 477   $self->item(SL::DB::RequirementSpecItem->new(id => $::form->{id})->load);
 478 }
 479
 480 #
 481 # helpers
 482 #
 483
 484 sub create_random_id {
 485   return join '-', Time::HiRes::gettimeofday();
 486 }
 487
 488 sub format_exception {
 489   return join "\n", (split m/\n/, $@)[0..4];
 490 }
 491
 492 sub init_complexities {
 493   my ($self) = @_;
 494
 495   return SL::DB::Manager::RequirementSpecComplexity->get_all_sorted;
 496 }
 497
 498 sub init_risks {
 499   my ($self) = @_;
 500
 501   return SL::DB::Manager::RequirementSpecRisk->get_all_sorted;
 502 }
 503
 504 sub init_js {
 505   my ($self) = @_;
 506   $self->js(SL::ClientJS->new);
 507 }
 508
 509 sub replace_bottom {
 510   my ($self, $item_or_id) = @_;
 511
 512   my $item      = (ref($item_or_id) ? $item_or_id : SL::DB::RequirementSpecItem->new(id => $item_or_id))->load;
 513   my $id_prefix = $item->item_type eq 'function-block' ? '' : 'sub-';
 514   my $html      = $self->render('requirement_spec_item/_function_block_content_bottom', { output => 0 }, requirement_spec_item => $item, id_prefix => $id_prefix);
 515   return $self->js->replaceWith('#' . $id_prefix . 'function-block-content-bottom-' . $item->id, $html);
 516 }
 517
 518 sub render_list {
 519   my ($self, $item, $item_to_select) = @_;
 520
 521   my $html = $self->render('requirement_spec_item/_section', { output => 0 }, requirement_spec_item => $item);
 522   $self->js->html('#column-content', $html);
 523   $self->select_node($item_to_select || $item);
 524 }
 525
 526 sub select_node {
 527   my ($self, $item) = @_;
 528
 529   $self->js
 530     ->val( '#current_content_type', $item->item_type)
 531     ->val( '#current_content_id',   $item->id)
 532     ->jstree->select_node('#tree', '#fb-' . $item->id);
 533 }
 534
 535 sub create_dependency_item {
 536   my $self = shift;
 537   [ $_[0]->id, $self->presenter->truncate(join(' ', grep { $_ } ($_[1], $_[0]->fb_number, $_[0]->description))) ];
 538 }
 539
 540 sub create_dependencies {
 541   my ($self) = @_;
 542
 543   return map { [ $_->fb_number . ' ' . $_->title,
 544                  [ map { ( $self->create_dependency_item($_),
 545                            map { $self->create_dependency_item($_, '->') } @{ $_->children_sorted })
 546                        } @{ $_->children_sorted } ] ]
 547              } @{ $self->item->requirement_spec->sections };
 548 }
 549
 550 sub add_function_block {
 551   my ($self, $new_type) = @_;
 552
 553   my $clicked_id = $::form->{id} || ($self->visible_item ? $self->visible_item->id : undef);
 554
 555   die "Invalid new_type '$new_type'"               if $new_type !~ m/^(?:sub-)?function-block$/;
 556   die "Missing parameter 'id' and no visible item" if !$clicked_id;
 557   die "Missing parameter 'requirement_spec_id'"    if !$::form->{requirement_spec_id};
 558
 559   my $clicked_item = SL::DB::RequirementSpecItem->new(id => $clicked_id)->load;
 560   my $clicked_type = $clicked_item->item_type;
 561
 562   die "Invalid clicked_type '$clicked_type'" if $clicked_type !~ m/^(?: section | (?:sub-)? function-block )$/x;
 563
 564   my $case = "${clicked_type}:${new_type}";
 565
 566   my ($insert_position, $insert_reference, $parent_id, $display_reference)
 567     = $case eq 'section:function-block'                ? ( 'appendTo',    $clicked_item->id,        $clicked_item->id,                '#section-list'                  )
 568     : $case eq 'function-block:function-block'         ? ( 'insertAfter', $clicked_item->id,        $clicked_item->parent_id,         '#function-block-'               )
 569     : $case eq 'function-block:sub-function-block'     ? ( 'appendTo'  ,  $clicked_item->id,        $clicked_item->id,                '#sub-function-block-container-' )
 570     : $case eq 'sub-function-block:function-block'     ? ( 'insertAfter', $clicked_item->parent_id, $clicked_item->parent->parent_id, '#function-block-'               )
 571     : $case eq 'sub-function-block:sub-function-block' ? ( 'insertAfter', $clicked_item->id,        $clicked_item->parent_id,         '#sub-function-block-'           )
 572     :                                                    die "Invalid combination of 'clicked_type (section)/new_type ($new_type)'";
 573
 574   $self->item(SL::DB::RequirementSpecItem->new(requirement_spec_id => $::form->{requirement_spec_id}, parent_id => $parent_id, item_type => $new_type));
 575
 576   $display_reference .= $insert_reference if $display_reference =~ m/-$/;
 577   my $id_base         = join('_', 'new_function_block', Time::HiRes::gettimeofday(), int rand 1000000000000);
 578   my $html            = $self->render(
 579     'requirement_spec_item/_function_block_form',
 580     { output => 0 },
 581     DEPENDENCIES          => [ $self->create_dependencies ],
 582     SELECTED_DEPENDENCIES => [],
 583     requirement_spec_item => $self->item,
 584     id_base               => $id_base,
 585     insert_after          => $insert_position eq 'insertAfter' ? $insert_reference : undef,
 586   );
 587
 588   my $new_section = $self->item->section;
 589   if (!$self->is_item_visible) {
 590     # Show section/item to edit if it is not visible.
 591
 592     $html = $self->render('requirement_spec_item/_section', { output => 0 }, requirement_spec_item => $new_section);
 593     $self->js
 594       ->html('#column-content', $html)
 595       ->val('#current_content_type', 'section')
 596       ->val('#current_content_id',   $new_section->id)
 597       ->jstree->select_node('#tree', '#fb-' . $new_section->id);
 598   }
 599
 600   # $::lxdebug->message(0, "alright! clicked ID " . $::form->{id} . " type $clicked_type new_type $new_type insert_pos $insert_position ref " . ($insert_reference // '<undef>') . " parent $parent_id display_ref $display_reference");
 601
 602   $self->js->action($insert_position, $html, $display_reference)
 603            ->focus("#${id_base}_description");
 604
 605   $self->js->show('#sub-function-block-container-' . $parent_id) if $new_type eq 'sub-function-block';
 606
 607   $self->js->render($self);
 608 }
 609
 610 sub is_item_visible {
 611   my ($self, $item) = @_;
 612
 613   $item ||= $self->item;
 614   return $self->visible_section && ($self->visible_section->id == $item->section->id);
 615 }
 616
 617 sub invalidate_version {
 618   my ($self) = @_;
 619
 620   my $html   = $self->render('requirement_spec/_version', { output => 0 },
 621                              requirement_spec => SL::DB::RequirementSpec->new(id => $::form->{requirement_spec_id} || $self->item->requirement_spec_id)->load);
 622   return $self->js->html('#requirement_spec_version', $html);
 623 }
 624
 625 1;