SL/Controller/SimpleSystemSetting.pm

   1 package SL::Controller::SimpleSystemSetting;
   2
   3 use strict;
   4 use utf8;
   5
   6 use parent qw(SL::Controller::Base);
   7
   8 use SL::Helper::Flash;
   9 use SL::Locale::String;
  10 use SL::DB::Default;
  11 use SL::System::Process;
  12
  13 use Rose::Object::MakeMethods::Generic (
  14   scalar                  => [ qw(type config) ],
  15   'scalar --get_set_init' => [ qw(defaults object all_objects class manager_class list_attributes list_url supports_reordering) ],
  16 );
  17
  18 __PACKAGE__->run_before('check_type_and_auth');
  19 __PACKAGE__->run_before('setup_javascript', only => [ qw(add create edit update delete) ]);
  20
  21 # Make locales.pl happy: $self->render("simple_system_setting/_default_form")
  22
  23 my %supported_types = (
  24   bank_account => {
  25     # Make locales.pl happy: $self->render("simple_system_setting/_bank_account_form")
  26     class  => 'BankAccount',
  27     titles => {
  28       list => t8('Bank accounts'),
  29       add  => t8('Add bank account'),
  30       edit => t8('Edit bank account'),
  31     },
  32     list_attributes => [
  33       { method => 'name',                                      title => t8('Name'), },
  34       { method => 'iban',                                      title => t8('IBAN'), },
  35       { method => 'bank',                                      title => t8('Bank'), },
  36       { method => 'bank_code',                                 title => t8('Bank code'), },
  37       { method => 'bic',                                       title => t8('BIC'), },
  38       { method => 'reconciliation_starting_date_as_date',      title => t8('Date'),    align => 'right' },
  39       { method => 'reconciliation_starting_balance_as_number', title => t8('Balance'), align => 'right' },
  40     ],
  41   },
  42
  43   business => {
  44     # Make locales.pl happy: $self->render("simple_system_setting/_business_form")
  45     class  => 'Business',
  46     titles => {
  47       list => t8('Businesses'),
  48       add  => t8('Add business'),
  49       edit => t8('Edit business'),
  50     },
  51     list_attributes => [
  52       { method => 'description',         title => t8('Description'), },
  53       {                                  title => t8('Discount'), formatter => sub { $_[0]->discount_as_percent . ' %' }, align => 'right' },
  54       { method => 'customernumberinit',  title => t8('Customernumberinit'), },
  55     ],
  56   },
  57
  58   department => {
  59     class  => 'Department',
  60     titles => {
  61       list => t8('Departments'),
  62       add  => t8('Add department'),
  63       edit => t8('Edit department'),
  64     },
  65   },
  66
  67   part_classification => {
  68     # Make locales.pl happy: $self->render("simple_system_setting/_part_classification_form")
  69     class  => 'PartClassification',
  70     titles => {
  71       list => t8('Part classifications'),
  72       add  => t8('Add part classification'),
  73       edit => t8('Edit part classification'),
  74     },
  75     list_attributes => [
  76       { title => t8('Description'),       formatter => sub { t8($_[0]->description) } },
  77       { title => t8('Type abbreviation'), formatter => sub { t8($_[0]->abbreviation) } },
  78       { title => t8('Used for Purchase'), formatter => sub { $_[0]->used_for_purchase ? t8('yes') : t8('no') } },
  79       { title => t8('Used for Sale'),     formatter => sub { $_[0]->used_for_sale     ? t8('yes') : t8('no') } },
  80       { title => t8('Report separately'), formatter => sub { $_[0]->report_separate   ? t8('yes') : t8('no') } },
  81     ],
  82   },
  83
  84   parts_group => {
  85     # Make locales.pl happy: $self->render("simple_system_setting/_parts_group_form")
  86     class  => 'PartsGroup',
  87     titles => {
  88       list => t8('Partsgroups'),
  89       add  => t8('Add partsgroup'),
  90       edit => t8('Edit partsgroup'),
  91     },
  92     list_attributes => [
  93       { method => 'partsgroup', title => t8('Description') },
  94       { method => 'obsolete',   title => t8('Obsolete'), formatter => sub { $_[0]->obsolete ? t8('yes') : t8('no') } },
  95     ],
  96   },
  97
  98   price_factor => {
  99     # Make locales.pl happy: $self->render("simple_system_setting/_price_factor_form")
 100     class  => 'PriceFactor',
 101     titles => {
 102       list => t8('Price Factors'),
 103       add  => t8('Add Price Factor'),
 104       edit => t8('Edit Price Factor'),
 105     },
 106     list_attributes => [
 107       { method => 'description',      title => t8('Description') },
 108       { method => 'factor_as_number', title => t8('Factor'), align => 'right' },
 109     ],
 110   },
 111
 112   pricegroup => {
 113     # Make locales.pl happy: $self->render("simple_system_setting/_pricegroup_form")
 114     class  => 'Pricegroup',
 115     titles => {
 116       list => t8('Pricegroups'),
 117       add  => t8('Add pricegroup'),
 118       edit => t8('Edit pricegroup'),
 119     },
 120     list_attributes => [
 121       { method => 'pricegroup', title => t8('Description') },
 122       { method => 'obsolete',   title => t8('Obsolete'), formatter => sub { $_[0]->obsolete ? t8('yes') : t8('no') } },
 123     ],
 124   },
 125
 126   project_status => {
 127     class  => 'ProjectStatus',
 128     titles => {
 129       list => t8('Project statuses'),
 130       add  => t8('Add project status'),
 131       edit => t8('Edit project status'),
 132     },
 133   },
 134
 135   project_type => {
 136     class  => 'ProjectType',
 137     titles => {
 138       list => t8('Project types'),
 139       add  => t8('Add project type'),
 140       edit => t8('Edit project type'),
 141     },
 142   },
 143
 144   requirement_spec_predefined_text => {
 145     # Make locales.pl happy: $self->render("simple_system_setting/_requirement_spec_predefined_text_form")
 146     class  => 'RequirementSpecPredefinedText',
 147     titles => {
 148       list => t8('Pre-defined Texts'),
 149       add  => t8('Add pre-defined text'),
 150       edit => t8('Edit pre-defined text'),
 151     },
 152     list_attributes => [
 153       { method => 'description', title => t8('Description') },
 154       { method => 'title',       title => t8('Title') },
 155       {                          title => t8('Content'),                 formatter => sub { my $t = $_[0]->text_as_stripped_html; length($t) > 50 ? substr($t, 0, 50) . '…' : $t } },
 156       {                          title => t8('Useable for text blocks'), formatter => sub { $_[0]->useable_for_text_blocks ? t8('yes') : t8('no') } },
 157       {                          title => t8('Useable for sections'),    formatter => sub { $_[0]->useable_for_sections    ? t8('yes') : t8('no') } },
 158     ],
 159   },
 160
 161   requirement_spec_type => {
 162     # Make locales.pl happy: $self->render("simple_system_setting/_requirement_spec_type_form")
 163     class  => 'RequirementSpecType',
 164     titles => {
 165       list => t8('Requirement Spec Types'),
 166       add  => t8('Add requirement spec type'),
 167       edit => t8('Edit requirement spec type'),
 168     },
 169     list_attributes => [
 170       { method => 'description',                  title => t8('Description') },
 171       { method => 'section_number_format',        title => t8('Section number format') },
 172       { method => 'function_block_number_format', title => t8('Function block number format') },
 173     ],
 174   },
 175
 176 );
 177
 178 my @default_list_attributes = (
 179   { method => 'description', title => t8('Description') },
 180 );
 181
 182 #
 183 # actions
 184 #
 185
 186 sub action_list {
 187   my ($self) = @_;
 188
 189   $self->render('simple_system_setting/list', title => $self->config->{titles}->{list});
 190 }
 191
 192 sub action_new {
 193   my ($self) = @_;
 194
 195   $self->object($self->class->new);
 196   $self->render_form(title => $self->config->{titles}->{add});
 197 }
 198
 199 sub action_edit {
 200   my ($self) = @_;
 201
 202   $self->render_form(title => $self->config->{titles}->{edit});
 203 }
 204
 205 sub action_create {
 206   my ($self) = @_;
 207
 208   $self->object($self->class->new);
 209   $self->create_or_update;
 210 }
 211
 212 sub action_update {
 213   my ($self) = @_;
 214
 215   $self->create_or_update;
 216 }
 217
 218 sub action_delete {
 219   my ($self) = @_;
 220
 221   if ($self->object->can('orphaned') && !$self->object->orphaned) {
 222     flash_later('error', t8('The object is in use and cannot be deleted.'));
 223
 224   } elsif ( eval { $self->object->delete; 1; } ) {
 225     flash_later('info',  t8('The object has been deleted.'));
 226
 227   } else {
 228     flash_later('error', t8('The object is in use and cannot be deleted.'));
 229   }
 230
 231   $self->redirect_to($self->list_url);
 232 }
 233
 234 sub action_reorder {
 235   my ($self) = @_;
 236
 237   $self->class->reorder_list(@{ $::form->{object_id} || [] });
 238   $self->render(\'', { type => 'json' });
 239 }
 240
 241 #
 242 # filters
 243 #
 244
 245 sub check_type_and_auth {
 246   my ($self) = @_;
 247
 248   $self->type($::form->{type});
 249   $self->config($supported_types{$self->type}) || die "Unsupported type";
 250
 251   $::auth->assert($self->config->{auth} || 'config');
 252
 253   my $pm = (map { s{::}{/}g; "${_}.pm" } $self->class)[0];
 254   require $pm;
 255
 256   my $setup = "setup_" . $self->type;
 257   $self->$setup if $self->can($setup);
 258
 259   1;
 260 }
 261
 262 sub setup_javascript {
 263   $::request->layout->use_javascript("${_}.js") for qw(ckeditor/ckeditor ckeditor/adapters/jquery);
 264 }
 265
 266 sub init_class               { "SL::DB::"          . $_[0]->config->{class}                  }
 267 sub init_manager_class       { "SL::DB::Manager::" . $_[0]->config->{class}                  }
 268 sub init_object              { $_[0]->class->new(id => $::form->{id})->load                  }
 269 sub init_all_objects         { $_[0]->manager_class->get_all_sorted                          }
 270 sub init_list_url            { $_[0]->url_for(action => 'list', type => $_[0]->type)         }
 271 sub init_supports_reordering { $_[0]->class->new->can('reorder_list')                        }
 272 sub init_defaults            { SL::DB::Default->get                                          }
 273
 274 sub init_list_attributes {
 275   my ($self) = @_;
 276
 277   my $method = "list_attributes_" . $self->type;
 278
 279   return $self->$method if $self->can($method);
 280   return $self->config->{list_attributes} // \@default_list_attributes;
 281 }
 282
 283 #
 284 # helpers
 285 #
 286
 287 sub create_or_update {
 288   my ($self) = @_;
 289   my $is_new = !$self->object->id;
 290
 291   my $params = delete($::form->{object}) || { };
 292
 293   $self->object->assign_attributes(%{ $params });
 294
 295   my @errors;
 296
 297   push @errors, $self->object->validate if $self->object->can('validate');
 298
 299   if (@errors) {
 300     flash('error', @errors);
 301     return $self->render_form(title => $self->config->{titles}->{$is_new ? 'add' : 'edit'});
 302   }
 303
 304   $self->object->save;
 305
 306   flash_later('info', $is_new ? t8('The object has been created.') : t8('The object has been saved.'));
 307
 308   $self->redirect_to($self->list_url);
 309 }
 310
 311 sub render_form {
 312   my ($self, %params) = @_;
 313
 314   my $sub_form_template = SL::System::Process->exe_dir . '/templates/webpages/simple_system_setting/_' . $self->type . '_form.html';
 315
 316   $self->render(
 317     'simple_system_setting/form',
 318     %params,
 319     sub_form_template => (-f $sub_form_template ? $self->type : 'default'),
 320   );
 321 }
 322
 323 #
 324 # type-specific helper functions
 325 #
 326
 327 1;
 328
 329 __END__
 330
 331 =encoding utf-8
 332
 333 =head1 NAME
 334
 335 SL::Controller::SimpleSystemSettings — a common CRUD controller for
 336 various settings in the "System" menu
 337
 338 =head1 AUTHOR
 339
 340 Moritz Bunkus <m.bunkus@linet-services.de>
 341
 342 =cut