SL/Controller/TimeRecording.pm

   1 package SL::Controller::TimeRecording;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use DateTime;
   7 use English qw(-no_match_vars);
   8 use POSIX qw(strftime);
   9
  10 use SL::Controller::Helper::GetModels;
  11 use SL::Controller::Helper::ReportGenerator;
  12 use SL::DB::Customer;
  13 use SL::DB::Employee;
  14 use SL::DB::TimeRecording;
  15 use SL::Locale::String qw(t8);
  16 use SL::ReportGenerator;
  17
  18 use Rose::Object::MakeMethods::Generic
  19 (
  20 # scalar                  => [ qw() ],
  21  'scalar --get_set_init' => [ qw(time_recording models all_time_recording_types all_employees) ],
  22 );
  23
  24
  25 # safety
  26 __PACKAGE__->run_before('check_auth');
  27
  28 #
  29 # actions
  30 #
  31
  32 my %sort_columns = (
  33   start_time   => t8('Start'),
  34   end_time     => t8('End'),
  35   customer     => t8('Customer'),
  36   type         => t8('Type'),
  37   project      => t8('Project'),
  38   description  => t8('Description'),
  39   staff_member => t8('Mitarbeiter'),
  40   duration     => t8('Duration'),
  41 );
  42
  43 sub action_list {
  44   my ($self, %params) = @_;
  45
  46   $::form->{filter} //=  {
  47     staff_member_id       => SL::DB::Manager::Employee->current->id,
  48     "start_time:date::ge" => DateTime->now_local->add(weeks => -2)->to_kivitendo,
  49   };
  50
  51   $self->setup_list_action_bar;
  52   $self->make_filter_summary;
  53   $self->prepare_report;
  54
  55   $self->report_generator_list_objects(report => $self->{report}, objects => $self->models->get);
  56 }
  57
  58 sub action_edit {
  59   my ($self) = @_;
  60
  61   $::request->{layout}->use_javascript("${_}.js") for qw(kivi.TimeRecording ckeditor/ckeditor ckeditor/adapters/jquery kivi.Validator);
  62
  63   if ($self->time_recording->start_time) {
  64     $self->{start_date} = $self->time_recording->start_time->to_kivitendo;
  65     $self->{start_time} = $self->time_recording->start_time->to_kivitendo_time;
  66   }
  67   if ($self->time_recording->end_time) {
  68     $self->{end_date}   = $self->time_recording->end_time->to_kivitendo;
  69     $self->{end_time}   = $self->time_recording->end_time->to_kivitendo_time;
  70   }
  71
  72   $self->setup_edit_action_bar;
  73
  74   $self->render('time_recording/form',
  75                 title  => t8('Time Recording'),
  76   );
  77 }
  78
  79 sub action_save {
  80   my ($self) = @_;
  81
  82   my @errors = $self->time_recording->validate;
  83   if (@errors) {
  84     $::form->error(t8('Saving the time recording entry failed: #1', join '<br>', @errors));
  85     return;
  86   }
  87
  88   if ( !eval { $self->time_recording->save; 1; } ) {
  89     $::form->error(t8('Saving the time recording entry failed: #1', $EVAL_ERROR));
  90     return;
  91   }
  92
  93   $self->redirect_to(safe_callback());
  94 }
  95
  96 sub action_delete {
  97   my ($self) = @_;
  98
  99   $self->time_recording->delete;
 100
 101   $self->redirect_to(safe_callback());
 102 }
 103
 104 sub init_time_recording {
 105   my $time_recording = ($::form->{id}) ? SL::DB::TimeRecording->new(id => $::form->{id})->load
 106                                        : SL::DB::TimeRecording->new(start_time => DateTime->now_local);
 107
 108   my %attributes = %{ $::form->{time_recording} || {} };
 109
 110   foreach my $type (qw(start end)) {
 111     if ($::form->{$type . '_date'}) {
 112       my $date = DateTime->from_kivitendo($::form->{$type . '_date'});
 113       $attributes{$type . '_time'} = $date->clone;
 114       if ($::form->{$type . '_time'}) {
 115         my ($hour, $min) = split ':', $::form->{$type . '_time'};
 116         $attributes{$type . '_time'}->set_hour($hour)  if $hour;
 117         $attributes{$type . '_time'}->set_minute($min) if $min;
 118       }
 119     }
 120   }
 121
 122   $attributes{staff_member_id} = $attributes{employee_id} = SL::DB::Manager::Employee->current->id;
 123
 124   $time_recording->assign_attributes(%attributes);
 125
 126   return $time_recording;
 127 }
 128
 129 sub init_models {
 130   SL::Controller::Helper::GetModels->new(
 131     controller     => $_[0],
 132     sorted         => \%sort_columns,
 133     disable_plugin => 'paginated',
 134     with_objects   => [ 'customer', 'type', 'project', 'staff_member', 'employee' ],
 135   );
 136 }
 137
 138 sub init_all_time_recording_types {
 139   SL::DB::Manager::TimeRecordingType->get_all_sorted(query => [obsolete => 0]);
 140 }
 141
 142 sub init_all_employees {
 143   SL::DB::Manager::Employee->get_all_sorted(query => [ deleted => 0 ]);
 144 }
 145
 146 sub check_auth {
 147   $::auth->assert('time_recording');
 148 }
 149
 150 sub prepare_report {
 151   my ($self) = @_;
 152
 153   my $report      = SL::ReportGenerator->new(\%::myconfig, $::form);
 154   $self->{report} = $report;
 155
 156   my @columns  = qw(start_time end_time customer type project description staff_member duration);
 157
 158   my %column_defs = (
 159     start_time   => { text => t8('Start'),        sub => sub { $_[0]->start_time_as_timestamp },
 160                       obj_link => sub { $self->url_for(action => 'edit', 'id' => $_[0]->id, callback => $self->models->get_callback) }  },
 161     end_time     => { text => t8('End'),          sub => sub { $_[0]->end_time_as_timestamp },
 162                       obj_link => sub { $self->url_for(action => 'edit', 'id' => $_[0]->id, callback => $self->models->get_callback) }  },
 163     customer     => { text => t8('Customer'),     sub => sub { $_[0]->customer->displayable_name } },
 164     type         => { text => t8('Type'),         sub => sub { $_[0]->type && $_[0]->type->abbreviation } },
 165     project      => { text => t8('Project'),      sub => sub { $_[0]->project && $_[0]->project->displayable_name } },
 166     description  => { text => t8('Description'),  sub => sub { $_[0]->description_as_stripped_html },
 167                       raw_data => sub { $_[0]->description_as_restricted_html }, # raw_data only used for html(?)
 168                       obj_link => sub { $self->url_for(action => 'edit', 'id' => $_[0]->id, callback => $self->models->get_callback) }  },
 169     staff_member => { text => t8('Mitarbeiter'),  sub => sub { $_[0]->staff_member->safe_name } },
 170     duration     => { text => t8('Duration'),     sub => sub { $_[0]->duration_as_duration_string },
 171                       align => 'right'},
 172   );
 173
 174   $report->set_options(
 175     controller_class      => 'TimeRecording',
 176     std_column_visibility => 1,
 177     output_format         => 'HTML',
 178     title                 => t8('Time Recordings'),
 179     allow_pdf_export      => 1,
 180     allow_csv_export      => 1,
 181   );
 182
 183   $report->set_columns(%column_defs);
 184   $report->set_column_order(@columns);
 185   $report->set_export_options(qw(list filter));
 186   $report->set_options_from_form;
 187
 188   $self->models->disable_plugin('paginated') if $report->{options}{output_format} =~ /^(pdf|csv)$/i;
 189   #$self->models->add_additional_url_params();
 190   $self->models->finalize;
 191   $self->models->set_report_generator_sort_options(report => $report, sortable_columns => [keys %sort_columns]);
 192
 193   $report->set_options(
 194     raw_top_info_text    => $self->render('time_recording/report_top',    { output => 0 }),
 195     raw_bottom_info_text => $self->render('time_recording/report_bottom', { output => 0 }, models => $self->models),
 196     attachment_basename  => t8('time_recordings') . strftime('_%Y%m%d', localtime time),
 197   );
 198 }
 199
 200 sub make_filter_summary {
 201   my ($self) = @_;
 202
 203   my $filter = $::form->{filter} || {};
 204   my @filter_strings;
 205
 206   my $staff_member = $filter->{staff_member_id} ? SL::DB::Employee->new(id => $filter->{staff_member_id})->load->safe_name : '';
 207
 208   my @filters = (
 209     [ $filter->{"start_time:date::ge"},                        t8('From Start')      ],
 210     [ $filter->{"start_time:date::le"},                        t8('To Start')        ],
 211     [ $filter->{"customer"}->{"name:substr::ilike"},           t8('Customer')        ],
 212     [ $filter->{"customer"}->{"customernumber:substr::ilike"}, t8('Customer Number') ],
 213     [ $staff_member,                                           t8('Mitarbeiter')     ],
 214   );
 215
 216   for (@filters) {
 217     push @filter_strings, "$_->[1]: $_->[0]" if $_->[0];
 218   }
 219
 220   $self->{filter_summary} = join ', ', @filter_strings;
 221 }
 222
 223 sub setup_list_action_bar {
 224   my ($self) = @_;
 225
 226   for my $bar ($::request->layout->get('actionbar')) {
 227     $bar->add(
 228       action => [
 229         t8('Update'),
 230         submit    => [ '#filter_form', { action => 'TimeRecording/list' } ],
 231         accesskey => 'enter',
 232       ],
 233       action => [
 234         t8('Add'),
 235         link => $self->url_for(action => 'edit', callback => $self->models->get_callback),
 236       ],
 237     );
 238   }
 239 }
 240
 241 sub setup_edit_action_bar {
 242   my ($self) = @_;
 243
 244   for my $bar ($::request->layout->get('actionbar')) {
 245     $bar->add(
 246       action => [
 247         t8('Save'),
 248         submit => [ '#form', { action => 'TimeRecording/save' } ],
 249         checks => [ 'kivi.validate_form' ],
 250       ],
 251       action => [
 252         t8('Delete'),
 253         submit  => [ '#form', { action => 'TimeRecording/delete' } ],
 254         only_if => $self->time_recording->id,
 255       ],
 256       action => [
 257         t8('Cancel'),
 258         link  => $self->url_for(safe_callback()),
 259       ],
 260     );
 261   }
 262 }
 263
 264 sub safe_callback {
 265   $::form->{callback} || (action => 'list')
 266 }
 267
 268 1;