SL/DB/Chart.pm

   1 package SL::DB::Chart;
   2
   3 use strict;
   4
   5 use SL::DB::MetaSetup::Chart;
   6 use SL::DB::Manager::Chart;
   7 use SL::DBUtils;
   8 use Rose::DB::Object::Helpers qw(as_tree);
   9 use SL::DB::Helper::AccountingPeriod qw(get_balance_starting_date);
  10 use SL::Locale::String qw(t8);
  11
  12 __PACKAGE__->meta->add_relationships(taxkeys => { type         => 'one to many',
  13                                                   class        => 'SL::DB::TaxKey',
  14                                                   column_map   => { id => 'chart_id' },
  15                                                 },
  16                                     );
  17
  18 __PACKAGE__->meta->initialize;
  19
  20 sub get_active_taxkey {
  21   my ($self, $date) = @_;
  22   $date ||= DateTime->today_local;
  23
  24   my $cache = $::request->cache("get_active_taxkey")->{$date} //= {};
  25   return $cache->{$self->id} if $cache->{$self->id};
  26
  27   require SL::DB::TaxKey;
  28   return $cache->{$self->id} = SL::DB::Manager::TaxKey->get_all(
  29     query   => [ and => [ chart_id  => $self->id,
  30                           startdate => { le => $date } ] ],
  31     sort_by => "startdate DESC")->[0];
  32 }
  33
  34 sub get_active_taxrate {
  35   my ($self, $date) = @_;
  36   $date ||= DateTime->today_local;
  37   require SL::DB::Tax;
  38   my $tax = SL::DB::Manager::Tax->find_by( id => $self->get_active_taxkey->tax_id );
  39   return $tax->rate;
  40 }
  41
  42
  43 sub get_balance {
  44   my ($self, %params) = @_;
  45
  46   return undef unless $self->id;
  47
  48   # return empty string if user doesn't have rights
  49   return "" unless ($main::auth->assert('general_ledger', 1));
  50
  51   my $query = qq|SELECT SUM(amount) AS sum FROM acc_trans WHERE chart_id = ? AND transdate >= ? and transdate <= ?|;
  52
  53   my $startdate = $self->get_balance_starting_date;
  54   my $today     = DateTime->today_local;
  55
  56   my ($balance)  = selectfirst_array_query($::form, $self->db->dbh, $query, $self->id, $startdate, $today);
  57
  58   return $balance;
  59 };
  60
  61 sub formatted_balance_dc {
  62   my ($self, %params) = @_;
  63
  64   # return empty string if user doesn't have rights
  65   return "" unless ($main::auth->assert('general_ledger', 1));
  66
  67   # return empty string if chart has never been booked
  68   return "" unless $self->has_transaction;
  69
  70   # return abs of current balance with the abbreviation for debit or credit behind it
  71   my $balance = $self->get_balance || 0;
  72   my $dc_abbreviation = $balance > 0 ? t8("Credit (one letter abbreviation)") : t8("Debit (one letter abbreviation)");
  73   my $amount = $::form->format_amount(\%::myconfig, abs($balance), 2);
  74
  75   return "$amount $dc_abbreviation";
  76 };
  77
  78 sub number_of_transactions {
  79   my ($self) = @_;
  80   require SL::DB::AccTransaction;
  81   return SL::DB::Manager::AccTransaction->get_all_count( where => [ chart_id => $self->id ] );
  82 };
  83
  84 sub has_transaction {
  85   my ($self) = @_;
  86
  87   $self->db->dbh->selectrow_array('select exists(select 1 from acc_trans where chart_id = ?)', {}, $self->id);
  88 }
  89
  90 sub new_chart_valid {
  91   my ($self) = @_;
  92
  93   if ( $self->valid_from && DateTime->today >= $self->valid_from ) {
  94     return 1;
  95   } else {
  96     return 0;
  97   };
  98 }
  99
 100 sub displayable_name {
 101   my ($self) = @_;
 102
 103   return join ' ', grep $_, $self->accno, $self->description;
 104 }
 105
 106 sub displayable_category {
 107   my ($self) = @_;
 108
 109   return t8("Account Category E") if $self->category eq "E";
 110   return t8("Account Category I") if $self->category eq "I";
 111   return t8("Account Category A") if $self->category eq "A";
 112   return t8("Account Category L") if $self->category eq "L";
 113   return t8("Account Category Q") if $self->category eq "Q";
 114   return t8("Account Category C") if $self->category eq "C";
 115   return '';
 116 }
 117
 118 sub date_of_last_transaction {
 119   my ($self) = @_;
 120
 121   die unless $self->id;
 122
 123   return '' unless $self->has_transaction;
 124
 125   my ($transdate) = $self->db->dbh->selectrow_array('select max(transdate) from acc_trans where chart_id = ?', {}, $self->id);
 126   return DateTime->from_lxoffice($transdate);
 127 }
 128
 129 1;
 130
 131 __END__
 132
 133 =pod
 134
 135 =encoding utf8
 136
 137 =head1 NAME
 138
 139 SL::DB::Chart - Rose database model for the "chart" table
 140
 141 =head1 FUNCTIONS
 142
 143 =over 4
 144
 145 =item C<get_active_taxkey $date>
 146
 147 Returns the active tax key object for a given date. C<$date> defaults
 148 to the current date if undefined.
 149
 150 =item C<get_active_taxrate $date>
 151
 152 Returns the tax rate of the active tax key as determined by
 153 C<get_active_taxkey>.
 154
 155 =item C<get_balance>
 156
 157 Returns the current balance of the chart (sum of amount in acc_trans, positive
 158 or negative). The transactions are filtered by transdate, the maximum date is
 159 the current day, the minimum date is determined by get_balance_starting_date.
 160
 161 The balance should be same as that in the balance report for that chart, with
 162 the asofdate as the current day, and the accounting_method "accrual".
 163
 164 =item C<formatted_balance_dc>
 165
 166 Returns a formatted version of C<get_balance>, taking the absolute value and
 167 adding the translated abbreviation for debit or credit after the number.
 168
 169 =item C<number_of_transactions>
 170
 171 Returns number of transactions that exist for this chart in acc_trans.
 172
 173 =item C<has_transaction>
 174
 175 Returns 1 or 0, depending whether the chart has a transaction in the database
 176 or not.
 177
 178 =item C<date_of_last_transaction>
 179
 180 Returns the date of the last transaction of the chart in the database, which
 181 may lie in the future.
 182
 183 =item C<new_chart_valid>
 184
 185 Checks whether a follow-up chart is configured, and returns 1 or 0 depending on
 186 whether the valid_from date is before or after the current date.
 187 Is this even used anywhere?
 188
 189 =back
 190
 191 =head1 BUGS
 192
 193 Nothing here yet.
 194
 195 =head1 AUTHOR
 196
 197 Moritz Bunkus E<lt>m.bunkus@linet-services.deE<gt>
 198
 199 G. Richardson E<lt>information@kivitendo-premium.deE<gt>
 200
 201 =cut