SL/Controller/RequirementSpecVersion.pm

   1 package SL::Controller::RequirementSpecVersion;
   2
   3 use strict;
   4
   5 use parent qw(SL::Controller::Base);
   6
   7 use Carp;
   8 use List::MoreUtils qw(any);
   9
  10 use SL::ClientJS;
  11 use SL::DB::Customer;
  12 use SL::DB::Project;
  13 use SL::DB::RequirementSpec;
  14 use SL::DB::RequirementSpecVersion;
  15 use SL::Helper::Flash;
  16 use SL::Locale::String;
  17
  18 use Rose::Object::MakeMethods::Generic
  19 (
  20   'scalar --get_set_init' => [ qw(requirement_spec version js) ],
  21 );
  22
  23 __PACKAGE__->run_before('check_auth');
  24
  25 #
  26 # actions
  27 #
  28
  29 sub action_list {
  30   my ($self, %params) = @_;
  31
  32   $self->render('requirement_spec_version/list', { layout => 0 });
  33 }
  34
  35 sub action_new {
  36   my ($self) = @_;
  37
  38   $self->version(SL::DB::RequirementSpecVersion->new);
  39
  40   my $previous_version = $self->requirement_spec->highest_version;
  41
  42   if (!$previous_version) {
  43     $self->version->description(t8('Initial version.'));
  44
  45   } else {
  46     my %differences = $self->calculate_differences(current => $self->requirement_spec, previous => $previous_version);
  47
  48     my @lines;
  49
  50     my $fb_diff = $differences{function_blocks};
  51     push @lines, t8('Added sections and function blocks: #1',   $::locale->language_join([ map { $_->fb_number         } @{ $fb_diff->{additions} } ])) if @{ $fb_diff->{additions} };
  52     push @lines, t8('Changed sections and function blocks: #1', $::locale->language_join([ map { $_->fb_number         } @{ $fb_diff->{changes}   } ])) if @{ $fb_diff->{changes}   };
  53     push @lines, t8('Removed sections and function blocks: #1', $::locale->language_join([ map { $_->fb_number         } @{ $fb_diff->{removals}  } ])) if @{ $fb_diff->{removals}  };
  54
  55     my $tb_diff = $differences{text_blocks};
  56     push @lines, t8('Added text blocks: #1',                    $::locale->language_join([ map { '"' . $_->title . '"' } @{ $tb_diff->{additions} } ])) if @{ $tb_diff->{additions} };
  57     push @lines, t8('Changed text blocks: #1',                  $::locale->language_join([ map { '"' . $_->title . '"' } @{ $tb_diff->{changes}   } ])) if @{ $tb_diff->{changes}   };
  58     push @lines, t8('Removed text blocks: #1',                  $::locale->language_join([ map { '"' . $_->title . '"' } @{ $tb_diff->{removals}  } ])) if @{ $tb_diff->{removals}  };
  59
  60     $self->version->description(@lines ? join("\n", @lines) : t8('No changes since previous version.'));
  61   }
  62
  63   $self->render('requirement_spec_version/new', { layout => 0 });
  64 }
  65
  66 sub action_create {
  67   my ($self, %params) = @_;
  68
  69   my %attributes = %{ delete($::form->{rs_version}) || {} };
  70   my @errors     = SL::DB::RequirementSpecVersion->new(%attributes, version_number => 1)->validate;
  71
  72   return $self->js->error(@errors)->render($self) if @errors;
  73
  74   my $db     = $self->requirement_spec->db;
  75   my @result = $self->version($self->requirement_spec->create_version(%attributes));
  76
  77   if (!@result) {
  78     $::lxdebug->message(LXDebug::WARN(), "Error: " . $db->error);
  79     return $self->js->error($::locale->text('Saving failed. Error message from the database: #1'), $db->error)->render($self);
  80   }
  81
  82   my $version_info_html = $self->render('requirement_spec/_version',     { output => 0 }, requirement_spec => $self->requirement_spec);
  83   my $version_list_html = $self->render('requirement_spec_version/list', { output => 0 });
  84
  85   $self->js
  86     ->html('#requirement_spec_version', $version_info_html)
  87     ->html('#versioned_copies_list',    $version_list_html)
  88     ->dialog->close('#jqueryui_popup_dialog')
  89     ->render($self);
  90 }
  91
  92 #
  93 # filters
  94 #
  95
  96 sub check_auth {
  97   my ($self, %params) = @_;
  98   $::auth->assert('requirement_spec_edit');
  99 }
 100
 101 #
 102 # helpers
 103 #
 104
 105 sub init_requirement_spec {
 106   my ($self) = @_;
 107   $self->requirement_spec(SL::DB::RequirementSpec->new(id => $::form->{requirement_spec_id})->load) if $::form->{requirement_spec_id};
 108 }
 109
 110 sub init_version {
 111   my ($self) = @_;
 112   $self->version(SL::DB::RequirementSpecVersion->new(id => $::form->{id})->load) if $::form->{id};
 113 }
 114
 115 sub init_js {
 116   my ($self, %params) = @_;
 117   $self->js(SL::ClientJS->new);
 118 }
 119
 120 sub has_item_changed {
 121   my ($previous, $current) = @_;
 122   croak "Missing previous/current" if !$previous || !$current;
 123
 124   return 1 if any { ($previous->$_ || '') ne ($current->$_ || '') } qw(item_type fb_number title description complexity_id risk_id);
 125   return 0 if !$current->parent_id;
 126   return $previous->parent->fb_number ne $current->parent->fb_number;
 127 }
 128
 129 sub has_text_block_changed {
 130   my ($previous, $current) = @_;
 131   croak "Missing previous/current" if !$previous || !$current;
 132   return any { ($previous->$_ || '') ne ($current->$_ || '') } qw(title text);
 133 }
 134
 135 sub compare_items {
 136   return -1 if ($a->item_type eq 'section') && ($b->item_type ne 'section');
 137   return +1 if ($a->item_type ne 'section') && ($b->item_type eq 'section');
 138   return $a->fb_number cmp $b->fb_number;
 139 }
 140
 141 sub calculate_differences {
 142   my ($self, %params) = @_;
 143
 144   my %differences = (
 145     function_blocks => {
 146       additions => [],
 147       changes   => [],
 148       removals  => [],
 149     },
 150     text_blocks => {
 151       additions => [],
 152       changes   => [],
 153       removals  => [],
 154     },
 155   );
 156
 157   return %differences if !$params{previous} || !$params{current};
 158
 159   my @previous_items                         = sort compare_items @{ $params{previous}->items };
 160   my @current_items                          = sort compare_items @{ $params{current}->items  };
 161
 162   my @previous_text_blocks                   = sort { lc $a->title cmp lc $b->title } @{ $params{previous}->text_blocks };
 163   my @current_text_blocks                    = sort { lc $a->title cmp lc $b->title } @{ $params{current}->text_blocks  };
 164
 165   my %previous_items_map                     = map { $_->fb_number => $_ } @previous_items;
 166   my %current_items_map                      = map { $_->fb_number => $_ } @current_items;
 167
 168   my %previous_text_blocks_map               = map { $_->title     => $_ } @previous_text_blocks;
 169   my %current_text_blocks_map                = map { $_->title     => $_ } @current_text_blocks;
 170
 171   $differences{function_blocks}->{additions} = [ grep { !$previous_items_map{ $_->fb_number }                                                                         } @current_items        ];
 172   $differences{function_blocks}->{removals}  = [ grep { !$current_items_map{  $_->fb_number }                                                                         } @previous_items       ];
 173   $differences{function_blocks}->{changes}   = [ grep {  $previous_items_map{ $_->fb_number }       && has_item_changed($previous_items_map{ $_->fb_number }, $_)     } @current_items        ];
 174
 175   $differences{text_blocks}->{additions}     = [ grep { !$previous_text_blocks_map{ $_->title }                                                                       } @current_text_blocks  ];
 176   $differences{text_blocks}->{removals}      = [ grep { !$current_text_blocks_map{  $_->title }                                                                       } @previous_text_blocks ];
 177   $differences{text_blocks}->{changes}       = [ grep {  $previous_text_blocks_map{ $_->title } && has_text_block_changed($previous_text_blocks_map{ $_->title }, $_) } @current_text_blocks  ];
 178
 179   return %differences;
 180 }
 181
 182 1;