SL/Controller/RequirementSpecOrder.pm

   1 package SL::Controller::RequirementSpecOrder;
   2
   3 use strict;
   4 use utf8;
   5
   6 use parent qw(SL::Controller::Base);
   7
   8 use List::MoreUtils qw(uniq);
   9 use List::Util qw(first);
  10
  11 use SL::ClientJS;
  12 use SL::DB::Customer;
  13 use SL::DB::Order;
  14 use SL::DB::Part;
  15 use SL::DB::RequirementSpec;
  16 use SL::DB::RequirementSpecOrder;
  17 use SL::Helper::Flash;
  18 use SL::Locale::String;
  19
  20 use constant TAB_ID => 'ui-tabs-4';
  21
  22 use Rose::Object::MakeMethods::Generic
  23 (
  24   scalar                  => [ qw(parts) ],
  25   'scalar --get_set_init' => [ qw(requirement_spec js h_unit_name all_customers all_parts) ],
  26 );
  27
  28 __PACKAGE__->run_before('setup');
  29
  30 #
  31 # actions
  32 #
  33
  34 sub action_list {
  35   my ($self) = @_;
  36
  37   $self->render('requirement_spec_order/list', { layout => 0 });
  38 }
  39
  40 sub action_new {
  41   my ($self) = @_;
  42
  43   my $html   = $self->render('requirement_spec_order/new', { output => 0 }, make_part_title => sub { $_[0]->partnumber . ' ' . $_[0]->description });
  44   $self->js->html('#' . TAB_ID(), $html)
  45            ->render($self);
  46 }
  47
  48 sub action_create {
  49   my ($self)         = @_;
  50
  51   # 1. Update sections with selected part IDs.
  52   my $section_attrs  = $::form->{sections} || [];
  53   my $sections       = SL::DB::Manager::RequirementSpecItem->get_all(where => [ id => [ map { $_->{id} } @{ $section_attrs } ] ]);
  54   my %sections_by_id = map { ($_->{id} => $_) } @{ $sections };
  55
  56   $sections_by_id{ $_->{id} }->update_attributes(order_part_id => $_->{order_part_id}) for @{ $section_attrs };
  57
  58   # 2. Create actual quotation/order.
  59   my $order = $self->create_order(sections => $sections);
  60   $order->save;
  61
  62   $self->requirement_spec->orders(
  63     @{ $self->requirement_spec->orders },
  64     SL::DB::RequirementSpecOrder->new(order => $order, version => $self->requirement_spec->version)
  65   );
  66   $self->requirement_spec->save;
  67   $self->init_requirement_spec;
  68
  69   # 3. Notify the user and return to list.
  70   my $html = $self->render('requirement_spec_order/list', { output => 0 });
  71   $self->js->html('#' . TAB_ID(), $html)
  72            ->flash('info', $::form->{quotation} ? t8('Sales quotation #1 has been created.', $order->quonumber) : t8('Sales order #1 has been created.', $order->ordnumber))
  73            ->render($self);
  74 }
  75
  76 sub action_edit_assignment {
  77   my ($self) = @_;
  78
  79   my $html   = $self->render('requirement_spec_order/edit_assignment', { output => 0 }, make_part_title => sub { $_[0]->partnumber . ' ' . $_[0]->description });
  80   $self->js->html('#' . TAB_ID(), $html)
  81            ->render($self);
  82 }
  83
  84 sub action_save_assignment {
  85   my ($self)   = @_;
  86   my $sections = $::form->{sections} || [];
  87   SL::DB::RequirementSpecItem->new(id => $_->{id})->load->update_attributes(order_part_id => ($_->{order_part_id} || undef)) for @{ $sections };
  88
  89   my $html = $self->render('requirement_spec_order/list', { output => 0 });
  90   $self->js->html('#' . TAB_ID(), $html)
  91            ->render($self);
  92 }
  93
  94 sub action_cancel {
  95   my ($self) = @_;
  96
  97   my $html = $self->render('requirement_spec_order/list', { output => 0 });
  98   $self->js->html('#' . TAB_ID(), $html)
  99            ->render($self);
 100 }
 101
 102 #
 103 # filters
 104 #
 105
 106 sub setup {
 107   my ($self) = @_;
 108
 109   $::auth->assert('sales_quotation_edit');
 110   $::request->{layout}->use_stylesheet("${_}.css") for qw(jquery.contextMenu requirement_spec);
 111   $::request->{layout}->use_javascript("${_}.js")  for qw(jquery.jstree jquery/jquery.contextMenu client_js requirement_spec);
 112
 113   return 1;
 114 }
 115
 116 sub init_requirement_spec {
 117   my ($self) = @_;
 118   $self->requirement_spec(SL::DB::RequirementSpec->new(id => $::form->{requirement_spec_id})->load) if $::form->{requirement_spec_id};
 119 }
 120
 121 sub init_js {
 122   my ($self) = @_;
 123   $self->js(SL::ClientJS->new);
 124 }
 125
 126 #
 127 # helpers
 128 #
 129
 130 sub init_all_customers { SL::DB::Manager::Customer->get_all_sorted }
 131 sub init_all_parts     { SL::DB::Manager::Part->get_all_sorted     }
 132 sub init_h_unit_name   { first { SL::DB::Manager::Unit->find_by(name => $_) } qw(Std h Stunde) };
 133
 134 sub load_parts_for_sections {
 135   my ($self, %params) = @_;
 136
 137   $self->parts({ map { ($_->{id} => $_) } @{ SL::DB::Manager::Part->get_all(where => [ id => [ uniq map { $_->{order_part_id} } @{ $params{sections} } ] ]) } });
 138 }
 139
 140 sub create_order_item {
 141   my ($self, %params) = @_;
 142
 143   my $section         = $params{section};
 144   my $item            = $params{item} || SL::DB::OrderItem->new;
 145   my $part            = $self->parts->{ $section->order_part_id };
 146   my $description     = $section->{keep_description} ? $item->description : $part->description;
 147
 148   if (!$section->{keep_description}) {
 149     $description =  '<%fb_number%> <%title%>' unless $description =~ m{<%};
 150     $description =~ s{<% (.+?) %>}{$section->$1}egx;
 151   }
 152
 153   $item->assign_attributes(
 154     parts_id    => $part->id,
 155     description => $description,
 156     qty         => $section->time_estimation * 1,
 157     unit        => $self->h_unit_name,
 158     sellprice   => $::form->round_amount($self->requirement_spec->hourly_rate, 2),
 159     discount    => 0,
 160     project_id  => $self->requirement_spec->project_id,
 161   );
 162
 163   return $item;
 164 }
 165
 166 sub create_order {
 167   my ($self, %params) = @_;
 168
 169   $self->load_parts_for_sections(%params);
 170
 171   my @orderitems = map { $self->create_order_item(section => $_) } @{ $params{sections} };
 172   my $employee   = SL::DB::Manager::Employee->current;
 173   my $customer   = SL::DB::Customer->new(id => $::form->{customer_id})->load;
 174   my $order      = SL::DB::Order->new(
 175     globalproject_id        => $self->requirement_spec->project_id,
 176     transdate               => DateTime->today_local,
 177     reqdate                 => $::form->{quotation} && $customer->payment_id ? $customer->payment->calc_date : undef,
 178     quotation               => !!$::form->{quotation},
 179     orderitems              => \@orderitems,
 180     customer_id             => $customer->id,
 181     taxincluded             => $customer->taxincluded,
 182     intnotes                => $customer->notes,
 183     language_id             => $customer->language_id,
 184     payment_id              => $customer->payment_id,
 185     taxzone_id              => $customer->taxzone_id,
 186     employee_id             => $employee->id,
 187     salesman_id             => $employee->id,
 188     transaction_description => $self->requirement_spec->displayable_name,
 189     currency_id             => $::instance_conf->get_currency_id,
 190   );
 191
 192   $order->calculate_prices_and_taxes;
 193
 194   return $order;
 195 }
 196
 197 1;