SL/Controller/SimpleSystemSetting.pm

   1 package SL::Controller::SimpleSystemSetting;
   2
   3 use strict;
   4 use utf8;
   5
   6 use parent qw(SL::Controller::Base);
   7
   8 use SL::Helper::Flash;
   9 use SL::Locale::String;
  10 use SL::DB::Default;
  11 use SL::System::Process;
  12
  13 use Rose::Object::MakeMethods::Generic (
  14   scalar                  => [ qw(type config) ],
  15   'scalar --get_set_init' => [ qw(defaults object all_objects class manager_class list_attributes list_url supports_reordering) ],
  16 );
  17
  18 __PACKAGE__->run_before('check_type_and_auth');
  19 __PACKAGE__->run_before('setup_javascript', only => [ qw(add create edit update delete) ]);
  20
  21 # Make locales.pl happy: $self->render("simple_system_setting/_default_form")
  22
  23 my %supported_types = (
  24   bank_account => {
  25     # Make locales.pl happy: $self->render("simple_system_setting/_bank_account_form")
  26     class  => 'BankAccount',
  27     titles => {
  28       list => t8('Bank accounts'),
  29       add  => t8('Add bank account'),
  30       edit => t8('Edit bank account'),
  31     },
  32     list_attributes => [
  33       { method => 'name',                                      title => t8('Name'), },
  34       { method => 'iban',                                      title => t8('IBAN'), },
  35       { method => 'bank',                                      title => t8('Bank'), },
  36       { method => 'bank_code',                                 title => t8('Bank code'), },
  37       { method => 'bic',                                       title => t8('BIC'), },
  38       { method => 'reconciliation_starting_date_as_date',      title => t8('Date'),    align => 'right' },
  39       { method => 'reconciliation_starting_balance_as_number', title => t8('Balance'), align => 'right' },
  40     ],
  41   },
  42
  43   part_classification => {
  44     # Make locales.pl happy: $self->render("simple_system_setting/_part_classification_form")
  45     class  => 'PartClassification',
  46     titles => {
  47       list => t8('Part classifications'),
  48       add  => t8('Add part classification'),
  49       edit => t8('Edit part classification'),
  50     },
  51     list_attributes => [
  52       { title => t8('Description'),       formatter => sub { t8($_[0]->description) } },
  53       { title => t8('Type abbreviation'), formatter => sub { t8($_[0]->abbreviation) } },
  54       { title => t8('Used for Purchase'), formatter => sub { $_[0]->used_for_purchase ? t8('yes') : t8('no') } },
  55       { title => t8('Used for Sale'),     formatter => sub { $_[0]->used_for_sale     ? t8('yes') : t8('no') } },
  56       { title => t8('Report separately'), formatter => sub { $_[0]->report_separate   ? t8('yes') : t8('no') } },
  57     ],
  58   },
  59
  60   parts_group => {
  61     # Make locales.pl happy: $self->render("simple_system_setting/_parts_group_form")
  62     class  => 'PartsGroup',
  63     titles => {
  64       list => t8('Partsgroups'),
  65       add  => t8('Add partsgroup'),
  66       edit => t8('Edit partsgroup'),
  67     },
  68     list_attributes => [
  69       { method => 'partsgroup', title => t8('Description') },
  70       { method => 'obsolete',   title => t8('Obsolete'), formatter => sub { $_[0]->obsolete ? t8('yes') : t8('no') } },
  71     ],
  72   },
  73
  74   pricegroup => {
  75     # Make locales.pl happy: $self->render("simple_system_setting/_pricegroup_form")
  76     class  => 'Pricegroup',
  77     titles => {
  78       list => t8('Pricegroups'),
  79       add  => t8('Add pricegroup'),
  80       edit => t8('Edit pricegroup'),
  81     },
  82     list_attributes => [
  83       { method => 'pricegroup', title => t8('Description') },
  84       { method => 'obsolete',   title => t8('Obsolete'), formatter => sub { $_[0]->obsolete ? t8('yes') : t8('no') } },
  85     ],
  86   },
  87 );
  88
  89 my @default_list_attributes = (
  90   { method => 'description', title => t8('Description') },
  91 );
  92
  93 #
  94 # actions
  95 #
  96
  97 sub action_list {
  98   my ($self) = @_;
  99
 100   $self->render('simple_system_setting/list', title => $self->config->{titles}->{list});
 101 }
 102
 103 sub action_new {
 104   my ($self) = @_;
 105
 106   $self->object($self->class->new);
 107   $self->render_form(title => $self->config->{titles}->{add});
 108 }
 109
 110 sub action_edit {
 111   my ($self) = @_;
 112
 113   $self->render_form(title => $self->config->{titles}->{edit});
 114 }
 115
 116 sub action_create {
 117   my ($self) = @_;
 118
 119   $self->object($self->class->new);
 120   $self->create_or_update;
 121 }
 122
 123 sub action_update {
 124   my ($self) = @_;
 125
 126   $self->create_or_update;
 127 }
 128
 129 sub action_delete {
 130   my ($self) = @_;
 131
 132   if ($self->object->can('orphaned') && !$self->object->orphaned) {
 133     flash_later('error', t8('The object is in use and cannot be deleted.'));
 134
 135   } elsif ( eval { $self->object->delete; 1; } ) {
 136     flash_later('info',  t8('The object has been deleted.'));
 137
 138   } else {
 139     flash_later('error', t8('The object is in use and cannot be deleted.'));
 140   }
 141
 142   $self->redirect_to($self->list_url);
 143 }
 144
 145 sub action_reorder {
 146   my ($self) = @_;
 147
 148   $self->class->reorder_list(@{ $::form->{object_id} || [] });
 149   $self->render(\'', { type => 'json' });
 150 }
 151
 152 #
 153 # filters
 154 #
 155
 156 sub check_type_and_auth {
 157   my ($self) = @_;
 158
 159   $self->type($::form->{type});
 160   $self->config($supported_types{$self->type}) || die "Unsupported type";
 161
 162   $::auth->assert($self->config->{auth} || 'config');
 163
 164   my $pm = (map { s{::}{/}g; "${_}.pm" } $self->class)[0];
 165   require $pm;
 166
 167   my $setup = "setup_" . $self->type;
 168   $self->$setup if $self->can($setup);
 169
 170   1;
 171 }
 172
 173 sub setup_javascript {
 174   $::request->layout->use_javascript("${_}.js") for qw(ckeditor/ckeditor ckeditor/adapters/jquery);
 175 }
 176
 177 sub init_class               { "SL::DB::"          . $_[0]->config->{class}                  }
 178 sub init_manager_class       { "SL::DB::Manager::" . $_[0]->config->{class}                  }
 179 sub init_object              { $_[0]->class->new(id => $::form->{id})->load                  }
 180 sub init_all_objects         { $_[0]->manager_class->get_all_sorted                          }
 181 sub init_list_url            { $_[0]->url_for(action => 'list', type => $_[0]->type)         }
 182 sub init_supports_reordering { $_[0]->class->new->can('reorder_list')                        }
 183 sub init_defaults            { SL::DB::Default->get                                          }
 184
 185 sub init_list_attributes {
 186   my ($self) = @_;
 187
 188   my $method = "list_attributes_" . $self->type;
 189
 190   return $self->$method if $self->can($method);
 191   return $self->config->{list_attributes} // \@default_list_attributes;
 192 }
 193
 194 #
 195 # helpers
 196 #
 197
 198 sub create_or_update {
 199   my ($self) = @_;
 200   my $is_new = !$self->object->id;
 201
 202   my $params = delete($::form->{object}) || { };
 203
 204   $self->object->assign_attributes(%{ $params });
 205
 206   my @errors;
 207
 208   push @errors, $self->object->validate if $self->object->can('validate');
 209
 210   if (@errors) {
 211     flash('error', @errors);
 212     return $self->render_form(title => $self->config->{titles}->{$is_new ? 'add' : 'edit'});
 213   }
 214
 215   $self->object->save;
 216
 217   flash_later('info', $is_new ? t8('The object has been created.') : t8('The object has been saved.'));
 218
 219   $self->redirect_to($self->list_url);
 220 }
 221
 222 sub render_form {
 223   my ($self, %params) = @_;
 224
 225   my $sub_form_template = SL::System::Process->exe_dir . '/templates/webpages/simple_system_setting/_' . $self->type . '_form.html';
 226
 227   $self->render(
 228     'simple_system_setting/form',
 229     %params,
 230     sub_form_template => (-f $sub_form_template ? $self->type : 'default'),
 231   );
 232 }
 233
 234 #
 235 # type-specific helper functions
 236 #
 237
 238 1;
 239
 240 __END__
 241
 242 =encoding utf-8
 243
 244 =head1 NAME
 245
 246 SL::Controller::SimpleSystemSettings — a common CRUD controller for
 247 various settings in the "System" menu
 248
 249 =head1 AUTHOR
 250
 251 Moritz Bunkus <m.bunkus@linet-services.de>
 252
 253 =cut