SL/Controller/RequirementSpecOrder.pm

   1 package SL::Controller::RequirementSpecOrder;
   2
   3 use strict;
   4 use utf8;
   5
   6 use parent qw(SL::Controller::Base);
   7
   8 use List::MoreUtils qw(uniq);
   9 use List::Util qw(first);
  10
  11 use SL::ClientJS;
  12 use SL::DB::Customer;
  13 use SL::DB::Order;
  14 use SL::DB::Part;
  15 use SL::DB::RequirementSpec;
  16 use SL::DB::RequirementSpecOrder;
  17 use SL::Helper::Flash;
  18 use SL::Locale::String;
  19
  20 use constant LIST_SELECTOR  => '#quotations_and_orders';
  21 use constant FORMS_SELECTOR => '#quotations_and_orders_article_assignment,#quotations_and_orders_new,#quotations_and_orders_update';
  22
  23 use Rose::Object::MakeMethods::Generic
  24 (
  25   scalar                  => [ qw(parts) ],
  26   'scalar --get_set_init' => [ qw(requirement_spec rs_order js h_unit_name all_customers all_parts_time_unit) ],
  27 );
  28
  29 __PACKAGE__->run_before('setup');
  30
  31 #
  32 # actions
  33 #
  34
  35 sub action_list {
  36   my ($self) = @_;
  37
  38   $self->render('requirement_spec_order/list', { layout => 0 });
  39 }
  40
  41 sub action_new {
  42   my ($self) = @_;
  43
  44   if (!@{ $self->all_parts_time_unit }) {
  45     return $self->js->flash('error', t8('This function requires the presence of articles with a time-based unit such as "h" or "min".'))->render($self);
  46   }
  47
  48   my $html = $self->render('requirement_spec_order/new', { output => 0 }, make_part_title => sub { $_[0]->partnumber . ' ' . $_[0]->description });
  49   $self->js->hide(LIST_SELECTOR())
  50            ->after(LIST_SELECTOR(), $html)
  51            ->render($self);
  52 }
  53
  54 sub action_create {
  55   my ($self)         = @_;
  56
  57   if (!$::auth->assert($::form->{quotation} ? 'sales_quotation_edit' : 'sales_order_edit', 1)) {
  58     return $self->js->flash('error', t8("You do not have the permissions to access this function."))->render($self);
  59   }
  60
  61   # 1. Update sections with selected part IDs.
  62   my $section_attrs  = $::form->{sections} || [];
  63   my $sections       = SL::DB::Manager::RequirementSpecItem->get_all_sorted(where => [ id => [ map { $_->{id} } @{ $section_attrs } ] ]);
  64   my %sections_by_id = map { ($_->{id} => $_) } @{ $sections };
  65
  66   $sections_by_id{ $_->{id} }->update_attributes(order_part_id => $_->{order_part_id}) for @{ $section_attrs };
  67
  68   # 2. Create actual quotation/order.
  69   my $order = $self->create_order(sections => $sections);
  70   $order->db->with_transaction(sub {
  71     $order->save;
  72
  73     $self->requirement_spec->orders(
  74       @{ $self->requirement_spec->orders },
  75       SL::DB::RequirementSpecOrder->new(order => $order, version => $self->requirement_spec->version)
  76     );
  77     $self->requirement_spec->save;
  78
  79     $self->requirement_spec->link_to_record($order);
  80   }) or do {
  81     $::lxdebug->message(LXDebug::WARN(), "Error creating the order object: $@");
  82   };
  83
  84   $self->init_requirement_spec;
  85
  86   # 3. Notify the user and return to list.
  87   my $html = $self->render('requirement_spec_order/list', { output => 0 });
  88   $self->js->replaceWith(LIST_SELECTOR(), $html)
  89            ->remove(FORMS_SELECTOR())
  90            ->flash('info', $::form->{quotation} ? t8('Sales quotation #1 has been created.', $order->quonumber) : t8('Sales order #1 has been created.', $order->ordnumber))
  91            ->render($self);
  92 }
  93
  94 sub action_update {
  95   my ($self)   = @_;
  96
  97   my $order    = $self->rs_order->order;
  98   my $sections = $self->requirement_spec->sections_sorted;
  99
 100   if (!$::auth->assert($order->quotation ? 'sales_quotation_edit' : 'sales_order_edit', 1)) {
 101     return $self->js->flash('error', t8("You do not have the permissions to access this function."))->render($self);
 102   }
 103
 104   my (@orderitems, %sections_seen);
 105   foreach my $item (@{ $order->items_sorted }) {
 106     my $section = first { my $num = $_->fb_number; $item->description =~ m{\b\Q${num}\E\b} && !$sections_seen{ $_->id } } @{ $sections };
 107
 108     $sections_seen{ $section->id } = 1 if $section;
 109
 110     push @orderitems, { item => $item, section => $section };
 111   }
 112
 113   my $html = $self->render(
 114     'requirement_spec_order/update', { output => 0 },
 115     orderitems         => \@orderitems,
 116     sections           => $sections,
 117     make_section_title => sub { $_[0]->fb_number . ' ' . $_[0]->title },
 118   );
 119
 120   $self->js->hide(LIST_SELECTOR())
 121            ->after(LIST_SELECTOR(), $html)
 122            ->render($self);
 123 }
 124
 125 sub action_do_update {
 126   my ($self)           = @_;
 127
 128   my $order            = $self->rs_order->order;
 129   my $sections         = $self->requirement_spec->sections_sorted;
 130   my %orderitems_by_id = map { ($_->id => $_) } @{ $order->orderitems };
 131   my %sections_by_id   = map { ($_->id => $_) } @{ $sections };
 132   $self->{parts}       = { map { ($_->id => $_) } @{ SL::DB::Manager::Part->get_all(where => [ id => [ uniq map { $_->order_part_id } @{ $sections } ] ]) } };
 133   my $language_id      = $self->requirement_spec->customer->language_id;
 134
 135   my %sections_seen;
 136
 137   foreach my $attributes (@{ $::form->{orderitems} || [] }) {
 138     my $orderitem = $orderitems_by_id{ $attributes->{id}         };
 139     my $section   = $sections_by_id{   $attributes->{section_id} };
 140     next unless $orderitem && $section;
 141
 142     $self->create_order_item(section => $section, item => $orderitem, language_id => $language_id)->save;
 143     $sections_seen{ $section->id } = 1;
 144   }
 145
 146   my @new_orderitems = map  { $self->create_order_item(section => $_, language_id => $language_id) }
 147                        grep { !$sections_seen{ $_->id } }
 148                        @{ $sections };
 149
 150   $order->orderitems([ @{ $order->orderitems }, @new_orderitems ]) if @new_orderitems;
 151
 152   $order->calculate_prices_and_taxes;
 153
 154   $order->db->with_transaction(sub {
 155     $order->save;
 156     $self->requirement_spec->link_to_record($order);
 157   }) or do {
 158     $::lxdebug->message(LXDebug::WARN(), "Error updating the order object: $@");
 159   };
 160
 161   $self->init_requirement_spec;
 162
 163   my $html = $self->render('requirement_spec_order/list', { output => 0 });
 164   $self->js->replaceWith(LIST_SELECTOR(), $html)
 165            ->remove(FORMS_SELECTOR())
 166            ->flash('info', $::form->{quotation} ? t8('Sales quotation #1 has been updated.', $order->quonumber) : t8('Sales order #1 has been updated.', $order->ordnumber))
 167            ->render($self);
 168 }
 169
 170 sub action_edit_assignment {
 171   my ($self) = @_;
 172
 173   if (!@{ $self->all_parts_time_unit }) {
 174     return $self->js->flash('error', t8('This function requires the presence of articles with a time-based unit such as "h" or "min".'))->render($self);
 175   }
 176
 177   my $html   = $self->render('requirement_spec_order/edit_assignment', { output => 0 }, make_part_title => sub { $_[0]->partnumber . ' ' . $_[0]->description });
 178   $self->js->hide(LIST_SELECTOR())
 179            ->after(LIST_SELECTOR(), $html)
 180            ->render($self);
 181 }
 182
 183 sub action_save_assignment {
 184   my ($self)   = @_;
 185   my $sections = $::form->{sections} || [];
 186   SL::DB::RequirementSpecItem->new(id => $_->{id})->load->update_attributes(order_part_id => ($_->{order_part_id} || undef)) for @{ $sections };
 187
 188   my $html = $self->render('requirement_spec_order/list', { output => 0 });
 189   $self->js->replaceWith(LIST_SELECTOR(), $html)
 190            ->remove(FORMS_SELECTOR())
 191            ->render($self);
 192 }
 193
 194 sub action_delete {
 195   my ($self) = @_;
 196
 197   my $order  = $self->rs_order->order;
 198
 199   $order->delete;
 200   $self->init_requirement_spec;
 201
 202   my $html = $self->render('requirement_spec_order/list', { output => 0 });
 203   $self->js->replaceWith(LIST_SELECTOR(), $html)
 204            ->flash('info', $order->quotation ? t8('Sales quotation #1 has been deleted.', $order->quonumber) : t8('Sales order #1 has been deleted.', $order->ordnumber))
 205            ->render($self);
 206 }
 207
 208 #
 209 # filters
 210 #
 211
 212 sub setup {
 213   my ($self) = @_;
 214
 215   $::auth->assert('requirement_spec_edit');
 216   $::request->{layout}->use_stylesheet("${_}.css") for qw(jquery.contextMenu requirement_spec autocomplete_part);
 217   $::request->{layout}->use_javascript("${_}.js")  for qw(jquery.jstree jquery/jquery.contextMenu client_js requirement_spec);
 218
 219   return 1;
 220 }
 221
 222 sub init_requirement_spec {
 223   my ($self) = @_;
 224   $self->requirement_spec(SL::DB::RequirementSpec->new(id => $::form->{requirement_spec_id})->load) if $::form->{requirement_spec_id};
 225 }
 226
 227 sub init_js {
 228   my ($self) = @_;
 229   $self->js(SL::ClientJS->new);
 230 }
 231
 232 sub init_all_customers { SL::DB::Manager::Customer->get_all_sorted }
 233 sub init_h_unit_name   { first { SL::DB::Manager::Unit->find_by(name => $_) } qw(Std h Stunde) };
 234 sub init_rs_order      { SL::DB::RequirementSpecOrder->new(id => $::form->{rs_order_id})->load };
 235
 236 sub init_all_parts_time_unit {
 237   my ($self) = @_;
 238
 239   return [] unless $self->h_unit_name;
 240
 241   my @convertible_unit_names = map { $_->name } @{ SL::DB::Manager::Unit->find_by(name => $self->h_unit_name)->convertible_units };
 242
 243   return SL::DB::Manager::Part->get_all_sorted(where => [ unit => \@convertible_unit_names ]);
 244 }
 245
 246 #
 247 # helpers
 248 #
 249
 250 sub load_parts_for_sections {
 251   my ($self, %params) = @_;
 252
 253 }
 254
 255 sub create_order_item {
 256   my ($self, %params) = @_;
 257
 258   my $section         = $params{section};
 259   my $item            = $params{item} || SL::DB::OrderItem->new;
 260   my $part            = $self->parts->{ $section->order_part_id };
 261   my $translation     = $params{language_id} ? first { $params{language_id} == $_->language_id } @{ $part->translations } : {};
 262   my $description     = $section->{keep_description} ? $item->description : ($translation->{translation} || $part->description);
 263   my $longdescription = $translation->{longdescription} || $part->notes;
 264
 265   if (!$section->{keep_description}) {
 266     $description     = '<%fb_number%> <%title%>' unless $description =~ m{<%};
 267     $longdescription = '&lt;%description%&gt;'   unless $longdescription =~ m{&lt;%};
 268
 269     $description     =~ s{<% (.+?) %>}{ $section->can($1) ? $section->$1 : '<' . t8('Invalid variable #1', $1) . '>' }egx;
 270     $longdescription =~ s{\&lt;\% description \%\&gt;}{!!!!DESCRIPTION!!!!}gx;
 271     $longdescription =~ s{<[pP]> !!!!DESCRIPTION!!!! </[pP]>}{!!!!DESCRIPTION!!!!}gx;
 272     $longdescription =~ s{\&lt;\% (.+?) \%\&gt;}{ $section->can($1) ? $::locale->quote_special_chars('HTML', $section->$1 // '') : '<' . t8('Invalid variable #1', $1) . '>' }egx;
 273     $longdescription =~ s{!!!!DESCRIPTION!!!!}{ $section->description // '' }egx;
 274   }
 275
 276   $item->assign_attributes(
 277     parts_id        => $part->id,
 278     description     => $description,
 279     longdescription => $longdescription,
 280     qty             => $section->time_estimation * 1,
 281     unit            => $self->h_unit_name,
 282     sellprice       => $::form->round_amount($self->requirement_spec->hourly_rate, 2),
 283     lastcost        => $part->lastcost,
 284     discount        => 0,
 285     project_id      => $self->requirement_spec->project_id,
 286   );
 287
 288   return $item;
 289 }
 290
 291 sub create_order {
 292   my ($self, %params) = @_;
 293
 294   $self->{parts} = { map { ($_->{id} => $_) } @{ SL::DB::Manager::Part->get_all(where => [ id => [ uniq map { $_->{order_part_id} } @{ $params{sections} } ] ]) } };
 295
 296   my $customer   = SL::DB::Customer->new(id => $::form->{customer_id})->load;
 297   my @orderitems = map { $self->create_order_item(section => $_, language_id => $customer->language_id) } @{ $params{sections} };
 298   my $employee   = SL::DB::Manager::Employee->current;
 299   my $order      = SL::DB::Order->new(
 300     globalproject_id        => $self->requirement_spec->project_id,
 301     transdate               => DateTime->today_local,
 302     reqdate                 => $::form->{quotation} && $customer->payment_id ? $customer->payment->calc_date : undef,
 303     quotation               => !!$::form->{quotation},
 304     orderitems              => \@orderitems,
 305     customer_id             => $customer->id,
 306     taxincluded             => $customer->taxincluded,
 307     intnotes                => $customer->notes,
 308     language_id             => $customer->language_id,
 309     payment_id              => $customer->payment_id,
 310     taxzone_id              => $customer->taxzone_id,
 311     employee_id             => $employee->id,
 312     salesman_id             => $employee->id,
 313     transaction_description => $self->requirement_spec->displayable_name,
 314     currency_id             => $::instance_conf->get_currency_id,
 315   );
 316
 317   $order->calculate_prices_and_taxes;
 318
 319   return $order;
 320 }
 321
 322 1;