SL/Controller/RequirementSpecItem.pm

   1 package SL::Controller::RequirementSpecItem;
   2
   3 use strict;
   4
   5 use parent qw(SL::Controller::Base);
   6
   7 use Carp;
   8 use List::MoreUtils qw(apply);
   9 use List::Util qw(first);
  10 use Time::HiRes ();
  11
  12 use SL::Clipboard;
  13 use SL::Controller::Helper::RequirementSpec;
  14 use SL::DB::RequirementSpec;
  15 use SL::DB::RequirementSpecComplexity;
  16 use SL::DB::RequirementSpecItem;
  17 use SL::DB::RequirementSpecRisk;
  18 use SL::Helper::Flash;
  19 use SL::JSON;
  20 use SL::Locale::String;
  21
  22 use Rose::Object::MakeMethods::Generic
  23 (
  24   scalar                  => [ qw(item visible_item visible_section clicked_item sections) ],
  25   'scalar --get_set_init' => [ qw(complexities risks js) ],
  26 );
  27
  28 __PACKAGE__->run_before('check_auth');
  29 __PACKAGE__->run_before('load_requirement_spec_item', only => [ qw(dragged_and_dropped ajax_update ajax_edit ajax_delete ajax_flag ajax_copy) ]);
  30 __PACKAGE__->run_before('init_visible_section');
  31
  32 #
  33 # actions
  34 #
  35
  36 sub action_ajax_list {
  37   my ($self) = @_;
  38
  39   if (!$::form->{clicked_id}) {
  40     # Clicked on "sections" in the tree. Do nothing.
  41     return $self->render($self->js);
  42   }
  43
  44   my $clicked_item = SL::DB::RequirementSpecItem->new(id => $::form->{clicked_id})->load;
  45   $self->item($clicked_item->section);
  46
  47   if (!$self->visible_section || ($self->visible_section->id != $self->item->id)) {
  48     $self->render_list($self->item, $clicked_item);
  49   } else {
  50     $self->select_node($clicked_item);
  51   }
  52
  53   $self->render($self->js);
  54 }
  55
  56 sub insert_new_item_in_section_view {
  57   my ($self) = @_;
  58
  59   $self->js->hide('#section-list-empty');
  60
  61   my $new_type  = $self->item->item_type;
  62   my $id_prefix = $new_type eq 'sub-function-block' ? 'sub-' : '';
  63   my $template  = 'requirement_spec_item/_' . (apply { s/-/_/g; $_ } $new_type);
  64   my $html      = "" . $self->render($template, { output => 0 }, requirement_spec_item => $self->item);
  65   my $next_item = $self->item->get_next_in_list;
  66
  67   if ($next_item) {
  68     $self->js->insertBefore($html, '#' . $id_prefix . 'function-block-' . $next_item->id);
  69   } else {
  70     my $parent_is_section = $self->item->parent->item_type eq 'section';
  71     $self->js->appendTo($html, $parent_is_section ? '#section-list' : '#sub-function-block-container-' . $self->item->parent_id);
  72     $self->js->show('#sub-function-block-container-' . $self->item->parent_id) if !$parent_is_section;
  73   }
  74
  75   $self->replace_bottom($self->item->parent) if $new_type eq 'sub-function-block';
  76 }
  77
  78 sub action_dragged_and_dropped {
  79   my ($self)              = @_;
  80
  81   my $position            = $::form->{position} =~ m/^ (?: before | after | last ) $/x ? $::form->{position}                                             : die "Unknown 'position' parameter";
  82   my $dropped_item        = $::form->{dropped_id}                                  ? SL::DB::RequirementSpecItem->new(id => $::form->{dropped_id})->load : undef;
  83
  84   my $old_visible_section = $self->visible_section ? $self->visible_section : undef;
  85   my $old_parent_id       = $self->item->parent_id;
  86   my $old_type            = $self->item->item_type;
  87   my $new_type            = !$dropped_item ? 'section' : $position =~ m/before|after/ ? $dropped_item->item_type : $dropped_item->child_type;
  88
  89   $self->item->db->do_transaction(sub {
  90     $self->item->remove_from_list;
  91     $self->item->parent_id($position =~ m/before|after/ ? $dropped_item->parent_id : $dropped_item->id) if $dropped_item;
  92     $self->item->item_type($new_type);
  93     $self->item->add_to_list(position => $position, reference => $::form->{dropped_id} || undef);
  94   });
  95
  96   $self->item(SL::DB::RequirementSpecItem->new(id => $self->item->id)->load);
  97   my $new_section         = $self->item->section;
  98   my $new_visible_section = SL::DB::RequirementSpecItem->new(id => $self->visible_item->id)->load->section;
  99
 100   return $self->invalidate_version->render($self) if !$old_visible_section || ($new_type eq 'section');
 101
 102   # From here on $old_visible_section is definitely set.
 103
 104   my $old_parent  = SL::DB::RequirementSpecItem->new(id => $old_parent_id)->load;
 105   my $old_section = $old_parent->section;
 106
 107   # Section debug info:
 108   # $::lxdebug->message(0, "old sec ID " . $old_section->id . " new " . $new_section->id . " old visible " . $old_visible_section->id . " new visible " . $new_visible_section->id
 109   #                       . " PARENT: old " . $old_parent->id . " new " . $self->item->parent_id . '/' . $self->item->parent->id);
 110
 111   # Item debug info:
 112   # $::lxdebug->message(0, 'item id: ' . $self->item->id . " new type: $new_type old type: $old_type #old children: " . scalar(@{ $old_parent->children }));
 113
 114   if ($old_visible_section->id != $new_visible_section->id) {
 115     # The currently visible item has been dragged to a different section.
 116     $self->invalidate_version;
 117     return $self->render_list($new_section, $self->item)
 118       ->render($self);
 119   }
 120
 121   if ($old_visible_section->id == $old_section->id) {
 122     my $id_prefix = $old_type eq 'sub-function-block' ? 'sub-' : '';
 123     $self->js->remove('#' . $id_prefix . 'function-block-' . $self->item->id);
 124
 125     if ($old_type eq 'sub-function-block') {
 126       $self->replace_bottom($old_parent) ;
 127       $self->js->hide('#sub-function-block-container-' . $old_parent->id) if 0 == scalar(@{ $old_parent->children });
 128
 129     } elsif (0 == scalar(@{ $old_section->children })) {
 130       $self->js->show('#section-list-empty');
 131     }
 132   }
 133
 134   if ($old_visible_section->id == $new_section->id) {
 135     $self->insert_new_item_in_section_view($self->js);
 136   }
 137
 138   # $::lxdebug->dump(0, "js", $self->js->to_array);
 139
 140   $self->invalidate_version->render($self);
 141 }
 142
 143 sub action_ajax_add_section {
 144   my ($self, %params) = @_;
 145
 146   die "Missing parameter 'requirement_spec_id'" if !$::form->{requirement_spec_id};
 147
 148   $self->item(SL::DB::RequirementSpecItem->new(requirement_spec_id => $::form->{requirement_spec_id}, item_type => 'section'));
 149
 150   my $insert_after = $::form->{id} ? SL::DB::RequirementSpecItem->new(id => $::form->{id})->load->section->id : undef;
 151   my $html         = $self->render('requirement_spec_item/_section_form', { output => 0 }, id_base => 'new_section', insert_after => $insert_after);
 152
 153   $self->js
 154     ->remove('#new_section_form')
 155     ->hide('#column-content > *')
 156     ->appendTo($html, '#column-content')
 157     ->focus('#new_section_title')
 158     ->render($self);
 159 }
 160
 161 sub action_ajax_add_function_block {
 162   my ($self, %params) = @_;
 163
 164   return $self->add_function_block('function-block');
 165 }
 166
 167 sub action_ajax_add_sub_function_block {
 168   my ($self, %params) = @_;
 169
 170   return $self->add_function_block('sub-function-block');
 171 }
 172
 173 sub action_ajax_create {
 174   my ($self, %params) = @_;
 175
 176   my $prefix          = $::form->{form_prefix} || die "Missing parameter 'form_prefix'";
 177   my $attributes      = $::form->{$prefix}     || die "Missing parameter group '${prefix}'";
 178   my $insert_after    = delete $attributes->{insert_after};
 179
 180   if (!$attributes->{parent_id}) {
 181     $attributes->{order_part_id} ||= $::instance_conf->get_requirement_spec_section_order_part_id;
 182   }
 183
 184   my @errors = $self->item(SL::DB::RequirementSpecItem->new(%{ $attributes }))->validate;
 185   return $self->js->error(@errors)->render($self) if @errors;
 186
 187   $self->item->save;
 188   $self->item->add_to_list(position => 'after', reference => $insert_after) if $insert_after;
 189
 190   my $type = $self->item->item_type;
 191
 192   if ($type eq 'section') {
 193     my $node = $self->presenter->requirement_spec_item_jstree_data($self->item);
 194     $self->invalidate_version;
 195     $self->render_list($self->item)
 196       ->hide('#section-list-empty')
 197       ->jstree->create_node('#tree', $insert_after ? ('#fb-' . $insert_after, 'after') : ('#sections', 'last'), $node)
 198       ->jstree->select_node('#tree', '#fb-' . $self->item->id);
 199     return $self->add_new_item_form_after_create
 200       ->reinit_widgets
 201       ->render($self);
 202   }
 203
 204   my $template = 'requirement_spec_item/_' . (apply { s/-/_/g; $_ } $type);
 205   my $html     = $self->render($template, { output => 0 }, requirement_spec_item => $self->item, id_prefix => $type eq 'function-block' ? '' : 'sub-');
 206   my $node     = $self->presenter->requirement_spec_item_jstree_data($self->item);
 207
 208   $self->js
 209     ->replaceWith('#' . $prefix . '_form', $html)
 210     ->hide('#section-list-empty')
 211     ->jstree->create_node('#tree', $insert_after ? ('#fb-' . $insert_after, 'after') : ('#fb-' . $self->item->parent_id, 'last'), $node)
 212     ->reinit_widgets
 213     ->jstree->select_node('#tree', '#fb-' . $self->item->id);
 214
 215   $self->replace_bottom($self->item->parent) if $type eq 'sub-function-block';
 216
 217   $self->add_new_item_form_after_create;
 218
 219   $self->invalidate_version->render($self);
 220 }
 221
 222 sub action_ajax_edit {
 223   my ($self, %params) = @_;
 224
 225   $self->item(SL::DB::RequirementSpecItem->new(id => $::form->{id})->load);
 226
 227   if (!$self->is_item_visible) {
 228     # Show section/item to edit if it is not visible.
 229
 230     my $html = $self->render('requirement_spec_item/_section', { output => 0 }, requirement_spec_item => $self->item->section);
 231     $self->set_function_blocks_tab_menu_class(class => 'section-context-menu')
 232       ->html('#column-content', $html);
 233   }
 234
 235   if ($self->item->item_type =~ m/section/) {
 236     # Edit the section header, not an item.
 237     my $html = $self->render('requirement_spec_item/_section_form', { output => 0 });
 238
 239     $self->js
 240       ->hide('#section-header-' . $self->item->id)
 241       ->remove("#edit_section_form")
 242       ->insertAfter($html, '#section-header-' . $self->item->id)
 243       ->jstree->select_node('#tree', '#fb-' . $self->item->id)
 244       ->focus("#edit_section_title")
 245       ->val('#current_content_type', 'section')
 246       ->val('#current_content_id',   $self->item->id)
 247       ->render($self);
 248     return;
 249   }
 250
 251   # Edit a function block or a sub function block
 252   my @dependencies          = $self->create_dependencies;
 253   my @selected_dependencies = map { $_->id } @{ $self->item->dependencies };
 254
 255   my $html                  = $self->render('requirement_spec_item/_function_block_form', { output => 0 }, DEPENDENCIES => \@dependencies, SELECTED_DEPENDENCIES => \@selected_dependencies);
 256   my $id_base               = 'edit_function_block_' . $self->item->id;
 257   my $content_top_id        = '#' . $self->item->item_type . '-content-top-' . $self->item->id;
 258
 259   $self->js
 260     ->hide($content_top_id)
 261     ->remove("#${id_base}_form")
 262     ->insertAfter($html, $content_top_id)
 263     ->run('kivi.requirement_spec.init_function_block_keypress_events', "${id_base}_form")
 264     ->jstree->select_node('#tree', '#fb-' . $self->item->id)
 265     ->focus("#${id_base}_description")
 266     ->val('#current_content_type', $self->item->item_type)
 267     ->val('#current_content_id', $self->item->id)
 268     ->render($self);
 269 }
 270
 271 sub action_ajax_update {
 272   my ($self, %params) = @_;
 273
 274   my $prefix     = $::form->{form_prefix} || die "Missing parameter 'form_prefix'";
 275   my $attributes = $::form->{$prefix}     || {};
 276
 277   foreach (qw(requirement_spec_id parent_id position)) {
 278     delete $attributes->{$_} if !defined $attributes->{$_};
 279   }
 280
 281   my @errors = $self->item->assign_attributes(%{ $attributes })->validate;
 282   return $self->js->error(@errors)->render($self) if @errors;
 283
 284   $self->item->save;
 285
 286   my $type = $self->item->item_type;
 287
 288   if ($type eq 'section') {
 289     # Updated section, now update section header.
 290
 291     my $html = $self->render('requirement_spec_item/_section_header', { output => 0 }, requirement_spec_item => $self->item);
 292
 293     return $self->invalidate_version
 294       ->remove('#edit_section_form')
 295       ->html('#section-header-' . $self->item->id, $html)
 296       ->show('#section-header-' . $self->item->id)
 297       ->jstree->rename_node('#tree', '#fb-' . $self->item->id, $::request->presenter->requirement_spec_item_tree_node_title($self->item))
 298       ->prop('#fb-' . $self->item->id . ' a', 'title', $self->item->content_excerpt)
 299       ->addClass('#fb-' . $self->item->id . ' a', 'tooltip')
 300       ->reinit_widgets
 301       ->render($self);
 302   }
 303
 304   # Updated function block or sub function block. Update (sub)
 305   # function block and potentially the bottom of the parent function
 306   # block.
 307
 308   my $id_prefix    = $type eq 'function-block' ? '' : 'sub-';
 309   my $html_top     = $self->render('requirement_spec_item/_function_block_content_top',    { output => 0 }, requirement_spec_item => $self->item, id_prefix => $id_prefix);
 310   $id_prefix      .= 'function-block-content-';
 311
 312   $self->js
 313     ->remove('#' . $prefix . '_form')
 314     ->replaceWith('#' . $id_prefix . 'top-' . $self->item->id, $html_top)
 315     ->prop('#fb-' . $self->item->id . ' a', 'title', $self->item->content_excerpt)
 316     ->addClass('#fb-' . $self->item->id . ' a', 'tooltip')
 317     ->reinit_widgets
 318     ->jstree->rename_node('#tree', '#fb-' . $self->item->id, $::request->presenter->requirement_spec_item_tree_node_title($self->item));
 319
 320   $self->replace_bottom($self->item, id_prefix => $id_prefix);
 321   $self->replace_bottom($self->item->parent) if $type eq 'sub-function-block';
 322
 323   $self->invalidate_version->render($self);
 324 }
 325
 326 sub action_ajax_delete {
 327   my ($self) = @_;
 328
 329   my $full_list = $self->item->get_full_list;
 330
 331   $self->item->delete;
 332
 333   if ($self->visible_section && ($self->visible_section->id == $self->item->id)) {
 334     # Currently visible section is deleted.
 335
 336     my $new_section = first { $_->id != $self->item->id } @{ $self->item->requirement_spec->sections };
 337     if ($new_section) {
 338       $self->render_list($new_section);
 339
 340     } else {
 341       my $html = $self->render('requirement_spec_item/_no_section', { output => 0 });
 342       $self->set_function_blocks_tab_menu_class(class => 'section-context-menu')
 343         ->html('#column-content',      $html)
 344         ->val('#current_content_type', '')
 345         ->val('#current_content_id',   '')
 346     }
 347
 348   } elsif ($self->is_item_visible) {
 349     # Item in currently visible section is deleted.
 350
 351     my $type = $self->item->item_type;
 352     $self->js->remove('#edit_function_block_' . $self->item->id . '_form')
 353              ->remove('#' . $type . '-' . $self->item->id);
 354
 355     $self->replace_bottom($self->item->parent_id) if $type eq 'sub-function-block';
 356
 357     if (1 == scalar @{ $full_list }) {
 358       if ($type eq 'function-block') {
 359         $self->js->show('#section-list-empty');
 360       } elsif ($type eq 'sub-function-block') {
 361         $self->js->hide('#sub-function-block-container-' . $self->item->parent_id);
 362       }
 363     }
 364   }
 365
 366   $self->invalidate_version
 367     ->jstree->delete_node('#tree', '#fb-' . $self->item->id)
 368     ->render($self);
 369 }
 370
 371 sub action_ajax_flag {
 372   my ($self) = @_;
 373
 374   $self->item->update_attributes(is_flagged => !$self->item->is_flagged);
 375
 376   $self->js
 377    ->action_if($self->is_item_visible, 'toggleClass', '#' . $self->item->item_type . '-' . $self->item->id, 'flagged')
 378    ->toggleClass('#fb-' . $self->item->id, 'flagged')
 379    ->render($self);
 380 }
 381
 382 sub action_ajax_copy {
 383   my ($self, %params) = @_;
 384
 385   SL::Clipboard->new->copy($self->item);
 386   $self->render($self->js);
 387 }
 388
 389 sub determine_paste_position {
 390   my ($self) = @_;
 391
 392   if ($self->item->item_type eq 'section') {
 393     # Sections are always pasted either directly after the
 394     # clicked-upon section or at the very end.
 395     return $self->clicked_item ? (undef, $self->clicked_item->section->id) : ();
 396
 397   } elsif ($self->item->item_type eq 'function-block') {
 398     # A function block:
 399     # - paste on section list: insert into last section as last element
 400     # - paste on section: insert into that section as last element
 401     # - paste on function block: insert after clicked-upon element
 402     # - paste on sub function block: insert after parent function block of clicked-upon element
 403     return !$self->clicked_item                                ? ( $self->sections->[-1]->id,              undef                          )
 404          :  $self->clicked_item->item_type eq 'section'        ? ( $self->clicked_item->id,                undef                          )
 405          :  $self->clicked_item->item_type eq 'function-block' ? ( $self->clicked_item->parent_id,         $self->clicked_item->id        )
 406          :                                                       ( $self->clicked_item->parent->parent_id, $self->clicked_item->parent_id );
 407
 408   } else {                      # sub-function-block
 409     # A sub function block:
 410     # - paste on section list: promote to function block and insert into last section as last element
 411     # - paste on section: promote to function block and insert into that section as last element
 412     # - paste on function block: insert as last element in clicked-upon element
 413     # - paste on sub function block: insert after clicked-upon element
 414
 415     # Promote sub function blocks to function blocks when pasting on a
 416     # section or the section list.
 417     $self->item->item_type('function-block') if !$self->clicked_item || ($self->clicked_item->item_type eq 'section');
 418
 419     return !$self->clicked_item                                ? ( $self->sections->[-1]->id,      undef                   )
 420          :  $self->clicked_item->item_type eq 'section'        ? ( $self->clicked_item->id,        undef                   )
 421          :  $self->clicked_item->item_type eq 'function-block' ? ( $self->clicked_item->id,        undef                   )
 422          :                                                       ( $self->clicked_item->parent_id, $self->clicked_item->id );
 423   }
 424 }
 425
 426 sub assign_requirement_spec_id_rec {
 427   my ($self, $item) = @_;
 428
 429   $item->assign_attributes(requirement_spec_id => $::form->{requirement_spec_id}, fb_number => undef);
 430   $self->assign_requirement_spec_id_rec($_) for @{ $item->children || [] };
 431
 432   return $item;
 433 }
 434
 435 sub create_and_insert_node_rec {
 436   my ($self, $item, $new_parent_id, $insert_after) = @_;
 437
 438   my $node = $self->presenter->requirement_spec_item_jstree_data($item);
 439   $self->js->jstree->create_node('#tree', $insert_after ? ('#fb-' . $insert_after, 'after') : $new_parent_id ? ('#fb-' . $new_parent_id, 'last') : ('#sections', 'last'), $node);
 440
 441   $self->create_and_insert_node_rec($_, $item->id) for @{ $item->children || [] };
 442
 443   $self->js->jstree->open_node('#tree', '#fb-' . $item->id);
 444 }
 445
 446 sub action_ajax_paste {
 447   my ($self, %params) = @_;
 448
 449   my $copied = SL::Clipboard->new->get_entry(qr/^RequirementSpecItem$/);
 450
 451   if (!$copied) {
 452     return $self->js->error(t8("The clipboard does not contain anything that can be pasted here."))
 453                     ->render($self);
 454   }
 455
 456   $self->item($self->assign_requirement_spec_id_rec($copied->to_object));
 457   my $req_spec = SL::DB::RequirementSpec->new(id => $::form->{requirement_spec_id})->load;
 458   $self->sections($req_spec->sections);
 459
 460   if (($self->item->item_type ne 'section') && !@{ $self->sections }) {
 461     return $self->js->error(t8("You cannot paste function blocks or sub function blocks if there is no section."))
 462                     ->render($self);
 463   }
 464
 465   $self->clicked_item($::form->{id} ? SL::DB::RequirementSpecItem->new(id => $::form->{id})->load : undef);
 466
 467   my ($new_parent_id, $insert_after) = $self->determine_paste_position;
 468
 469   # Store result in database.
 470   $self->item->update_attributes(parent_id => $new_parent_id);
 471   $self->item->add_to_list(position => 'after', reference => $insert_after) if $insert_after;
 472
 473   # Update the tree: create the node for all pasted objects.
 474   $self->create_and_insert_node_rec($self->item, $new_parent_id, $insert_after);
 475
 476   # Pasting the very first section?
 477   if (!@{ $self->sections }) {
 478     my $html = $self->render('requirement_spec_item/_section', { output => 0 }, requirement_spec_item => $self->item);
 479     $self->set_function_blocks_tab_menu_class(class => 'section-context-menu')
 480          ->html('#column-content', $html)
 481          ->jstree->select_node('#tree', '#fb-' . $self->item->id)
 482   }
 483
 484   # Update the current view if required.
 485   $self->insert_new_item_in_section_view($self->js) if $self->is_item_visible;
 486
 487   $self->invalidate_version->render($self);
 488 }
 489
 490 #
 491 # filters
 492 #
 493
 494 sub check_auth {
 495   my ($self) = @_;
 496   $::auth->assert('sales_quotation_edit');
 497 }
 498
 499 sub load_requirement_spec_item {
 500   my ($self) = @_;
 501   $self->item(SL::DB::RequirementSpecItem->new(id => $::form->{id})->load);
 502 }
 503
 504 #
 505 # helpers
 506 #
 507
 508 sub create_random_id {
 509   return join '-', Time::HiRes::gettimeofday();
 510 }
 511
 512 sub format_exception {
 513   return join "\n", (split m/\n/, $@)[0..4];
 514 }
 515
 516 sub init_complexities {
 517   my ($self) = @_;
 518
 519   return SL::DB::Manager::RequirementSpecComplexity->get_all_sorted;
 520 }
 521
 522 sub init_risks {
 523   my ($self) = @_;
 524
 525   return SL::DB::Manager::RequirementSpecRisk->get_all_sorted;
 526 }
 527
 528 sub init_js {
 529   my ($self) = @_;
 530   $self->js(SL::ClientJS->new);
 531 }
 532
 533 sub replace_bottom {
 534   my ($self, $item_or_id) = @_;
 535
 536   my $item      = (ref($item_or_id) ? $item_or_id : SL::DB::RequirementSpecItem->new(id => $item_or_id))->load;
 537   my $id_prefix = $item->item_type eq 'function-block' ? '' : 'sub-';
 538   my $html      = $self->render('requirement_spec_item/_function_block_content_bottom', { output => 0 }, requirement_spec_item => $item, id_prefix => $id_prefix);
 539   return $self->js->replaceWith('#' . $id_prefix . 'function-block-content-bottom-' . $item->id, $html);
 540 }
 541
 542 sub render_list {
 543   my ($self, $item, $item_to_select) = @_;
 544
 545   my $html = $self->render('requirement_spec_item/_section', { output => 0 }, requirement_spec_item => $item);
 546   $self->set_function_blocks_tab_menu_class(class => 'section-context-menu')
 547        ->html('#column-content', $html);
 548   $self->select_node($item_to_select || $item);
 549 }
 550
 551 sub select_node {
 552   my ($self, $item) = @_;
 553
 554   $self->js
 555     ->val( '#current_content_type', $item->item_type)
 556     ->val( '#current_content_id',   $item->id)
 557     ->jstree->select_node('#tree', '#fb-' . $item->id);
 558 }
 559
 560 sub create_dependency_item {
 561   my $self = shift;
 562   [ $_[0]->id, $self->presenter->truncate(join(' ', grep { $_ } ($_[1], $_[0]->fb_number, $_[0]->description))) ];
 563 }
 564
 565 sub create_dependencies {
 566   my ($self) = @_;
 567
 568   return map { [ $_->fb_number . ' ' . $_->title,
 569                  [ map { ( $self->create_dependency_item($_),
 570                            map { $self->create_dependency_item($_, '->') } @{ $_->children_sorted })
 571                        } @{ $_->children_sorted } ] ]
 572              } @{ $self->item->requirement_spec->sections };
 573 }
 574
 575 sub ensure_section_is_shown {
 576   my ($self, %params) = @_;
 577
 578   return $self->js if $self->is_item_visible;
 579
 580   # Show section/item to edit if it is not visible.
 581   my $new_section = $self->item->section;
 582   my $html        = $self->render('requirement_spec_item/_section', { output => 0 }, requirement_spec_item => $new_section);
 583
 584   return $self->set_function_blocks_tab_menu_class(class => 'section-context-menu')
 585     ->html('#column-content', $html)
 586     ->val('#current_content_type', 'section')
 587     ->val('#current_content_id',   $new_section->id)
 588     ->jstree->select_node('#tree', '#fb-' . $new_section->id);
 589 }
 590
 591 sub add_new_item_form {
 592   my ($self, %params) = @_;
 593
 594   for (qw(insert_position display_reference)) {
 595     croak "Missing parameter $_" if !$params{$_};
 596   }
 597   croak "Missing parameter insert_reference" if ($params{insert_position} eq 'insertAfter') && !$params{insert_reference};
 598
 599   my $id_base = join('_', 'new_function_block', Time::HiRes::gettimeofday(), int rand 1000000000000);
 600   my $html    = $self->render(
 601     'requirement_spec_item/_function_block_form',
 602     { output => 0 },
 603     DEPENDENCIES          => [ $self->create_dependencies ],
 604     SELECTED_DEPENDENCIES => [],
 605     requirement_spec_item => $self->item,
 606     id_base               => $id_base,
 607     insert_after          => $params{insert_position} eq 'insertAfter' ? $params{insert_reference} : undef,
 608   );
 609
 610   return $self->js
 611     ->action($params{insert_position}, $html, $params{display_reference})
 612     ->action_if($self->item->item_type eq 'sub-function-block', 'show', '#sub-function-block-container-' . $self->item->parent_id)
 613     ->run('kivi.requirement_spec.init_function_block_keypress_events', "${id_base}_form")
 614     ->focus("#${id_base}_description");
 615 }
 616
 617 sub add_new_item_form_after_create {
 618   my ($self, %params) = @_;
 619
 620   my $created_item    = $self->item;
 621
 622   my ($new_item_type, $new_parent_id, $insert_position, $insert_reference, $display_reference);
 623   if ($created_item->item_type eq 'section') {
 624     # $created_item is section, new one will be function-block
 625     $new_item_type     = 'function-block';
 626     $new_parent_id     = $created_item->id;
 627     $insert_position   = 'appendTo';
 628     $display_reference = '#section-list';
 629
 630   } elsif (!$::form->{shift_in_out}) {
 631     # $created_item is function-block or sub-function-block, new one will be the same
 632     $new_item_type     = $created_item->item_type;
 633     $new_parent_id     = $created_item->parent_id;
 634     $insert_position   = 'insertAfter';
 635     $insert_reference  = $created_item->id;
 636     $display_reference = '#' . $created_item->item_type . '-' . $created_item->id;
 637
 638   } elsif ($created_item->item_type eq 'function-block') {
 639     # $created_item is function-block, new one will be sub-function-block
 640     $new_item_type     = 'sub-function-block';
 641     $new_parent_id     = $created_item->id;
 642     $insert_position   = 'appendTo';
 643     $display_reference = '#sub-function-block-container-' . $created_item->id;
 644
 645   } else {
 646     # $created_item is sub-function-block, new one will be function-block
 647     $new_item_type     = 'function-block';
 648     $new_parent_id     = $created_item->parent->parent_id;
 649     $insert_position   = 'insertAfter';
 650     $insert_reference  = $created_item->parent_id;
 651     $display_reference = '#function-block-' . $created_item->parent_id;
 652   }
 653
 654   $::lxdebug->message(LXDebug::DEBUG1(),
 655                       "OLD item_type " . $created_item->item_type . " ; NEW item_type $new_item_type ; parent_id $new_parent_id ; " .
 656                       "insert_position $insert_position ; insert_reference $insert_reference ; display_reference $display_reference");
 657
 658   $self->item(SL::DB::RequirementSpecItem->new(
 659     requirement_spec_id => $created_item->requirement_spec_id,
 660     parent_id           => $new_parent_id,
 661     item_type           => $new_item_type,
 662   ));
 663
 664   $self->add_new_item_form(
 665     insert_reference  => $insert_reference,
 666     insert_position   => $insert_position,
 667     display_reference => $display_reference,
 668   );
 669 }
 670
 671 sub add_function_block {
 672   my ($self, $new_type) = @_;
 673
 674   my $clicked_id = $::form->{id} || ($self->visible_item ? $self->visible_item->id : undef);
 675
 676   die "Invalid new_type '$new_type'"               if $new_type !~ m/^(?:sub-)?function-block$/;
 677   die "Missing parameter 'id' and no visible item" if !$clicked_id;
 678   die "Missing parameter 'requirement_spec_id'"    if !$::form->{requirement_spec_id};
 679
 680   my $clicked_item = SL::DB::RequirementSpecItem->new(id => $clicked_id)->load;
 681   my $clicked_type = $clicked_item->item_type;
 682
 683   die "Invalid clicked_type '$clicked_type'" if $clicked_type !~ m/^(?: section | (?:sub-)? function-block )$/x;
 684
 685   my $case = "${clicked_type}:${new_type}";
 686
 687   my ($insert_position, $insert_reference, $parent_id, $display_reference)
 688     = $case eq 'section:function-block'                ? ( 'appendTo',    $clicked_item->id,        $clicked_item->id,                '#section-list'                  )
 689     : $case eq 'function-block:function-block'         ? ( 'insertAfter', $clicked_item->id,        $clicked_item->parent_id,         '#function-block-'               )
 690     : $case eq 'function-block:sub-function-block'     ? ( 'appendTo'  ,  $clicked_item->id,        $clicked_item->id,                '#sub-function-block-container-' )
 691     : $case eq 'sub-function-block:function-block'     ? ( 'insertAfter', $clicked_item->parent_id, $clicked_item->parent->parent_id, '#function-block-'               )
 692     : $case eq 'sub-function-block:sub-function-block' ? ( 'insertAfter', $clicked_item->id,        $clicked_item->parent_id,         '#sub-function-block-'           )
 693     :                                                    die "Invalid combination of 'clicked_type (section)/new_type ($new_type)'";
 694
 695   $display_reference .= $insert_reference if $display_reference =~ m/-$/;
 696
 697   $self->item(SL::DB::RequirementSpecItem->new(requirement_spec_id => $::form->{requirement_spec_id}, parent_id => $parent_id, item_type => $new_type));
 698
 699   $self->ensure_section_is_shown;
 700   $self->js->show('#sub-function-block-container-' . $parent_id) if $new_type eq 'sub-function-block';
 701   $self->add_new_item_form(insert_position => $insert_position, insert_reference => $insert_reference, display_reference => $display_reference);
 702
 703   $self->js->render($self);
 704 }
 705
 706 sub is_item_visible {
 707   my ($self, $item) = @_;
 708
 709   $item ||= $self->item;
 710   return $self->visible_section && ($self->visible_section->id == $item->section->id);
 711 }
 712
 713 sub invalidate_version {
 714   my ($self) = @_;
 715
 716   my $html   = $self->render('requirement_spec/_version', { output => 0 },
 717                              requirement_spec => SL::DB::RequirementSpec->new(id => $::form->{requirement_spec_id} || $self->item->requirement_spec_id)->load);
 718   return $self->js->html('#requirement_spec_version', $html);
 719 }
 720
 721 1;