SL/Controller/SimpleSystemSetting.pm

   1 package SL::Controller::SimpleSystemSetting;
   2
   3 use strict;
   4 use utf8;
   5
   6 use parent qw(SL::Controller::Base);
   7
   8 use SL::Helper::Flash;
   9 use SL::Locale::String;
  10 use SL::DB::Default;
  11 use SL::System::Process;
  12
  13 use Rose::Object::MakeMethods::Generic (
  14   scalar                  => [ qw(type config) ],
  15   'scalar --get_set_init' => [ qw(defaults object all_objects class manager_class list_attributes list_url supports_reordering) ],
  16 );
  17
  18 __PACKAGE__->run_before('check_type_and_auth');
  19 __PACKAGE__->run_before('setup_javascript', only => [ qw(add create edit update delete) ]);
  20
  21 # Make locales.pl happy: $self->render("simple_system_setting/_default_form")
  22
  23 my %supported_types = (
  24   bank_account => {
  25     # Make locales.pl happy: $self->render("simple_system_setting/_bank_account_form")
  26     class  => 'BankAccount',
  27     titles => {
  28       list => t8('Bank accounts'),
  29       add  => t8('Add bank account'),
  30       edit => t8('Edit bank account'),
  31     },
  32     list_attributes => [
  33       { method => 'name',                                      title => t8('Name'), },
  34       { method => 'iban',                                      title => t8('IBAN'), },
  35       { method => 'bank',                                      title => t8('Bank'), },
  36       { method => 'bank_code',                                 title => t8('Bank code'), },
  37       { method => 'bic',                                       title => t8('BIC'), },
  38       { method => 'reconciliation_starting_date_as_date',      title => t8('Date'),    align => 'right' },
  39       { method => 'reconciliation_starting_balance_as_number', title => t8('Balance'), align => 'right' },
  40     ],
  41   },
  42
  43   business => {
  44     # Make locales.pl happy: $self->render("simple_system_setting/_business_form")
  45     class  => 'Business',
  46     titles => {
  47       list => t8('Businesses'),
  48       add  => t8('Add business'),
  49       edit => t8('Edit business'),
  50     },
  51     list_attributes => [
  52       { method => 'description',         title => t8('Description'), },
  53       {                                  title => t8('Discount'), formatter => sub { $_[0]->discount_as_percent . ' %' }, align => 'right' },
  54       { method => 'customernumberinit',  title => t8('Customernumberinit'), },
  55     ],
  56   },
  57
  58   department => {
  59     class  => 'Department',
  60     titles => {
  61       list => t8('Departments'),
  62       add  => t8('Add department'),
  63       edit => t8('Edit department'),
  64     },
  65   },
  66
  67   part_classification => {
  68     # Make locales.pl happy: $self->render("simple_system_setting/_part_classification_form")
  69     class  => 'PartClassification',
  70     titles => {
  71       list => t8('Part classifications'),
  72       add  => t8('Add part classification'),
  73       edit => t8('Edit part classification'),
  74     },
  75     list_attributes => [
  76       { title => t8('Description'),       formatter => sub { t8($_[0]->description) } },
  77       { title => t8('Type abbreviation'), formatter => sub { t8($_[0]->abbreviation) } },
  78       { title => t8('Used for Purchase'), formatter => sub { $_[0]->used_for_purchase ? t8('yes') : t8('no') } },
  79       { title => t8('Used for Sale'),     formatter => sub { $_[0]->used_for_sale     ? t8('yes') : t8('no') } },
  80       { title => t8('Report separately'), formatter => sub { $_[0]->report_separate   ? t8('yes') : t8('no') } },
  81     ],
  82   },
  83
  84   parts_group => {
  85     # Make locales.pl happy: $self->render("simple_system_setting/_parts_group_form")
  86     class  => 'PartsGroup',
  87     titles => {
  88       list => t8('Partsgroups'),
  89       add  => t8('Add partsgroup'),
  90       edit => t8('Edit partsgroup'),
  91     },
  92     list_attributes => [
  93       { method => 'partsgroup', title => t8('Description') },
  94       { method => 'obsolete',   title => t8('Obsolete'), formatter => sub { $_[0]->obsolete ? t8('yes') : t8('no') } },
  95     ],
  96   },
  97
  98   price_factor => {
  99     # Make locales.pl happy: $self->render("simple_system_setting/_price_factor_form")
 100     class  => 'PriceFactor',
 101     titles => {
 102       list => t8('Price Factors'),
 103       add  => t8('Add Price Factor'),
 104       edit => t8('Edit Price Factor'),
 105     },
 106     list_attributes => [
 107       { method => 'description',      title => t8('Description') },
 108       { method => 'factor_as_number', title => t8('Factor'), align => 'right' },
 109     ],
 110   },
 111
 112   pricegroup => {
 113     # Make locales.pl happy: $self->render("simple_system_setting/_pricegroup_form")
 114     class  => 'Pricegroup',
 115     titles => {
 116       list => t8('Pricegroups'),
 117       add  => t8('Add pricegroup'),
 118       edit => t8('Edit pricegroup'),
 119     },
 120     list_attributes => [
 121       { method => 'pricegroup', title => t8('Description') },
 122       { method => 'obsolete',   title => t8('Obsolete'), formatter => sub { $_[0]->obsolete ? t8('yes') : t8('no') } },
 123     ],
 124   },
 125
 126   project_status => {
 127     class  => 'ProjectStatus',
 128     titles => {
 129       list => t8('Project statuses'),
 130       add  => t8('Add project status'),
 131       edit => t8('Edit project status'),
 132     },
 133   },
 134
 135   project_type => {
 136     class  => 'ProjectType',
 137     titles => {
 138       list => t8('Project types'),
 139       add  => t8('Add project type'),
 140       edit => t8('Edit project type'),
 141     },
 142   },
 143
 144   requirement_spec_acceptance_status => {
 145     # Make locales.pl happy: $self->render("simple_system_setting/_requirement_spec_acceptance_status_form")
 146     class  => 'RequirementSpecAcceptanceStatus',
 147     titles => {
 148       list => t8('Acceptance Statuses'),
 149       add  => t8('Add acceptance status'),
 150       edit => t8('Edit acceptance status'),
 151     },
 152     list_attributes => [
 153       { method => 'name',        title => t8('Name') },
 154       { method => 'description', title => t8('Description') },
 155     ],
 156   },
 157
 158   requirement_spec_predefined_text => {
 159     # Make locales.pl happy: $self->render("simple_system_setting/_requirement_spec_predefined_text_form")
 160     class  => 'RequirementSpecPredefinedText',
 161     titles => {
 162       list => t8('Pre-defined Texts'),
 163       add  => t8('Add pre-defined text'),
 164       edit => t8('Edit pre-defined text'),
 165     },
 166     list_attributes => [
 167       { method => 'description', title => t8('Description') },
 168       { method => 'title',       title => t8('Title') },
 169       {                          title => t8('Content'),                 formatter => sub { my $t = $_[0]->text_as_stripped_html; length($t) > 50 ? substr($t, 0, 50) . '…' : $t } },
 170       {                          title => t8('Useable for text blocks'), formatter => sub { $_[0]->useable_for_text_blocks ? t8('yes') : t8('no') } },
 171       {                          title => t8('Useable for sections'),    formatter => sub { $_[0]->useable_for_sections    ? t8('yes') : t8('no') } },
 172     ],
 173   },
 174
 175   requirement_spec_status => {
 176     # Make locales.pl happy: $self->render("simple_system_setting/_requirement_spec_status_form")
 177     class  => 'RequirementSpecStatus',
 178     titles => {
 179       list => t8('Requirement Spec Statuses'),
 180       add  => t8('Add requirement spec status'),
 181       edit => t8('Edit requirement spec status'),
 182     },
 183     list_attributes => [
 184       { method => 'name',        title => t8('Name') },
 185       { method => 'description', title => t8('Description') },
 186     ],
 187   },
 188
 189   requirement_spec_type => {
 190     # Make locales.pl happy: $self->render("simple_system_setting/_requirement_spec_type_form")
 191     class  => 'RequirementSpecType',
 192     titles => {
 193       list => t8('Requirement Spec Types'),
 194       add  => t8('Add requirement spec type'),
 195       edit => t8('Edit requirement spec type'),
 196     },
 197     list_attributes => [
 198       { method => 'description',                  title => t8('Description') },
 199       { method => 'section_number_format',        title => t8('Section number format') },
 200       { method => 'function_block_number_format', title => t8('Function block number format') },
 201     ],
 202   },
 203
 204 );
 205
 206 my @default_list_attributes = (
 207   { method => 'description', title => t8('Description') },
 208 );
 209
 210 #
 211 # actions
 212 #
 213
 214 sub action_list {
 215   my ($self) = @_;
 216
 217   $self->render('simple_system_setting/list', title => $self->config->{titles}->{list});
 218 }
 219
 220 sub action_new {
 221   my ($self) = @_;
 222
 223   $self->object($self->class->new);
 224   $self->render_form(title => $self->config->{titles}->{add});
 225 }
 226
 227 sub action_edit {
 228   my ($self) = @_;
 229
 230   $self->render_form(title => $self->config->{titles}->{edit});
 231 }
 232
 233 sub action_create {
 234   my ($self) = @_;
 235
 236   $self->object($self->class->new);
 237   $self->create_or_update;
 238 }
 239
 240 sub action_update {
 241   my ($self) = @_;
 242
 243   $self->create_or_update;
 244 }
 245
 246 sub action_delete {
 247   my ($self) = @_;
 248
 249   if ($self->object->can('orphaned') && !$self->object->orphaned) {
 250     flash_later('error', t8('The object is in use and cannot be deleted.'));
 251
 252   } elsif ( eval { $self->object->delete; 1; } ) {
 253     flash_later('info',  t8('The object has been deleted.'));
 254
 255   } else {
 256     flash_later('error', t8('The object is in use and cannot be deleted.'));
 257   }
 258
 259   $self->redirect_to($self->list_url);
 260 }
 261
 262 sub action_reorder {
 263   my ($self) = @_;
 264
 265   $self->class->reorder_list(@{ $::form->{object_id} || [] });
 266   $self->render(\'', { type => 'json' });
 267 }
 268
 269 #
 270 # filters
 271 #
 272
 273 sub check_type_and_auth {
 274   my ($self) = @_;
 275
 276   $self->type($::form->{type});
 277   $self->config($supported_types{$self->type}) || die "Unsupported type";
 278
 279   $::auth->assert($self->config->{auth} || 'config');
 280
 281   my $pm = (map { s{::}{/}g; "${_}.pm" } $self->class)[0];
 282   require $pm;
 283
 284   my $setup = "setup_" . $self->type;
 285   $self->$setup if $self->can($setup);
 286
 287   1;
 288 }
 289
 290 sub setup_javascript {
 291   $::request->layout->use_javascript("${_}.js") for qw(ckeditor/ckeditor ckeditor/adapters/jquery);
 292 }
 293
 294 sub init_class               { "SL::DB::"          . $_[0]->config->{class}                  }
 295 sub init_manager_class       { "SL::DB::Manager::" . $_[0]->config->{class}                  }
 296 sub init_object              { $_[0]->class->new(id => $::form->{id})->load                  }
 297 sub init_all_objects         { $_[0]->manager_class->get_all_sorted                          }
 298 sub init_list_url            { $_[0]->url_for(action => 'list', type => $_[0]->type)         }
 299 sub init_supports_reordering { $_[0]->class->new->can('reorder_list')                        }
 300 sub init_defaults            { SL::DB::Default->get                                          }
 301
 302 sub init_list_attributes {
 303   my ($self) = @_;
 304
 305   my $method = "list_attributes_" . $self->type;
 306
 307   return $self->$method if $self->can($method);
 308   return $self->config->{list_attributes} // \@default_list_attributes;
 309 }
 310
 311 #
 312 # helpers
 313 #
 314
 315 sub create_or_update {
 316   my ($self) = @_;
 317   my $is_new = !$self->object->id;
 318
 319   my $params = delete($::form->{object}) || { };
 320
 321   $self->object->assign_attributes(%{ $params });
 322
 323   my @errors;
 324
 325   push @errors, $self->object->validate if $self->object->can('validate');
 326
 327   if (@errors) {
 328     flash('error', @errors);
 329     return $self->render_form(title => $self->config->{titles}->{$is_new ? 'add' : 'edit'});
 330   }
 331
 332   $self->object->save;
 333
 334   flash_later('info', $is_new ? t8('The object has been created.') : t8('The object has been saved.'));
 335
 336   $self->redirect_to($self->list_url);
 337 }
 338
 339 sub render_form {
 340   my ($self, %params) = @_;
 341
 342   my $sub_form_template = SL::System::Process->exe_dir . '/templates/webpages/simple_system_setting/_' . $self->type . '_form.html';
 343
 344   $self->render(
 345     'simple_system_setting/form',
 346     %params,
 347     sub_form_template => (-f $sub_form_template ? $self->type : 'default'),
 348   );
 349 }
 350
 351 #
 352 # type-specific helper functions
 353 #
 354
 355 sub setup_requirement_spec_acceptance_status {
 356   my ($self) = @_;
 357
 358   no warnings 'once';
 359   $self->{valid_names} = \@SL::DB::RequirementSpecAcceptanceStatus::valid_names;
 360 }
 361
 362 sub setup_requirement_spec_status {
 363   my ($self) = @_;
 364
 365   no warnings 'once';
 366   $self->{valid_names} = \@SL::DB::RequirementSpecStatus::valid_names;
 367 }
 368
 369 1;
 370
 371 __END__
 372
 373 =encoding utf-8
 374
 375 =head1 NAME
 376
 377 SL::Controller::SimpleSystemSettings — a common CRUD controller for
 378 various settings in the "System" menu
 379
 380 =head1 AUTHOR
 381
 382 Moritz Bunkus <m.bunkus@linet-services.de>
 383
 384 =cut