922ab7afb5d1344c3f4b4bb0f4916a652b16fe9a
[kivitendo-erp.git] / SL / DB / CsvImportProfile.pm
1 package SL::DB::CsvImportProfile;
2
3 use strict;
4
5 use List::Util qw(first);
6
7 require SL::DB::MetaSetup::CsvImportProfile;
8
9 __PACKAGE__->meta->add_relationship(
10   settings => {
11     type       => 'one to many',
12     class      => 'SL::DB::CsvImportProfileSetting',
13     column_map => { id      => 'csv_import_profile_id' },
14   },
15 );
16
17 __PACKAGE__->meta->initialize;
18
19 __PACKAGE__->meta->make_manager_class;
20
21 __PACKAGE__->before_save('_before_save_unset_default_on_others');
22
23 #
24 # public functions
25 #
26
27 sub new_with_default {
28   my ($class, $type) = @_;
29
30   return $class->new(type => $type)->set_defaults;
31 }
32
33 sub set_defaults {
34   my ($self) = @_;
35
36   $self->_set_defaults(sep_char     => ',',
37                        quote_char   => '"',
38                        escape_char  => '"',
39                        charset      => 'CP850',
40                        numberformat => $::myconfig{numberformat},
41                        duplicates   => 'no_check',
42                       );
43
44   return $self;
45 }
46
47 sub set {
48   my ($self, %params) = @_;
49
50   while (my ($key, $value) = each %params) {
51     my $setting = $self->_get_setting($key);
52
53     if (!$setting) {
54       $setting = SL::DB::CsvImportProfileSetting->new(key => $key);
55       $self->settings(@{ $self->settings || [] }, $setting);
56     }
57
58     $setting->value($value);
59   }
60
61   return $self;
62 }
63
64 sub get {
65   my ($self, $key, $default) = @_;
66
67   my $setting = $self->_get_setting($key);
68   return $setting ? $setting->value : $default;
69 }
70
71 sub _set_defaults {
72   my ($self, %params) = @_;
73
74   while (my ($key, $value) = each %params) {
75     $self->settings(@{ $self->settings || [] }, { key => $key, value => $value }) if !$self->_get_setting($key);
76   }
77
78   return $self;
79 }
80
81 sub clone_and_reset_deep {
82   my ($self) = @_;
83
84   my $clone = $self->clone_and_reset;
85   $clone->settings(map { $_->clone_and_reset } $self->settings);
86   $clone->is_default(0);
87   $clone->name('');
88
89   return $clone;
90 }
91
92 sub flatten {
93   my ($self) = @_;
94
95   return map {
96     $_->key => $_->value
97   } $self->settings;
98 }
99
100 #
101 # hooks
102 #
103
104 sub _before_save_unset_default_on_others {
105   my ($self) = @_;
106
107   if ($self->is_default) {
108     SL::DB::Manager::CsvImportProfile->update_all(set   => { is_default => 0 },
109                                                   where => [ type       => $self->type,
110                                                              '!id'      => $self->id ]);
111   }
112
113   return 1;
114 }
115
116 #
117 # helper functions
118 #
119
120 sub _get_setting {
121   my ($self, $key) = @_;
122   return first { $_->key eq $key } @{ $self->settings || [] };
123 }
124
125 1;