SL/Controller/TimeRecording.pm

   1 package SL::Controller::TimeRecording;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use DateTime;
   7 use English qw(-no_match_vars);
   8 use POSIX qw(strftime);
   9
  10 use SL::Controller::Helper::GetModels;
  11 use SL::Controller::Helper::ReportGenerator;
  12 use SL::DB::Customer;
  13 use SL::DB::Employee;
  14 use SL::DB::TimeRecording;
  15 use SL::Locale::String qw(t8);
  16 use SL::ReportGenerator;
  17
  18 use Rose::Object::MakeMethods::Generic
  19 (
  20 # scalar                  => [ qw() ],
  21  'scalar --get_set_init' => [ qw(time_recording models all_time_recording_types all_employees can_view_all) ],
  22 );
  23
  24
  25 # safety
  26 __PACKAGE__->run_before('check_auth');
  27
  28 #
  29 # actions
  30 #
  31
  32 my %sort_columns = (
  33   start_time   => t8('Start'),
  34   end_time     => t8('End'),
  35   customer     => t8('Customer'),
  36   type         => t8('Type'),
  37   project      => t8('Project'),
  38   description  => t8('Description'),
  39   staff_member => t8('Mitarbeiter'),
  40   duration     => t8('Duration'),
  41 );
  42
  43 sub action_list {
  44   my ($self, %params) = @_;
  45
  46   $::form->{filter} //=  {
  47     staff_member_id       => SL::DB::Manager::Employee->current->id,
  48     "start_time:date::ge" => DateTime->now_local->add(weeks => -2)->to_kivitendo,
  49   };
  50
  51   $self->setup_list_action_bar;
  52   $self->make_filter_summary;
  53   $self->prepare_report;
  54
  55   $self->report_generator_list_objects(report => $self->{report}, objects => $self->models->get);
  56 }
  57
  58 sub action_edit {
  59   my ($self) = @_;
  60
  61   $::request->{layout}->use_javascript("${_}.js") for qw(kivi.TimeRecording ckeditor/ckeditor ckeditor/adapters/jquery kivi.Validator);
  62
  63   if ($self->time_recording->start_time) {
  64     $self->{start_date} = $self->time_recording->start_time->to_kivitendo;
  65     $self->{start_time} = $self->time_recording->start_time->to_kivitendo_time;
  66   }
  67   if ($self->time_recording->end_time) {
  68     $self->{end_date}   = $self->time_recording->end_time->to_kivitendo;
  69     $self->{end_time}   = $self->time_recording->end_time->to_kivitendo_time;
  70   }
  71
  72   $self->setup_edit_action_bar;
  73
  74   $self->render('time_recording/form',
  75                 title  => t8('Time Recording'),
  76   );
  77 }
  78
  79 sub action_save {
  80   my ($self) = @_;
  81
  82   my @errors = $self->time_recording->validate;
  83   if (@errors) {
  84     $::form->error(t8('Saving the time recording entry failed: #1', join '<br>', @errors));
  85     return;
  86   }
  87
  88   if ( !eval { $self->time_recording->save; 1; } ) {
  89     $::form->error(t8('Saving the time recording entry failed: #1', $EVAL_ERROR));
  90     return;
  91   }
  92
  93   $self->redirect_to(safe_callback());
  94 }
  95
  96 sub action_delete {
  97   my ($self) = @_;
  98
  99   $self->time_recording->delete;
 100
 101   $self->redirect_to(safe_callback());
 102 }
 103
 104 sub init_time_recording {
 105   my $is_new         = !$::form->{id};
 106   my $time_recording = $is_new ? SL::DB::TimeRecording->new(start_time => DateTime->now_local)
 107                                : SL::DB::TimeRecording->new(id => $::form->{id})->load;
 108
 109   my %attributes = %{ $::form->{time_recording} || {} };
 110
 111   foreach my $type (qw(start end)) {
 112     if ($::form->{$type . '_date'}) {
 113       my $date = DateTime->from_kivitendo($::form->{$type . '_date'});
 114       $attributes{$type . '_time'} = $date->clone;
 115       if ($::form->{$type . '_time'}) {
 116         my ($hour, $min) = split ':', $::form->{$type . '_time'};
 117         $attributes{$type . '_time'}->set_hour($hour)  if $hour;
 118         $attributes{$type . '_time'}->set_minute($min) if $min;
 119       }
 120     }
 121   }
 122
 123   $attributes{employee_id}     = SL::DB::Manager::Employee->current->id;
 124   $attributes{staff_member_id} = SL::DB::Manager::Employee->current->id if $is_new;
 125
 126   $time_recording->assign_attributes(%attributes);
 127
 128   return $time_recording;
 129 }
 130
 131 sub init_can_view_all {
 132   $::auth->assert('time_recording_show_all', 1) || $::auth->assert('time_recording_edit_all', 1)
 133 }
 134
 135 sub init_models {
 136   my ($self) = @_;
 137
 138   my @where;
 139   push @where, (staff_member_id => SL::DB::Manager::Employee->current->id) if !$self->can_view_all;
 140
 141   SL::Controller::Helper::GetModels->new(
 142     controller     => $_[0],
 143     sorted         => \%sort_columns,
 144     disable_plugin => 'paginated',
 145     query          => \@where,
 146     with_objects   => [ 'customer', 'type', 'project', 'staff_member', 'employee' ],
 147   );
 148 }
 149
 150 sub init_all_time_recording_types {
 151   SL::DB::Manager::TimeRecordingType->get_all_sorted(query => [obsolete => 0]);
 152 }
 153
 154 sub init_all_employees {
 155   SL::DB::Manager::Employee->get_all_sorted(query => [ deleted => 0 ]);
 156 }
 157
 158 sub check_auth {
 159   $::auth->assert('time_recording');
 160 }
 161
 162 sub prepare_report {
 163   my ($self) = @_;
 164
 165   my $report      = SL::ReportGenerator->new(\%::myconfig, $::form);
 166   $self->{report} = $report;
 167
 168   my @columns  = qw(start_time end_time customer type project description staff_member duration);
 169
 170   my %column_defs = (
 171     start_time   => { text => t8('Start'),        sub => sub { $_[0]->start_time_as_timestamp },
 172                       obj_link => sub { $self->url_for(action => 'edit', 'id' => $_[0]->id, callback => $self->models->get_callback) }  },
 173     end_time     => { text => t8('End'),          sub => sub { $_[0]->end_time_as_timestamp },
 174                       obj_link => sub { $self->url_for(action => 'edit', 'id' => $_[0]->id, callback => $self->models->get_callback) }  },
 175     customer     => { text => t8('Customer'),     sub => sub { $_[0]->customer->displayable_name } },
 176     type         => { text => t8('Type'),         sub => sub { $_[0]->type && $_[0]->type->abbreviation } },
 177     project      => { text => t8('Project'),      sub => sub { $_[0]->project && $_[0]->project->displayable_name } },
 178     description  => { text => t8('Description'),  sub => sub { $_[0]->description_as_stripped_html },
 179                       raw_data => sub { $_[0]->description_as_restricted_html }, # raw_data only used for html(?)
 180                       obj_link => sub { $self->url_for(action => 'edit', 'id' => $_[0]->id, callback => $self->models->get_callback) }  },
 181     staff_member => { text => t8('Mitarbeiter'),  sub => sub { $_[0]->staff_member->safe_name } },
 182     duration     => { text => t8('Duration'),     sub => sub { $_[0]->duration_as_duration_string },
 183                       align => 'right'},
 184   );
 185
 186   $report->set_options(
 187     controller_class      => 'TimeRecording',
 188     std_column_visibility => 1,
 189     output_format         => 'HTML',
 190     title                 => t8('Time Recordings'),
 191     allow_pdf_export      => 1,
 192     allow_csv_export      => 1,
 193   );
 194
 195   $report->set_columns(%column_defs);
 196   $report->set_column_order(@columns);
 197   $report->set_export_options(qw(list filter));
 198   $report->set_options_from_form;
 199
 200   $self->models->disable_plugin('paginated') if $report->{options}{output_format} =~ /^(pdf|csv)$/i;
 201   #$self->models->add_additional_url_params();
 202   $self->models->finalize;
 203   $self->models->set_report_generator_sort_options(report => $report, sortable_columns => [keys %sort_columns]);
 204
 205   $report->set_options(
 206     raw_top_info_text    => $self->render('time_recording/report_top',    { output => 0 }),
 207     raw_bottom_info_text => $self->render('time_recording/report_bottom', { output => 0 }, models => $self->models),
 208     attachment_basename  => t8('time_recordings') . strftime('_%Y%m%d', localtime time),
 209   );
 210 }
 211
 212 sub make_filter_summary {
 213   my ($self) = @_;
 214
 215   my $filter = $::form->{filter} || {};
 216   my @filter_strings;
 217
 218   my $staff_member = $filter->{staff_member_id} ? SL::DB::Employee->new(id => $filter->{staff_member_id})->load->safe_name : '';
 219
 220   my @filters = (
 221     [ $filter->{"start_time:date::ge"},                        t8('From Start')      ],
 222     [ $filter->{"start_time:date::le"},                        t8('To Start')        ],
 223     [ $filter->{"customer"}->{"name:substr::ilike"},           t8('Customer')        ],
 224     [ $filter->{"customer"}->{"customernumber:substr::ilike"}, t8('Customer Number') ],
 225     [ $staff_member,                                           t8('Mitarbeiter')     ],
 226   );
 227
 228   for (@filters) {
 229     push @filter_strings, "$_->[1]: $_->[0]" if $_->[0];
 230   }
 231
 232   $self->{filter_summary} = join ', ', @filter_strings;
 233 }
 234
 235 sub setup_list_action_bar {
 236   my ($self) = @_;
 237
 238   for my $bar ($::request->layout->get('actionbar')) {
 239     $bar->add(
 240       action => [
 241         t8('Update'),
 242         submit    => [ '#filter_form', { action => 'TimeRecording/list' } ],
 243         accesskey => 'enter',
 244       ],
 245       action => [
 246         t8('Add'),
 247         link => $self->url_for(action => 'edit', callback => $self->models->get_callback),
 248       ],
 249     );
 250   }
 251 }
 252
 253 sub setup_edit_action_bar {
 254   my ($self) = @_;
 255
 256   for my $bar ($::request->layout->get('actionbar')) {
 257     $bar->add(
 258       action => [
 259         t8('Save'),
 260         submit => [ '#form', { action => 'TimeRecording/save' } ],
 261         checks => [ 'kivi.validate_form' ],
 262       ],
 263       action => [
 264         t8('Delete'),
 265         submit  => [ '#form', { action => 'TimeRecording/delete' } ],
 266         only_if => $self->time_recording->id,
 267       ],
 268       action => [
 269         t8('Cancel'),
 270         link  => $self->url_for(safe_callback()),
 271       ],
 272     );
 273   }
 274 }
 275
 276 sub safe_callback {
 277   $::form->{callback} || (action => 'list')
 278 }
 279
 280 1;