SL/Controller/SellPriceInformation.pm

   1 package SL::Controller::SellPriceInformation;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use Clone qw(clone);
   7 use SL::DB::OrderItem;
   8 use SL::Controller::Helper::ParseFilter;
   9 use SL::Controller::Helper::ReportGenerator;
  10
  11 sub action_list {
  12   my ($self) = @_;
  13   $self->{action} = 'list';
  14
  15   my %list_params = (
  16     sort_by  => $::form->{sort_by} || 'reqdate',
  17     sort_dir => $::form->{sort_dir},
  18     filter   => $::form->{filter},
  19     page     => $::form->{page},
  20   );
  21
  22   my $db_args = $self->setup_for_list(%list_params);
  23   $self->{pages} = SL::DB::Manager::OrderItem->paginate(%list_params, args => $db_args, per_page => 5);
  24
  25   my $bottom = $::form->parse_html_template('price_information/report_bottom', { SELF => $self });
  26
  27   $self->prepare_report(
  28     report_generator_options => {
  29       raw_bottom_info_text => $bottom,
  30       controller_class     => 'SellPriceInformation',
  31     },
  32     db_args => $db_args,
  33   );
  34
  35   $self->{orderitems} = SL::DB::Manager::OrderItem->get_all(%$db_args);
  36
  37   $self->list_objects;
  38 }
  39
  40 # private functions
  41
  42 sub setup_for_list {
  43   my ($self, %params) = @_;
  44   $self->{filter} = _pre_parse_filter($params{filter});
  45
  46   my %args = (
  47     parse_filter($self->{filter},
  48       with_objects => [ 'order', 'order.customer', 'part' ],
  49     ),
  50     sort_by => $self->set_sort_params(%params),
  51     page    => $params{page},
  52   );
  53
  54 #  $args{query} = [ @{ $args{query} || [] } ];
  55
  56   return \%args;
  57 }
  58
  59 sub set_sort_params {
  60   my ($self, %params) = @_;
  61   my $sort_str;
  62   ($self->{sort_by}, $self->{sort_dir}, $sort_str) =
  63     SL::DB::Manager::OrderItem->make_sort_string(%params);
  64   return $sort_str;
  65 }
  66
  67 sub prepare_report {
  68   my ($self, %params) = @_;
  69
  70   my $objects  = $params{objects} || [];
  71   my $report = SL::ReportGenerator->new(\%::myconfig, $::form);
  72   $self->{report} = $report;
  73
  74   my @columns  = qw(orddate ordnumber customer ship qty sellprice discount amount);
  75   my @visible  = qw(orddate ordnumber customer ship qty sellprice discount amount);
  76   my @sortable = qw(orddate ordnumber customer          sellprice discount       );
  77
  78   my %column_defs = (
  79     orddate                 => { text => $::locale->text('Date'),
  80                                   sub => sub { $_[0]->order->orddate_as_date }},
  81     ordnumber               => { text => $::locale->text('Number'),
  82                                   sub => sub { $_[0]->order->ordnumber },
  83                              obj_link => sub { $self->link_to($_[0]->order) }},
  84     customer                => { text => $::locale->text('Customer'),
  85                                   sub => sub { $_[0]->order->customer->name },
  86                              obj_link => sub { $self->link_to($_[0]->order->customer) }},
  87     customer                => { text => $::locale->text('Customer'),
  88                                   sub => sub { $_[0]->order->customer->name },
  89                              obj_link => sub { $self->link_to($_[0]->order->customer) }},
  90     ship                    => { text => $::locale->text('Delivered'),
  91                                   sub => sub { $::form->format_amount(\%::myconfig, $_[0]->shipped_qty) . ' ' . $_[0]->unit }},
  92     qty                     => { text => $::locale->text('Qty'),
  93                                   sub => sub { $_[0]->qty_as_number . ' ' . $_[0]->unit }},
  94     sellprice               => { text => $::locale->text('Sell Price'),
  95                                   sub => sub { $_[0]->sellprice_as_number }},
  96     discount                => { text => $::locale->text('Discount'),
  97                                   sub => sub { $_[0]->discount_as_percent . "%" }},
  98     amount                  => { text => $::locale->text('Amount'),
  99                                   sub => sub { $::form->format_amount(\%::myconfig, $_[0]->qty * $_[0]->sellprice * (1 - $_[0]->discount), 2) }},
 100   );
 101
 102   for my $col (@sortable) {
 103     $column_defs{$col}{link} = $self->self_url(
 104       sort_by  => $col,
 105       sort_dir => ($self->{sort_by} eq $col ? 1 - $self->{sort_dir} : $self->{sort_dir}),
 106       page     => $self->{pages}{cur},
 107     );
 108   }
 109
 110   map { $column_defs{$_}->{visible} = 1 } @visible;
 111
 112   $report->set_columns(%column_defs);
 113   $report->set_column_order(@columns);
 114   $report->set_options(allow_pdf_export => 0, allow_csv_export => 0);
 115   $report->set_sort_indicator(%params);
 116   $report->set_export_options(@{ $params{report_generator_export_options} || [] });
 117   $report->set_options(
 118     %{ $params{report_generator_options} || {} },
 119     output_format        => 'HTML',
 120     top_info_text        => $::locale->text('Sales Price Information'),
 121     title                => $::locale->text('Sales Price information'),
 122   );
 123   $report->set_options_from_form;
 124
 125   $self->{report_data} = {
 126     column_defs => \%column_defs,
 127     columns     => \@columns,
 128     visible     => \@visible,
 129     sortable    => \@sortable,
 130   };
 131 }
 132
 133 sub list_objects {
 134   my ($self) = @_;
 135   my $column_defs = $self->{report_data}{column_defs};
 136   for my $obj (@{ $self->{orderitems} || [] }) {
 137     $self->{report}->add_data({
 138       map {
 139         $_ => {
 140           data => $column_defs->{$_}{sub} ? $column_defs->{$_}{sub}->($obj)
 141                 : $obj->can($_)           ? $obj->$_
 142                 :                           $obj->{$_},
 143           link => $column_defs->{$_}{obj_link} ? $column_defs->{$_}{obj_link}->($obj) : '',
 144         },
 145       } @{ $self->{report_data}{columns} || {} }
 146     });
 147   }
 148
 149   return $self->{report}->generate_with_headers;
 150 }
 151
 152 sub link_to {
 153   my ($self, $object, %params) = @_;
 154
 155   return unless $object;
 156   my $action = $params{action} || 'edit';
 157
 158   if ($object->isa('SL::DB::Order')) {
 159     my $type   = $object->type;
 160     my $vc     = $object->is_sales ? 'customer' : 'vendor';
 161     my $id     = $object->id;
 162
 163     return "oe.pl?action=$action&type=$type&vc=$vc&id=$id";
 164   }
 165   if ($object->isa('SL::DB::Customer')) {
 166     my $id     = $object->id;
 167     return "ct.pl?action=$action&id=$id&db=customer";
 168   }
 169 }
 170
 171 sub _pre_parse_filter {
 172   my $filter = clone(shift);
 173
 174   if (  exists $filter->{order}
 175      && exists $filter->{order}{type}) {
 176      push @{ $filter->{and} }, SL::DB::Manager::Order->type_filter(delete $filter->{order}{type}, "order."),
 177   }
 178
 179   return $filter;
 180 }
 181
 182 sub self_url {
 183   my ($self, %params) = @_;
 184   %params = (
 185     action   => $self->{action},
 186     sort_by  => $self->{sort},
 187     sort_dir => $self->{sort_dir},
 188     page     => $self->{pages}{cur},
 189     filter   => $::form->{filter},
 190     %params,
 191   );
 192
 193   return $self->url_for(%params);
 194 }
 195
 196 1;