SL/Controller/SimpleSystemSetting.pm

   1 package SL::Controller::SimpleSystemSetting;
   2
   3 use strict;
   4 use utf8;
   5
   6 use parent qw(SL::Controller::Base);
   7
   8 use SL::Helper::Flash;
   9 use SL::Locale::String;
  10 use SL::DB::Default;
  11 use SL::System::Process;
  12
  13 use Rose::Object::MakeMethods::Generic (
  14   scalar                  => [ qw(type config) ],
  15   'scalar --get_set_init' => [ qw(defaults object all_objects class manager_class list_attributes list_url supports_reordering) ],
  16 );
  17
  18 __PACKAGE__->run_before('check_type_and_auth');
  19 __PACKAGE__->run_before('setup_javascript', only => [ qw(add create edit update delete) ]);
  20
  21 # Make locales.pl happy: $self->render("simple_system_setting/_default_form")
  22
  23 my %supported_types = (
  24   bank_account => {
  25     # Make locales.pl happy: $self->render("simple_system_setting/_bank_account_form")
  26     class  => 'BankAccount',
  27     titles => {
  28       list => t8('Bank accounts'),
  29       add  => t8('Add bank account'),
  30       edit => t8('Edit bank account'),
  31     },
  32     list_attributes => [
  33       { method => 'name',                                      title => t8('Name'), },
  34       { method => 'iban',                                      title => t8('IBAN'), },
  35       { method => 'bank',                                      title => t8('Bank'), },
  36       { method => 'bank_code',                                 title => t8('Bank code'), },
  37       { method => 'bic',                                       title => t8('BIC'), },
  38       { method => 'reconciliation_starting_date_as_date',      title => t8('Date'),    align => 'right' },
  39       { method => 'reconciliation_starting_balance_as_number', title => t8('Balance'), align => 'right' },
  40     ],
  41   },
  42
  43   pricegroup => {
  44     # Make locales.pl happy: $self->render("simple_system_setting/_pricegroup_form")
  45     class  => 'Pricegroup',
  46     titles => {
  47       list => t8('Pricegroups'),
  48       add  => t8('Add pricegroup'),
  49       edit => t8('Edit pricegroup'),
  50     },
  51     list_attributes => [
  52       { method => 'pricegroup', title => t8('Description') },
  53       { method => 'obsolete',   title => t8('Obsolete'), formatter => sub { $_[0]->obsolete ? t8('yes') : t8('no') } },
  54     ],
  55   },
  56 );
  57
  58 my @default_list_attributes = (
  59   { method => 'description', title => t8('Description') },
  60 );
  61
  62 #
  63 # actions
  64 #
  65
  66 sub action_list {
  67   my ($self) = @_;
  68
  69   $self->render('simple_system_setting/list', title => $self->config->{titles}->{list});
  70 }
  71
  72 sub action_new {
  73   my ($self) = @_;
  74
  75   $self->object($self->class->new);
  76   $self->render_form(title => $self->config->{titles}->{add});
  77 }
  78
  79 sub action_edit {
  80   my ($self) = @_;
  81
  82   $self->render_form(title => $self->config->{titles}->{edit});
  83 }
  84
  85 sub action_create {
  86   my ($self) = @_;
  87
  88   $self->object($self->class->new);
  89   $self->create_or_update;
  90 }
  91
  92 sub action_update {
  93   my ($self) = @_;
  94
  95   $self->create_or_update;
  96 }
  97
  98 sub action_delete {
  99   my ($self) = @_;
 100
 101   if ($self->object->can('orphaned') && !$self->object->orphaned) {
 102     flash_later('error', t8('The object is in use and cannot be deleted.'));
 103
 104   } elsif ( eval { $self->object->delete; 1; } ) {
 105     flash_later('info',  t8('The object has been deleted.'));
 106
 107   } else {
 108     flash_later('error', t8('The object is in use and cannot be deleted.'));
 109   }
 110
 111   $self->redirect_to($self->list_url);
 112 }
 113
 114 sub action_reorder {
 115   my ($self) = @_;
 116
 117   $self->class->reorder_list(@{ $::form->{object_id} || [] });
 118   $self->render(\'', { type => 'json' });
 119 }
 120
 121 #
 122 # filters
 123 #
 124
 125 sub check_type_and_auth {
 126   my ($self) = @_;
 127
 128   $self->type($::form->{type});
 129   $self->config($supported_types{$self->type}) || die "Unsupported type";
 130
 131   $::auth->assert($self->config->{auth} || 'config');
 132
 133   my $pm = (map { s{::}{/}g; "${_}.pm" } $self->class)[0];
 134   require $pm;
 135
 136   my $setup = "setup_" . $self->type;
 137   $self->$setup if $self->can($setup);
 138
 139   1;
 140 }
 141
 142 sub setup_javascript {
 143   $::request->layout->use_javascript("${_}.js") for qw(ckeditor/ckeditor ckeditor/adapters/jquery);
 144 }
 145
 146 sub init_class               { "SL::DB::"          . $_[0]->config->{class}                  }
 147 sub init_manager_class       { "SL::DB::Manager::" . $_[0]->config->{class}                  }
 148 sub init_object              { $_[0]->class->new(id => $::form->{id})->load                  }
 149 sub init_all_objects         { $_[0]->manager_class->get_all_sorted                          }
 150 sub init_list_url            { $_[0]->url_for(action => 'list', type => $_[0]->type)         }
 151 sub init_supports_reordering { $_[0]->class->new->can('reorder_list')                        }
 152 sub init_defaults            { SL::DB::Default->get                                          }
 153
 154 sub init_list_attributes {
 155   my ($self) = @_;
 156
 157   my $method = "list_attributes_" . $self->type;
 158
 159   return $self->$method if $self->can($method);
 160   return $self->config->{list_attributes} // \@default_list_attributes;
 161 }
 162
 163 #
 164 # helpers
 165 #
 166
 167 sub create_or_update {
 168   my ($self) = @_;
 169   my $is_new = !$self->object->id;
 170
 171   my $params = delete($::form->{object}) || { };
 172
 173   $self->object->assign_attributes(%{ $params });
 174
 175   my @errors;
 176
 177   push @errors, $self->object->validate if $self->object->can('validate');
 178
 179   if (@errors) {
 180     flash('error', @errors);
 181     return $self->render_form(title => $self->config->{titles}->{$is_new ? 'add' : 'edit'});
 182   }
 183
 184   $self->object->save;
 185
 186   flash_later('info', $is_new ? t8('The object has been created.') : t8('The object has been saved.'));
 187
 188   $self->redirect_to($self->list_url);
 189 }
 190
 191 sub render_form {
 192   my ($self, %params) = @_;
 193
 194   my $sub_form_template = SL::System::Process->exe_dir . '/templates/webpages/simple_system_setting/_' . $self->type . '_form.html';
 195
 196   $self->render(
 197     'simple_system_setting/form',
 198     %params,
 199     sub_form_template => (-f $sub_form_template ? $self->type : 'default'),
 200   );
 201 }
 202
 203 #
 204 # type-specific helper functions
 205 #
 206
 207 1;
 208
 209 __END__
 210
 211 =encoding utf-8
 212
 213 =head1 NAME
 214
 215 SL::Controller::SimpleSystemSettings — a common CRUD controller for
 216 various settings in the "System" menu
 217
 218 =head1 AUTHOR
 219
 220 Moritz Bunkus <m.bunkus@linet-services.de>
 221
 222 =cut