SL/Controller/RequirementSpecOrder.pm

   1 package SL::Controller::RequirementSpecOrder;
   2
   3 use strict;
   4 use utf8;
   5
   6 use parent qw(SL::Controller::Base);
   7
   8 use List::MoreUtils qw(uniq);
   9 use List::Util qw(first);
  10
  11 use SL::ClientJS;
  12 use SL::DB::Customer;
  13 use SL::DB::Order;
  14 use SL::DB::Part;
  15 use SL::DB::RequirementSpec;
  16 use SL::DB::RequirementSpecOrder;
  17 use SL::Helper::Flash;
  18 use SL::Locale::String;
  19
  20 use constant TAB_ID => 'ui-tabs-4';
  21
  22 use Rose::Object::MakeMethods::Generic
  23 (
  24   scalar                  => [ qw(parts) ],
  25   'scalar --get_set_init' => [ qw(requirement_spec rs_order js h_unit_name all_customers all_parts_time_unit) ],
  26 );
  27
  28 __PACKAGE__->run_before('setup');
  29
  30 #
  31 # actions
  32 #
  33
  34 sub action_list {
  35   my ($self) = @_;
  36
  37   $self->render('requirement_spec_order/list', { layout => 0 });
  38 }
  39
  40 sub action_new {
  41   my ($self) = @_;
  42
  43   if (!@{ $self->all_parts_time_unit }) {
  44     return $self->js->flash('error', t8('This function requires the presence of articles with a time-based unit such as "h" or "min".'))->render($self);
  45   }
  46
  47   my $html   = $self->render('requirement_spec_order/new', { output => 0 }, make_part_title => sub { $_[0]->partnumber . ' ' . $_[0]->description });
  48   $self->js->html('#' . TAB_ID(), $html)
  49            ->render($self);
  50 }
  51
  52 sub action_create {
  53   my ($self)         = @_;
  54
  55   # 1. Update sections with selected part IDs.
  56   my $section_attrs  = $::form->{sections} || [];
  57   my $sections       = SL::DB::Manager::RequirementSpecItem->get_all(where => [ id => [ map { $_->{id} } @{ $section_attrs } ] ]);
  58   my %sections_by_id = map { ($_->{id} => $_) } @{ $sections };
  59
  60   $sections_by_id{ $_->{id} }->update_attributes(order_part_id => $_->{order_part_id}) for @{ $section_attrs };
  61
  62   # 2. Create actual quotation/order.
  63   my $order = $self->create_order(sections => $sections);
  64   $order->save;
  65
  66   $self->requirement_spec->orders(
  67     @{ $self->requirement_spec->orders },
  68     SL::DB::RequirementSpecOrder->new(order => $order, version => $self->requirement_spec->version)
  69   );
  70   $self->requirement_spec->save;
  71   $self->init_requirement_spec;
  72
  73   # 3. Notify the user and return to list.
  74   my $html = $self->render('requirement_spec_order/list', { output => 0 });
  75   $self->js->html('#' . TAB_ID(), $html)
  76            ->flash('info', $::form->{quotation} ? t8('Sales quotation #1 has been created.', $order->quonumber) : t8('Sales order #1 has been created.', $order->ordnumber))
  77            ->render($self);
  78 }
  79
  80 sub action_update {
  81   my ($self)   = @_;
  82
  83   my $order    = $self->rs_order->order;
  84   my $sections = $self->requirement_spec->sections_sorted;
  85
  86   my (@orderitems, %sections_seen);
  87   foreach my $item (@{ $order->items_sorted }) {
  88     my $section = first { my $num = $_->fb_number; $item->description =~ m{\b\Q${num}\E\b} && !$sections_seen{ $_->id } } @{ $sections };
  89
  90     $sections_seen{ $section->id } = 1 if $section;
  91
  92     push @orderitems, { item => $item, section => $section };
  93   }
  94
  95   my $html = $self->render(
  96     'requirement_spec_order/update', { output => 0 },
  97     orderitems         => \@orderitems,
  98     sections           => $sections,
  99     make_section_title => sub { $_[0]->fb_number . ' ' . $_[0]->title },
 100   );
 101
 102   $self->js->html('#' . TAB_ID(), $html)
 103            ->render($self);
 104 }
 105
 106 sub action_do_update {
 107   my ($self)           = @_;
 108
 109   my $order            = $self->rs_order->order;
 110   my $sections         = $self->requirement_spec->sections_sorted;
 111   my %orderitems_by_id = map { ($_->id => $_) } @{ $order->orderitems };
 112   my %sections_by_id   = map { ($_->id => $_) } @{ $sections };
 113   $self->{parts}       = { map { ($_->id => $_) } @{ SL::DB::Manager::Part->get_all(where => [ id => [ uniq map { $_->order_part_id } @{ $sections } ] ]) } };
 114
 115   my %sections_seen;
 116
 117   foreach my $attributes (@{ $::form->{orderitems} || [] }) {
 118     my $orderitem = $orderitems_by_id{ $attributes->{id}         };
 119     my $section   = $sections_by_id{   $attributes->{section_id} };
 120     next unless $orderitem && $section;
 121
 122     $self->create_order_item(section => $section, item => $orderitem)->save;
 123     $sections_seen{ $section->id } = 1;
 124   }
 125
 126   my @new_orderitems = map  { $self->create_order_item(section => $_) }
 127                        grep { !$sections_seen{ $_->id } }
 128                        @{ $sections };
 129
 130   $order->orderitems([ @{ $order->orderitems }, @new_orderitems ]) if @new_orderitems;
 131
 132   $order->calculate_prices_and_taxes;
 133   $order->save;
 134
 135   $self->init_requirement_spec;
 136
 137   my $html = $self->render('requirement_spec_order/list', { output => 0 });
 138   $self->js->html('#' . TAB_ID(), $html)
 139            ->flash('info', $::form->{quotation} ? t8('Sales quotation #1 has been updated.', $order->quonumber) : t8('Sales order #1 has been updated.', $order->ordnumber))
 140            ->render($self);
 141 }
 142
 143 sub action_edit_assignment {
 144   my ($self) = @_;
 145
 146   if (!@{ $self->all_parts_time_unit }) {
 147     return $self->js->flash('error', t8('This function requires the presence of articles with a time-based unit such as "h" or "min".'))->render($self);
 148   }
 149
 150   my $html   = $self->render('requirement_spec_order/edit_assignment', { output => 0 }, make_part_title => sub { $_[0]->partnumber . ' ' . $_[0]->description });
 151   $self->js->html('#' . TAB_ID(), $html)
 152            ->render($self);
 153 }
 154
 155 sub action_save_assignment {
 156   my ($self)   = @_;
 157   my $sections = $::form->{sections} || [];
 158   SL::DB::RequirementSpecItem->new(id => $_->{id})->load->update_attributes(order_part_id => ($_->{order_part_id} || undef)) for @{ $sections };
 159
 160   my $html = $self->render('requirement_spec_order/list', { output => 0 });
 161   $self->js->html('#' . TAB_ID(), $html)
 162            ->render($self);
 163 }
 164
 165 sub action_delete {
 166   my ($self) = @_;
 167
 168   my $order  = $self->rs_order->order;
 169
 170   $order->delete;
 171   $self->init_requirement_spec;
 172
 173   my $html = $self->render('requirement_spec_order/list', { output => 0 });
 174   $self->js->html('#' . TAB_ID(), $html)
 175            ->flash('info', $order->quotation ? t8('Sales quotation #1 has been deleted.', $order->quonumber) : t8('Sales order #1 has been deleted.', $order->ordnumber))
 176            ->render($self);
 177 }
 178
 179 sub action_cancel {
 180   my ($self) = @_;
 181
 182   my $html = $self->render('requirement_spec_order/list', { output => 0 });
 183   $self->js->html('#' . TAB_ID(), $html)
 184            ->render($self);
 185 }
 186
 187 #
 188 # filters
 189 #
 190
 191 sub setup {
 192   my ($self) = @_;
 193
 194   $::auth->assert('sales_quotation_edit');
 195   $::request->{layout}->use_stylesheet("${_}.css") for qw(jquery.contextMenu requirement_spec autocomplete_part);
 196   $::request->{layout}->use_javascript("${_}.js")  for qw(jquery.jstree jquery/jquery.contextMenu client_js requirement_spec);
 197
 198   return 1;
 199 }
 200
 201 sub init_requirement_spec {
 202   my ($self) = @_;
 203   $self->requirement_spec(SL::DB::RequirementSpec->new(id => $::form->{requirement_spec_id})->load) if $::form->{requirement_spec_id};
 204 }
 205
 206 sub init_js {
 207   my ($self) = @_;
 208   $self->js(SL::ClientJS->new);
 209 }
 210
 211 sub init_all_customers { SL::DB::Manager::Customer->get_all_sorted }
 212 sub init_h_unit_name   { first { SL::DB::Manager::Unit->find_by(name => $_) } qw(Std h Stunde) };
 213 sub init_rs_order      { SL::DB::RequirementSpecOrder->new(id => $::form->{rs_order_id})->load };
 214
 215 sub init_all_parts_time_unit {
 216   my ($self) = @_;
 217
 218   return [] unless $self->h_unit_name;
 219
 220   my @convertible_unit_names = map { $_->name } @{ SL::DB::Manager::Unit->find_by(name => $self->h_unit_name)->convertible_units };
 221
 222   return SL::DB::Manager::Part->get_all_sorted(where => [ unit => \@convertible_unit_names ]);
 223 }
 224
 225 #
 226 # helpers
 227 #
 228
 229 sub load_parts_for_sections {
 230   my ($self, %params) = @_;
 231
 232 }
 233
 234 sub create_order_item {
 235   my ($self, %params) = @_;
 236
 237   my $section         = $params{section};
 238   my $item            = $params{item} || SL::DB::OrderItem->new;
 239   my $part            = $self->parts->{ $section->order_part_id };
 240   my $description     = $section->{keep_description} ? $item->description : $part->description;
 241
 242   if (!$section->{keep_description}) {
 243     $description =  '<%fb_number%> <%title%>' unless $description =~ m{<%};
 244     $description =~ s{<% (.+?) %>}{$section->$1}egx;
 245   }
 246
 247   $item->assign_attributes(
 248     parts_id    => $part->id,
 249     description => $description,
 250     qty         => $section->time_estimation * 1,
 251     unit        => $self->h_unit_name,
 252     sellprice   => $::form->round_amount($self->requirement_spec->hourly_rate, 2),
 253     lastcost    => $part->lastcost,
 254     discount    => 0,
 255     project_id  => $self->requirement_spec->project_id,
 256   );
 257
 258   return $item;
 259 }
 260
 261 sub create_order {
 262   my ($self, %params) = @_;
 263
 264   $self->{parts} = { map { ($_->{id} => $_) } @{ SL::DB::Manager::Part->get_all(where => [ id => [ uniq map { $_->{order_part_id} } @{ $params{sections} } ] ]) } };
 265
 266   my @orderitems = map { $self->create_order_item(section => $_) } @{ $params{sections} };
 267   my $employee   = SL::DB::Manager::Employee->current;
 268   my $customer   = SL::DB::Customer->new(id => $::form->{customer_id})->load;
 269   my $order      = SL::DB::Order->new(
 270     globalproject_id        => $self->requirement_spec->project_id,
 271     transdate               => DateTime->today_local,
 272     reqdate                 => $::form->{quotation} && $customer->payment_id ? $customer->payment->calc_date : undef,
 273     quotation               => !!$::form->{quotation},
 274     orderitems              => \@orderitems,
 275     customer_id             => $customer->id,
 276     taxincluded             => $customer->taxincluded,
 277     intnotes                => $customer->notes,
 278     language_id             => $customer->language_id,
 279     payment_id              => $customer->payment_id,
 280     taxzone_id              => $customer->taxzone_id,
 281     employee_id             => $employee->id,
 282     salesman_id             => $employee->id,
 283     transaction_description => $self->requirement_spec->displayable_name,
 284     currency_id             => $::instance_conf->get_currency_id,
 285   );
 286
 287   $order->calculate_prices_and_taxes;
 288
 289   return $order;
 290 }
 291
 292 1;