SL/Controller/SimpleSystemSetting.pm

   1 package SL::Controller::SimpleSystemSetting;
   2
   3 use strict;
   4 use utf8;
   5
   6 use parent qw(SL::Controller::Base);
   7
   8 use SL::Helper::Flash;
   9 use SL::Locale::String;
  10 use SL::DB::Default;
  11 use SL::System::Process;
  12
  13 use Rose::Object::MakeMethods::Generic (
  14   scalar                  => [ qw(type config) ],
  15   'scalar --get_set_init' => [ qw(defaults object all_objects class manager_class list_attributes list_url supports_reordering) ],
  16 );
  17
  18 __PACKAGE__->run_before('check_type_and_auth');
  19 __PACKAGE__->run_before('setup_javascript', only => [ qw(add create edit update delete) ]);
  20
  21 # Make locales.pl happy: $self->render("simple_system_setting/_default_form")
  22
  23 my %supported_types = (
  24   bank_account => {
  25     # Make locales.pl happy: $self->render("simple_system_setting/_bank_account_form")
  26     class  => 'BankAccount',
  27     titles => {
  28       list => t8('Bank accounts'),
  29       add  => t8('Add bank account'),
  30       edit => t8('Edit bank account'),
  31     },
  32     list_attributes => [
  33       { method => 'name',                                      title => t8('Name'), },
  34       { method => 'iban',                                      title => t8('IBAN'), },
  35       { method => 'bank',                                      title => t8('Bank'), },
  36       { method => 'bank_code',                                 title => t8('Bank code'), },
  37       { method => 'bic',                                       title => t8('BIC'), },
  38       { method => 'reconciliation_starting_date_as_date',      title => t8('Date'),    align => 'right' },
  39       { method => 'reconciliation_starting_balance_as_number', title => t8('Balance'), align => 'right' },
  40     ],
  41   },
  42
  43   business => {
  44     # Make locales.pl happy: $self->render("simple_system_setting/_business_form")
  45     class  => 'Business',
  46     titles => {
  47       list => t8('Businesses'),
  48       add  => t8('Add business'),
  49       edit => t8('Edit business'),
  50     },
  51     list_attributes => [
  52       { method => 'description',         title => t8('Description'), },
  53       {                                  title => t8('Discount'), formatter => sub { $_[0]->discount_as_percent . ' %' }, align => 'right' },
  54       { method => 'customernumberinit',  title => t8('Customernumberinit'), },
  55     ],
  56   },
  57
  58   department => {
  59     class  => 'Department',
  60     titles => {
  61       list => t8('Departments'),
  62       add  => t8('Add department'),
  63       edit => t8('Edit department'),
  64     },
  65   },
  66
  67   part_classification => {
  68     # Make locales.pl happy: $self->render("simple_system_setting/_part_classification_form")
  69     class  => 'PartClassification',
  70     titles => {
  71       list => t8('Part classifications'),
  72       add  => t8('Add part classification'),
  73       edit => t8('Edit part classification'),
  74     },
  75     list_attributes => [
  76       { title => t8('Description'),       formatter => sub { t8($_[0]->description) } },
  77       { title => t8('Type abbreviation'), formatter => sub { t8($_[0]->abbreviation) } },
  78       { title => t8('Used for Purchase'), formatter => sub { $_[0]->used_for_purchase ? t8('yes') : t8('no') } },
  79       { title => t8('Used for Sale'),     formatter => sub { $_[0]->used_for_sale     ? t8('yes') : t8('no') } },
  80       { title => t8('Report separately'), formatter => sub { $_[0]->report_separate   ? t8('yes') : t8('no') } },
  81     ],
  82   },
  83
  84   parts_group => {
  85     # Make locales.pl happy: $self->render("simple_system_setting/_parts_group_form")
  86     class  => 'PartsGroup',
  87     titles => {
  88       list => t8('Partsgroups'),
  89       add  => t8('Add partsgroup'),
  90       edit => t8('Edit partsgroup'),
  91     },
  92     list_attributes => [
  93       { method => 'partsgroup', title => t8('Description') },
  94       { method => 'obsolete',   title => t8('Obsolete'), formatter => sub { $_[0]->obsolete ? t8('yes') : t8('no') } },
  95     ],
  96   },
  97
  98   price_factor => {
  99     # Make locales.pl happy: $self->render("simple_system_setting/_price_factor_form")
 100     class  => 'PriceFactor',
 101     titles => {
 102       list => t8('Price Factors'),
 103       add  => t8('Add Price Factor'),
 104       edit => t8('Edit Price Factor'),
 105     },
 106     list_attributes => [
 107       { method => 'description',      title => t8('Description') },
 108       { method => 'factor_as_number', title => t8('Factor'), align => 'right' },
 109     ],
 110   },
 111
 112   pricegroup => {
 113     # Make locales.pl happy: $self->render("simple_system_setting/_pricegroup_form")
 114     class  => 'Pricegroup',
 115     titles => {
 116       list => t8('Pricegroups'),
 117       add  => t8('Add pricegroup'),
 118       edit => t8('Edit pricegroup'),
 119     },
 120     list_attributes => [
 121       { method => 'pricegroup', title => t8('Description') },
 122       { method => 'obsolete',   title => t8('Obsolete'), formatter => sub { $_[0]->obsolete ? t8('yes') : t8('no') } },
 123     ],
 124   },
 125 );
 126
 127 my @default_list_attributes = (
 128   { method => 'description', title => t8('Description') },
 129 );
 130
 131 #
 132 # actions
 133 #
 134
 135 sub action_list {
 136   my ($self) = @_;
 137
 138   $self->render('simple_system_setting/list', title => $self->config->{titles}->{list});
 139 }
 140
 141 sub action_new {
 142   my ($self) = @_;
 143
 144   $self->object($self->class->new);
 145   $self->render_form(title => $self->config->{titles}->{add});
 146 }
 147
 148 sub action_edit {
 149   my ($self) = @_;
 150
 151   $self->render_form(title => $self->config->{titles}->{edit});
 152 }
 153
 154 sub action_create {
 155   my ($self) = @_;
 156
 157   $self->object($self->class->new);
 158   $self->create_or_update;
 159 }
 160
 161 sub action_update {
 162   my ($self) = @_;
 163
 164   $self->create_or_update;
 165 }
 166
 167 sub action_delete {
 168   my ($self) = @_;
 169
 170   if ($self->object->can('orphaned') && !$self->object->orphaned) {
 171     flash_later('error', t8('The object is in use and cannot be deleted.'));
 172
 173   } elsif ( eval { $self->object->delete; 1; } ) {
 174     flash_later('info',  t8('The object has been deleted.'));
 175
 176   } else {
 177     flash_later('error', t8('The object is in use and cannot be deleted.'));
 178   }
 179
 180   $self->redirect_to($self->list_url);
 181 }
 182
 183 sub action_reorder {
 184   my ($self) = @_;
 185
 186   $self->class->reorder_list(@{ $::form->{object_id} || [] });
 187   $self->render(\'', { type => 'json' });
 188 }
 189
 190 #
 191 # filters
 192 #
 193
 194 sub check_type_and_auth {
 195   my ($self) = @_;
 196
 197   $self->type($::form->{type});
 198   $self->config($supported_types{$self->type}) || die "Unsupported type";
 199
 200   $::auth->assert($self->config->{auth} || 'config');
 201
 202   my $pm = (map { s{::}{/}g; "${_}.pm" } $self->class)[0];
 203   require $pm;
 204
 205   my $setup = "setup_" . $self->type;
 206   $self->$setup if $self->can($setup);
 207
 208   1;
 209 }
 210
 211 sub setup_javascript {
 212   $::request->layout->use_javascript("${_}.js") for qw(ckeditor/ckeditor ckeditor/adapters/jquery);
 213 }
 214
 215 sub init_class               { "SL::DB::"          . $_[0]->config->{class}                  }
 216 sub init_manager_class       { "SL::DB::Manager::" . $_[0]->config->{class}                  }
 217 sub init_object              { $_[0]->class->new(id => $::form->{id})->load                  }
 218 sub init_all_objects         { $_[0]->manager_class->get_all_sorted                          }
 219 sub init_list_url            { $_[0]->url_for(action => 'list', type => $_[0]->type)         }
 220 sub init_supports_reordering { $_[0]->class->new->can('reorder_list')                        }
 221 sub init_defaults            { SL::DB::Default->get                                          }
 222
 223 sub init_list_attributes {
 224   my ($self) = @_;
 225
 226   my $method = "list_attributes_" . $self->type;
 227
 228   return $self->$method if $self->can($method);
 229   return $self->config->{list_attributes} // \@default_list_attributes;
 230 }
 231
 232 #
 233 # helpers
 234 #
 235
 236 sub create_or_update {
 237   my ($self) = @_;
 238   my $is_new = !$self->object->id;
 239
 240   my $params = delete($::form->{object}) || { };
 241
 242   $self->object->assign_attributes(%{ $params });
 243
 244   my @errors;
 245
 246   push @errors, $self->object->validate if $self->object->can('validate');
 247
 248   if (@errors) {
 249     flash('error', @errors);
 250     return $self->render_form(title => $self->config->{titles}->{$is_new ? 'add' : 'edit'});
 251   }
 252
 253   $self->object->save;
 254
 255   flash_later('info', $is_new ? t8('The object has been created.') : t8('The object has been saved.'));
 256
 257   $self->redirect_to($self->list_url);
 258 }
 259
 260 sub render_form {
 261   my ($self, %params) = @_;
 262
 263   my $sub_form_template = SL::System::Process->exe_dir . '/templates/webpages/simple_system_setting/_' . $self->type . '_form.html';
 264
 265   $self->render(
 266     'simple_system_setting/form',
 267     %params,
 268     sub_form_template => (-f $sub_form_template ? $self->type : 'default'),
 269   );
 270 }
 271
 272 #
 273 # type-specific helper functions
 274 #
 275
 276 1;
 277
 278 __END__
 279
 280 =encoding utf-8
 281
 282 =head1 NAME
 283
 284 SL::Controller::SimpleSystemSettings — a common CRUD controller for
 285 various settings in the "System" menu
 286
 287 =head1 AUTHOR
 288
 289 Moritz Bunkus <m.bunkus@linet-services.de>
 290
 291 =cut