SL/Controller/SimpleSystemSetting.pm

   1 package SL::Controller::SimpleSystemSetting;
   2
   3 use strict;
   4 use utf8;
   5
   6 use parent qw(SL::Controller::Base);
   7
   8 use SL::Helper::Flash;
   9 use SL::Locale::String;
  10 use SL::DB::Default;
  11 use SL::System::Process;
  12
  13 use Rose::Object::MakeMethods::Generic (
  14   scalar                  => [ qw(type config) ],
  15   'scalar --get_set_init' => [ qw(defaults object all_objects class manager_class list_attributes list_url supports_reordering) ],
  16 );
  17
  18 __PACKAGE__->run_before('check_type_and_auth');
  19 __PACKAGE__->run_before('setup_javascript', only => [ qw(add create edit update delete) ]);
  20
  21 # Make locales.pl happy: $self->render("simple_system_setting/_default_form")
  22
  23 my %supported_types = (
  24   bank_account => {
  25     # Make locales.pl happy: $self->render("simple_system_setting/_bank_account_form")
  26     class  => 'BankAccount',
  27     titles => {
  28       list => t8('Bank accounts'),
  29       add  => t8('Add bank account'),
  30       edit => t8('Edit bank account'),
  31     },
  32     list_attributes => [
  33       { method => 'name',                                      title => t8('Name'), },
  34       { method => 'iban',                                      title => t8('IBAN'), },
  35       { method => 'bank',                                      title => t8('Bank'), },
  36       { method => 'bank_code',                                 title => t8('Bank code'), },
  37       { method => 'bic',                                       title => t8('BIC'), },
  38       { method => 'reconciliation_starting_date_as_date',      title => t8('Date'),    align => 'right' },
  39       { method => 'reconciliation_starting_balance_as_number', title => t8('Balance'), align => 'right' },
  40     ],
  41   },
  42
  43   business => {
  44     # Make locales.pl happy: $self->render("simple_system_setting/_business_form")
  45     class  => 'Business',
  46     titles => {
  47       list => t8('Businesses'),
  48       add  => t8('Add business'),
  49       edit => t8('Edit business'),
  50     },
  51     list_attributes => [
  52       { method => 'description',         title => t8('Description'), },
  53       {                                  title => t8('Discount'), formatter => sub { $_[0]->discount_as_percent . ' %' }, align => 'right' },
  54       { method => 'customernumberinit',  title => t8('Customernumberinit'), },
  55     ],
  56   },
  57
  58   department => {
  59     class  => 'Department',
  60     titles => {
  61       list => t8('Departments'),
  62       add  => t8('Add department'),
  63       edit => t8('Edit department'),
  64     },
  65   },
  66
  67   part_classification => {
  68     # Make locales.pl happy: $self->render("simple_system_setting/_part_classification_form")
  69     class  => 'PartClassification',
  70     titles => {
  71       list => t8('Part classifications'),
  72       add  => t8('Add part classification'),
  73       edit => t8('Edit part classification'),
  74     },
  75     list_attributes => [
  76       { title => t8('Description'),       formatter => sub { t8($_[0]->description) } },
  77       { title => t8('Type abbreviation'), formatter => sub { t8($_[0]->abbreviation) } },
  78       { title => t8('Used for Purchase'), formatter => sub { $_[0]->used_for_purchase ? t8('yes') : t8('no') } },
  79       { title => t8('Used for Sale'),     formatter => sub { $_[0]->used_for_sale     ? t8('yes') : t8('no') } },
  80       { title => t8('Report separately'), formatter => sub { $_[0]->report_separate   ? t8('yes') : t8('no') } },
  81     ],
  82   },
  83
  84   parts_group => {
  85     # Make locales.pl happy: $self->render("simple_system_setting/_parts_group_form")
  86     class  => 'PartsGroup',
  87     titles => {
  88       list => t8('Partsgroups'),
  89       add  => t8('Add partsgroup'),
  90       edit => t8('Edit partsgroup'),
  91     },
  92     list_attributes => [
  93       { method => 'partsgroup', title => t8('Description') },
  94       { method => 'obsolete',   title => t8('Obsolete'), formatter => sub { $_[0]->obsolete ? t8('yes') : t8('no') } },
  95     ],
  96   },
  97
  98   price_factor => {
  99     # Make locales.pl happy: $self->render("simple_system_setting/_price_factor_form")
 100     class  => 'PriceFactor',
 101     titles => {
 102       list => t8('Price Factors'),
 103       add  => t8('Add Price Factor'),
 104       edit => t8('Edit Price Factor'),
 105     },
 106     list_attributes => [
 107       { method => 'description',      title => t8('Description') },
 108       { method => 'factor_as_number', title => t8('Factor'), align => 'right' },
 109     ],
 110   },
 111
 112   pricegroup => {
 113     # Make locales.pl happy: $self->render("simple_system_setting/_pricegroup_form")
 114     class  => 'Pricegroup',
 115     titles => {
 116       list => t8('Pricegroups'),
 117       add  => t8('Add pricegroup'),
 118       edit => t8('Edit pricegroup'),
 119     },
 120     list_attributes => [
 121       { method => 'pricegroup', title => t8('Description') },
 122       { method => 'obsolete',   title => t8('Obsolete'), formatter => sub { $_[0]->obsolete ? t8('yes') : t8('no') } },
 123     ],
 124   },
 125
 126   project_status => {
 127     class  => 'ProjectStatus',
 128     titles => {
 129       list => t8('Project statuses'),
 130       add  => t8('Add project status'),
 131       edit => t8('Edit project status'),
 132     },
 133   },
 134
 135   project_type => {
 136     class  => 'ProjectType',
 137     titles => {
 138       list => t8('Project types'),
 139       add  => t8('Add project type'),
 140       edit => t8('Edit project type'),
 141     },
 142   },
 143
 144 );
 145
 146 my @default_list_attributes = (
 147   { method => 'description', title => t8('Description') },
 148 );
 149
 150 #
 151 # actions
 152 #
 153
 154 sub action_list {
 155   my ($self) = @_;
 156
 157   $self->render('simple_system_setting/list', title => $self->config->{titles}->{list});
 158 }
 159
 160 sub action_new {
 161   my ($self) = @_;
 162
 163   $self->object($self->class->new);
 164   $self->render_form(title => $self->config->{titles}->{add});
 165 }
 166
 167 sub action_edit {
 168   my ($self) = @_;
 169
 170   $self->render_form(title => $self->config->{titles}->{edit});
 171 }
 172
 173 sub action_create {
 174   my ($self) = @_;
 175
 176   $self->object($self->class->new);
 177   $self->create_or_update;
 178 }
 179
 180 sub action_update {
 181   my ($self) = @_;
 182
 183   $self->create_or_update;
 184 }
 185
 186 sub action_delete {
 187   my ($self) = @_;
 188
 189   if ($self->object->can('orphaned') && !$self->object->orphaned) {
 190     flash_later('error', t8('The object is in use and cannot be deleted.'));
 191
 192   } elsif ( eval { $self->object->delete; 1; } ) {
 193     flash_later('info',  t8('The object has been deleted.'));
 194
 195   } else {
 196     flash_later('error', t8('The object is in use and cannot be deleted.'));
 197   }
 198
 199   $self->redirect_to($self->list_url);
 200 }
 201
 202 sub action_reorder {
 203   my ($self) = @_;
 204
 205   $self->class->reorder_list(@{ $::form->{object_id} || [] });
 206   $self->render(\'', { type => 'json' });
 207 }
 208
 209 #
 210 # filters
 211 #
 212
 213 sub check_type_and_auth {
 214   my ($self) = @_;
 215
 216   $self->type($::form->{type});
 217   $self->config($supported_types{$self->type}) || die "Unsupported type";
 218
 219   $::auth->assert($self->config->{auth} || 'config');
 220
 221   my $pm = (map { s{::}{/}g; "${_}.pm" } $self->class)[0];
 222   require $pm;
 223
 224   my $setup = "setup_" . $self->type;
 225   $self->$setup if $self->can($setup);
 226
 227   1;
 228 }
 229
 230 sub setup_javascript {
 231   $::request->layout->use_javascript("${_}.js") for qw(ckeditor/ckeditor ckeditor/adapters/jquery);
 232 }
 233
 234 sub init_class               { "SL::DB::"          . $_[0]->config->{class}                  }
 235 sub init_manager_class       { "SL::DB::Manager::" . $_[0]->config->{class}                  }
 236 sub init_object              { $_[0]->class->new(id => $::form->{id})->load                  }
 237 sub init_all_objects         { $_[0]->manager_class->get_all_sorted                          }
 238 sub init_list_url            { $_[0]->url_for(action => 'list', type => $_[0]->type)         }
 239 sub init_supports_reordering { $_[0]->class->new->can('reorder_list')                        }
 240 sub init_defaults            { SL::DB::Default->get                                          }
 241
 242 sub init_list_attributes {
 243   my ($self) = @_;
 244
 245   my $method = "list_attributes_" . $self->type;
 246
 247   return $self->$method if $self->can($method);
 248   return $self->config->{list_attributes} // \@default_list_attributes;
 249 }
 250
 251 #
 252 # helpers
 253 #
 254
 255 sub create_or_update {
 256   my ($self) = @_;
 257   my $is_new = !$self->object->id;
 258
 259   my $params = delete($::form->{object}) || { };
 260
 261   $self->object->assign_attributes(%{ $params });
 262
 263   my @errors;
 264
 265   push @errors, $self->object->validate if $self->object->can('validate');
 266
 267   if (@errors) {
 268     flash('error', @errors);
 269     return $self->render_form(title => $self->config->{titles}->{$is_new ? 'add' : 'edit'});
 270   }
 271
 272   $self->object->save;
 273
 274   flash_later('info', $is_new ? t8('The object has been created.') : t8('The object has been saved.'));
 275
 276   $self->redirect_to($self->list_url);
 277 }
 278
 279 sub render_form {
 280   my ($self, %params) = @_;
 281
 282   my $sub_form_template = SL::System::Process->exe_dir . '/templates/webpages/simple_system_setting/_' . $self->type . '_form.html';
 283
 284   $self->render(
 285     'simple_system_setting/form',
 286     %params,
 287     sub_form_template => (-f $sub_form_template ? $self->type : 'default'),
 288   );
 289 }
 290
 291 #
 292 # type-specific helper functions
 293 #
 294
 295 1;
 296
 297 __END__
 298
 299 =encoding utf-8
 300
 301 =head1 NAME
 302
 303 SL::Controller::SimpleSystemSettings — a common CRUD controller for
 304 various settings in the "System" menu
 305
 306 =head1 AUTHOR
 307
 308 Moritz Bunkus <m.bunkus@linet-services.de>
 309
 310 =cut