SL/Controller/RequirementSpecItem.pm

   1 package SL::Controller::RequirementSpecItem;
   2
   3 use strict;
   4
   5 use parent qw(SL::Controller::Base);
   6
   7 use Carp;
   8 use List::MoreUtils qw(apply);
   9 use List::Util qw(first);
  10 use Time::HiRes ();
  11
  12 use SL::Clipboard;
  13 use SL::Controller::Helper::RequirementSpec;
  14 use SL::DB::RequirementSpec;
  15 use SL::DB::RequirementSpecComplexity;
  16 use SL::DB::RequirementSpecItem;
  17 use SL::DB::RequirementSpecRisk;
  18 use SL::Helper::Flash;
  19 use SL::JSON;
  20 use SL::Locale::String;
  21
  22 use Rose::Object::MakeMethods::Generic
  23 (
  24   scalar                  => [ qw(item visible_item visible_section clicked_item sections) ],
  25   'scalar --get_set_init' => [ qw(complexities risks js) ],
  26 );
  27
  28 __PACKAGE__->run_before('check_auth');
  29 __PACKAGE__->run_before('load_requirement_spec_item', only => [ qw(dragged_and_dropped ajax_update ajax_edit ajax_delete ajax_flag ajax_copy) ]);
  30 __PACKAGE__->run_before('init_visible_section');
  31
  32 #
  33 # actions
  34 #
  35
  36 sub action_ajax_list {
  37   my ($self) = @_;
  38
  39   if (!$::form->{clicked_id}) {
  40     # Clicked on "sections" in the tree. Do nothing.
  41     return $self->render($self->js);
  42   }
  43
  44   my $clicked_item = SL::DB::RequirementSpecItem->new(id => $::form->{clicked_id})->load;
  45   $self->item($clicked_item->section);
  46
  47   if (!$self->visible_section || ($self->visible_section->id != $self->item->id)) {
  48     $self->render_list($self->item, $clicked_item);
  49   } else {
  50     $self->select_node($clicked_item);
  51   }
  52
  53   $self->render($self->js);
  54 }
  55
  56 sub insert_new_item_in_section_view {
  57   my ($self) = @_;
  58
  59   $self->js->hide('#section-list-empty');
  60
  61   my $new_type  = $self->item->item_type;
  62   my $id_prefix = $new_type eq 'sub-function-block' ? 'sub-' : '';
  63   my $template  = 'requirement_spec_item/_' . (apply { s/-/_/g; $_ } $new_type);
  64   my $html      = "" . $self->render($template, { output => 0 }, requirement_spec_item => $self->item);
  65   my $next_item = $self->item->get_next_in_list;
  66
  67   if ($next_item) {
  68     $self->js->insertBefore($html, '#' . $id_prefix . 'function-block-' . $next_item->id);
  69   } else {
  70     my $parent_is_section = $self->item->parent->item_type eq 'section';
  71     $self->js->appendTo($html, $parent_is_section ? '#section-list' : '#sub-function-block-container-' . $self->item->parent_id);
  72     $self->js->show('#sub-function-block-container-' . $self->item->parent_id) if !$parent_is_section;
  73   }
  74
  75   $self->replace_bottom($self->item->parent) if $new_type eq 'sub-function-block';
  76 }
  77
  78 sub action_dragged_and_dropped {
  79   my ($self)              = @_;
  80
  81   my $position            = $::form->{position} =~ m/^ (?: before | after | last ) $/x ? $::form->{position}                                             : die "Unknown 'position' parameter";
  82   my $dropped_item        = $::form->{dropped_id}                                  ? SL::DB::RequirementSpecItem->new(id => $::form->{dropped_id})->load : undef;
  83
  84   my $old_visible_section = $self->visible_section ? $self->visible_section : undef;
  85   my $old_parent_id       = $self->item->parent_id;
  86   my $old_type            = $self->item->item_type;
  87   my $new_type            = !$dropped_item ? 'section' : $position =~ m/before|after/ ? $dropped_item->item_type : $dropped_item->child_type;
  88
  89   $self->item->db->do_transaction(sub {
  90     $self->item->remove_from_list;
  91     $self->item->parent_id($position =~ m/before|after/ ? $dropped_item->parent_id : $dropped_item->id) if $dropped_item;
  92     $self->item->item_type($new_type);
  93     $self->item->add_to_list(position => $position, reference => $::form->{dropped_id} || undef);
  94   });
  95
  96   $self->item(SL::DB::RequirementSpecItem->new(id => $self->item->id)->load);
  97   my $new_section         = $self->item->section;
  98   my $new_visible_section = SL::DB::RequirementSpecItem->new(id => $self->visible_item->id)->load->section;
  99
 100   return $self->invalidate_version->render($self) if !$old_visible_section || ($new_type eq 'section');
 101
 102   # From here on $old_visible_section is definitely set.
 103
 104   my $old_parent  = SL::DB::RequirementSpecItem->new(id => $old_parent_id)->load;
 105   my $old_section = $old_parent->section;
 106
 107   # Section debug info:
 108   # $::lxdebug->message(0, "old sec ID " . $old_section->id . " new " . $new_section->id . " old visible " . $old_visible_section->id . " new visible " . $new_visible_section->id
 109   #                       . " PARENT: old " . $old_parent->id . " new " . $self->item->parent_id . '/' . $self->item->parent->id);
 110
 111   # Item debug info:
 112   # $::lxdebug->message(0, 'item id: ' . $self->item->id . " new type: $new_type old type: $old_type #old children: " . scalar(@{ $old_parent->children }));
 113
 114   if ($old_visible_section->id != $new_visible_section->id) {
 115     # The currently visible item has been dragged to a different section.
 116     $self->invalidate_version;
 117     return $self->render_list($new_section, $self->item)
 118       ->render($self);
 119   }
 120
 121   if ($old_visible_section->id == $old_section->id) {
 122     my $id_prefix = $old_type eq 'sub-function-block' ? 'sub-' : '';
 123     $self->js->remove('#' . $id_prefix . 'function-block-' . $self->item->id);
 124
 125     if ($old_type eq 'sub-function-block') {
 126       $self->replace_bottom($old_parent) ;
 127       $self->js->hide('#sub-function-block-container-' . $old_parent->id) if 0 == scalar(@{ $old_parent->children });
 128
 129     } elsif (0 == scalar(@{ $old_section->children })) {
 130       $self->js->show('#section-list-empty');
 131     }
 132   }
 133
 134   if ($old_visible_section->id == $new_section->id) {
 135     $self->insert_new_item_in_section_view($self->js);
 136   }
 137
 138   # $::lxdebug->dump(0, "js", $self->js->to_array);
 139
 140   $self->invalidate_version->render($self);
 141 }
 142
 143 sub action_ajax_add_section {
 144   my ($self, %params) = @_;
 145
 146   die "Missing parameter 'requirement_spec_id'" if !$::form->{requirement_spec_id};
 147
 148   $self->item(SL::DB::RequirementSpecItem->new(requirement_spec_id => $::form->{requirement_spec_id}, item_type => 'section'));
 149
 150   my $insert_after = $::form->{id} ? SL::DB::RequirementSpecItem->new(id => $::form->{id})->load->section->id : undef;
 151   my $html         = $self->render('requirement_spec_item/_section_form', { output => 0 }, id_base => 'new_section', insert_after => $insert_after);
 152
 153   $self->js
 154     ->remove('#new_section_form')
 155     ->hide('#column-content > *')
 156     ->appendTo($html, '#column-content')
 157     ->focus('#new_section_title')
 158     ->reinit_widgets
 159     ->render($self);
 160 }
 161
 162 sub action_ajax_add_function_block {
 163   my ($self, %params) = @_;
 164
 165   return $self->add_function_block('function-block');
 166 }
 167
 168 sub action_ajax_add_sub_function_block {
 169   my ($self, %params) = @_;
 170
 171   return $self->add_function_block('sub-function-block');
 172 }
 173
 174 sub action_ajax_create {
 175   my ($self, %params) = @_;
 176
 177   my $prefix          = $::form->{form_prefix} || die "Missing parameter 'form_prefix'";
 178   my $attributes      = $::form->{$prefix}     || die "Missing parameter group '${prefix}'";
 179   my $insert_after    = delete $attributes->{insert_after};
 180
 181   if (!$attributes->{parent_id}) {
 182     $attributes->{order_part_id} ||= $::instance_conf->get_requirement_spec_section_order_part_id;
 183   }
 184
 185   my @errors = $self->item(SL::DB::RequirementSpecItem->new(%{ $attributes }))->validate;
 186   return $self->js->error(@errors)->render($self) if @errors;
 187
 188   $self->item->save;
 189   $self->item->add_to_list(position => 'after', reference => $insert_after) if $insert_after;
 190
 191   my $type = $self->item->item_type;
 192
 193   if ($type eq 'section') {
 194     my $node = $self->presenter->requirement_spec_item_jstree_data($self->item);
 195     $self->invalidate_version;
 196     $self->render_list($self->item)
 197       ->hide('#section-list-empty')
 198       ->jstree->create_node('#tree', $insert_after ? ('#fb-' . $insert_after, 'after') : ('#sections', 'last'), $node)
 199       ->jstree->select_node('#tree', '#fb-' . $self->item->id);
 200     return $self->add_new_item_form_after_create
 201       ->reinit_widgets
 202       ->render($self);
 203   }
 204
 205   my $template = 'requirement_spec_item/_' . (apply { s/-/_/g; $_ } $type);
 206   my $html     = $self->render($template, { output => 0 }, requirement_spec_item => $self->item, id_prefix => $type eq 'function-block' ? '' : 'sub-');
 207   my $node     = $self->presenter->requirement_spec_item_jstree_data($self->item);
 208
 209   $self->js
 210     ->replaceWith('#' . $prefix . '_form', $html)
 211     ->hide('#section-list-empty')
 212     ->jstree->create_node('#tree', $insert_after ? ('#fb-' . $insert_after, 'after') : ('#fb-' . $self->item->parent_id, 'last'), $node)
 213     ->reinit_widgets
 214     ->jstree->select_node('#tree', '#fb-' . $self->item->id);
 215
 216   $self->replace_bottom($self->item->parent) if $type eq 'sub-function-block';
 217
 218   $self->add_new_item_form_after_create;
 219
 220   $self->invalidate_version->render($self);
 221 }
 222
 223 sub action_ajax_edit {
 224   my ($self, %params) = @_;
 225
 226   $self->item(SL::DB::RequirementSpecItem->new(id => $::form->{id})->load);
 227
 228   if (!$self->is_item_visible) {
 229     # Show section/item to edit if it is not visible.
 230
 231     my $html = $self->render('requirement_spec_item/_section', { output => 0 }, requirement_spec_item => $self->item->section);
 232     $self->set_function_blocks_tab_menu_class(class => 'section-context-menu')
 233       ->html('#column-content', $html);
 234   }
 235
 236   if ($self->item->item_type =~ m/section/) {
 237     # Edit the section header, not an item.
 238     my $html = $self->render('requirement_spec_item/_section_form', { output => 0 });
 239
 240     $self->js
 241       ->hide('#section-header-' . $self->item->id)
 242       ->remove("#edit_section_form")
 243       ->insertAfter($html, '#section-header-' . $self->item->id)
 244       ->jstree->select_node('#tree', '#fb-' . $self->item->id)
 245       ->val('#current_content_type', 'section')
 246       ->val('#current_content_id',   $self->item->id)
 247       ->reinit_widgets
 248       ->focus("#edit_section_title")
 249       ->render($self);
 250     return;
 251   }
 252
 253   # Edit a function block or a sub function block
 254   my @dependencies          = $self->create_dependencies;
 255   my @selected_dependencies = map { $_->id } @{ $self->item->dependencies };
 256
 257   my $html                  = $self->render('requirement_spec_item/_function_block_form', { output => 0 }, DEPENDENCIES => \@dependencies, SELECTED_DEPENDENCIES => \@selected_dependencies);
 258   my $id_base               = 'edit_function_block_' . $self->item->id;
 259   my $content_top_id        = '#' . $self->item->item_type . '-content-top-' . $self->item->id;
 260
 261   $self->js
 262     ->hide($content_top_id)
 263     ->remove("#${id_base}_form")
 264     ->insertAfter($html, $content_top_id)
 265     ->run('kivi.requirement_spec.init_function_block_keypress_events', "${id_base}_form")
 266     ->jstree->select_node('#tree', '#fb-' . $self->item->id)
 267     ->val('#current_content_type', $self->item->item_type)
 268     ->val('#current_content_id', $self->item->id)
 269     ->reinit_widgets
 270     ->focus("#${id_base}_description")
 271     ->render($self);
 272 }
 273
 274 sub action_ajax_update {
 275   my ($self, %params) = @_;
 276
 277   my $prefix     = $::form->{form_prefix} || die "Missing parameter 'form_prefix'";
 278   my $attributes = $::form->{$prefix}     || {};
 279
 280   foreach (qw(requirement_spec_id parent_id position)) {
 281     delete $attributes->{$_} if !defined $attributes->{$_};
 282   }
 283
 284   my @errors = $self->item->assign_attributes(%{ $attributes })->validate;
 285   return $self->js->error(@errors)->render($self) if @errors;
 286
 287   $self->item->save;
 288
 289   my $type = $self->item->item_type;
 290
 291   if ($type eq 'section') {
 292     # Updated section, now update section header.
 293
 294     my $html = $self->render('requirement_spec_item/_section_header', { output => 0 }, requirement_spec_item => $self->item);
 295
 296     return $self->invalidate_version
 297       ->remove('#edit_section_form')
 298       ->html('#section-header-' . $self->item->id, $html)
 299       ->show('#section-header-' . $self->item->id)
 300       ->jstree->rename_node('#tree', '#fb-' . $self->item->id, $::request->presenter->requirement_spec_item_tree_node_title($self->item))
 301       ->prop('#fb-' . $self->item->id . ' a', 'title', $self->item->content_excerpt)
 302       ->addClass('#fb-' . $self->item->id . ' a', 'tooltip')
 303       ->reinit_widgets
 304       ->render($self);
 305   }
 306
 307   # Updated function block or sub function block. Update (sub)
 308   # function block and potentially the bottom of the parent function
 309   # block.
 310
 311   my $id_prefix    = $type eq 'function-block' ? '' : 'sub-';
 312   my $html_top     = $self->render('requirement_spec_item/_function_block_content_top',    { output => 0 }, requirement_spec_item => $self->item, id_prefix => $id_prefix);
 313   $id_prefix      .= 'function-block-content-';
 314
 315   $self->js
 316     ->remove('#' . $prefix . '_form')
 317     ->replaceWith('#' . $id_prefix . 'top-' . $self->item->id, $html_top)
 318     ->prop('#fb-' . $self->item->id . ' a', 'title', $self->item->content_excerpt)
 319     ->addClass('#fb-' . $self->item->id . ' a', 'tooltip')
 320     ->reinit_widgets
 321     ->jstree->rename_node('#tree', '#fb-' . $self->item->id, $::request->presenter->requirement_spec_item_tree_node_title($self->item));
 322
 323   $self->replace_bottom($self->item, id_prefix => $id_prefix);
 324   $self->replace_bottom($self->item->parent) if $type eq 'sub-function-block';
 325
 326   $self->invalidate_version->render($self);
 327 }
 328
 329 sub action_ajax_delete {
 330   my ($self) = @_;
 331
 332   my $full_list = $self->item->get_full_list;
 333
 334   $self->item->delete;
 335
 336   if ($self->visible_section && ($self->visible_section->id == $self->item->id)) {
 337     # Currently visible section is deleted.
 338
 339     my $new_section = first { $_->id != $self->item->id } @{ $self->item->requirement_spec->sections };
 340     if ($new_section) {
 341       $self->render_list($new_section);
 342
 343     } else {
 344       my $html = $self->render('requirement_spec_item/_no_section', { output => 0 });
 345       $self->set_function_blocks_tab_menu_class(class => 'section-context-menu')
 346         ->html('#column-content',      $html)
 347         ->val('#current_content_type', '')
 348         ->val('#current_content_id',   '')
 349     }
 350
 351   } elsif ($self->is_item_visible) {
 352     # Item in currently visible section is deleted.
 353
 354     my $type = $self->item->item_type;
 355     $self->js->remove('#edit_function_block_' . $self->item->id . '_form')
 356              ->remove('#' . $type . '-' . $self->item->id);
 357
 358     $self->replace_bottom($self->item->parent_id) if $type eq 'sub-function-block';
 359
 360     if (1 == scalar @{ $full_list }) {
 361       if ($type eq 'function-block') {
 362         $self->js->show('#section-list-empty');
 363       } elsif ($type eq 'sub-function-block') {
 364         $self->js->hide('#sub-function-block-container-' . $self->item->parent_id);
 365       }
 366     }
 367   }
 368
 369   $self->invalidate_version
 370     ->jstree->delete_node('#tree', '#fb-' . $self->item->id)
 371     ->render($self);
 372 }
 373
 374 sub action_ajax_flag {
 375   my ($self) = @_;
 376
 377   $self->item->update_attributes(is_flagged => !$self->item->is_flagged);
 378
 379   $self->js
 380    ->action_if($self->is_item_visible, 'toggleClass', '#' . $self->item->item_type . '-' . $self->item->id, 'flagged')
 381    ->toggleClass('#fb-' . $self->item->id, 'flagged')
 382    ->render($self);
 383 }
 384
 385 sub action_ajax_copy {
 386   my ($self, %params) = @_;
 387
 388   SL::Clipboard->new->copy($self->item);
 389   $self->render($self->js);
 390 }
 391
 392 sub determine_paste_position {
 393   my ($self) = @_;
 394
 395   if ($self->item->item_type eq 'section') {
 396     # Sections are always pasted either directly after the
 397     # clicked-upon section or at the very end.
 398     return $self->clicked_item ? (undef, $self->clicked_item->section->id) : ();
 399
 400   } elsif ($self->item->item_type eq 'function-block') {
 401     # A function block:
 402     # - paste on section list: insert into last section as last element
 403     # - paste on section: insert into that section as last element
 404     # - paste on function block: insert after clicked-upon element
 405     # - paste on sub function block: insert after parent function block of clicked-upon element
 406     return !$self->clicked_item                                ? ( $self->sections->[-1]->id,              undef                          )
 407          :  $self->clicked_item->item_type eq 'section'        ? ( $self->clicked_item->id,                undef                          )
 408          :  $self->clicked_item->item_type eq 'function-block' ? ( $self->clicked_item->parent_id,         $self->clicked_item->id        )
 409          :                                                       ( $self->clicked_item->parent->parent_id, $self->clicked_item->parent_id );
 410
 411   } else {                      # sub-function-block
 412     # A sub function block:
 413     # - paste on section list: promote to function block and insert into last section as last element
 414     # - paste on section: promote to function block and insert into that section as last element
 415     # - paste on function block: insert as last element in clicked-upon element
 416     # - paste on sub function block: insert after clicked-upon element
 417
 418     # Promote sub function blocks to function blocks when pasting on a
 419     # section or the section list.
 420     $self->item->item_type('function-block') if !$self->clicked_item || ($self->clicked_item->item_type eq 'section');
 421
 422     return !$self->clicked_item                                ? ( $self->sections->[-1]->id,      undef                   )
 423          :  $self->clicked_item->item_type eq 'section'        ? ( $self->clicked_item->id,        undef                   )
 424          :  $self->clicked_item->item_type eq 'function-block' ? ( $self->clicked_item->id,        undef                   )
 425          :                                                       ( $self->clicked_item->parent_id, $self->clicked_item->id );
 426   }
 427 }
 428
 429 sub assign_requirement_spec_id_rec {
 430   my ($self, $item) = @_;
 431
 432   $item->assign_attributes(requirement_spec_id => $::form->{requirement_spec_id}, fb_number => undef);
 433   $self->assign_requirement_spec_id_rec($_) for @{ $item->children || [] };
 434
 435   return $item;
 436 }
 437
 438 sub create_and_insert_node_rec {
 439   my ($self, $item, $new_parent_id, $insert_after) = @_;
 440
 441   my $node = $self->presenter->requirement_spec_item_jstree_data($item);
 442   $self->js->jstree->create_node('#tree', $insert_after ? ('#fb-' . $insert_after, 'after') : $new_parent_id ? ('#fb-' . $new_parent_id, 'last') : ('#sections', 'last'), $node);
 443
 444   $self->create_and_insert_node_rec($_, $item->id) for @{ $item->children || [] };
 445
 446   $self->js->jstree->open_node('#tree', '#fb-' . $item->id);
 447 }
 448
 449 sub action_ajax_paste {
 450   my ($self, %params) = @_;
 451
 452   my $copied = SL::Clipboard->new->get_entry(qr/^RequirementSpecItem$/);
 453
 454   if (!$copied) {
 455     return $self->js->error(t8("The clipboard does not contain anything that can be pasted here."))
 456                     ->render($self);
 457   }
 458
 459   $self->item($self->assign_requirement_spec_id_rec($copied->to_object));
 460   my $req_spec = SL::DB::RequirementSpec->new(id => $::form->{requirement_spec_id})->load;
 461   $self->sections($req_spec->sections);
 462
 463   if (($self->item->item_type ne 'section') && !@{ $self->sections }) {
 464     return $self->js->error(t8("You cannot paste function blocks or sub function blocks if there is no section."))
 465                     ->render($self);
 466   }
 467
 468   $self->clicked_item($::form->{id} ? SL::DB::RequirementSpecItem->new(id => $::form->{id})->load : undef);
 469
 470   my ($new_parent_id, $insert_after) = $self->determine_paste_position;
 471
 472   # Store result in database.
 473   $self->item->update_attributes(parent_id => $new_parent_id);
 474   $self->item->add_to_list(position => 'after', reference => $insert_after) if $insert_after;
 475
 476   # Update the tree: create the node for all pasted objects.
 477   $self->create_and_insert_node_rec($self->item, $new_parent_id, $insert_after);
 478
 479   # Pasting the very first section?
 480   if (!@{ $self->sections }) {
 481     my $html = $self->render('requirement_spec_item/_section', { output => 0 }, requirement_spec_item => $self->item);
 482     $self->set_function_blocks_tab_menu_class(class => 'section-context-menu')
 483          ->html('#column-content', $html)
 484          ->jstree->select_node('#tree', '#fb-' . $self->item->id)
 485   }
 486
 487   # Update the current view if required.
 488   $self->insert_new_item_in_section_view($self->js) if $self->is_item_visible;
 489
 490   $self->invalidate_version->render($self);
 491 }
 492
 493 #
 494 # filters
 495 #
 496
 497 sub check_auth {
 498   my ($self) = @_;
 499   $::auth->assert('sales_quotation_edit');
 500 }
 501
 502 sub load_requirement_spec_item {
 503   my ($self) = @_;
 504   $self->item(SL::DB::RequirementSpecItem->new(id => $::form->{id})->load);
 505 }
 506
 507 #
 508 # helpers
 509 #
 510
 511 sub create_random_id {
 512   return join '-', Time::HiRes::gettimeofday();
 513 }
 514
 515 sub format_exception {
 516   return join "\n", (split m/\n/, $@)[0..4];
 517 }
 518
 519 sub init_complexities {
 520   my ($self) = @_;
 521
 522   return SL::DB::Manager::RequirementSpecComplexity->get_all_sorted;
 523 }
 524
 525 sub init_risks {
 526   my ($self) = @_;
 527
 528   return SL::DB::Manager::RequirementSpecRisk->get_all_sorted;
 529 }
 530
 531 sub init_js {
 532   my ($self) = @_;
 533   $self->js(SL::ClientJS->new);
 534 }
 535
 536 sub replace_bottom {
 537   my ($self, $item_or_id) = @_;
 538
 539   my $item      = (ref($item_or_id) ? $item_or_id : SL::DB::RequirementSpecItem->new(id => $item_or_id))->load;
 540   my $id_prefix = $item->item_type eq 'function-block' ? '' : 'sub-';
 541   my $html      = $self->render('requirement_spec_item/_function_block_content_bottom', { output => 0 }, requirement_spec_item => $item, id_prefix => $id_prefix);
 542   return $self->js->replaceWith('#' . $id_prefix . 'function-block-content-bottom-' . $item->id, $html);
 543 }
 544
 545 sub render_list {
 546   my ($self, $item, $item_to_select) = @_;
 547
 548   my $html = $self->render('requirement_spec_item/_section', { output => 0 }, requirement_spec_item => $item);
 549   $self->set_function_blocks_tab_menu_class(class => 'section-context-menu')
 550        ->html('#column-content', $html);
 551   $self->select_node($item_to_select || $item);
 552 }
 553
 554 sub select_node {
 555   my ($self, $item) = @_;
 556
 557   $self->js
 558     ->val( '#current_content_type', $item->item_type)
 559     ->val( '#current_content_id',   $item->id)
 560     ->jstree->select_node('#tree', '#fb-' . $item->id);
 561 }
 562
 563 sub create_dependency_item {
 564   my $self = shift;
 565   [ $_[0]->id, $self->presenter->truncate(join(' ', grep { $_ } ($_[1], $_[0]->fb_number, $_[0]->description_as_stripped_html))) ];
 566 }
 567
 568 sub create_dependencies {
 569   my ($self) = @_;
 570
 571   return map { [ $_->fb_number . ' ' . $_->title,
 572                  [ map { ( $self->create_dependency_item($_),
 573                            map { $self->create_dependency_item($_, '->') } @{ $_->children_sorted })
 574                        } @{ $_->children_sorted } ] ]
 575              } @{ $self->item->requirement_spec->sections };
 576 }
 577
 578 sub ensure_section_is_shown {
 579   my ($self, %params) = @_;
 580
 581   return $self->js if $self->is_item_visible;
 582
 583   # Show section/item to edit if it is not visible.
 584   my $new_section = $self->item->section;
 585   my $html        = $self->render('requirement_spec_item/_section', { output => 0 }, requirement_spec_item => $new_section);
 586
 587   return $self->set_function_blocks_tab_menu_class(class => 'section-context-menu')
 588     ->html('#column-content', $html)
 589     ->val('#current_content_type', 'section')
 590     ->val('#current_content_id',   $new_section->id)
 591     ->jstree->select_node('#tree', '#fb-' . $new_section->id);
 592 }
 593
 594 sub add_new_item_form {
 595   my ($self, %params) = @_;
 596
 597   for (qw(insert_position display_reference)) {
 598     croak "Missing parameter $_" if !$params{$_};
 599   }
 600   croak "Missing parameter insert_reference" if ($params{insert_position} eq 'insertAfter') && !$params{insert_reference};
 601
 602   my $id_base = join('_', 'new_function_block', Time::HiRes::gettimeofday(), int rand 1000000000000);
 603   my $html    = $self->render(
 604     'requirement_spec_item/_function_block_form',
 605     { output => 0 },
 606     DEPENDENCIES          => [ $self->create_dependencies ],
 607     SELECTED_DEPENDENCIES => [],
 608     requirement_spec_item => $self->item,
 609     id_base               => $id_base,
 610     insert_after          => $params{insert_position} eq 'insertAfter' ? $params{insert_reference} : undef,
 611   );
 612
 613   return $self->js
 614     ->action($params{insert_position}, $html, $params{display_reference})
 615     ->action_if($self->item->item_type eq 'sub-function-block', 'show', '#sub-function-block-container-' . $self->item->parent_id)
 616     ->run('kivi.requirement_spec.init_function_block_keypress_events', "${id_base}_form")
 617     ->reinit_widgets
 618     ->focus("#${id_base}_description");
 619 }
 620
 621 sub add_new_item_form_after_create {
 622   my ($self, %params) = @_;
 623
 624   my $created_item    = $self->item;
 625
 626   my ($new_item_type, $new_parent_id, $insert_position, $insert_reference, $display_reference);
 627   if ($created_item->item_type eq 'section') {
 628     # $created_item is section, new one will be function-block
 629     $new_item_type     = 'function-block';
 630     $new_parent_id     = $created_item->id;
 631     $insert_position   = 'appendTo';
 632     $display_reference = '#section-list';
 633
 634   } elsif (!$::form->{shift_in_out}) {
 635     # $created_item is function-block or sub-function-block, new one will be the same
 636     $new_item_type     = $created_item->item_type;
 637     $new_parent_id     = $created_item->parent_id;
 638     $insert_position   = 'insertAfter';
 639     $insert_reference  = $created_item->id;
 640     $display_reference = '#' . $created_item->item_type . '-' . $created_item->id;
 641
 642   } elsif ($created_item->item_type eq 'function-block') {
 643     # $created_item is function-block, new one will be sub-function-block
 644     $new_item_type     = 'sub-function-block';
 645     $new_parent_id     = $created_item->id;
 646     $insert_position   = 'appendTo';
 647     $display_reference = '#sub-function-block-container-' . $created_item->id;
 648
 649   } else {
 650     # $created_item is sub-function-block, new one will be function-block
 651     $new_item_type     = 'function-block';
 652     $new_parent_id     = $created_item->parent->parent_id;
 653     $insert_position   = 'insertAfter';
 654     $insert_reference  = $created_item->parent_id;
 655     $display_reference = '#function-block-' . $created_item->parent_id;
 656   }
 657
 658   $::lxdebug->message(LXDebug::DEBUG1(),
 659                       "OLD item_type " . $created_item->item_type . " ; NEW item_type $new_item_type ; parent_id $new_parent_id ; " .
 660                       "insert_position $insert_position ; insert_reference $insert_reference ; display_reference $display_reference");
 661
 662   $self->item(SL::DB::RequirementSpecItem->new(
 663     requirement_spec_id => $created_item->requirement_spec_id,
 664     parent_id           => $new_parent_id,
 665     item_type           => $new_item_type,
 666   ));
 667
 668   $self->add_new_item_form(
 669     insert_reference  => $insert_reference,
 670     insert_position   => $insert_position,
 671     display_reference => $display_reference,
 672   );
 673 }
 674
 675 sub add_function_block {
 676   my ($self, $new_type) = @_;
 677
 678   my $clicked_id = $::form->{id} || ($self->visible_item ? $self->visible_item->id : undef);
 679
 680   die "Invalid new_type '$new_type'"               if $new_type !~ m/^(?:sub-)?function-block$/;
 681   die "Missing parameter 'id' and no visible item" if !$clicked_id;
 682   die "Missing parameter 'requirement_spec_id'"    if !$::form->{requirement_spec_id};
 683
 684   my $clicked_item = SL::DB::RequirementSpecItem->new(id => $clicked_id)->load;
 685   my $clicked_type = $clicked_item->item_type;
 686
 687   die "Invalid clicked_type '$clicked_type'" if $clicked_type !~ m/^(?: section | (?:sub-)? function-block )$/x;
 688
 689   my $case = "${clicked_type}:${new_type}";
 690
 691   my ($insert_position, $insert_reference, $parent_id, $display_reference)
 692     = $case eq 'section:function-block'                ? ( 'appendTo',    $clicked_item->id,        $clicked_item->id,                '#section-list'                  )
 693     : $case eq 'function-block:function-block'         ? ( 'insertAfter', $clicked_item->id,        $clicked_item->parent_id,         '#function-block-'               )
 694     : $case eq 'function-block:sub-function-block'     ? ( 'appendTo'  ,  $clicked_item->id,        $clicked_item->id,                '#sub-function-block-container-' )
 695     : $case eq 'sub-function-block:function-block'     ? ( 'insertAfter', $clicked_item->parent_id, $clicked_item->parent->parent_id, '#function-block-'               )
 696     : $case eq 'sub-function-block:sub-function-block' ? ( 'insertAfter', $clicked_item->id,        $clicked_item->parent_id,         '#sub-function-block-'           )
 697     :                                                    die "Invalid combination of 'clicked_type (section)/new_type ($new_type)'";
 698
 699   $display_reference .= $insert_reference if $display_reference =~ m/-$/;
 700
 701   $self->item(SL::DB::RequirementSpecItem->new(requirement_spec_id => $::form->{requirement_spec_id}, parent_id => $parent_id, item_type => $new_type));
 702
 703   $self->ensure_section_is_shown;
 704   $self->js->show('#sub-function-block-container-' . $parent_id) if $new_type eq 'sub-function-block';
 705   $self->add_new_item_form(insert_position => $insert_position, insert_reference => $insert_reference, display_reference => $display_reference);
 706
 707   $self->js->render($self);
 708 }
 709
 710 sub is_item_visible {
 711   my ($self, $item) = @_;
 712
 713   $item ||= $self->item;
 714   return $self->visible_section && ($self->visible_section->id == $item->section->id);
 715 }
 716
 717 sub invalidate_version {
 718   my ($self) = @_;
 719
 720   my $html   = $self->render('requirement_spec/_version', { output => 0 },
 721                              requirement_spec => SL::DB::RequirementSpec->new(id => $::form->{requirement_spec_id} || $self->item->requirement_spec_id)->load);
 722   return $self->js->html('#requirement_spec_version', $html);
 723 }
 724
 725 1;