SL/Controller/TimeRecording.pm

   1 package SL::Controller::TimeRecording;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use DateTime;
   7 use English qw(-no_match_vars);
   8 use POSIX qw(strftime);
   9
  10 use SL::Controller::Helper::GetModels;
  11 use SL::Controller::Helper::ReportGenerator;
  12 use SL::DB::Customer;
  13 use SL::DB::Employee;
  14 use SL::DB::TimeRecording;
  15 use SL::Locale::String qw(t8);
  16 use SL::ReportGenerator;
  17
  18 use Rose::Object::MakeMethods::Generic
  19 (
  20 # scalar                  => [ qw() ],
  21  'scalar --get_set_init' => [ qw(time_recording models all_time_recording_types all_employees) ],
  22 );
  23
  24
  25 # safety
  26 #__PACKAGE__->run_before('check_auth');
  27
  28 #
  29 # actions
  30 #
  31
  32 my %sort_columns = (
  33   start_time   => t8('Start'),
  34   end_time     => t8('End'),
  35   customer     => t8('Customer'),
  36   type         => t8('Type'),
  37   project      => t8('Project'),
  38   description  => t8('Description'),
  39   staff_member => t8('Mitarbeiter'),
  40   duration     => t8('Duration'),
  41 );
  42
  43 sub action_list {
  44   my ($self, %params) = @_;
  45
  46   $self->setup_list_action_bar;
  47   $self->make_filter_summary;
  48   $self->prepare_report;
  49
  50   $self->report_generator_list_objects(report => $self->{report}, objects => $self->models->get);
  51 }
  52
  53 sub action_edit {
  54   my ($self) = @_;
  55
  56   $::request->{layout}->use_javascript("${_}.js") for qw(kivi.TimeRecording ckeditor/ckeditor ckeditor/adapters/jquery kivi.Validator);
  57
  58   if ($self->time_recording->start_time) {
  59     $self->{start_date} = $self->time_recording->start_time->to_kivitendo;
  60     $self->{start_time} = $self->time_recording->start_time->to_kivitendo_time;
  61   }
  62   if ($self->time_recording->end_time) {
  63     $self->{end_date}   = $self->time_recording->end_time->to_kivitendo;
  64     $self->{end_time}   = $self->time_recording->end_time->to_kivitendo_time;
  65   }
  66
  67   $self->setup_edit_action_bar;
  68
  69   $self->render('time_recording/form',
  70                 title  => t8('Time Recording'),
  71   );
  72 }
  73
  74 sub action_save {
  75   my ($self) = @_;
  76
  77   my @errors = $self->time_recording->validate;
  78   if (@errors) {
  79     $::form->error(t8('Saving the time recording entry failed: #1', join '<br>', @errors));
  80     return;
  81   }
  82
  83   if ( !eval { $self->time_recording->save; 1; } ) {
  84     $::form->error(t8('Saving the time recording entry failed: #1', $EVAL_ERROR));
  85     return;
  86   }
  87
  88   $self->redirect_to(safe_callback());
  89 }
  90
  91 sub action_delete {
  92   my ($self) = @_;
  93
  94   $self->time_recording->delete;
  95
  96   $self->redirect_to(safe_callback());
  97 }
  98
  99 sub init_time_recording {
 100   my $time_recording = ($::form->{id}) ? SL::DB::TimeRecording->new(id => $::form->{id})->load
 101                                        : SL::DB::TimeRecording->new(start_time => DateTime->now_local);
 102
 103   my %attributes = %{ $::form->{time_recording} || {} };
 104
 105   foreach my $type (qw(start end)) {
 106     if ($::form->{$type . '_date'}) {
 107       my $date = DateTime->from_kivitendo($::form->{$type . '_date'});
 108       $attributes{$type . '_time'} = $date->clone;
 109       if ($::form->{$type . '_time'}) {
 110         my ($hour, $min) = split ':', $::form->{$type . '_time'};
 111         $attributes{$type . '_time'}->set_hour($hour)  if $hour;
 112         $attributes{$type . '_time'}->set_minute($min) if $min;
 113       }
 114     }
 115   }
 116
 117   $attributes{staff_member_id} = $attributes{employee_id} = SL::DB::Manager::Employee->current->id;
 118
 119   $time_recording->assign_attributes(%attributes);
 120
 121   return $time_recording;
 122 }
 123
 124 sub init_models {
 125   SL::Controller::Helper::GetModels->new(
 126     controller     => $_[0],
 127     sorted         => \%sort_columns,
 128     disable_plugin => 'paginated',
 129     with_objects   => [ 'customer', 'type', 'project', 'staff_member', 'employee' ],
 130   );
 131 }
 132
 133 sub init_all_time_recording_types {
 134   SL::DB::Manager::TimeRecordingType->get_all_sorted(query => [obsolete => 0]);
 135 }
 136
 137 sub init_all_employees {
 138   SL::DB::Manager::Employee->get_all_sorted;
 139 }
 140
 141 sub prepare_report {
 142   my ($self) = @_;
 143
 144   my $report      = SL::ReportGenerator->new(\%::myconfig, $::form);
 145   $self->{report} = $report;
 146
 147   my @columns  = qw(start_time end_time customer type project description staff_member duration);
 148
 149   my %column_defs = (
 150     start_time   => { text => t8('Start'),        sub => sub { $_[0]->start_time_as_timestamp },
 151                       obj_link => sub { $self->url_for(action => 'edit', 'id' => $_[0]->id, callback => $self->models->get_callback) }  },
 152     end_time     => { text => t8('End'),          sub => sub { $_[0]->end_time_as_timestamp },
 153                       obj_link => sub { $self->url_for(action => 'edit', 'id' => $_[0]->id, callback => $self->models->get_callback) }  },
 154     customer     => { text => t8('Customer'),     sub => sub { $_[0]->customer->displayable_name } },
 155     type         => { text => t8('Type'),         sub => sub { $_[0]->type && $_[0]->type->abbreviation } },
 156     project      => { text => t8('Project'),      sub => sub { $_[0]->project && $_[0]->project->displayable_name } },
 157     description  => { text => t8('Description'),  sub => sub { $_[0]->description_as_stripped_html },
 158                       raw_data => sub { $_[0]->description_as_restricted_html }, # raw_data only used for html(?)
 159                       obj_link => sub { $self->url_for(action => 'edit', 'id' => $_[0]->id, callback => $self->models->get_callback) }  },
 160     staff_member => { text => t8('Mitarbeiter'),  sub => sub { $_[0]->staff_member->safe_name } },
 161     duration     => { text => t8('Duration'),     sub => sub { $_[0]->duration_as_duration_string },
 162                       align => 'right'},
 163   );
 164
 165   $report->set_options(
 166     controller_class      => 'TimeRecording',
 167     std_column_visibility => 1,
 168     output_format         => 'HTML',
 169     title                 => t8('Time Recordings'),
 170     allow_pdf_export      => 1,
 171     allow_csv_export      => 1,
 172   );
 173
 174   $report->set_columns(%column_defs);
 175   $report->set_column_order(@columns);
 176   $report->set_export_options(qw(list filter));
 177   $report->set_options_from_form;
 178
 179   $self->models->disable_plugin('paginated') if $report->{options}{output_format} =~ /^(pdf|csv)$/i;
 180   #$self->models->add_additional_url_params();
 181   $self->models->finalize;
 182   $self->models->set_report_generator_sort_options(report => $report, sortable_columns => [keys %sort_columns]);
 183
 184   $report->set_options(
 185     raw_top_info_text    => $self->render('time_recording/report_top',    { output => 0 }),
 186     raw_bottom_info_text => $self->render('time_recording/report_bottom', { output => 0 }, models => $self->models),
 187     attachment_basename  => t8('time_recordings') . strftime('_%Y%m%d', localtime time),
 188   );
 189 }
 190
 191 sub make_filter_summary {
 192   my ($self) = @_;
 193
 194   my $filter = $::form->{filter} || {};
 195   my @filter_strings;
 196
 197   my $staff_member = $filter->{staff_member_id} ? SL::DB::Employee->new(id => $filter->{staff_member_id})->load->safe_name : '';
 198
 199   my @filters = (
 200     [ $filter->{"start_time:date::ge"},                        t8('From Start')      ],
 201     [ $filter->{"start_time:date::le"},                        t8('To Start')        ],
 202     [ $filter->{"customer"}->{"name:substr::ilike"},           t8('Customer')        ],
 203     [ $filter->{"customer"}->{"customernumber:substr::ilike"}, t8('Customer Number') ],
 204     [ $staff_member,                                           t8('Mitarbeiter')     ],
 205   );
 206
 207   for (@filters) {
 208     push @filter_strings, "$_->[1]: $_->[0]" if $_->[0];
 209   }
 210
 211   $self->{filter_summary} = join ', ', @filter_strings;
 212 }
 213
 214 sub setup_list_action_bar {
 215   my ($self) = @_;
 216
 217   for my $bar ($::request->layout->get('actionbar')) {
 218     $bar->add(
 219       action => [
 220         t8('Update'),
 221         submit    => [ '#filter_form', { action => 'TimeRecording/list' } ],
 222         accesskey => 'enter',
 223       ],
 224       action => [
 225         t8('Add'),
 226         link => $self->url_for(action => 'edit', callback => $self->models->get_callback),
 227       ],
 228     );
 229   }
 230 }
 231
 232 sub setup_edit_action_bar {
 233   my ($self) = @_;
 234
 235   for my $bar ($::request->layout->get('actionbar')) {
 236     $bar->add(
 237       action => [
 238         t8('Save'),
 239         submit => [ '#form', { action => 'TimeRecording/save' } ],
 240         checks => [ 'kivi.validate_form' ],
 241       ],
 242       action => [
 243         t8('Delete'),
 244         submit  => [ '#form', { action => 'TimeRecording/delete' } ],
 245         only_if => $self->time_recording->id,
 246       ],
 247       action => [
 248         t8('Cancel'),
 249         link  => $self->url_for(safe_callback()),
 250       ],
 251     );
 252   }
 253 }
 254
 255 sub safe_callback {
 256   $::form->{callback} || (action => 'list')
 257 }
 258
 259 1;