SL/Controller/RequirementSpecItem.pm

   1 package SL::Controller::RequirementSpecItem;
   2
   3 use strict;
   4
   5 use parent qw(SL::Controller::Base);
   6
   7 use Carp;
   8 use List::MoreUtils qw(apply);
   9 use List::Util qw(first);
  10 use Time::HiRes ();
  11
  12 use SL::Clipboard;
  13 use SL::Controller::Helper::RequirementSpec;
  14 use SL::DB::RequirementSpec;
  15 use SL::DB::RequirementSpecComplexity;
  16 use SL::DB::RequirementSpecItem;
  17 use SL::DB::RequirementSpecRisk;
  18 use SL::Helper::Flash;
  19 use SL::JSON;
  20 use SL::Locale::String;
  21
  22 use Rose::Object::MakeMethods::Generic
  23 (
  24   scalar                  => [ qw(item visible_item visible_section clicked_item sections) ],
  25   'scalar --get_set_init' => [ qw(complexities risks js) ],
  26 );
  27
  28 __PACKAGE__->run_before('check_auth');
  29 __PACKAGE__->run_before('load_requirement_spec_item', only => [ qw(dragged_and_dropped ajax_update ajax_edit ajax_delete ajax_flag ajax_copy) ]);
  30 __PACKAGE__->run_before('init_visible_section');
  31
  32 #
  33 # actions
  34 #
  35
  36 sub action_ajax_list {
  37   my ($self) = @_;
  38
  39   if (!$::form->{clicked_id}) {
  40     # Clicked on "sections" in the tree. Do nothing.
  41     return $self->render($self->js);
  42   }
  43
  44   my $clicked_item = SL::DB::RequirementSpecItem->new(id => $::form->{clicked_id})->load;
  45   $self->item($clicked_item->section);
  46
  47   if (!$self->visible_section || ($self->visible_section->id != $self->item->id)) {
  48     $self->render_list($self->item, $clicked_item);
  49   } else {
  50     $self->select_node($clicked_item);
  51   }
  52
  53   $self->render($self->js);
  54 }
  55
  56 sub insert_new_item_in_section_view {
  57   my ($self) = @_;
  58
  59   $self->js->hide('#section-list-empty');
  60
  61   my $new_type  = $self->item->item_type;
  62   my $id_prefix = $new_type eq 'sub-function-block' ? 'sub-' : '';
  63   my $template  = 'requirement_spec_item/_' . (apply { s/-/_/g; $_ } $new_type);
  64   my $html      = "" . $self->render($template, { output => 0 }, requirement_spec_item => $self->item);
  65   my $next_item = $self->item->get_next_in_list;
  66
  67   if ($next_item) {
  68     $self->js->insertBefore($html, '#' . $id_prefix . 'function-block-' . $next_item->id);
  69   } else {
  70     my $parent_is_section = $self->item->parent->item_type eq 'section';
  71     $self->js->appendTo($html, $parent_is_section ? '#section-list' : '#sub-function-block-container-' . $self->item->parent_id);
  72     $self->js->show('#sub-function-block-container-' . $self->item->parent_id) if !$parent_is_section;
  73   }
  74
  75   $self->replace_bottom($self->item->parent) if $new_type eq 'sub-function-block';
  76 }
  77
  78 sub action_dragged_and_dropped {
  79   my ($self)              = @_;
  80
  81   my $position            = $::form->{position} =~ m/^ (?: before | after | last ) $/x ? $::form->{position}                                             : die "Unknown 'position' parameter";
  82   my $dropped_item        = $::form->{dropped_id}                                  ? SL::DB::RequirementSpecItem->new(id => $::form->{dropped_id})->load : undef;
  83
  84   my $old_visible_section = $self->visible_section ? $self->visible_section : undef;
  85   my $old_parent_id       = $self->item->parent_id;
  86   my $old_type            = $self->item->item_type;
  87   my $new_type            = $position =~ m/before|after/ ? $dropped_item->item_type : $dropped_item->child_type;
  88
  89   $self->item->db->do_transaction(sub {
  90     $self->item->remove_from_list;
  91     $self->item->parent_id($position =~ m/before|after/ ? $dropped_item->parent_id : $dropped_item->id);
  92     $self->item->item_type($new_type);
  93     $self->item->add_to_list(position => $position, reference => $::form->{dropped_id} || undef);
  94   });
  95
  96   $self->item(SL::DB::RequirementSpecItem->new(id => $self->item->id)->load);
  97   my $new_section         = $self->item->section;
  98   my $new_visible_section = SL::DB::RequirementSpecItem->new(id => $self->visible_item->id)->load->section;
  99
 100   return $self->invalidate_version->render($self) if !$old_visible_section || ($new_type eq 'section');
 101
 102   # From here on $old_visible_section is definitely set.
 103
 104   my $old_parent  = SL::DB::RequirementSpecItem->new(id => $old_parent_id)->load;
 105   my $old_section = $old_parent->section;
 106
 107   # Section debug info:
 108   # $::lxdebug->message(0, "old sec ID " . $old_section->id . " new " . $new_section->id . " old visible " . $old_visible_section->id . " new visible " . $new_visible_section->id
 109   #                       . " PARENT: old " . $old_parent->id . " new " . $self->item->parent_id . '/' . $self->item->parent->id);
 110
 111   # Item debug info:
 112   # $::lxdebug->message(0, 'item id: ' . $self->item->id . " new type: $new_type old type: $old_type #old children: " . scalar(@{ $old_parent->children }));
 113
 114   if ($old_visible_section->id != $new_visible_section->id) {
 115     # The currently visible item has been dragged to a different section.
 116     $self->invalidate_version;
 117     return $self->render_list($new_section, $self->item)
 118       ->render($self);
 119   }
 120
 121   if ($old_visible_section->id == $old_section->id) {
 122     my $id_prefix = $old_type eq 'sub-function-block' ? 'sub-' : '';
 123     $self->js->remove('#' . $id_prefix . 'function-block-' . $self->item->id);
 124
 125     if ($old_type eq 'sub-function-block') {
 126       $self->replace_bottom($old_parent) ;
 127       $self->js->hide('#sub-function-block-container-' . $old_parent->id) if 0 == scalar(@{ $old_parent->children });
 128
 129     } elsif (0 == scalar(@{ $old_section->children })) {
 130       $self->js->show('#section-list-empty');
 131     }
 132   }
 133
 134   if ($old_visible_section->id == $new_section->id) {
 135     $self->insert_new_item_in_section_view($self->js);
 136   }
 137
 138   # $::lxdebug->dump(0, "js", $self->js->to_array);
 139
 140   $self->invalidate_version->render($self);
 141 }
 142
 143 sub action_ajax_add_section {
 144   my ($self, %params) = @_;
 145
 146   die "Missing parameter 'requirement_spec_id'" if !$::form->{requirement_spec_id};
 147
 148   $self->item(SL::DB::RequirementSpecItem->new(requirement_spec_id => $::form->{requirement_spec_id}, item_type => 'section'));
 149
 150   my $insert_after = $::form->{id} ? SL::DB::RequirementSpecItem->new(id => $::form->{id})->load->section->id : undef;
 151   my $html         = $self->render('requirement_spec_item/_section_form', { output => 0 }, id_base => 'new_section', insert_after => $insert_after);
 152
 153   $self->js
 154     ->remove('#new_section_form')
 155     ->hide('#column-content > *')
 156     ->appendTo($html, '#column-content')
 157     ->focus('#new_section_title')
 158     ->render($self);
 159 }
 160
 161 sub action_ajax_add_function_block {
 162   my ($self, %params) = @_;
 163
 164   return $self->add_function_block('function-block');
 165 }
 166
 167 sub action_ajax_add_sub_function_block {
 168   my ($self, %params) = @_;
 169
 170   return $self->add_function_block('sub-function-block');
 171 }
 172
 173 sub action_ajax_create {
 174   my ($self, %params) = @_;
 175
 176   my $prefix          = $::form->{form_prefix} || die "Missing parameter 'form_prefix'";
 177   my $attributes      = $::form->{$prefix}     || die "Missing parameter group '${prefix}'";
 178   my $insert_after    = delete $attributes->{insert_after};
 179
 180   if (!$attributes->{parent_id}) {
 181     $attributes->{order_part_id} ||= $::instance_conf->get_requirement_spec_section_order_part_id;
 182   }
 183
 184   my @errors = $self->item(SL::DB::RequirementSpecItem->new(%{ $attributes }))->validate;
 185   return $self->js->error(@errors)->render($self) if @errors;
 186
 187   $self->item->save;
 188   $self->item->add_to_list(position => 'after', reference => $insert_after) if $insert_after;
 189
 190   my $type = $self->item->item_type;
 191
 192   if ($type eq 'section') {
 193     my $node = $self->presenter->requirement_spec_item_jstree_data($self->item);
 194     $self->invalidate_version;
 195     return $self->render_list($self->item)
 196       ->jstree->create_node('#tree', $insert_after ? ('#fb-' . $insert_after, 'after') : ('#sections', 'last'), $node)
 197       ->jstree->select_node('#tree', '#fb-' . $self->item->id)
 198       ->render($self);
 199   }
 200
 201   my $template = 'requirement_spec_item/_' . (apply { s/-/_/g; $_ } $type);
 202   my $html     = $self->render($template, { output => 0 }, requirement_spec_item => $self->item, id_prefix => $type eq 'function-block' ? '' : 'sub-');
 203   my $node     = $self->presenter->requirement_spec_item_jstree_data($self->item);
 204
 205   $self->js
 206     ->replaceWith('#' . $prefix . '_form', $html)
 207     ->hide('#section-list-empty')
 208     ->jstree->create_node('#tree', $insert_after ? ('#fb-' . $insert_after, 'after') : ('#fb-' . $self->item->parent_id, 'last'), $node)
 209     ->jstree->select_node('#tree', '#fb-' . $self->item->id);
 210
 211   $self->replace_bottom($self->item->parent) if $type eq 'sub-function-block';
 212
 213   $self->add_new_item_form_after_create if $type =~ m/function-block/;
 214
 215   $self->invalidate_version->render($self);
 216 }
 217
 218 sub action_ajax_edit {
 219   my ($self, %params) = @_;
 220
 221   $self->item(SL::DB::RequirementSpecItem->new(id => $::form->{id})->load);
 222
 223   if (!$self->is_item_visible) {
 224     # Show section/item to edit if it is not visible.
 225
 226     my $html = $self->render('requirement_spec_item/_section', { output => 0 }, requirement_spec_item => $self->item->section);
 227     $self->js->html('#column-content', $html);
 228   }
 229
 230   if ($self->item->item_type =~ m/section/) {
 231     # Edit the section header, not an item.
 232     my $html = $self->render('requirement_spec_item/_section_form', { output => 0 });
 233
 234     $self->js
 235       ->hide('#section-header-' . $self->item->id)
 236       ->remove("#edit_section_form")
 237       ->insertAfter($html, '#section-header-' . $self->item->id)
 238       ->jstree->select_node('#tree', '#fb-' . $self->item->id)
 239       ->focus("#edit_section_title")
 240       ->val('#current_content_type', 'section')
 241       ->val('#current_content_id',   $self->item->id)
 242       ->render($self);
 243     return;
 244   }
 245
 246   # Edit a function block or a sub function block
 247   my @dependencies          = $self->create_dependencies;
 248   my @selected_dependencies = map { $_->id } @{ $self->item->dependencies };
 249
 250   my $html                  = $self->render('requirement_spec_item/_function_block_form', { output => 0 }, DEPENDENCIES => \@dependencies, SELECTED_DEPENDENCIES => \@selected_dependencies);
 251   my $id_base               = 'edit_function_block_' . $self->item->id;
 252   my $content_top_id        = '#' . $self->item->item_type . '-content-top-' . $self->item->id;
 253
 254   $self->js
 255     ->hide($content_top_id)
 256     ->remove("#${id_base}_form")
 257     ->insertAfter($html, $content_top_id)
 258     ->jstree->select_node('#tree', '#fb-' . $self->item->id)
 259     ->focus("#${id_base}_description")
 260     ->val('#current_content_type', $self->item->item_type)
 261     ->val('#current_content_id', $self->item->id)
 262     ->render($self);
 263 }
 264
 265 sub action_ajax_update {
 266   my ($self, %params) = @_;
 267
 268   my $prefix     = $::form->{form_prefix} || die "Missing parameter 'form_prefix'";
 269   my $attributes = $::form->{$prefix}     || {};
 270
 271   foreach (qw(requirement_spec_id parent_id position)) {
 272     delete $attributes->{$_} if !defined $attributes->{$_};
 273   }
 274
 275   my @errors = $self->item->assign_attributes(%{ $attributes })->validate;
 276   return $self->js->error(@errors)->render($self) if @errors;
 277
 278   $self->item->save;
 279
 280   my $type = $self->item->item_type;
 281
 282   if ($type eq 'section') {
 283     # Updated section, now update section header.
 284
 285     my $html = $self->render('requirement_spec_item/_section_header', { output => 0 }, requirement_spec_item => $self->item);
 286
 287     return $self->invalidate_version
 288       ->remove('#edit_section_form')
 289       ->html('#section-header-' . $self->item->id, $html)
 290       ->show('#section-header-' . $self->item->id)
 291       ->jstree->rename_node('#tree', '#fb-' . $self->item->id, $::request->presenter->requirement_spec_item_tree_node_title($self->item))
 292       ->render($self);
 293   }
 294
 295   # Updated function block or sub function block. Update (sub)
 296   # function block and potentially the bottom of the parent function
 297   # block.
 298
 299   my $id_prefix    = $type eq 'function-block' ? '' : 'sub-';
 300   my $html_top     = $self->render('requirement_spec_item/_function_block_content_top',    { output => 0 }, requirement_spec_item => $self->item, id_prefix => $id_prefix);
 301   $id_prefix      .= 'function-block-content-';
 302
 303   $self->js
 304     ->remove('#' . $prefix . '_form')
 305     ->replaceWith('#' . $id_prefix . 'top-' . $self->item->id, $html_top)
 306     ->jstree->rename_node('#tree', '#fb-' . $self->item->id, $::request->presenter->requirement_spec_item_tree_node_title($self->item));
 307
 308   $self->replace_bottom($self->item, id_prefix => $id_prefix);
 309   $self->replace_bottom($self->item->parent) if $type eq 'sub-function-block';
 310
 311   $self->invalidate_version->render($self);
 312 }
 313
 314 sub action_ajax_delete {
 315   my ($self) = @_;
 316
 317   my $full_list = $self->item->get_full_list;
 318
 319   $self->item->delete;
 320
 321   if ($self->visible_section && ($self->visible_section->id == $self->item->id)) {
 322     # Currently visible section is deleted.
 323
 324     my $new_section = first { $_->id != $self->item->id } @{ $self->item->requirement_spec->sections };
 325     if ($new_section) {
 326       $self->render_list($new_section);
 327
 328     } else {
 329       my $html = $self->render('requirement_spec_item/_no_section', { output => 0 });
 330       $self->js
 331         ->html('#column-content',      $html)
 332         ->val('#current_content_type', '')
 333         ->val('#current_content_id',   '')
 334     }
 335
 336   } elsif ($self->is_item_visible) {
 337     # Item in currently visible section is deleted.
 338
 339     my $type = $self->item->item_type;
 340     $self->js->remove('#edit_function_block_' . $self->item->id . '_form')
 341              ->remove('#' . $type . '-' . $self->item->id);
 342
 343     $self->replace_bottom($self->item->parent_id) if $type eq 'sub-function-block';
 344
 345     if (1 == scalar @{ $full_list }) {
 346       if ($type eq 'function-block') {
 347         $self->js->show('#section-list-empty');
 348       } elsif ($type eq 'sub-function-block') {
 349         $self->js->hide('#sub-function-block-container-' . $self->item->parent_id);
 350       }
 351     }
 352   }
 353
 354   $self->invalidate_version
 355     ->jstree->delete_node('#tree', '#fb-' . $self->item->id)
 356     ->render($self);
 357 }
 358
 359 sub action_ajax_flag {
 360   my ($self) = @_;
 361
 362   $self->item->update_attributes(is_flagged => !$self->item->is_flagged);
 363
 364   $self->js
 365    ->action_if($self->is_item_visible, 'toggleClass', '#' . $self->item->item_type . '-' . $self->item->id, 'flagged')
 366    ->toggleClass('#fb-' . $self->item->id, 'flagged')
 367    ->render($self);
 368 }
 369
 370 sub action_ajax_copy {
 371   my ($self, %params) = @_;
 372
 373   SL::Clipboard->new->copy($self->item);
 374   $self->render($self->js);
 375 }
 376
 377 sub determine_paste_position {
 378   my ($self) = @_;
 379
 380   if ($self->item->item_type eq 'section') {
 381     # Sections are always pasted either directly after the
 382     # clicked-upon section or at the very end.
 383     return $self->clicked_item ? (undef, $self->clicked_item->section->id) : ();
 384
 385   } elsif ($self->item->item_type eq 'function-block') {
 386     # A function block:
 387     # - paste on section list: insert into last section as last element
 388     # - paste on section: insert into that section as last element
 389     # - paste on function block: insert after clicked-upon element
 390     # - paste on sub function block: insert after parent function block of clicked-upon element
 391     return !$self->clicked_item                                ? ( $self->sections->[-1]->id,              undef                          )
 392          :  $self->clicked_item->item_type eq 'section'        ? ( $self->clicked_item->id,                undef                          )
 393          :  $self->clicked_item->item_type eq 'function-block' ? ( $self->clicked_item->parent_id,         $self->clicked_item->id        )
 394          :                                                       ( $self->clicked_item->parent->parent_id, $self->clicked_item->parent_id );
 395
 396   } else {                      # sub-function-block
 397     # A sub function block:
 398     # - paste on section list: promote to function block and insert into last section as last element
 399     # - paste on section: promote to function block and insert into that section as last element
 400     # - paste on function block: insert as last element in clicked-upon element
 401     # - paste on sub function block: insert after clicked-upon element
 402
 403     # Promote sub function blocks to function blocks when pasting on a
 404     # section or the section list.
 405     $self->item->item_type('function-block') if !$self->clicked_item || ($self->clicked_item->item_type eq 'section');
 406
 407     return !$self->clicked_item                                ? ( $self->sections->[-1]->id,      undef                   )
 408          :  $self->clicked_item->item_type eq 'section'        ? ( $self->clicked_item->id,        undef                   )
 409          :  $self->clicked_item->item_type eq 'function-block' ? ( $self->clicked_item->id,        undef                   )
 410          :                                                       ( $self->clicked_item->parent_id, $self->clicked_item->id );
 411   }
 412 }
 413
 414 sub assign_requirement_spec_id_rec {
 415   my ($self, $item) = @_;
 416
 417   $item->assign_attributes(requirement_spec_id => $::form->{requirement_spec_id}, fb_number => undef);
 418   $self->assign_requirement_spec_id_rec($_) for @{ $item->children || [] };
 419
 420   return $item;
 421 }
 422
 423 sub create_and_insert_node_rec {
 424   my ($self, $item, $new_parent_id, $insert_after) = @_;
 425
 426   my $node = $self->presenter->requirement_spec_item_jstree_data($item);
 427   $self->js->jstree->create_node('#tree', $insert_after ? ('#fb-' . $insert_after, 'after') : $new_parent_id ? ('#fb-' . $new_parent_id, 'last') : ('#sections', 'last'), $node);
 428
 429   $self->create_and_insert_node_rec($_, $item->id) for @{ $item->children || [] };
 430
 431   $self->js->jstree->open_node('#tree', '#fb-' . $item->id);
 432 }
 433
 434 sub action_ajax_paste {
 435   my ($self, %params) = @_;
 436
 437   my $copied = SL::Clipboard->new->get_entry(qr/^RequirementSpecItem$/);
 438
 439   if (!$copied) {
 440     return $self->js->error(t8("The clipboard does not contain anything that can be pasted here."))
 441                     ->render($self);
 442   }
 443
 444   $self->item($self->assign_requirement_spec_id_rec($copied->to_object));
 445   my $req_spec = SL::DB::RequirementSpec->new(id => $::form->{requirement_spec_id})->load;
 446   $self->sections($req_spec->sections);
 447
 448   if (($self->item->item_type ne 'section') && !@{ $self->sections }) {
 449     return $self->js->error(t8("You cannot paste function blocks or sub function blocks if there is no section."))
 450                     ->render($self);
 451   }
 452
 453   $self->clicked_item($::form->{id} ? SL::DB::RequirementSpecItem->new(id => $::form->{id})->load : undef);
 454
 455   my ($new_parent_id, $insert_after) = $self->determine_paste_position;
 456
 457   # Store result in database.
 458   $self->item->update_attributes(parent_id => $new_parent_id);
 459   $self->item->add_to_list(position => 'after', reference => $insert_after) if $insert_after;
 460
 461   # Update the tree: create the node for all pasted objects.
 462   $self->create_and_insert_node_rec($self->item, $new_parent_id, $insert_after);
 463
 464   # Pasting the very first section?
 465   if (!@{ $self->sections }) {
 466     my $html = $self->render('requirement_spec_item/_section', { output => 0 }, requirement_spec_item => $self->item);
 467     $self->js->html('#column-content', $html)
 468              ->jstree->select_node('#tree', '#fb-' . $self->item->id)
 469   }
 470
 471   # Update the current view if required.
 472   $self->insert_new_item_in_section_view($self->js) if $self->is_item_visible;
 473
 474   $self->invalidate_version->render($self);
 475 }
 476
 477 #
 478 # filters
 479 #
 480
 481 sub check_auth {
 482   my ($self) = @_;
 483   $::auth->assert('sales_quotation_edit');
 484 }
 485
 486 sub load_requirement_spec_item {
 487   my ($self) = @_;
 488   $self->item(SL::DB::RequirementSpecItem->new(id => $::form->{id})->load);
 489 }
 490
 491 #
 492 # helpers
 493 #
 494
 495 sub create_random_id {
 496   return join '-', Time::HiRes::gettimeofday();
 497 }
 498
 499 sub format_exception {
 500   return join "\n", (split m/\n/, $@)[0..4];
 501 }
 502
 503 sub init_complexities {
 504   my ($self) = @_;
 505
 506   return SL::DB::Manager::RequirementSpecComplexity->get_all_sorted;
 507 }
 508
 509 sub init_risks {
 510   my ($self) = @_;
 511
 512   return SL::DB::Manager::RequirementSpecRisk->get_all_sorted;
 513 }
 514
 515 sub init_js {
 516   my ($self) = @_;
 517   $self->js(SL::ClientJS->new);
 518 }
 519
 520 sub replace_bottom {
 521   my ($self, $item_or_id) = @_;
 522
 523   my $item      = (ref($item_or_id) ? $item_or_id : SL::DB::RequirementSpecItem->new(id => $item_or_id))->load;
 524   my $id_prefix = $item->item_type eq 'function-block' ? '' : 'sub-';
 525   my $html      = $self->render('requirement_spec_item/_function_block_content_bottom', { output => 0 }, requirement_spec_item => $item, id_prefix => $id_prefix);
 526   return $self->js->replaceWith('#' . $id_prefix . 'function-block-content-bottom-' . $item->id, $html);
 527 }
 528
 529 sub render_list {
 530   my ($self, $item, $item_to_select) = @_;
 531
 532   my $html = $self->render('requirement_spec_item/_section', { output => 0 }, requirement_spec_item => $item);
 533   $self->js->html('#column-content', $html);
 534   $self->select_node($item_to_select || $item);
 535 }
 536
 537 sub select_node {
 538   my ($self, $item) = @_;
 539
 540   $self->js
 541     ->val( '#current_content_type', $item->item_type)
 542     ->val( '#current_content_id',   $item->id)
 543     ->jstree->select_node('#tree', '#fb-' . $item->id);
 544 }
 545
 546 sub create_dependency_item {
 547   my $self = shift;
 548   [ $_[0]->id, $self->presenter->truncate(join(' ', grep { $_ } ($_[1], $_[0]->fb_number, $_[0]->description))) ];
 549 }
 550
 551 sub create_dependencies {
 552   my ($self) = @_;
 553
 554   return map { [ $_->fb_number . ' ' . $_->title,
 555                  [ map { ( $self->create_dependency_item($_),
 556                            map { $self->create_dependency_item($_, '->') } @{ $_->children_sorted })
 557                        } @{ $_->children_sorted } ] ]
 558              } @{ $self->item->requirement_spec->sections };
 559 }
 560
 561 sub ensure_section_is_shown {
 562   my ($self, %params) = @_;
 563
 564   return $self->js if $self->is_item_visible;
 565
 566   # Show section/item to edit if it is not visible.
 567   my $new_section = $self->item->section;
 568   my $html        = $self->render('requirement_spec_item/_section', { output => 0 }, requirement_spec_item => $new_section);
 569
 570   return $self->js
 571     ->html('#column-content', $html)
 572     ->val('#current_content_type', 'section')
 573     ->val('#current_content_id',   $new_section->id)
 574     ->jstree->select_node('#tree', '#fb-' . $new_section->id);
 575 }
 576
 577 sub add_new_item_form {
 578   my ($self, %params) = @_;
 579
 580   for (qw(insert_position display_reference)) {
 581     croak "Missing parameter $_" if !$params{$_};
 582   }
 583   croak "Missing parameter insert_reference" if ($params{insert_position} eq 'insertAfter') && !$params{insert_reference};
 584
 585   my $id_base = join('_', 'new_function_block', Time::HiRes::gettimeofday(), int rand 1000000000000);
 586   my $html    = $self->render(
 587     'requirement_spec_item/_function_block_form',
 588     { output => 0 },
 589     DEPENDENCIES          => [ $self->create_dependencies ],
 590     SELECTED_DEPENDENCIES => [],
 591     requirement_spec_item => $self->item,
 592     id_base               => $id_base,
 593     insert_after          => $params{insert_position} eq 'insertAfter' ? $params{insert_reference} : undef,
 594   );
 595
 596   return $self->js
 597     ->action($params{insert_position}, $html, $params{display_reference})
 598     ->focus("#${id_base}_description");
 599 }
 600
 601 sub add_new_item_form_after_create {
 602   my ($self, %params) = @_;
 603
 604   my $created_item = $self->item;
 605   $self->item(SL::DB::RequirementSpecItem->new(requirement_spec_id => $created_item->requirement_spec_id, parent_id => $created_item->parent_id, item_type => $created_item->item_type));
 606
 607   $self->add_new_item_form(
 608     insert_position   => 'insertAfter',
 609     insert_reference  => $created_item->id,
 610     display_reference => '#' . $created_item->item_type . '-' . $created_item->id,
 611   );
 612 }
 613
 614 sub add_function_block {
 615   my ($self, $new_type) = @_;
 616
 617   my $clicked_id = $::form->{id} || ($self->visible_item ? $self->visible_item->id : undef);
 618
 619   die "Invalid new_type '$new_type'"               if $new_type !~ m/^(?:sub-)?function-block$/;
 620   die "Missing parameter 'id' and no visible item" if !$clicked_id;
 621   die "Missing parameter 'requirement_spec_id'"    if !$::form->{requirement_spec_id};
 622
 623   my $clicked_item = SL::DB::RequirementSpecItem->new(id => $clicked_id)->load;
 624   my $clicked_type = $clicked_item->item_type;
 625
 626   die "Invalid clicked_type '$clicked_type'" if $clicked_type !~ m/^(?: section | (?:sub-)? function-block )$/x;
 627
 628   my $case = "${clicked_type}:${new_type}";
 629
 630   my ($insert_position, $insert_reference, $parent_id, $display_reference)
 631     = $case eq 'section:function-block'                ? ( 'appendTo',    $clicked_item->id,        $clicked_item->id,                '#section-list'                  )
 632     : $case eq 'function-block:function-block'         ? ( 'insertAfter', $clicked_item->id,        $clicked_item->parent_id,         '#function-block-'               )
 633     : $case eq 'function-block:sub-function-block'     ? ( 'appendTo'  ,  $clicked_item->id,        $clicked_item->id,                '#sub-function-block-container-' )
 634     : $case eq 'sub-function-block:function-block'     ? ( 'insertAfter', $clicked_item->parent_id, $clicked_item->parent->parent_id, '#function-block-'               )
 635     : $case eq 'sub-function-block:sub-function-block' ? ( 'insertAfter', $clicked_item->id,        $clicked_item->parent_id,         '#sub-function-block-'           )
 636     :                                                    die "Invalid combination of 'clicked_type (section)/new_type ($new_type)'";
 637
 638   $display_reference .= $insert_reference if $display_reference =~ m/-$/;
 639
 640   $self->item(SL::DB::RequirementSpecItem->new(requirement_spec_id => $::form->{requirement_spec_id}, parent_id => $parent_id, item_type => $new_type));
 641
 642   $self->ensure_section_is_shown;
 643   $self->add_new_item_form(insert_position => $insert_position, insert_reference => $insert_reference, display_reference => $display_reference);
 644
 645   $self->js->show('#sub-function-block-container-' . $parent_id) if $new_type eq 'sub-function-block';
 646
 647   $self->js->render($self);
 648 }
 649
 650 sub is_item_visible {
 651   my ($self, $item) = @_;
 652
 653   $item ||= $self->item;
 654   return $self->visible_section && ($self->visible_section->id == $item->section->id);
 655 }
 656
 657 sub invalidate_version {
 658   my ($self) = @_;
 659
 660   my $html   = $self->render('requirement_spec/_version', { output => 0 },
 661                              requirement_spec => SL::DB::RequirementSpec->new(id => $::form->{requirement_spec_id} || $self->item->requirement_spec_id)->load);
 662   return $self->js->html('#requirement_spec_version', $html);
 663 }
 664
 665 1;