SL/DB/CsvImportProfile.pm

   1 package SL::DB::CsvImportProfile;
   2
   3 use strict;
   4
   5 use List::Util qw(first);
   6
   7 use SL::DB::MetaSetup::CsvImportProfile;
   8
   9 __PACKAGE__->meta->add_relationship(
  10   settings => {
  11     type       => 'one to many',
  12     class      => 'SL::DB::CsvImportProfileSetting',
  13     column_map => { id      => 'csv_import_profile_id' },
  14   },
  15 );
  16
  17 __PACKAGE__->meta->initialize;
  18
  19 __PACKAGE__->meta->make_manager_class;
  20
  21 __PACKAGE__->before_save('_before_save_unset_default_on_others');
  22
  23 #
  24 # public functions
  25 #
  26
  27 sub new_with_default {
  28   my ($class, $type) = @_;
  29
  30   return $class->new(type => $type)->set_defaults;
  31 }
  32
  33 sub set_defaults {
  34   my ($self) = @_;
  35
  36   $self->_set_defaults(sep_char     => ',',
  37                        quote_char   => '"',
  38                        escape_char  => '"',
  39                        charset      => 'CP850',
  40                        numberformat => $::myconfig{numberformat},
  41                        duplicates   => 'no_check',
  42                       );
  43
  44   if ($self->type eq 'parts') {
  45     my $bugru = SL::DB::Manager::Buchungsgruppe->find_by(description => { like => 'Standard%19%' });
  46
  47     $self->_set_defaults(sellprice_places          => 2,
  48                          sellprice_adjustment      => 0,
  49                          sellprice_adjustment_type => 'percent',
  50                          article_number_policy     => 'update_prices',
  51                          part_group_sep_char       => '!',
  52                          shoparticle_if_missing    => '0',
  53                          parts_type                => 'part',
  54                          default_buchungsgruppe    => ($bugru ? $bugru->description : undef),
  55                          apply_buchungsgruppe      => 'all',
  56                         );
  57   } else {
  58     $self->_set_defaults(table => 'customer');
  59   }
  60
  61   return $self;
  62 }
  63
  64 sub set {
  65   my ($self, %params) = @_;
  66
  67   while (my ($key, $value) = each %params) {
  68     my $setting = $self->_get_setting($key);
  69
  70     if (!$setting) {
  71       $setting = SL::DB::CsvImportProfileSetting->new(key => $key);
  72       $self->settings(@{ $self->settings || [] }, $setting);
  73     }
  74
  75     $setting->value($value);
  76   }
  77
  78   return $self;
  79 }
  80
  81 sub get {
  82   my ($self, $key, $default) = @_;
  83
  84   my $setting = $self->_get_setting($key);
  85   return $setting ? $setting->value : $default;
  86 }
  87
  88 sub _set_defaults {
  89   my ($self, %params) = @_;
  90
  91   while (my ($key, $value) = each %params) {
  92     $self->settings(@{ $self->settings || [] }, { key => $key, value => $value }) if !$self->_get_setting($key);
  93   }
  94
  95   return $self;
  96 }
  97
  98 #
  99 # hooks
 100 #
 101
 102 sub _before_save_unset_default_on_others {
 103   my ($self) = @_;
 104
 105   if ($self->is_default) {
 106     SL::DB::Manager::CsvImportProfile->update_all(set   => { is_default => 0 },
 107                                                   where => [ type       => $self->type,
 108                                                              '!id'      => $self->id ]);
 109   }
 110
 111   return 1;
 112 }
 113
 114 #
 115 # helper functions
 116 #
 117
 118 sub _get_setting {
 119   my ($self, $key) = @_;
 120   return first { $_->key eq $key } @{ $self->settings || [] };
 121 }
 122
 123 1;