SL/Controller/RequirementSpecItem.pm

   1 package SL::Controller::RequirementSpecItem;
   2
   3 use strict;
   4
   5 use parent qw(SL::Controller::Base);
   6
   7 use Carp;
   8 use List::MoreUtils qw(apply);
   9 use List::Util qw(first);
  10 use Time::HiRes ();
  11
  12 use SL::Clipboard;
  13 use SL::Controller::Helper::RequirementSpec;
  14 use SL::DB::RequirementSpec;
  15 use SL::DB::RequirementSpecComplexity;
  16 use SL::DB::RequirementSpecItem;
  17 use SL::DB::RequirementSpecRisk;
  18 use SL::Helper::Flash;
  19 use SL::JSON;
  20 use SL::Locale::String;
  21
  22 use Rose::Object::MakeMethods::Generic
  23 (
  24   scalar                  => [ qw(item visible_item visible_section clicked_item sections) ],
  25   'scalar --get_set_init' => [ qw(complexities risks js) ],
  26 );
  27
  28 __PACKAGE__->run_before('check_auth');
  29 __PACKAGE__->run_before('load_requirement_spec_item', only => [ qw(dragged_and_dropped ajax_update ajax_edit ajax_delete ajax_flag ajax_copy) ]);
  30 __PACKAGE__->run_before('init_visible_section');
  31
  32 #
  33 # actions
  34 #
  35
  36 sub action_ajax_list {
  37   my ($self) = @_;
  38
  39   if (!$::form->{clicked_id}) {
  40     # Clicked on "sections" in the tree. Do nothing.
  41     return $self->render($self->js);
  42   }
  43
  44   my $clicked_item = SL::DB::RequirementSpecItem->new(id => $::form->{clicked_id})->load;
  45   $self->item($clicked_item->section);
  46
  47   if (!$self->visible_section || ($self->visible_section->id != $self->item->id)) {
  48     $self->render_list($self->item, $clicked_item);
  49   } else {
  50     $self->select_node($clicked_item);
  51   }
  52
  53   $self->render($self->js);
  54 }
  55
  56 sub insert_new_item_in_section_view {
  57   my ($self) = @_;
  58
  59   $self->js->hide('#section-list-empty');
  60
  61   my $new_type  = $self->item->item_type;
  62   my $id_prefix = $new_type eq 'sub-function-block' ? 'sub-' : '';
  63   my $template  = 'requirement_spec_item/_' . (apply { s/-/_/g; $_ } $new_type);
  64   my $html      = "" . $self->render($template, { output => 0 }, requirement_spec_item => $self->item);
  65   my $next_item = $self->item->get_next_in_list;
  66
  67   if ($next_item) {
  68     $self->js->insertBefore($html, '#' . $id_prefix . 'function-block-' . $next_item->id);
  69   } else {
  70     my $parent_is_section = $self->item->parent->item_type eq 'section';
  71     $self->js->appendTo($html, $parent_is_section ? '#section-list' : '#sub-function-block-container-' . $self->item->parent_id);
  72     $self->js->show('#sub-function-block-container-' . $self->item->parent_id) if !$parent_is_section;
  73   }
  74
  75   $self->replace_bottom($self->item->parent) if $new_type eq 'sub-function-block';
  76 }
  77
  78 sub action_dragged_and_dropped {
  79   my ($self)              = @_;
  80
  81   my $position            = $::form->{position} =~ m/^ (?: before | after | last ) $/x ? $::form->{position}                                             : die "Unknown 'position' parameter";
  82   my $dropped_item        = $::form->{dropped_id}                                  ? SL::DB::RequirementSpecItem->new(id => $::form->{dropped_id})->load : undef;
  83
  84   my $old_visible_section = $self->visible_section ? $self->visible_section : undef;
  85   my $old_parent_id       = $self->item->parent_id;
  86   my $old_type            = $self->item->item_type;
  87   my $new_type            = $position =~ m/before|after/ ? $dropped_item->item_type : $dropped_item->child_type;
  88
  89   $self->item->db->do_transaction(sub {
  90     $self->item->remove_from_list;
  91     $self->item->parent_id($position =~ m/before|after/ ? $dropped_item->parent_id : $dropped_item->id);
  92     $self->item->item_type($new_type);
  93     $self->item->add_to_list(position => $position, reference => $::form->{dropped_id} || undef);
  94   });
  95
  96   $self->item(SL::DB::RequirementSpecItem->new(id => $self->item->id)->load);
  97   my $new_section         = $self->item->section;
  98   my $new_visible_section = SL::DB::RequirementSpecItem->new(id => $self->visible_item->id)->load->section;
  99
 100   return $self->invalidate_version->render($self) if !$old_visible_section || ($new_type eq 'section');
 101
 102   # From here on $old_visible_section is definitely set.
 103
 104   my $old_parent  = SL::DB::RequirementSpecItem->new(id => $old_parent_id)->load;
 105   my $old_section = $old_parent->section;
 106
 107   # Section debug info:
 108   # $::lxdebug->message(0, "old sec ID " . $old_section->id . " new " . $new_section->id . " old visible " . $old_visible_section->id . " new visible " . $new_visible_section->id
 109   #                       . " PARENT: old " . $old_parent->id . " new " . $self->item->parent_id . '/' . $self->item->parent->id);
 110
 111   # Item debug info:
 112   # $::lxdebug->message(0, 'item id: ' . $self->item->id . " new type: $new_type old type: $old_type #old children: " . scalar(@{ $old_parent->children }));
 113
 114   if ($old_visible_section->id != $new_visible_section->id) {
 115     # The currently visible item has been dragged to a different section.
 116     $self->invalidate_version;
 117     return $self->render_list($new_section, $self->item)
 118       ->render($self);
 119   }
 120
 121   if ($old_visible_section->id == $old_section->id) {
 122     my $id_prefix = $old_type eq 'sub-function-block' ? 'sub-' : '';
 123     $self->js->remove('#' . $id_prefix . 'function-block-' . $self->item->id);
 124
 125     if ($old_type eq 'sub-function-block') {
 126       $self->replace_bottom($old_parent) ;
 127       $self->js->hide('#sub-function-block-container-' . $old_parent->id) if 0 == scalar(@{ $old_parent->children });
 128
 129     } elsif (0 == scalar(@{ $old_section->children })) {
 130       $self->js->show('#section-list-empty');
 131     }
 132   }
 133
 134   if ($old_visible_section->id == $new_section->id) {
 135     $self->insert_new_item_in_section_view($self->js);
 136   }
 137
 138   # $::lxdebug->dump(0, "js", $self->js->to_array);
 139
 140   $self->invalidate_version->render($self);
 141 }
 142
 143 sub action_ajax_add_section {
 144   my ($self, %params) = @_;
 145
 146   die "Missing parameter 'requirement_spec_id'" if !$::form->{requirement_spec_id};
 147
 148   $self->item(SL::DB::RequirementSpecItem->new(requirement_spec_id => $::form->{requirement_spec_id}, item_type => 'section'));
 149
 150   my $insert_after = $::form->{id} ? SL::DB::RequirementSpecItem->new(id => $::form->{id})->load->section->id : undef;
 151   my $html         = $self->render('requirement_spec_item/_section_form', { output => 0 }, id_base => 'new_section', insert_after => $insert_after);
 152
 153   $self->js
 154     ->remove('#new_section_form')
 155     ->hide('#column-content > *')
 156     ->appendTo($html, '#column-content')
 157     ->focus('#new_section_title')
 158     ->render($self);
 159 }
 160
 161 sub action_ajax_add_function_block {
 162   my ($self, %params) = @_;
 163
 164   return $self->add_function_block('function-block');
 165 }
 166
 167 sub action_ajax_add_sub_function_block {
 168   my ($self, %params) = @_;
 169
 170   return $self->add_function_block('sub-function-block');
 171 }
 172
 173 sub action_ajax_create {
 174   my ($self, %params) = @_;
 175
 176   my $prefix          = $::form->{form_prefix} || die "Missing parameter 'form_prefix'";
 177   my $attributes      = $::form->{$prefix}     || die "Missing parameter group '${prefix}'";
 178   my $insert_after    = delete $attributes->{insert_after};
 179
 180   if (!$attributes->{parent_id}) {
 181     $attributes->{order_part_id} ||= $::instance_conf->get_requirement_spec_section_order_part_id;
 182   }
 183
 184   my @errors = $self->item(SL::DB::RequirementSpecItem->new(%{ $attributes }))->validate;
 185   return $self->js->error(@errors)->render($self) if @errors;
 186
 187   $self->item->save;
 188   $self->item->add_to_list(position => 'after', reference => $insert_after) if $insert_after;
 189
 190   my $type = $self->item->item_type;
 191
 192   if ($type eq 'section') {
 193     my $node = $self->presenter->requirement_spec_item_jstree_data($self->item);
 194     $self->invalidate_version;
 195     $self->render_list($self->item)
 196       ->hide('#section-list-empty')
 197       ->jstree->create_node('#tree', $insert_after ? ('#fb-' . $insert_after, 'after') : ('#sections', 'last'), $node)
 198       ->jstree->select_node('#tree', '#fb-' . $self->item->id);
 199     return $self->add_new_item_form_after_create
 200       ->render($self);
 201   }
 202
 203   my $template = 'requirement_spec_item/_' . (apply { s/-/_/g; $_ } $type);
 204   my $html     = $self->render($template, { output => 0 }, requirement_spec_item => $self->item, id_prefix => $type eq 'function-block' ? '' : 'sub-');
 205   my $node     = $self->presenter->requirement_spec_item_jstree_data($self->item);
 206
 207   $self->js
 208     ->replaceWith('#' . $prefix . '_form', $html)
 209     ->hide('#section-list-empty')
 210     ->jstree->create_node('#tree', $insert_after ? ('#fb-' . $insert_after, 'after') : ('#fb-' . $self->item->parent_id, 'last'), $node)
 211     ->jstree->select_node('#tree', '#fb-' . $self->item->id);
 212
 213   $self->replace_bottom($self->item->parent) if $type eq 'sub-function-block';
 214
 215   $self->add_new_item_form_after_create;
 216
 217   $self->invalidate_version->render($self);
 218 }
 219
 220 sub action_ajax_edit {
 221   my ($self, %params) = @_;
 222
 223   $self->item(SL::DB::RequirementSpecItem->new(id => $::form->{id})->load);
 224
 225   if (!$self->is_item_visible) {
 226     # Show section/item to edit if it is not visible.
 227
 228     my $html = $self->render('requirement_spec_item/_section', { output => 0 }, requirement_spec_item => $self->item->section);
 229     $self->set_function_blocks_tab_menu_class(class => 'section-context-menu')
 230       ->html('#column-content', $html);
 231   }
 232
 233   if ($self->item->item_type =~ m/section/) {
 234     # Edit the section header, not an item.
 235     my $html = $self->render('requirement_spec_item/_section_form', { output => 0 });
 236
 237     $self->js
 238       ->hide('#section-header-' . $self->item->id)
 239       ->remove("#edit_section_form")
 240       ->insertAfter($html, '#section-header-' . $self->item->id)
 241       ->jstree->select_node('#tree', '#fb-' . $self->item->id)
 242       ->focus("#edit_section_title")
 243       ->val('#current_content_type', 'section')
 244       ->val('#current_content_id',   $self->item->id)
 245       ->render($self);
 246     return;
 247   }
 248
 249   # Edit a function block or a sub function block
 250   my @dependencies          = $self->create_dependencies;
 251   my @selected_dependencies = map { $_->id } @{ $self->item->dependencies };
 252
 253   my $html                  = $self->render('requirement_spec_item/_function_block_form', { output => 0 }, DEPENDENCIES => \@dependencies, SELECTED_DEPENDENCIES => \@selected_dependencies);
 254   my $id_base               = 'edit_function_block_' . $self->item->id;
 255   my $content_top_id        = '#' . $self->item->item_type . '-content-top-' . $self->item->id;
 256
 257   $self->js
 258     ->hide($content_top_id)
 259     ->remove("#${id_base}_form")
 260     ->insertAfter($html, $content_top_id)
 261     ->jstree->select_node('#tree', '#fb-' . $self->item->id)
 262     ->focus("#${id_base}_description")
 263     ->val('#current_content_type', $self->item->item_type)
 264     ->val('#current_content_id', $self->item->id)
 265     ->render($self);
 266 }
 267
 268 sub action_ajax_update {
 269   my ($self, %params) = @_;
 270
 271   my $prefix     = $::form->{form_prefix} || die "Missing parameter 'form_prefix'";
 272   my $attributes = $::form->{$prefix}     || {};
 273
 274   foreach (qw(requirement_spec_id parent_id position)) {
 275     delete $attributes->{$_} if !defined $attributes->{$_};
 276   }
 277
 278   my @errors = $self->item->assign_attributes(%{ $attributes })->validate;
 279   return $self->js->error(@errors)->render($self) if @errors;
 280
 281   $self->item->save;
 282
 283   my $type = $self->item->item_type;
 284
 285   if ($type eq 'section') {
 286     # Updated section, now update section header.
 287
 288     my $html = $self->render('requirement_spec_item/_section_header', { output => 0 }, requirement_spec_item => $self->item);
 289
 290     return $self->invalidate_version
 291       ->remove('#edit_section_form')
 292       ->html('#section-header-' . $self->item->id, $html)
 293       ->show('#section-header-' . $self->item->id)
 294       ->jstree->rename_node('#tree', '#fb-' . $self->item->id, $::request->presenter->requirement_spec_item_tree_node_title($self->item))
 295       ->render($self);
 296   }
 297
 298   # Updated function block or sub function block. Update (sub)
 299   # function block and potentially the bottom of the parent function
 300   # block.
 301
 302   my $id_prefix    = $type eq 'function-block' ? '' : 'sub-';
 303   my $html_top     = $self->render('requirement_spec_item/_function_block_content_top',    { output => 0 }, requirement_spec_item => $self->item, id_prefix => $id_prefix);
 304   $id_prefix      .= 'function-block-content-';
 305
 306   $self->js
 307     ->remove('#' . $prefix . '_form')
 308     ->replaceWith('#' . $id_prefix . 'top-' . $self->item->id, $html_top)
 309     ->jstree->rename_node('#tree', '#fb-' . $self->item->id, $::request->presenter->requirement_spec_item_tree_node_title($self->item));
 310
 311   $self->replace_bottom($self->item, id_prefix => $id_prefix);
 312   $self->replace_bottom($self->item->parent) if $type eq 'sub-function-block';
 313
 314   $self->invalidate_version->render($self);
 315 }
 316
 317 sub action_ajax_delete {
 318   my ($self) = @_;
 319
 320   my $full_list = $self->item->get_full_list;
 321
 322   $self->item->delete;
 323
 324   if ($self->visible_section && ($self->visible_section->id == $self->item->id)) {
 325     # Currently visible section is deleted.
 326
 327     my $new_section = first { $_->id != $self->item->id } @{ $self->item->requirement_spec->sections };
 328     if ($new_section) {
 329       $self->render_list($new_section);
 330
 331     } else {
 332       my $html = $self->render('requirement_spec_item/_no_section', { output => 0 });
 333       $self->set_function_blocks_tab_menu_class(class => 'section-context-menu')
 334         ->html('#column-content',      $html)
 335         ->val('#current_content_type', '')
 336         ->val('#current_content_id',   '')
 337     }
 338
 339   } elsif ($self->is_item_visible) {
 340     # Item in currently visible section is deleted.
 341
 342     my $type = $self->item->item_type;
 343     $self->js->remove('#edit_function_block_' . $self->item->id . '_form')
 344              ->remove('#' . $type . '-' . $self->item->id);
 345
 346     $self->replace_bottom($self->item->parent_id) if $type eq 'sub-function-block';
 347
 348     if (1 == scalar @{ $full_list }) {
 349       if ($type eq 'function-block') {
 350         $self->js->show('#section-list-empty');
 351       } elsif ($type eq 'sub-function-block') {
 352         $self->js->hide('#sub-function-block-container-' . $self->item->parent_id);
 353       }
 354     }
 355   }
 356
 357   $self->invalidate_version
 358     ->jstree->delete_node('#tree', '#fb-' . $self->item->id)
 359     ->render($self);
 360 }
 361
 362 sub action_ajax_flag {
 363   my ($self) = @_;
 364
 365   $self->item->update_attributes(is_flagged => !$self->item->is_flagged);
 366
 367   $self->js
 368    ->action_if($self->is_item_visible, 'toggleClass', '#' . $self->item->item_type . '-' . $self->item->id, 'flagged')
 369    ->toggleClass('#fb-' . $self->item->id, 'flagged')
 370    ->render($self);
 371 }
 372
 373 sub action_ajax_copy {
 374   my ($self, %params) = @_;
 375
 376   SL::Clipboard->new->copy($self->item);
 377   $self->render($self->js);
 378 }
 379
 380 sub determine_paste_position {
 381   my ($self) = @_;
 382
 383   if ($self->item->item_type eq 'section') {
 384     # Sections are always pasted either directly after the
 385     # clicked-upon section or at the very end.
 386     return $self->clicked_item ? (undef, $self->clicked_item->section->id) : ();
 387
 388   } elsif ($self->item->item_type eq 'function-block') {
 389     # A function block:
 390     # - paste on section list: insert into last section as last element
 391     # - paste on section: insert into that section as last element
 392     # - paste on function block: insert after clicked-upon element
 393     # - paste on sub function block: insert after parent function block of clicked-upon element
 394     return !$self->clicked_item                                ? ( $self->sections->[-1]->id,              undef                          )
 395          :  $self->clicked_item->item_type eq 'section'        ? ( $self->clicked_item->id,                undef                          )
 396          :  $self->clicked_item->item_type eq 'function-block' ? ( $self->clicked_item->parent_id,         $self->clicked_item->id        )
 397          :                                                       ( $self->clicked_item->parent->parent_id, $self->clicked_item->parent_id );
 398
 399   } else {                      # sub-function-block
 400     # A sub function block:
 401     # - paste on section list: promote to function block and insert into last section as last element
 402     # - paste on section: promote to function block and insert into that section as last element
 403     # - paste on function block: insert as last element in clicked-upon element
 404     # - paste on sub function block: insert after clicked-upon element
 405
 406     # Promote sub function blocks to function blocks when pasting on a
 407     # section or the section list.
 408     $self->item->item_type('function-block') if !$self->clicked_item || ($self->clicked_item->item_type eq 'section');
 409
 410     return !$self->clicked_item                                ? ( $self->sections->[-1]->id,      undef                   )
 411          :  $self->clicked_item->item_type eq 'section'        ? ( $self->clicked_item->id,        undef                   )
 412          :  $self->clicked_item->item_type eq 'function-block' ? ( $self->clicked_item->id,        undef                   )
 413          :                                                       ( $self->clicked_item->parent_id, $self->clicked_item->id );
 414   }
 415 }
 416
 417 sub assign_requirement_spec_id_rec {
 418   my ($self, $item) = @_;
 419
 420   $item->assign_attributes(requirement_spec_id => $::form->{requirement_spec_id}, fb_number => undef);
 421   $self->assign_requirement_spec_id_rec($_) for @{ $item->children || [] };
 422
 423   return $item;
 424 }
 425
 426 sub create_and_insert_node_rec {
 427   my ($self, $item, $new_parent_id, $insert_after) = @_;
 428
 429   my $node = $self->presenter->requirement_spec_item_jstree_data($item);
 430   $self->js->jstree->create_node('#tree', $insert_after ? ('#fb-' . $insert_after, 'after') : $new_parent_id ? ('#fb-' . $new_parent_id, 'last') : ('#sections', 'last'), $node);
 431
 432   $self->create_and_insert_node_rec($_, $item->id) for @{ $item->children || [] };
 433
 434   $self->js->jstree->open_node('#tree', '#fb-' . $item->id);
 435 }
 436
 437 sub action_ajax_paste {
 438   my ($self, %params) = @_;
 439
 440   my $copied = SL::Clipboard->new->get_entry(qr/^RequirementSpecItem$/);
 441
 442   if (!$copied) {
 443     return $self->js->error(t8("The clipboard does not contain anything that can be pasted here."))
 444                     ->render($self);
 445   }
 446
 447   $self->item($self->assign_requirement_spec_id_rec($copied->to_object));
 448   my $req_spec = SL::DB::RequirementSpec->new(id => $::form->{requirement_spec_id})->load;
 449   $self->sections($req_spec->sections);
 450
 451   if (($self->item->item_type ne 'section') && !@{ $self->sections }) {
 452     return $self->js->error(t8("You cannot paste function blocks or sub function blocks if there is no section."))
 453                     ->render($self);
 454   }
 455
 456   $self->clicked_item($::form->{id} ? SL::DB::RequirementSpecItem->new(id => $::form->{id})->load : undef);
 457
 458   my ($new_parent_id, $insert_after) = $self->determine_paste_position;
 459
 460   # Store result in database.
 461   $self->item->update_attributes(parent_id => $new_parent_id);
 462   $self->item->add_to_list(position => 'after', reference => $insert_after) if $insert_after;
 463
 464   # Update the tree: create the node for all pasted objects.
 465   $self->create_and_insert_node_rec($self->item, $new_parent_id, $insert_after);
 466
 467   # Pasting the very first section?
 468   if (!@{ $self->sections }) {
 469     my $html = $self->render('requirement_spec_item/_section', { output => 0 }, requirement_spec_item => $self->item);
 470     $self->set_function_blocks_tab_menu_class(class => 'section-context-menu')
 471          ->html('#column-content', $html)
 472          ->jstree->select_node('#tree', '#fb-' . $self->item->id)
 473   }
 474
 475   # Update the current view if required.
 476   $self->insert_new_item_in_section_view($self->js) if $self->is_item_visible;
 477
 478   $self->invalidate_version->render($self);
 479 }
 480
 481 #
 482 # filters
 483 #
 484
 485 sub check_auth {
 486   my ($self) = @_;
 487   $::auth->assert('sales_quotation_edit');
 488 }
 489
 490 sub load_requirement_spec_item {
 491   my ($self) = @_;
 492   $self->item(SL::DB::RequirementSpecItem->new(id => $::form->{id})->load);
 493 }
 494
 495 #
 496 # helpers
 497 #
 498
 499 sub create_random_id {
 500   return join '-', Time::HiRes::gettimeofday();
 501 }
 502
 503 sub format_exception {
 504   return join "\n", (split m/\n/, $@)[0..4];
 505 }
 506
 507 sub init_complexities {
 508   my ($self) = @_;
 509
 510   return SL::DB::Manager::RequirementSpecComplexity->get_all_sorted;
 511 }
 512
 513 sub init_risks {
 514   my ($self) = @_;
 515
 516   return SL::DB::Manager::RequirementSpecRisk->get_all_sorted;
 517 }
 518
 519 sub init_js {
 520   my ($self) = @_;
 521   $self->js(SL::ClientJS->new);
 522 }
 523
 524 sub replace_bottom {
 525   my ($self, $item_or_id) = @_;
 526
 527   my $item      = (ref($item_or_id) ? $item_or_id : SL::DB::RequirementSpecItem->new(id => $item_or_id))->load;
 528   my $id_prefix = $item->item_type eq 'function-block' ? '' : 'sub-';
 529   my $html      = $self->render('requirement_spec_item/_function_block_content_bottom', { output => 0 }, requirement_spec_item => $item, id_prefix => $id_prefix);
 530   return $self->js->replaceWith('#' . $id_prefix . 'function-block-content-bottom-' . $item->id, $html);
 531 }
 532
 533 sub render_list {
 534   my ($self, $item, $item_to_select) = @_;
 535
 536   my $html = $self->render('requirement_spec_item/_section', { output => 0 }, requirement_spec_item => $item);
 537   $self->set_function_blocks_tab_menu_class(class => 'section-context-menu')
 538        ->html('#column-content', $html);
 539   $self->select_node($item_to_select || $item);
 540 }
 541
 542 sub select_node {
 543   my ($self, $item) = @_;
 544
 545   $self->js
 546     ->val( '#current_content_type', $item->item_type)
 547     ->val( '#current_content_id',   $item->id)
 548     ->jstree->select_node('#tree', '#fb-' . $item->id);
 549 }
 550
 551 sub create_dependency_item {
 552   my $self = shift;
 553   [ $_[0]->id, $self->presenter->truncate(join(' ', grep { $_ } ($_[1], $_[0]->fb_number, $_[0]->description))) ];
 554 }
 555
 556 sub create_dependencies {
 557   my ($self) = @_;
 558
 559   return map { [ $_->fb_number . ' ' . $_->title,
 560                  [ map { ( $self->create_dependency_item($_),
 561                            map { $self->create_dependency_item($_, '->') } @{ $_->children_sorted })
 562                        } @{ $_->children_sorted } ] ]
 563              } @{ $self->item->requirement_spec->sections };
 564 }
 565
 566 sub ensure_section_is_shown {
 567   my ($self, %params) = @_;
 568
 569   return $self->js if $self->is_item_visible;
 570
 571   # Show section/item to edit if it is not visible.
 572   my $new_section = $self->item->section;
 573   my $html        = $self->render('requirement_spec_item/_section', { output => 0 }, requirement_spec_item => $new_section);
 574
 575   return $self->set_function_blocks_tab_menu_class(class => 'section-context-menu')
 576     ->html('#column-content', $html)
 577     ->val('#current_content_type', 'section')
 578     ->val('#current_content_id',   $new_section->id)
 579     ->jstree->select_node('#tree', '#fb-' . $new_section->id);
 580 }
 581
 582 sub add_new_item_form {
 583   my ($self, %params) = @_;
 584
 585   for (qw(insert_position display_reference)) {
 586     croak "Missing parameter $_" if !$params{$_};
 587   }
 588   croak "Missing parameter insert_reference" if ($params{insert_position} eq 'insertAfter') && !$params{insert_reference};
 589
 590   my $id_base = join('_', 'new_function_block', Time::HiRes::gettimeofday(), int rand 1000000000000);
 591   my $html    = $self->render(
 592     'requirement_spec_item/_function_block_form',
 593     { output => 0 },
 594     DEPENDENCIES          => [ $self->create_dependencies ],
 595     SELECTED_DEPENDENCIES => [],
 596     requirement_spec_item => $self->item,
 597     id_base               => $id_base,
 598     insert_after          => $params{insert_position} eq 'insertAfter' ? $params{insert_reference} : undef,
 599   );
 600
 601   return $self->js
 602     ->action($params{insert_position}, $html, $params{display_reference})
 603     ->focus("#${id_base}_description");
 604 }
 605
 606 sub add_new_item_form_after_create {
 607   my ($self, %params) = @_;
 608
 609   my $created_item    = $self->item;
 610   my $is_section      = $created_item->item_type eq 'section';
 611
 612   $self->item(SL::DB::RequirementSpecItem->new(
 613     requirement_spec_id => $created_item->requirement_spec_id,
 614     parent_id           => $is_section ? $created_item->id : $created_item->parent_id,
 615     item_type           => $is_section ? 'function-block'  : $created_item->item_type,
 616   ));
 617
 618   $self->add_new_item_form(
 619     insert_reference  => $created_item->id,
 620     insert_position   => $is_section ? 'appendTo'      : 'insertAfter',
 621     display_reference => $is_section ? '#section-list' : '#' . $created_item->item_type . '-' . $created_item->id,
 622   );
 623 }
 624
 625 sub add_function_block {
 626   my ($self, $new_type) = @_;
 627
 628   my $clicked_id = $::form->{id} || ($self->visible_item ? $self->visible_item->id : undef);
 629
 630   die "Invalid new_type '$new_type'"               if $new_type !~ m/^(?:sub-)?function-block$/;
 631   die "Missing parameter 'id' and no visible item" if !$clicked_id;
 632   die "Missing parameter 'requirement_spec_id'"    if !$::form->{requirement_spec_id};
 633
 634   my $clicked_item = SL::DB::RequirementSpecItem->new(id => $clicked_id)->load;
 635   my $clicked_type = $clicked_item->item_type;
 636
 637   die "Invalid clicked_type '$clicked_type'" if $clicked_type !~ m/^(?: section | (?:sub-)? function-block )$/x;
 638
 639   my $case = "${clicked_type}:${new_type}";
 640
 641   my ($insert_position, $insert_reference, $parent_id, $display_reference)
 642     = $case eq 'section:function-block'                ? ( 'appendTo',    $clicked_item->id,        $clicked_item->id,                '#section-list'                  )
 643     : $case eq 'function-block:function-block'         ? ( 'insertAfter', $clicked_item->id,        $clicked_item->parent_id,         '#function-block-'               )
 644     : $case eq 'function-block:sub-function-block'     ? ( 'appendTo'  ,  $clicked_item->id,        $clicked_item->id,                '#sub-function-block-container-' )
 645     : $case eq 'sub-function-block:function-block'     ? ( 'insertAfter', $clicked_item->parent_id, $clicked_item->parent->parent_id, '#function-block-'               )
 646     : $case eq 'sub-function-block:sub-function-block' ? ( 'insertAfter', $clicked_item->id,        $clicked_item->parent_id,         '#sub-function-block-'           )
 647     :                                                    die "Invalid combination of 'clicked_type (section)/new_type ($new_type)'";
 648
 649   $display_reference .= $insert_reference if $display_reference =~ m/-$/;
 650
 651   $self->item(SL::DB::RequirementSpecItem->new(requirement_spec_id => $::form->{requirement_spec_id}, parent_id => $parent_id, item_type => $new_type));
 652
 653   $self->ensure_section_is_shown;
 654   $self->js->show('#sub-function-block-container-' . $parent_id) if $new_type eq 'sub-function-block';
 655   $self->add_new_item_form(insert_position => $insert_position, insert_reference => $insert_reference, display_reference => $display_reference);
 656
 657   $self->js->render($self);
 658 }
 659
 660 sub is_item_visible {
 661   my ($self, $item) = @_;
 662
 663   $item ||= $self->item;
 664   return $self->visible_section && ($self->visible_section->id == $item->section->id);
 665 }
 666
 667 sub invalidate_version {
 668   my ($self) = @_;
 669
 670   my $html   = $self->render('requirement_spec/_version', { output => 0 },
 671                              requirement_spec => SL::DB::RequirementSpec->new(id => $::form->{requirement_spec_id} || $self->item->requirement_spec_id)->load);
 672   return $self->js->html('#requirement_spec_version', $html);
 673 }
 674
 675 1;