SL/Controller/RequirementSpecItem.pm

   1 package SL::Controller::RequirementSpecItem;
   2
   3 use strict;
   4
   5 use parent qw(SL::Controller::Base);
   6
   7 use Carp;
   8 use List::MoreUtils qw(apply);
   9 use List::Util qw(first);
  10 use Time::HiRes ();
  11
  12 use SL::Clipboard;
  13 use SL::DB::RequirementSpec;
  14 use SL::DB::RequirementSpecComplexity;
  15 use SL::DB::RequirementSpecItem;
  16 use SL::DB::RequirementSpecRisk;
  17 use SL::Helper::Flash;
  18 use SL::JSON;
  19 use SL::Locale::String;
  20
  21 use Rose::Object::MakeMethods::Generic
  22 (
  23   scalar                  => [ qw(item visible_item visible_section clicked_item sections) ],
  24   'scalar --get_set_init' => [ qw(complexities risks) ],
  25 );
  26
  27 __PACKAGE__->run_before('load_requirement_spec_item', only => [ qw(dragged_and_dropped ajax_update ajax_edit ajax_delete ajax_flag ajax_copy) ]);
  28 __PACKAGE__->run_before('init_visible_section');
  29
  30 #
  31 # actions
  32 #
  33
  34 sub action_ajax_list {
  35   my ($self, $js) = @_;
  36
  37   my $js = SL::ClientJS->new;
  38
  39   if (!$::form->{clicked_id}) {
  40     # Clicked on "sections" in the tree. Do nothing.
  41     return $self->render($js);
  42   }
  43
  44   my $clicked_item = SL::DB::RequirementSpecItem->new(id => $::form->{clicked_id})->load;
  45   $self->item($clicked_item->section);
  46
  47   if (!$self->visible_section || ($self->visible_section->id != $self->item->id)) {
  48     $self->render_list($js, $self->item, $clicked_item);
  49   } else {
  50     $self->select_node($js, $clicked_item);
  51   }
  52
  53   $self->render($js);
  54 }
  55
  56 sub insert_new_item_in_section_view {
  57   my ($self, $js) = @_;
  58
  59   $js->hide('#section-list-empty');
  60
  61   my $new_type  = $self->item->item_type;
  62   my $id_prefix = $new_type eq 'sub-function-block' ? 'sub-' : '';
  63   my $template  = 'requirement_spec_item/_' . (apply { s/-/_/g; $_ } $new_type);
  64   my $html      = "" . $self->render($template, { output => 0 }, requirement_spec_item => $self->item);
  65   my $next_item = $self->item->get_next_in_list;
  66
  67   if ($next_item) {
  68     $js->insertBefore($html, '#' . $id_prefix . 'function-block-' . $next_item->id);
  69   } else {
  70     my $parent_is_section = $self->item->parent->item_type eq 'section';
  71     $js->appendTo($html, $parent_is_section ? '#section-list' : '#sub-function-block-container-' . $self->item->parent_id);
  72     $js->show('#sub-function-block-container-' . $self->item->parent_id) if !$parent_is_section;
  73   }
  74
  75   $self->replace_bottom($js, $self->item->parent) if $new_type eq 'sub-function-block';
  76 }
  77
  78 sub action_dragged_and_dropped {
  79   my ($self)              = @_;
  80
  81   my $position            = $::form->{position} =~ m/^ (?: before | after | last ) $/x ? $::form->{position}                                             : die "Unknown 'position' parameter";
  82   my $dropped_item        = $::form->{dropped_id}                                  ? SL::DB::RequirementSpecItem->new(id => $::form->{dropped_id})->load : undef;
  83
  84   my $old_visible_section = $self->visible_section ? $self->visible_section : undef;
  85   my $old_parent_id       = $self->item->parent_id;
  86   my $old_type            = $self->item->item_type;
  87
  88   $self->item->db->do_transaction(sub {
  89     $self->item->remove_from_list;
  90     $self->item->parent_id($position =~ m/before|after/ ? $dropped_item->parent_id : $dropped_item->id);
  91     $self->item->add_to_list(position => $position, reference => $::form->{dropped_id} || undef);
  92   });
  93
  94   my $js = SL::ClientJS->new;
  95
  96   $self->item(SL::DB::RequirementSpecItem->new(id => $self->item->id)->load);
  97   my $new_section         = $self->item->section;
  98   my $new_type            = $self->item->item_type;
  99   my $new_visible_section = SL::DB::RequirementSpecItem->new(id => $self->visible_item->id)->load->section;
 100
 101   return $self->render($js) if !$old_visible_section || ($new_type eq 'section');
 102
 103   # From here on $old_visible_section is definitely set.
 104
 105   my $old_parent  = SL::DB::RequirementSpecItem->new(id => $old_parent_id)->load;
 106   my $old_section = $old_parent->section;
 107
 108   # $::lxdebug->message(0, "old sec ID " . $old_section->id . " new " . $new_section->id . " old visible " . $old_visible_section->id . " new visible " . $new_visible_section->id
 109   #                       . " PARENT: old " . $old_parent->id . " new " . $self->item->parent_id . '/' . $self->item->parent->id);
 110
 111   if ($old_visible_section->id != $new_visible_section->id) {
 112     # The currently visible item has been dragged to a different section.
 113     return $self->render_list($js, $new_section, $self->item)
 114       ->render($self);
 115   }
 116
 117   if ($old_visible_section->id == $old_section->id) {
 118     my $id_prefix = $old_type eq 'sub-function-block' ? 'sub-' : '';
 119     $js->remove('#' . $id_prefix . 'function-block-' . $self->item->id);
 120
 121     if ($old_type eq 'sub-function-block') {
 122       $self->replace_bottom($js, $old_parent) ;
 123       $js->hide('#sub-function-block-container-' . $old_parent->id) if 0 == scalar(@{ $old_parent->children });
 124
 125     } elsif (0 == scalar(@{ $old_section->children })) {
 126       $js->show('#section-list-empty');
 127     }
 128   }
 129
 130   if ($old_visible_section->id == $new_section->id) {
 131     $self->insert_new_item_in_section_view($js);
 132   }
 133
 134   # $::lxdebug->dump(0, "js", $js->to_array);
 135
 136   $self->render($js);
 137 }
 138
 139 sub action_ajax_add_section {
 140   my ($self, %params) = @_;
 141
 142   die "Missing parameter 'requirement_spec_id'" if !$::form->{requirement_spec_id};
 143
 144   $self->item(SL::DB::RequirementSpecItem->new(requirement_spec_id => $::form->{requirement_spec_id}, item_type => 'section'));
 145
 146   my $insert_after = $::form->{id} ? SL::DB::RequirementSpecItem->new(id => $::form->{id})->load->section->id : undef;
 147   my $html         = $self->render('requirement_spec_item/_section_form', { output => 0 }, id_base => 'new_section', insert_after => $insert_after);
 148
 149   SL::ClientJS->new
 150     ->remove('#new_section_form')
 151     ->hide('#column-content > *')
 152     ->appendTo($html, '#column-content')
 153     ->focus('#new_section_title')
 154     ->render($self);
 155 }
 156
 157 sub action_ajax_add_function_block {
 158   my ($self, %params) = @_;
 159
 160   return $self->add_function_block('function-block');
 161 }
 162
 163 sub action_ajax_add_sub_function_block {
 164   my ($self, %params) = @_;
 165
 166   return $self->add_function_block('sub-function-block');
 167 }
 168
 169 sub action_ajax_create {
 170   my ($self, %params) = @_;
 171
 172   my $js              = SL::ClientJS->new;
 173   my $prefix          = $::form->{form_prefix} || die "Missing parameter 'form_prefix'";
 174   my $attributes      = $::form->{$prefix}     || die "Missing parameter group '${prefix}'";
 175   my $insert_after    = delete $attributes->{insert_after};
 176
 177   my @errors = $self->item(SL::DB::RequirementSpecItem->new(%{ $attributes }))->validate;
 178   return $js->error(@errors)->render($self) if @errors;
 179
 180   $self->item->save;
 181   $self->item->add_to_list(position => 'after', reference => $insert_after) if $insert_after;
 182
 183   my $type = $self->item->item_type;
 184
 185   if ($type eq 'section') {
 186     my $node = $self->presenter->requirement_spec_item_jstree_data($self->item);
 187     return $self->render_list($js, $self->item)
 188       ->jstree->create_node('#tree', $insert_after ? ('#fb-' . $insert_after, 'after') : ('#sections', 'last'), $node)
 189       ->jstree->select_node('#tree', '#fb-' . $self->item->id)
 190       ->render($self);
 191   }
 192
 193   my $template = 'requirement_spec_item/_' . (apply { s/-/_/g; $_ } $type);
 194   my $html     = $self->render($template, { output => 0 }, requirement_spec_item => $self->item, id_prefix => $type eq 'function-block' ? '' : 'sub-');
 195   my $node     = $self->presenter->requirement_spec_item_jstree_data($self->item);
 196
 197   $js->replaceWith('#' . $prefix . '_form', $html)
 198      ->hide('#section-list-empty')
 199      ->jstree->create_node('#tree', $insert_after ? ('#fb-' . $insert_after, 'after') : ('#fb-' . $self->item->parent_id, 'last'), $node)
 200      ->jstree->select_node('#tree', '#fb-' . $self->item->id);
 201
 202   $self->replace_bottom($js, $self->item->parent) if $type eq 'sub-function-block';
 203
 204   $js->render($self);
 205 }
 206
 207 sub action_ajax_edit {
 208   my ($self, %params) = @_;
 209
 210   $self->item(SL::DB::RequirementSpecItem->new(id => $::form->{id})->load);
 211
 212   my $js = SL::ClientJS->new;
 213
 214   if (!$self->is_item_visible) {
 215     # Show section/item to edit if it is not visible.
 216
 217     my $html = $self->render('requirement_spec_item/_section', { output => 0 }, requirement_spec_item => $self->item);
 218     $js->html('#column-content', $html);
 219   }
 220
 221   if ($self->item->item_type =~ m/section/) {
 222     # Edit the section header, not an item.
 223     my $html = $self->render('requirement_spec_item/_section_form', { output => 0 });
 224
 225     $js->hide('#section-header-' . $self->item->id)
 226        ->remove("#edit_section_form")
 227        ->insertAfter($html, '#section-header-' . $self->item->id)
 228        ->jstree->select_node('#tree', '#fb-' . $self->item->id)
 229        ->focus("#edit_section_title")
 230        ->val('#current_content_type', 'section')
 231        ->val('#current_content_id',   $self->item->id)
 232        ->render($self);
 233     return;
 234   }
 235
 236   # Edit a function block or a sub function block
 237   my @dependencies          = $self->create_dependencies;
 238   my @selected_dependencies = map { $_->id } @{ $self->item->dependencies };
 239
 240   my $html                  = $self->render('requirement_spec_item/_function_block_form', { output => 0 }, DEPENDENCIES => \@dependencies, SELECTED_DEPENDENCIES => \@selected_dependencies);
 241   my $id_base               = 'edit_function_block_' . $self->item->id;
 242   my $content_top_id        = '#' . $self->item->item_type . '-content-top-' . $self->item->id;
 243
 244   $js->hide($content_top_id)
 245      ->remove("#${id_base}_form")
 246      ->insertAfter($html, $content_top_id)
 247      ->jstree->select_node('#tree', '#fb-' . $self->item->id)
 248      ->focus("#${id_base}_description")
 249      ->val('#current_content_type', $self->item->item_type)
 250      ->val('#current_content_id', $self->item->id)
 251      ->render($self);
 252 }
 253
 254 sub action_ajax_update {
 255   my ($self, %params) = @_;
 256
 257   my $js         = SL::ClientJS->new;
 258   my $prefix     = $::form->{form_prefix} || die "Missing parameter 'form_prefix'";
 259   my $attributes = $::form->{$prefix}     || {};
 260
 261   foreach (qw(requirement_spec_id parent_id position)) {
 262     delete $attributes->{$_} if !defined $attributes->{$_};
 263   }
 264
 265   my @errors = $self->item->assign_attributes(%{ $attributes })->validate;
 266   return $js->error(@errors)->render($self) if @errors;
 267
 268   $self->item->save;
 269
 270   my $type = $self->item->item_type;
 271
 272   if ($type eq 'section') {
 273     # Updated section, now update section header.
 274
 275     my $html = $self->render('requirement_spec_item/_section_header', { output => 0 }, requirement_spec_item => $self->item);
 276
 277     return SL::ClientJS->new
 278       ->remove('#edit_section_form')
 279       ->html('#section-header-' . $self->item->id, $html)
 280       ->show('#section-header-' . $self->item->id)
 281       ->jstree->rename_node('#tree', '#fb-' . $self->item->id, $::request->presenter->requirement_spec_item_tree_node_title($self->item))
 282       ->render($self);
 283   }
 284
 285   # Updated function block or sub function block. Update (sub)
 286   # function block and potentially the bottom of the parent function
 287   # block.
 288
 289   my $id_prefix    = $type eq 'function-block' ? '' : 'sub-';
 290   my $html_top     = $self->render('requirement_spec_item/_function_block_content_top',    { output => 0 }, requirement_spec_item => $self->item, id_prefix => $id_prefix);
 291   $id_prefix      .= 'function-block-content-';
 292
 293   my $js = SL::ClientJS->new
 294     ->remove('#' . $prefix . '_form')
 295     ->replaceWith('#' . $id_prefix . 'top-' . $self->item->id, $html_top)
 296     ->jstree->rename_node('#tree', '#fb-' . $self->item->id, $::request->presenter->requirement_spec_item_tree_node_title($self->item));
 297
 298   $self->replace_bottom($js, $self->item, id_prefix => $id_prefix);
 299   $self->replace_bottom($js, $self->item->parent) if $type eq 'sub-function-block';
 300
 301   $js->render($self);
 302 }
 303
 304 sub action_ajax_delete {
 305   my ($self) = @_;
 306
 307   my $js        = SL::ClientJS->new;
 308   my $full_list = $self->item->get_full_list;
 309
 310   $self->item->delete;
 311
 312   if ($self->visible_section && ($self->visible_section->id == $self->item->id)) {
 313     # Currently visible section is deleted.
 314
 315     my $new_section = first { $_->id != $self->item->id } @{ $self->item->requirement_spec->sections };
 316     if ($new_section) {
 317       $self->render_list($js, $new_section);
 318
 319     } else {
 320       my $html = $self->render('requirement_spec_item/_no_section', { output => 0 });
 321       $js->html('#column-content', $html)
 322          ->val('#current_content_type', '')
 323          ->val('#current_content_id', '')
 324     }
 325
 326   } elsif ($self->is_item_visible) {
 327     # Item in currently visible section is deleted.
 328
 329     my $type = $self->item->item_type;
 330     $js->remove('#edit_function_block_' . $self->item->id . '_form')
 331        ->remove('#' . $type . '-' . $self->item->id);
 332
 333     $self->replace_bottom($js, $self->item->parent_id) if $type eq 'sub-function-block';
 334
 335     if (1 == scalar @{ $full_list }) {
 336       if ($type eq 'function-block') {
 337         $js->show('#section-list-empty');
 338       } elsif ($type eq 'sub-function-block') {
 339         $js->hide('#sub-function-block-container-' . $self->item->parent_id);
 340       }
 341     }
 342   }
 343
 344   $js->jstree->delete_node('#tree', '#fb-' . $self->item->id)
 345      ->render($self);
 346 }
 347
 348 sub action_ajax_flag {
 349   my ($self) = @_;
 350
 351   $self->item->update_attributes(is_flagged => !$self->item->is_flagged);
 352
 353   SL::ClientJS->new
 354    ->action_if($self->is_item_visible, 'toggleClass', '#' . $self->item->item_type . '-' . $self->item->id, 'flagged')
 355    ->toggleClass('#fb-' . $self->item->id, 'flagged')
 356    ->render($self);
 357 }
 358
 359 sub action_ajax_copy {
 360   my ($self, %params) = @_;
 361
 362   SL::Clipboard->new->copy($self->item);
 363   SL::ClientJS->new->render($self);
 364 }
 365
 366 sub determine_paste_position {
 367   my ($self) = @_;
 368
 369   if ($self->item->item_type eq 'section') {
 370     # Sections are always pasted either directly after the
 371     # clicked-upon section or at the very end.
 372     return $self->clicked_item ? (undef, $self->clicked_item->section->id) : ();
 373
 374   } elsif ($self->item->item_type eq 'function-block') {
 375     # A function block:
 376     # - paste on section list: insert into last section as last element
 377     # - paste on section: insert into that section as last element
 378     # - paste on function block: insert after clicked-upon element
 379     # - paste on sub function block: insert after parent function block of clicked-upon element
 380     return !$self->clicked_item                                ? ( $self->sections->[-1]->id,              undef                          )
 381          :  $self->clicked_item->item_type eq 'section'        ? ( $self->clicked_item->id,                undef                          )
 382          :  $self->clicked_item->item_type eq 'function-block' ? ( $self->clicked_item->parent_id,         $self->clicked_item->id        )
 383          :                                                       ( $self->clicked_item->parent->parent_id, $self->clicked_item->parent_id );
 384
 385   } else {                      # sub-function-block
 386     # A sub function block:
 387     # - paste on section list: promote to function block and insert into last section as last element
 388     # - paste on section: promote to function block and insert into that section as last element
 389     # - paste on function block: insert as last element in clicked-upon element
 390     # - paste on sub function block: insert after clicked-upon element
 391
 392     # Promote sub function blocks to function blocks when pasting on a
 393     # section or the section list.
 394     $self->item->item_type('function-block') if !$self->clicked_item || ($self->clicked_item->item_type eq 'section');
 395
 396     return !$self->clicked_item                                ? ( $self->sections->[-1]->id,      undef                   )
 397          :  $self->clicked_item->item_type eq 'section'        ? ( $self->clicked_item->id,        undef                   )
 398          :  $self->clicked_item->item_type eq 'function-block' ? ( $self->clicked_item->id,        undef                   )
 399          :                                                       ( $self->clicked_item->parent_id, $self->clicked_item->id );
 400   }
 401 }
 402
 403 sub assign_requirement_spec_id_rec {
 404   my ($self, $item) = @_;
 405
 406   $item->requirement_spec_id($::form->{requirement_spec_id});
 407   $self->assign_requirement_spec_id_rec($_) for @{ $item->children || [] };
 408
 409   return $item;
 410 }
 411
 412 sub create_and_insert_node_rec {
 413   my ($self, $js, $item, $new_parent_id, $insert_after) = @_;
 414
 415   my $node = $self->presenter->requirement_spec_item_jstree_data($item);
 416   $js->jstree->create_node('#tree', $insert_after ? ('#fb-' . $insert_after, 'after') : $new_parent_id ? ('#fb-' . $new_parent_id, 'last') : ('#sections', 'last'), $node);
 417
 418   $self->create_and_insert_node_rec($js, $_, $item->id) for @{ $item->children || [] };
 419
 420   $js->jstree->open_node('#tree', '#fb-' . $item->id);
 421 }
 422
 423 sub action_ajax_paste {
 424   my ($self, %params) = @_;
 425
 426   my $js     = SL::ClientJS->new;
 427   my $copied = SL::Clipboard->new->get_entry(qr/^RequirementSpecItem$/);
 428
 429   if (!$copied) {
 430     return $js->error(t8("The clipboard does not contain anything that can be pasted here."))
 431               ->render($self);
 432   }
 433
 434   $self->item($self->assign_requirement_spec_id_rec($copied->to_object));
 435   my $req_spec = SL::DB::RequirementSpec->new(id => $::form->{requirement_spec_id})->load;
 436   $self->sections($req_spec->sections);
 437
 438   if (($self->item->item_type ne 'section') && !@{ $self->sections }) {
 439     return $js->error(t8("You cannot paste function blocks or sub function blocks if there is no section."))
 440               ->render($self);
 441   }
 442
 443   $self->clicked_item($::form->{id} ? SL::DB::RequirementSpecItem->new(id => $::form->{id})->load : undef);
 444
 445   my ($new_parent_id, $insert_after) = $self->determine_paste_position;
 446
 447   # Store result in database.
 448   $self->item->update_attributes(requirement_spec_id => $::form->{requirement_spec_id}, parent_id => $new_parent_id);
 449   $self->item->add_to_list(position => 'after', reference => $insert_after) if $insert_after;
 450
 451   # Update the tree: create the node for all pasted objects.
 452   $self->create_and_insert_node_rec($js, $self->item, $new_parent_id, $insert_after);
 453
 454   # Pasting the very first section?
 455   if (!@{ $self->sections }) {
 456     my $html = $self->render('requirement_spec_item/_section', { output => 0 }, requirement_spec_item => $self->item);
 457     $js->html('#column-content', $html)
 458        ->jstree->select_node('#tree', '#fb-' . $self->item->id)
 459   }
 460
 461   # Update the current view if required.
 462   $self->insert_new_item_in_section_view($js) if $self->is_item_visible;
 463
 464   $js->render($self);
 465 }
 466
 467 #
 468 # filters
 469 #
 470
 471 sub load_requirement_spec {
 472   my ($self) = @_;
 473   $self->requirement_spec(SL::DB::RequirementSpec->new(id => $::form->{requirement_spec_id})->load || die "No such requirement spec");
 474 }
 475
 476 sub load_requirement_spec_item {
 477   my ($self) = @_;
 478   $self->item(SL::DB::RequirementSpecItem->new(id => $::form->{id})->load || die "No such requirement spec item");
 479 }
 480
 481 #
 482 # helpers
 483 #
 484
 485 sub create_random_id {
 486   return join '-', Time::HiRes::gettimeofday();
 487 }
 488
 489 sub format_exception {
 490   return join "\n", (split m/\n/, $@)[0..4];
 491 }
 492
 493 sub init_visible_section {
 494   my ($self)       = @_;
 495
 496   my $content_id   = $::form->{current_content_id};
 497   my $content_type = $::form->{current_content_type};
 498
 499   return undef unless $content_id;
 500   return undef unless $content_type =~ m/section|function-block/;
 501
 502   $self->visible_item(SL::DB::Manager::RequirementSpecItem->find_by(id => $content_id));
 503   return undef unless $self->visible_item;
 504
 505   return $self->visible_section($self->visible_item->section);
 506 }
 507
 508 sub init_complexities {
 509   my ($self) = @_;
 510
 511   return SL::DB::Manager::RequirementSpecComplexity->get_all_sorted;
 512 }
 513
 514 sub init_risks {
 515   my ($self) = @_;
 516
 517   return SL::DB::Manager::RequirementSpecRisk->get_all_sorted;
 518 }
 519
 520 sub replace_bottom {
 521   my ($self, $js, $item_or_id) = @_;
 522
 523   my $item      = (ref($item_or_id) ? $item_or_id : SL::DB::RequirementSpecItem->new(id => $item_or_id))->load;
 524   my $id_prefix = $item->item_type eq 'function-block' ? '' : 'sub-';
 525   my $html      = $self->render('requirement_spec_item/_function_block_content_bottom', { output => 0 }, requirement_spec_item => $item, id_prefix => $id_prefix);
 526   return $js->replaceWith('#' . $id_prefix . 'function-block-content-bottom-' . $item->id, $html);
 527 }
 528
 529 sub render_list {
 530   my ($self, $js, $item, $item_to_select) = @_;
 531
 532   my $html = $self->render('requirement_spec_item/_section', { output => 0 }, requirement_spec_item => $item);
 533   $self->select_node($js->html('#column-content', $html), $item_to_select || $item);
 534 }
 535
 536 sub select_node {
 537   my ($self, $js, $item) = @_;
 538
 539   $js->val( '#current_content_type', $item->item_type)
 540      ->val( '#current_content_id',   $item->id)
 541      ->jstree->select_node('#tree', '#fb-' . $item->id);
 542 }
 543
 544 sub create_dependency_item {
 545   my $self = shift;
 546   [ $_[0]->id, $self->presenter->truncate(join(' ', grep { $_ } ($_[1], $_[0]->fb_number, $_[0]->description))) ];
 547 }
 548
 549 sub create_dependencies {
 550   my ($self) = @_;
 551
 552   return map { [ $_->fb_number . ' ' . $_->title,
 553                  [ map { ( $self->create_dependency_item($_),
 554                            map { $self->create_dependency_item($_, '->') } @{ $_->sorted_children })
 555                        } @{ $_->sorted_children } ] ]
 556              } @{ $self->item->requirement_spec->sections };
 557 }
 558
 559 sub add_function_block {
 560   my ($self, $new_type) = @_;
 561
 562   my $clicked_id = $::form->{id} || ($self->visible_item ? $self->visible_item->id : undef);
 563
 564   die "Invalid new_type '$new_type'"               if $new_type !~ m/^(?:sub-)?function-block$/;
 565   die "Missing parameter 'id' and no visible item" if !$clicked_id;
 566   die "Missing parameter 'requirement_spec_id'"    if !$::form->{requirement_spec_id};
 567
 568   my $clicked_item = SL::DB::RequirementSpecItem->new(id => $clicked_id)->load;
 569   my $clicked_type = $clicked_item->item_type;
 570
 571   die "Invalid clicked_type '$clicked_type'" if $clicked_type !~ m/^(?: section | (?:sub-)? function-block )$/x;
 572
 573   my $case = "${clicked_type}:${new_type}";
 574
 575   my ($insert_position, $insert_reference, $parent_id, $display_reference)
 576     = $case eq 'section:function-block'                ? ( 'appendTo',    $clicked_item->id,        $clicked_item->id,                '#section-list'                  )
 577     : $case eq 'function-block:function-block'         ? ( 'insertAfter', $clicked_item->id,        $clicked_item->parent_id,         '#function-block-'               )
 578     : $case eq 'function-block:sub-function-block'     ? ( 'appendTo'  ,  $clicked_item->id,        $clicked_item->id,                '#sub-function-block-container-' )
 579     : $case eq 'sub-function-block:function-block'     ? ( 'insertAfter', $clicked_item->parent_id, $clicked_item->parent->parent_id, '#function-block-'               )
 580     : $case eq 'sub-function-block:sub-function-block' ? ( 'insertAfter', $clicked_item->id,        $clicked_item->parent_id,         '#sub-function-block-'           )
 581     :                                                    die "Invalid combination of 'clicked_type (section)/new_type ($new_type)'";
 582
 583   $self->item(SL::DB::RequirementSpecItem->new(requirement_spec_id => $::form->{requirement_spec_id}, parent_id => $parent_id, item_type => $new_type));
 584
 585   $display_reference .= $insert_reference if $display_reference =~ m/-$/;
 586   my $id_base         = join('_', 'new_function_block', Time::HiRes::gettimeofday(), int rand 1000000000000);
 587   my $html            = $self->render(
 588     'requirement_spec_item/_function_block_form',
 589     { output => 0 },
 590     DEPENDENCIES          => [ $self->create_dependencies ],
 591     SELECTED_DEPENDENCIES => [],
 592     requirement_spec_item => $self->item,
 593     id_base               => $id_base,
 594     insert_after          => $insert_position eq 'insertAfter' ? $insert_reference : undef,
 595   );
 596
 597   my $js = SL::ClientJS->new;
 598
 599   my $new_section = $self->item->section;
 600   if (!$self->is_item_visible) {
 601     # Show section/item to edit if it is not visible.
 602
 603     $html = $self->render('requirement_spec_item/_section', { output => 0 }, requirement_spec_item => $new_section);
 604     $js->html('#column-content', $html)
 605        ->val('#current_content_type', 'section')
 606        ->val('#current_content_id',   $new_section->id)
 607        ->jstree->select_node('#tree', '#fb-' . $new_section->id);
 608   }
 609
 610   # $::lxdebug->message(0, "alright! clicked ID " . $::form->{id} . " type $clicked_type new_type $new_type insert_pos $insert_position ref " . ($insert_reference // '<undef>') . " parent $parent_id display_ref $display_reference");
 611
 612   $js->action($insert_position, $html, $display_reference)
 613      ->focus("#${id_base}_description");
 614
 615   $js->show('#sub-function-block-container-' . $parent_id) if $new_type eq 'sub-function-block';
 616
 617   $js->render($self);
 618 }
 619
 620 sub is_item_visible {
 621   my ($self, $item) = @_;
 622
 623   $item ||= $self->item;
 624   return $self->visible_section && ($self->visible_section->id == $item->section->id);
 625 }
 626
 627 1;