SL/Controller/RequirementSpecOrder.pm

   1 package SL::Controller::RequirementSpecOrder;
   2
   3 use strict;
   4 use utf8;
   5
   6 use parent qw(SL::Controller::Base);
   7
   8 use List::MoreUtils qw(uniq);
   9 use List::Util qw(first);
  10
  11 use SL::ClientJS;
  12 use SL::DB::Customer;
  13 use SL::DB::Order;
  14 use SL::DB::Part;
  15 use SL::DB::RequirementSpec;
  16 use SL::DB::RequirementSpecOrder;
  17 use SL::Helper::Flash;
  18 use SL::Locale::String;
  19
  20 use constant TAB_ID => 'ui-tabs-4';
  21
  22 use Rose::Object::MakeMethods::Generic
  23 (
  24   scalar                  => [ qw(parts) ],
  25   'scalar --get_set_init' => [ qw(requirement_spec rs_order js h_unit_name all_customers all_parts) ],
  26 );
  27
  28 __PACKAGE__->run_before('setup');
  29
  30 #
  31 # actions
  32 #
  33
  34 sub action_list {
  35   my ($self) = @_;
  36
  37   $self->render('requirement_spec_order/list', { layout => 0 });
  38 }
  39
  40 sub action_new {
  41   my ($self) = @_;
  42
  43   my $html   = $self->render('requirement_spec_order/new', { output => 0 }, make_part_title => sub { $_[0]->partnumber . ' ' . $_[0]->description });
  44   $self->js->html('#' . TAB_ID(), $html)
  45            ->render($self);
  46 }
  47
  48 sub action_create {
  49   my ($self)         = @_;
  50
  51   # 1. Update sections with selected part IDs.
  52   my $section_attrs  = $::form->{sections} || [];
  53   my $sections       = SL::DB::Manager::RequirementSpecItem->get_all(where => [ id => [ map { $_->{id} } @{ $section_attrs } ] ]);
  54   my %sections_by_id = map { ($_->{id} => $_) } @{ $sections };
  55
  56   $sections_by_id{ $_->{id} }->update_attributes(order_part_id => $_->{order_part_id}) for @{ $section_attrs };
  57
  58   # 2. Create actual quotation/order.
  59   my $order = $self->create_order(sections => $sections);
  60   $order->save;
  61
  62   $self->requirement_spec->orders(
  63     @{ $self->requirement_spec->orders },
  64     SL::DB::RequirementSpecOrder->new(order => $order, version => $self->requirement_spec->version)
  65   );
  66   $self->requirement_spec->save;
  67   $self->init_requirement_spec;
  68
  69   # 3. Notify the user and return to list.
  70   my $html = $self->render('requirement_spec_order/list', { output => 0 });
  71   $self->js->html('#' . TAB_ID(), $html)
  72            ->flash('info', $::form->{quotation} ? t8('Sales quotation #1 has been created.', $order->quonumber) : t8('Sales order #1 has been created.', $order->ordnumber))
  73            ->render($self);
  74 }
  75
  76 sub action_update {
  77   my ($self)   = @_;
  78
  79   my $order    = $self->rs_order->order;
  80   my $sections = $self->requirement_spec->sections_sorted;
  81
  82   my (@orderitems, %sections_seen);
  83   foreach my $item (@{ $order->items_sorted }) {
  84     my $section = first { my $num = $_->fb_number; $item->description =~ m{\b\Q${num}\E\b} && !$sections_seen{ $_->id } } @{ $sections };
  85
  86     $sections_seen{ $section->id } = 1 if $section;
  87
  88     push @orderitems, { item => $item, section => $section };
  89   }
  90
  91   my $html = $self->render(
  92     'requirement_spec_order/update', { output => 0 },
  93     orderitems         => \@orderitems,
  94     sections           => $sections,
  95     make_section_title => sub { $_[0]->fb_number . ' ' . $_[0]->title },
  96   );
  97
  98   $self->js->html('#' . TAB_ID(), $html)
  99            ->render($self);
 100 }
 101
 102 sub action_do_update {
 103   my ($self)           = @_;
 104
 105   my $order            = $self->rs_order->order;
 106   my $sections         = $self->requirement_spec->sections_sorted;
 107   my %orderitems_by_id = map { ($_->id => $_) } @{ $order->orderitems };
 108   my %sections_by_id   = map { ($_->id => $_) } @{ $sections };
 109   $self->{parts}       = { map { ($_->id => $_) } @{ SL::DB::Manager::Part->get_all(where => [ id => [ uniq map { $_->order_part_id } @{ $sections } ] ]) } };
 110
 111   my %sections_seen;
 112
 113   foreach my $attributes (@{ $::form->{orderitems} || [] }) {
 114     my $orderitem = $orderitems_by_id{ $attributes->{id}         };
 115     my $section   = $sections_by_id{   $attributes->{section_id} };
 116     next unless $orderitem && $section;
 117
 118     $self->create_order_item(section => $section, item => $orderitem)->save;
 119     $sections_seen{ $section->id } = 1;
 120   }
 121
 122   my @new_orderitems = map  { $self->create_order_item(section => $_) }
 123                        grep { !$sections_seen{ $_->id } }
 124                        @{ $sections };
 125
 126   $order->orderitems([ @{ $order->orderitems }, @new_orderitems ]) if @new_orderitems;
 127
 128   $order->calculate_prices_and_taxes;
 129   $order->save;
 130
 131   $self->init_requirement_spec;
 132
 133   my $html = $self->render('requirement_spec_order/list', { output => 0 });
 134   $self->js->html('#' . TAB_ID(), $html)
 135            ->flash('info', $::form->{quotation} ? t8('Sales quotation #1 has been updated.', $order->quonumber) : t8('Sales order #1 has been updated.', $order->ordnumber))
 136            ->render($self);
 137 }
 138
 139 sub action_edit_assignment {
 140   my ($self) = @_;
 141
 142   my $html   = $self->render('requirement_spec_order/edit_assignment', { output => 0 }, make_part_title => sub { $_[0]->partnumber . ' ' . $_[0]->description });
 143   $self->js->html('#' . TAB_ID(), $html)
 144            ->render($self);
 145 }
 146
 147 sub action_save_assignment {
 148   my ($self)   = @_;
 149   my $sections = $::form->{sections} || [];
 150   SL::DB::RequirementSpecItem->new(id => $_->{id})->load->update_attributes(order_part_id => ($_->{order_part_id} || undef)) for @{ $sections };
 151
 152   my $html = $self->render('requirement_spec_order/list', { output => 0 });
 153   $self->js->html('#' . TAB_ID(), $html)
 154            ->render($self);
 155 }
 156
 157 sub action_delete {
 158   my ($self) = @_;
 159
 160   my $order  = $self->rs_order->order;
 161
 162   $order->delete;
 163   $self->init_requirement_spec;
 164
 165   my $html = $self->render('requirement_spec_order/list', { output => 0 });
 166   $self->js->html('#' . TAB_ID(), $html)
 167            ->flash('info', $order->quotation ? t8('Sales quotation #1 has been deleted.', $order->quonumber) : t8('Sales order #1 has been deleted.', $order->ordnumber))
 168            ->render($self);
 169 }
 170
 171 sub action_cancel {
 172   my ($self) = @_;
 173
 174   my $html = $self->render('requirement_spec_order/list', { output => 0 });
 175   $self->js->html('#' . TAB_ID(), $html)
 176            ->render($self);
 177 }
 178
 179 #
 180 # filters
 181 #
 182
 183 sub setup {
 184   my ($self) = @_;
 185
 186   $::auth->assert('sales_quotation_edit');
 187   $::request->{layout}->use_stylesheet("${_}.css") for qw(jquery.contextMenu requirement_spec);
 188   $::request->{layout}->use_javascript("${_}.js")  for qw(jquery.jstree jquery/jquery.contextMenu client_js requirement_spec);
 189
 190   return 1;
 191 }
 192
 193 sub init_requirement_spec {
 194   my ($self) = @_;
 195   $self->requirement_spec(SL::DB::RequirementSpec->new(id => $::form->{requirement_spec_id})->load) if $::form->{requirement_spec_id};
 196 }
 197
 198 sub init_js {
 199   my ($self) = @_;
 200   $self->js(SL::ClientJS->new);
 201 }
 202
 203 sub init_all_customers { SL::DB::Manager::Customer->get_all_sorted }
 204 sub init_all_parts     { SL::DB::Manager::Part->get_all_sorted     }
 205 sub init_h_unit_name   { first { SL::DB::Manager::Unit->find_by(name => $_) } qw(Std h Stunde) };
 206 sub init_rs_order      { SL::DB::RequirementSpecOrder->new(id => $::form->{rs_order_id})->load };
 207
 208 #
 209 # helpers
 210 #
 211
 212 sub load_parts_for_sections {
 213   my ($self, %params) = @_;
 214
 215 }
 216
 217 sub create_order_item {
 218   my ($self, %params) = @_;
 219
 220   my $section         = $params{section};
 221   my $item            = $params{item} || SL::DB::OrderItem->new;
 222   my $part            = $self->parts->{ $section->order_part_id };
 223   my $description     = $section->{keep_description} ? $item->description : $part->description;
 224
 225   if (!$section->{keep_description}) {
 226     $description =  '<%fb_number%> <%title%>' unless $description =~ m{<%};
 227     $description =~ s{<% (.+?) %>}{$section->$1}egx;
 228   }
 229
 230   $item->assign_attributes(
 231     parts_id    => $part->id,
 232     description => $description,
 233     qty         => $section->time_estimation * 1,
 234     unit        => $self->h_unit_name,
 235     sellprice   => $::form->round_amount($self->requirement_spec->hourly_rate, 2),
 236     lastcost    => $part->lastcost,
 237     discount    => 0,
 238     project_id  => $self->requirement_spec->project_id,
 239   );
 240
 241   return $item;
 242 }
 243
 244 sub create_order {
 245   my ($self, %params) = @_;
 246
 247   $self->{parts} = { map { ($_->{id} => $_) } @{ SL::DB::Manager::Part->get_all(where => [ id => [ uniq map { $_->{order_part_id} } @{ $params{sections} } ] ]) } };
 248
 249   my @orderitems = map { $self->create_order_item(section => $_) } @{ $params{sections} };
 250   my $employee   = SL::DB::Manager::Employee->current;
 251   my $customer   = SL::DB::Customer->new(id => $::form->{customer_id})->load;
 252   my $order      = SL::DB::Order->new(
 253     globalproject_id        => $self->requirement_spec->project_id,
 254     transdate               => DateTime->today_local,
 255     reqdate                 => $::form->{quotation} && $customer->payment_id ? $customer->payment->calc_date : undef,
 256     quotation               => !!$::form->{quotation},
 257     orderitems              => \@orderitems,
 258     customer_id             => $customer->id,
 259     taxincluded             => $customer->taxincluded,
 260     intnotes                => $customer->notes,
 261     language_id             => $customer->language_id,
 262     payment_id              => $customer->payment_id,
 263     taxzone_id              => $customer->taxzone_id,
 264     employee_id             => $employee->id,
 265     salesman_id             => $employee->id,
 266     transaction_description => $self->requirement_spec->displayable_name,
 267     currency_id             => $::instance_conf->get_currency_id,
 268   );
 269
 270   $order->calculate_prices_and_taxes;
 271
 272   return $order;
 273 }
 274
 275 1;