SL/Controller/RequirementSpecOrder.pm

   1 package SL::Controller::RequirementSpecOrder;
   2
   3 use strict;
   4 use utf8;
   5
   6 use parent qw(SL::Controller::Base);
   7
   8 use List::MoreUtils qw(uniq);
   9 use List::Util qw(first);
  10
  11 use SL::ClientJS;
  12 use SL::DB::Customer;
  13 use SL::DB::Order;
  14 use SL::DB::Part;
  15 use SL::DB::RequirementSpec;
  16 use SL::DB::RequirementSpecOrder;
  17 use SL::Helper::Flash;
  18 use SL::Locale::String;
  19
  20 use constant LIST_SELECTOR  => '#quotations_and_orders';
  21 use constant FORMS_SELECTOR => '#quotations_and_orders_article_assignment,#quotations_and_orders_new,#quotations_and_orders_update';
  22
  23 use Rose::Object::MakeMethods::Generic
  24 (
  25   scalar                  => [ qw(parts) ],
  26   'scalar --get_set_init' => [ qw(requirement_spec rs_order js h_unit_name all_customers all_parts_time_unit) ],
  27 );
  28
  29 __PACKAGE__->run_before('setup');
  30
  31 #
  32 # actions
  33 #
  34
  35 sub action_list {
  36   my ($self) = @_;
  37
  38   $self->render('requirement_spec_order/list', { layout => 0 });
  39 }
  40
  41 sub action_new {
  42   my ($self) = @_;
  43
  44   if (!@{ $self->all_parts_time_unit }) {
  45     return $self->js->flash('error', t8('This function requires the presence of articles with a time-based unit such as "h" or "min".'))->render($self);
  46   }
  47
  48   my $html = $self->render('requirement_spec_order/new', { output => 0 }, make_part_title => sub { $_[0]->partnumber . ' ' . $_[0]->description });
  49   $self->js->hide(LIST_SELECTOR())
  50            ->after(LIST_SELECTOR(), $html)
  51            ->render($self);
  52 }
  53
  54 sub action_create {
  55   my ($self)         = @_;
  56
  57   if (!$::auth->assert($::form->{quotation} ? 'sales_quotation_edit' : 'sales_order_edit', 1)) {
  58     return $self->js->flash('error', t8("You do not have the permissions to access this function."))->render($self);
  59   }
  60
  61   # 1. Update sections with selected part IDs.
  62   my $section_attrs  = $::form->{sections} || [];
  63   my $sections       = SL::DB::Manager::RequirementSpecItem->get_all_sorted(where => [ id => [ map { $_->{id} } @{ $section_attrs } ] ]);
  64   my %sections_by_id = map { ($_->{id} => $_) } @{ $sections };
  65
  66   $sections_by_id{ $_->{id} }->update_attributes(order_part_id => $_->{order_part_id}) for @{ $section_attrs };
  67
  68   # 2. Create actual quotation/order.
  69   my $order = $self->create_order(sections => $sections, additional_parts => $self->requirement_spec->parts_sorted);
  70   $order->db->with_transaction(sub {
  71     $order->save;
  72
  73     $self->requirement_spec->add_orders(SL::DB::RequirementSpecOrder->new(order => $order, version => $self->requirement_spec->version));
  74     $self->requirement_spec->save;
  75
  76     $self->requirement_spec->link_to_record($order);
  77   }) or do {
  78     $::lxdebug->message(LXDebug::WARN(), "Error creating the order object: $@");
  79   };
  80
  81   $self->init_requirement_spec;
  82
  83   # 3. Notify the user and return to list.
  84   my $html = $self->render('requirement_spec_order/list', { output => 0 });
  85   $self->js->replaceWith(LIST_SELECTOR(), $html)
  86            ->remove(FORMS_SELECTOR())
  87            ->flash('info', $::form->{quotation} ? t8('Sales quotation #1 has been created.', $order->quonumber) : t8('Sales order #1 has been created.', $order->ordnumber))
  88            ->render($self);
  89 }
  90
  91 sub action_update {
  92   my ($self)   = @_;
  93
  94   my $order    = $self->rs_order->order;
  95   my $sections = $self->requirement_spec->sections_sorted;
  96
  97   if (!$::auth->assert($order->quotation ? 'sales_quotation_edit' : 'sales_order_edit', 1)) {
  98     return $self->js->flash('error', t8("You do not have the permissions to access this function."))->render($self);
  99   }
 100
 101   my (@orderitems, %sections_seen);
 102   foreach my $item (@{ $order->items_sorted }) {
 103     my $section = first { my $num = $_->fb_number; $item->description =~ m{\b\Q${num}\E\b} && !$sections_seen{ $_->id } } @{ $sections };
 104
 105     $sections_seen{ $section->id } = 1 if $section;
 106
 107     push @orderitems, { item => $item, section => $section };
 108   }
 109
 110   my $html = $self->render(
 111     'requirement_spec_order/update', { output => 0 },
 112     orderitems         => \@orderitems,
 113     sections           => $sections,
 114     make_section_title => sub { $_[0]->fb_number . ' ' . $_[0]->title },
 115   );
 116
 117   $self->js->hide(LIST_SELECTOR())
 118            ->after(LIST_SELECTOR(), $html)
 119            ->render($self);
 120 }
 121
 122 sub action_do_update {
 123   my ($self)         = @_;
 124
 125   my $order          = $self->rs_order->order;
 126   my @new_orderitems =  $self->do_update_sections;
 127   push @new_orderitems, $self->do_update_additional_parts;
 128
 129   $order->add_orderitems(\@new_orderitems) if @new_orderitems;
 130
 131   $order->calculate_prices_and_taxes;
 132
 133   $order->db->with_transaction(sub {
 134     $order->save;
 135     $self->requirement_spec->link_to_record($order);
 136   }) or do {
 137     $::lxdebug->message(LXDebug::WARN(), "Error updating the order object: $@");
 138   };
 139
 140   $self->init_requirement_spec;
 141
 142   my $html = $self->render('requirement_spec_order/list', { output => 0 });
 143   $self->js->replaceWith(LIST_SELECTOR(), $html)
 144            ->remove(FORMS_SELECTOR())
 145            ->flash('info', $::form->{quotation} ? t8('Sales quotation #1 has been updated.', $order->quonumber) : t8('Sales order #1 has been updated.', $order->ordnumber))
 146            ->render($self);
 147 }
 148
 149 sub action_edit_assignment {
 150   my ($self) = @_;
 151
 152   if (!@{ $self->all_parts_time_unit }) {
 153     return $self->js->flash('error', t8('This function requires the presence of articles with a time-based unit such as "h" or "min".'))->render($self);
 154   }
 155
 156   my $html   = $self->render('requirement_spec_order/edit_assignment', { output => 0 }, make_part_title => sub { $_[0]->partnumber . ' ' . $_[0]->description });
 157   $self->js->hide(LIST_SELECTOR())
 158            ->after(LIST_SELECTOR(), $html)
 159            ->render($self);
 160 }
 161
 162 sub action_save_assignment {
 163   my ($self)   = @_;
 164   my $sections = $::form->{sections} || [];
 165   SL::DB::RequirementSpecItem->new(id => $_->{id})->load->update_attributes(order_part_id => ($_->{order_part_id} || undef)) for @{ $sections };
 166
 167   my $html = $self->render('requirement_spec_order/list', { output => 0 });
 168   $self->js->replaceWith(LIST_SELECTOR(), $html)
 169            ->remove(FORMS_SELECTOR())
 170            ->render($self);
 171 }
 172
 173 sub action_delete {
 174   my ($self) = @_;
 175
 176   my $order  = $self->rs_order->order;
 177
 178   $order->delete;
 179   $self->init_requirement_spec;
 180
 181   my $html = $self->render('requirement_spec_order/list', { output => 0 });
 182   $self->js->replaceWith(LIST_SELECTOR(), $html)
 183            ->flash('info', $order->quotation ? t8('Sales quotation #1 has been deleted.', $order->quonumber) : t8('Sales order #1 has been deleted.', $order->ordnumber))
 184            ->render($self);
 185 }
 186
 187 #
 188 # filters
 189 #
 190
 191 sub setup {
 192   my ($self) = @_;
 193
 194   $::auth->assert('requirement_spec_edit');
 195   $::request->{layout}->use_stylesheet("${_}.css") for qw(jquery.contextMenu requirement_spec autocomplete_part);
 196   $::request->{layout}->use_javascript("${_}.js")  for qw(jquery.jstree jquery/jquery.contextMenu client_js requirement_spec);
 197
 198   return 1;
 199 }
 200
 201 sub init_requirement_spec {
 202   my ($self) = @_;
 203   $self->requirement_spec(SL::DB::RequirementSpec->new(id => $::form->{requirement_spec_id})->load) if $::form->{requirement_spec_id};
 204 }
 205
 206 sub init_js {
 207   my ($self) = @_;
 208   $self->js(SL::ClientJS->new);
 209 }
 210
 211 sub init_all_customers { SL::DB::Manager::Customer->get_all_sorted }
 212 sub init_h_unit_name   { first { SL::DB::Manager::Unit->find_by(name => $_) } qw(Std h Stunde) };
 213 sub init_rs_order      { SL::DB::RequirementSpecOrder->new(id => $::form->{rs_order_id})->load };
 214
 215 sub init_all_parts_time_unit {
 216   my ($self) = @_;
 217
 218   return [] unless $self->h_unit_name;
 219
 220   my @convertible_unit_names = map { $_->name } @{ SL::DB::Manager::Unit->find_by(name => $self->h_unit_name)->convertible_units };
 221
 222   return SL::DB::Manager::Part->get_all_sorted(where => [ unit => \@convertible_unit_names ]);
 223 }
 224
 225 #
 226 # helpers
 227 #
 228
 229 sub do_update_sections {
 230   my ($self)           = @_;
 231
 232   my $order            = $self->rs_order->order;
 233   my $sections         = $self->requirement_spec->sections_sorted;
 234   my %orderitems_by_id = map { ($_->id => $_) } @{ $order->orderitems };
 235   my %sections_by_id   = map { ($_->id => $_) } @{ $sections };
 236   $self->{parts}       = { map { ($_->id => $_) } @{ SL::DB::Manager::Part->get_all(where => [ id => [ uniq map { $_->order_part_id } @{ $sections } ] ]) } };
 237   my $language_id      = $self->requirement_spec->customer->language_id;
 238
 239   my %sections_seen;
 240
 241   foreach my $attributes (@{ $::form->{orderitems} || [] }) {
 242     my $orderitem = $orderitems_by_id{ $attributes->{id}         };
 243     my $section   = $sections_by_id{   $attributes->{section_id} };
 244     next unless $orderitem && $section;
 245
 246     $self->create_order_item(section => $section, item => $orderitem, language_id => $language_id)->save;
 247     $sections_seen{ $section->id } = 1;
 248   }
 249
 250   my @new_orderitems = map  { $self->create_order_item(section => $_, language_id => $language_id) }
 251                        grep { !$sections_seen{ $_->id } }
 252                        @{ $sections };
 253
 254   return @new_orderitems;
 255 }
 256
 257 sub do_update_additional_parts {
 258   my ($self)        = @_;
 259
 260   my $order         = $self->rs_order->order;
 261   my $add_parts     = $self->requirement_spec->parts_sorted;
 262   my %orderitems_by = map { (($_->parts_id . '-' . $_->description) => $_) } @{ $order->items };
 263   $self->{parts}    = { map { ($_->id => $_) } @{ SL::DB::Manager::Part->get_all(where => [ id => [ uniq map { $_->part_id } @{ $add_parts } ] ]) } };
 264   my $language_id   = $self->requirement_spec->customer->language_id;
 265
 266   my %add_part_seen;
 267   my @new_orderitems;
 268
 269   foreach my $add_part (@{ $add_parts }) {
 270     my $key       = $add_part->part_id . '-' . $add_part->description;
 271     my $orderitem = $orderitems_by{$key};
 272
 273     if ($orderitem) {
 274       $self->create_additional_part_order_item(additional_part => $add_part, item => $orderitem, language_id => $language_id)->save;
 275
 276     } else {
 277       push @new_orderitems, $self->create_additional_part_order_item(additional_part => $add_part, language_id => $language_id);
 278     }
 279   }
 280
 281   return @new_orderitems;
 282 }
 283
 284 sub create_order_item {
 285   my ($self, %params) = @_;
 286
 287   my $section         = $params{section};
 288   my $item            = $params{item} || SL::DB::OrderItem->new;
 289   my $part            = $self->parts->{ $section->order_part_id };
 290   my $translation     = $params{language_id} ? first { $params{language_id} == $_->language_id } @{ $part->translations } : {};
 291   my $description     = $section->{keep_description} ? $item->description : ($translation->{translation} || $part->description);
 292   my $longdescription = $translation->{longdescription} || $part->notes;
 293
 294   if (!$section->{keep_description}) {
 295     $description     = '<%fb_number%> <%title%>' unless $description =~ m{<%};
 296     $longdescription = '&lt;%description%&gt;'   unless $longdescription =~ m{&lt;%};
 297
 298     $description     =~ s{<% (.+?) %>}{ $section->can($1) ? $section->$1 : '<' . t8('Invalid variable #1', $1) . '>' }egx;
 299     $longdescription =~ s{\&lt;\% description \%\&gt;}{!!!!DESCRIPTION!!!!}gx;
 300     $longdescription =~ s{<[pP]> !!!!DESCRIPTION!!!! </[pP]>}{!!!!DESCRIPTION!!!!}gx;
 301     $longdescription =~ s{\&lt;\% (.+?) \%\&gt;}{ $section->can($1) ? $::locale->quote_special_chars('HTML', $section->$1 // '') : '<' . t8('Invalid variable #1', $1) . '>' }egx;
 302     $longdescription =~ s{!!!!DESCRIPTION!!!!}{ $section->description // '' }egx;
 303   }
 304
 305   $item->assign_attributes(
 306     parts_id        => $part->id,
 307     description     => $description,
 308     longdescription => $longdescription,
 309     qty             => $section->time_estimation * 1,
 310     unit            => $self->h_unit_name,
 311     sellprice       => $::form->round_amount($self->requirement_spec->hourly_rate, 2),
 312     lastcost        => $part->lastcost,
 313     discount        => 0,
 314     project_id      => $self->requirement_spec->project_id,
 315   );
 316
 317   return $item;
 318 }
 319
 320 sub create_additional_part_order_item {
 321   my ($self, %params) = @_;
 322
 323   my $add_part        = $params{additional_part};
 324   my $item            = $params{item} || SL::DB::OrderItem->new;
 325   my $part            = $self->parts->{ $add_part->part_id };
 326   my $translation     = $params{language_id} ? first { $params{language_id} == $_->language_id } @{ $part->translations } : {};
 327   my $description     = $item->description              || $add_part->description;
 328   my $longdescription = $translation->{longdescription} || $part->notes;
 329
 330   $item->assign_attributes(
 331     parts_id        => $part->id,
 332     description     => $description,
 333     longdescription => $longdescription,
 334     qty             => $add_part->qty,
 335     unit            => $add_part->unit->name,
 336     sellprice       => $add_part->unit->convert_to($part->sellprice, $part->unit_obj),
 337     lastcost        => $part->lastcost,
 338     discount        => 0,
 339     project_id      => $self->requirement_spec->project_id,
 340   );
 341
 342   return $item;
 343 }
 344
 345 sub create_order {
 346   my ($self, %params) = @_;
 347
 348   my @part_ids = (
 349     map({ $_->{order_part_id} } @{ $params{sections} }),
 350     map({ $_->part_id         } @{ $params{additional_parts} }),
 351   );
 352   $self->{parts} = { map { ($_->{id} => $_) } @{ SL::DB::Manager::Part->get_all(where => [ id => [ uniq @part_ids ] ]) } };
 353
 354   my $customer   = SL::DB::Customer->new(id => $::form->{customer_id})->load;
 355   my @orderitems = map { $self->create_order_item(                section => $_,         language_id => $customer->language_id) } @{ $params{sections} };
 356   my @add_items  = map { $self->create_additional_part_order_item(additional_part => $_, language_id => $customer->language_id) } @{ $params{additional_parts} };
 357   my $employee   = SL::DB::Manager::Employee->current;
 358   my $order      = SL::DB::Order->new(
 359     globalproject_id        => $self->requirement_spec->project_id,
 360     transdate               => DateTime->today_local,
 361     reqdate                 => $::form->{quotation} && $customer->payment_id ? $customer->payment->calc_date : undef,
 362     quotation               => !!$::form->{quotation},
 363     orderitems              => [ @orderitems, @add_items ],
 364     customer_id             => $customer->id,
 365     taxincluded             => $customer->taxincluded,
 366     intnotes                => $customer->notes,
 367     language_id             => $customer->language_id,
 368     payment_id              => $customer->payment_id,
 369     taxzone_id              => $customer->taxzone_id,
 370     employee_id             => $employee->id,
 371     salesman_id             => $employee->id,
 372     transaction_description => $self->requirement_spec->displayable_name,
 373     currency_id             => $::instance_conf->get_currency_id,
 374   );
 375
 376   $order->calculate_prices_and_taxes;
 377
 378   return $order;
 379 }
 380
 381 1;