SL/Controller/TimeRecording.pm

   1 package SL::Controller::TimeRecording;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use DateTime;
   7 use English qw(-no_match_vars);
   8 use POSIX qw(strftime);
   9
  10 use SL::Controller::Helper::GetModels;
  11 use SL::Controller::Helper::ReportGenerator;
  12 use SL::DB::Customer;
  13 use SL::DB::Employee;
  14 use SL::DB::TimeRecording;
  15 use SL::Locale::String qw(t8);
  16 use SL::ReportGenerator;
  17
  18 use Rose::Object::MakeMethods::Generic
  19 (
  20 # scalar                  => [ qw() ],
  21  'scalar --get_set_init' => [ qw(time_recording models all_time_recording_types all_employees can_view_all can_edit_all) ],
  22 );
  23
  24
  25 # safety
  26 __PACKAGE__->run_before('check_auth');
  27 __PACKAGE__->run_before('check_auth_edit', only => [ qw(edit save delete) ]);
  28
  29 #
  30 # actions
  31 #
  32
  33 my %sort_columns = (
  34   start_time   => t8('Start'),
  35   end_time     => t8('End'),
  36   customer     => t8('Customer'),
  37   type         => t8('Type'),
  38   project      => t8('Project'),
  39   description  => t8('Description'),
  40   staff_member => t8('Mitarbeiter'),
  41   duration     => t8('Duration'),
  42 );
  43
  44 sub action_list {
  45   my ($self, %params) = @_;
  46
  47   $::form->{filter} //=  {
  48     staff_member_id       => SL::DB::Manager::Employee->current->id,
  49     "start_time:date::ge" => DateTime->now_local->add(weeks => -2)->to_kivitendo,
  50   };
  51
  52   $self->setup_list_action_bar;
  53   $self->make_filter_summary;
  54   $self->prepare_report;
  55
  56   $self->report_generator_list_objects(report => $self->{report}, objects => $self->models->get);
  57 }
  58
  59 sub action_edit {
  60   my ($self) = @_;
  61
  62   $::request->{layout}->use_javascript("${_}.js") for qw(kivi.TimeRecording ckeditor/ckeditor ckeditor/adapters/jquery kivi.Validator);
  63
  64   if ($self->time_recording->start_time) {
  65     $self->{start_date} = $self->time_recording->start_time->to_kivitendo;
  66     $self->{start_time} = $self->time_recording->start_time->to_kivitendo_time;
  67   }
  68   if ($self->time_recording->end_time) {
  69     $self->{end_date}   = $self->time_recording->end_time->to_kivitendo;
  70     $self->{end_time}   = $self->time_recording->end_time->to_kivitendo_time;
  71   }
  72
  73   $self->setup_edit_action_bar;
  74
  75   $self->render('time_recording/form',
  76                 title  => t8('Time Recording'),
  77   );
  78 }
  79
  80 sub action_save {
  81   my ($self) = @_;
  82
  83   my @errors = $self->time_recording->validate;
  84   if (@errors) {
  85     $::form->error(t8('Saving the time recording entry failed: #1', join '<br>', @errors));
  86     return;
  87   }
  88
  89   if ( !eval { $self->time_recording->save; 1; } ) {
  90     $::form->error(t8('Saving the time recording entry failed: #1', $EVAL_ERROR));
  91     return;
  92   }
  93
  94   $self->redirect_to(safe_callback());
  95 }
  96
  97 sub action_delete {
  98   my ($self) = @_;
  99
 100   $self->time_recording->delete;
 101
 102   $self->redirect_to(safe_callback());
 103 }
 104
 105 sub init_time_recording {
 106   my $is_new         = !$::form->{id};
 107   my $time_recording = $is_new ? SL::DB::TimeRecording->new(start_time => DateTime->now_local)
 108                                : SL::DB::TimeRecording->new(id => $::form->{id})->load;
 109
 110   my %attributes = %{ $::form->{time_recording} || {} };
 111
 112   foreach my $type (qw(start end)) {
 113     if ($::form->{$type . '_date'}) {
 114       my $date = DateTime->from_kivitendo($::form->{$type . '_date'});
 115       $attributes{$type . '_time'} = $date->clone;
 116       if ($::form->{$type . '_time'}) {
 117         my ($hour, $min) = split ':', $::form->{$type . '_time'};
 118         $attributes{$type . '_time'}->set_hour($hour)  if $hour;
 119         $attributes{$type . '_time'}->set_minute($min) if $min;
 120       }
 121     }
 122   }
 123
 124   $attributes{employee_id}     = SL::DB::Manager::Employee->current->id;
 125   $attributes{staff_member_id} = SL::DB::Manager::Employee->current->id if $is_new;
 126
 127   $time_recording->assign_attributes(%attributes);
 128
 129   return $time_recording;
 130 }
 131
 132 sub init_can_view_all {
 133   $::auth->assert('time_recording_show_all', 1) || $::auth->assert('time_recording_edit_all', 1)
 134 }
 135
 136 sub init_can_edit_all {
 137   $::auth->assert('time_recording_edit_all', 1)
 138 }
 139
 140 sub init_models {
 141   my ($self) = @_;
 142
 143   my @where;
 144   push @where, (staff_member_id => SL::DB::Manager::Employee->current->id) if !$self->can_view_all;
 145
 146   SL::Controller::Helper::GetModels->new(
 147     controller     => $_[0],
 148     sorted         => \%sort_columns,
 149     disable_plugin => 'paginated',
 150     query          => \@where,
 151     with_objects   => [ 'customer', 'type', 'project', 'staff_member', 'employee' ],
 152   );
 153 }
 154
 155 sub init_all_time_recording_types {
 156   SL::DB::Manager::TimeRecordingType->get_all_sorted(query => [obsolete => 0]);
 157 }
 158
 159 sub init_all_employees {
 160   SL::DB::Manager::Employee->get_all_sorted(query => [ deleted => 0 ]);
 161 }
 162
 163 sub check_auth {
 164   $::auth->assert('time_recording');
 165 }
 166
 167 sub check_auth_edit {
 168   my ($self) = @_;
 169
 170   if (!$self->can_edit_all && ($self->time_recording->staff_member_id != SL::DB::Manager::Employee->current->id)) {
 171     $::form->error(t8('You do not have permission to access this entry.'));
 172   }
 173 }
 174
 175 sub prepare_report {
 176   my ($self) = @_;
 177
 178   my $report      = SL::ReportGenerator->new(\%::myconfig, $::form);
 179   $self->{report} = $report;
 180
 181   my @columns  = qw(start_time end_time customer type project description staff_member duration);
 182
 183   my %column_defs = (
 184     start_time   => { text => t8('Start'),        sub => sub { $_[0]->start_time_as_timestamp },
 185                       obj_link => sub { $self->url_for(action => 'edit', 'id' => $_[0]->id, callback => $self->models->get_callback) }  },
 186     end_time     => { text => t8('End'),          sub => sub { $_[0]->end_time_as_timestamp },
 187                       obj_link => sub { $self->url_for(action => 'edit', 'id' => $_[0]->id, callback => $self->models->get_callback) }  },
 188     customer     => { text => t8('Customer'),     sub => sub { $_[0]->customer->displayable_name } },
 189     type         => { text => t8('Type'),         sub => sub { $_[0]->type && $_[0]->type->abbreviation } },
 190     project      => { text => t8('Project'),      sub => sub { $_[0]->project && $_[0]->project->displayable_name } },
 191     description  => { text => t8('Description'),  sub => sub { $_[0]->description_as_stripped_html },
 192                       raw_data => sub { $_[0]->description_as_restricted_html }, # raw_data only used for html(?)
 193                       obj_link => sub { $self->url_for(action => 'edit', 'id' => $_[0]->id, callback => $self->models->get_callback) }  },
 194     staff_member => { text => t8('Mitarbeiter'),  sub => sub { $_[0]->staff_member->safe_name } },
 195     duration     => { text => t8('Duration'),     sub => sub { $_[0]->duration_as_duration_string },
 196                       align => 'right'},
 197   );
 198
 199   $report->set_options(
 200     controller_class      => 'TimeRecording',
 201     std_column_visibility => 1,
 202     output_format         => 'HTML',
 203     title                 => t8('Time Recordings'),
 204     allow_pdf_export      => 1,
 205     allow_csv_export      => 1,
 206   );
 207
 208   $report->set_columns(%column_defs);
 209   $report->set_column_order(@columns);
 210   $report->set_export_options(qw(list filter));
 211   $report->set_options_from_form;
 212
 213   $self->models->disable_plugin('paginated') if $report->{options}{output_format} =~ /^(pdf|csv)$/i;
 214   $self->models->add_additional_url_params(filter => $::form->{filter});
 215   $self->models->finalize;
 216   $self->models->set_report_generator_sort_options(report => $report, sortable_columns => [keys %sort_columns]);
 217
 218   $report->set_options(
 219     raw_top_info_text    => $self->render('time_recording/report_top',    { output => 0 }),
 220     raw_bottom_info_text => $self->render('time_recording/report_bottom', { output => 0 }, models => $self->models),
 221     attachment_basename  => t8('time_recordings') . strftime('_%Y%m%d', localtime time),
 222   );
 223 }
 224
 225 sub make_filter_summary {
 226   my ($self) = @_;
 227
 228   my $filter = $::form->{filter} || {};
 229   my @filter_strings;
 230
 231   my $staff_member = $filter->{staff_member_id} ? SL::DB::Employee->new(id => $filter->{staff_member_id})->load->safe_name : '';
 232
 233   my @filters = (
 234     [ $filter->{"start_time:date::ge"},                        t8('From Start')      ],
 235     [ $filter->{"start_time:date::le"},                        t8('To Start')        ],
 236     [ $filter->{"customer"}->{"name:substr::ilike"},           t8('Customer')        ],
 237     [ $filter->{"customer"}->{"customernumber:substr::ilike"}, t8('Customer Number') ],
 238     [ $staff_member,                                           t8('Mitarbeiter')     ],
 239   );
 240
 241   for (@filters) {
 242     push @filter_strings, "$_->[1]: $_->[0]" if $_->[0];
 243   }
 244
 245   $self->{filter_summary} = join ', ', @filter_strings;
 246 }
 247
 248 sub setup_list_action_bar {
 249   my ($self) = @_;
 250
 251   for my $bar ($::request->layout->get('actionbar')) {
 252     $bar->add(
 253       action => [
 254         t8('Update'),
 255         submit    => [ '#filter_form', { action => 'TimeRecording/list' } ],
 256         accesskey => 'enter',
 257       ],
 258       action => [
 259         t8('Add'),
 260         link => $self->url_for(action => 'edit', callback => $self->models->get_callback),
 261       ],
 262     );
 263   }
 264 }
 265
 266 sub setup_edit_action_bar {
 267   my ($self) = @_;
 268
 269   for my $bar ($::request->layout->get('actionbar')) {
 270     $bar->add(
 271       action => [
 272         t8('Save'),
 273         submit => [ '#form', { action => 'TimeRecording/save' } ],
 274         checks => [ 'kivi.validate_form' ],
 275       ],
 276       action => [
 277         t8('Delete'),
 278         submit  => [ '#form', { action => 'TimeRecording/delete' } ],
 279         only_if => $self->time_recording->id,
 280       ],
 281       action => [
 282         t8('Cancel'),
 283         link  => $self->url_for(safe_callback()),
 284       ],
 285     );
 286   }
 287 }
 288
 289 sub safe_callback {
 290   $::form->{callback} || (action => 'list')
 291 }
 292
 293 1;