SL/Controller/RequirementSpecVersion.pm

   1 package SL::Controller::RequirementSpecVersion;
   2
   3 use strict;
   4
   5 use parent qw(SL::Controller::Base);
   6
   7 use Carp;
   8 use List::MoreUtils qw(any);
   9
  10 use SL::ClientJS;
  11 use SL::DB::Customer;
  12 use SL::DB::Project;
  13 use SL::DB::RequirementSpec;
  14 use SL::DB::RequirementSpecVersion;
  15 use SL::Helper::Flash;
  16 use SL::Locale::String;
  17
  18 use Rose::Object::MakeMethods::Generic
  19 (
  20   'scalar --get_set_init' => [ qw(requirement_spec version js versioned_copies) ],
  21 );
  22
  23 __PACKAGE__->run_before('check_auth');
  24
  25 #
  26 # actions
  27 #
  28
  29 sub action_list {
  30   my ($self, %params) = @_;
  31
  32   $self->render('requirement_spec_version/list', { layout => 0 });
  33 }
  34
  35 sub action_new {
  36   my ($self) = @_;
  37
  38   $self->version(SL::DB::RequirementSpecVersion->new);
  39
  40   my $previous_version = $self->requirement_spec->previous_version;
  41   my %differences      = $self->calculate_differences(current => $self->requirement_spec, previous => $previous_version);
  42
  43   if (!$previous_version) {
  44     $self->version->description(t8('Initial version.'));
  45
  46   } else {
  47     my @lines;
  48
  49     my $fb_diff = $differences{function_blocks};
  50     push @lines, t8('Added sections and function blocks: #1',   $::locale->language_join([ map { $_->fb_number         } @{ $fb_diff->{additions} } ])) if @{ $fb_diff->{additions} };
  51     push @lines, t8('Changed sections and function blocks: #1', $::locale->language_join([ map { $_->fb_number         } @{ $fb_diff->{changes}   } ])) if @{ $fb_diff->{changes}   };
  52     push @lines, t8('Removed sections and function blocks: #1', $::locale->language_join([ map { $_->fb_number         } @{ $fb_diff->{removals}  } ])) if @{ $fb_diff->{removals}  };
  53
  54     my $tb_diff = $differences{text_blocks};
  55     push @lines, t8('Added text blocks: #1',                    $::locale->language_join([ map { '"' . $_->title . '"' } @{ $tb_diff->{additions} } ])) if @{ $tb_diff->{additions} };
  56     push @lines, t8('Changed text blocks: #1',                  $::locale->language_join([ map { '"' . $_->title . '"' } @{ $tb_diff->{changes}   } ])) if @{ $tb_diff->{changes}   };
  57     push @lines, t8('Removed text blocks: #1',                  $::locale->language_join([ map { '"' . $_->title . '"' } @{ $tb_diff->{removals}  } ])) if @{ $tb_diff->{removals}  };
  58
  59     $self->version->description(@lines ? join("\n", @lines) : t8('No changes since previous version.'));
  60   }
  61
  62   $self->render('requirement_spec_version/new', { layout => 0 }, title => t8('Create a new version'));
  63 }
  64
  65 sub action_create {
  66   my ($self, %params) = @_;
  67
  68   my %attributes = %{ delete($::form->{rs_version}) || {} };
  69   my @errors     = SL::DB::RequirementSpecVersion->new(%attributes, version_number => 1)->validate;
  70
  71   return $self->js->error(@errors)->render($self) if @errors;
  72
  73   my $db     = $self->requirement_spec->db;
  74   my @result = $self->version($self->requirement_spec->create_version(%attributes));
  75
  76   if (!@result) {
  77     $::lxdebug->message(LXDebug::WARN(), "Error: " . $db->error);
  78     return $self->js->error($::locale->text('Saving failed. Error message from the database: #1'), $db->error)->render($self);
  79   }
  80
  81   my $html = $self->render('requirement_spec/_version', { output => 0 }, requirement_spec => $self->requirement_spec);
  82
  83   $self->js
  84     ->html('#requirement_spec_version', $html)
  85     ->jqmClose('.jqmWindow')
  86     ->render($self);
  87 }
  88
  89 #
  90 # filters
  91 #
  92
  93 sub check_auth {
  94   my ($self, %params) = @_;
  95   $::auth->assert('sales_quotation_edit');
  96 }
  97
  98 #
  99 # helpers
 100 #
 101
 102 sub init_requirement_spec {
 103   my ($self) = @_;
 104   $self->requirement_spec(SL::DB::RequirementSpec->new(id => $::form->{requirement_spec_id})->load) if $::form->{requirement_spec_id};
 105 }
 106
 107 sub init_version {
 108   my ($self) = @_;
 109   $self->version(SL::DB::RequirementSpecVersion->new(id => $::form->{id})->load) if $::form->{id};
 110 }
 111
 112 sub init_js {
 113   my ($self, %params) = @_;
 114   $self->js(SL::ClientJS->new);
 115 }
 116
 117 sub init_versioned_copies {
 118   my ($self) = @_;
 119   $self->versioned_copies([
 120     sort { $b->mtime <=> $a->mtime } @{ $self->requirement_spec->versioned_copies }
 121   ]);
 122 }
 123
 124 sub has_item_changed {
 125   my ($previous, $current) = @_;
 126   croak "Missing previous/current" if !$previous || !$current;
 127   return any { ($previous->$_ || '') ne ($current->$_ || '') } qw(item_type parent_id fb_number title description complexity_id risk_id time_estimation net_sum);
 128 }
 129
 130 sub has_text_block_changed {
 131   my ($previous, $current) = @_;
 132   croak "Missing previous/current" if !$previous || !$current;
 133   return any { ($previous->$_ || '') ne ($current->$_ || '') } qw(title text);
 134 }
 135
 136 sub compare_items {
 137   return -1 if ($a->item_type eq 'section') && ($b->item_type ne 'section');
 138   return +1 if ($a->item_type ne 'section') && ($b->item_type eq 'section');
 139   return $a->fb_number cmp $b->fb_number;
 140 }
 141
 142 sub calculate_differences {
 143   my ($self, %params) = @_;
 144
 145   my %differences = (
 146     function_blocks => {
 147       additions => [],
 148       changes   => [],
 149       removals  => [],
 150     },
 151     text_blocks => {
 152       additions => [],
 153       changes   => [],
 154       removals  => [],
 155     },
 156   );
 157
 158   return %differences if !$params{previous} || !$params{current};
 159
 160   my @previous_items                         = sort compare_items @{ $params{previous}->items };
 161   my @current_items                          = sort compare_items @{ $params{current}->items  };
 162
 163   my @previous_text_blocks                   = sort { lc $a->title cmp lc $b->title } @{ $params{previous}->text_blocks };
 164   my @current_text_blocks                    = sort { lc $a->title cmp lc $b->title } @{ $params{current}->text_blocks  };
 165
 166   my %previous_items_map                     = map { $_->fb_number => $_ } @previous_items;
 167   my %current_items_map                      = map { $_->fb_number => $_ } @current_items;
 168
 169   my %previous_text_blocks_map               = map { $_->title     => $_ } @previous_text_blocks;
 170   my %current_text_blocks_map                = map { $_->title     => $_ } @current_text_blocks;
 171
 172   $differences{function_blocks}->{additions} = [ grep { !$previous_items_map{ $_->fb_number }                                                                         } @current_items        ];
 173   $differences{function_blocks}->{removals}  = [ grep { !$current_items_map{  $_->fb_number }                                                                         } @previous_items       ];
 174   $differences{function_blocks}->{changes}   = [ grep {  $previous_items_map{ $_->fb_number }       && has_item_changed($previous_items_map{ $_->fb_number }, $_)     } @current_items        ];
 175
 176   $differences{text_blocks}->{additions}     = [ grep { !$previous_text_blocks_map{ $_->title }                                                                       } @current_text_blocks  ];
 177   $differences{text_blocks}->{removals}      = [ grep { !$current_text_blocks_map{  $_->title }                                                                       } @previous_text_blocks ];
 178   $differences{text_blocks}->{changes}       = [ grep {  $previous_text_blocks_map{ $_->title } && has_text_block_changed($previous_text_blocks_map{ $_->title }, $_) } @current_text_blocks  ];
 179
 180   return %differences;
 181 }
 182
 183 1;