SL/DB/Customer.pm

   1 package SL::DB::Customer;
   2
   3 use strict;
   4
   5 use Rose::DB::Object::Helpers qw(as_tree);
   6
   7 use SL::Locale::String qw(t8);
   8 use SL::DBUtils ();
   9 use SL::DB::MetaSetup::Customer;
  10 use SL::DB::Manager::Customer;
  11 use SL::DB::Helper::IBANValidation;
  12 use SL::DB::Helper::TransNumberGenerator;
  13 use SL::DB::Helper::VATIDNrValidation;
  14 use SL::DB::Helper::CustomVariables (
  15   module      => 'CT',
  16   cvars_alias => 1,
  17 );
  18 use SL::DB::Helper::DisplayableNamePreferences (
  19   title   => t8('Customer'),
  20   options => [ {name => 'customernumber', title => t8('Customer Number') },
  21                {name => 'name',           title => t8('Name')   },
  22                {name => 'street',         title => t8('Street') },
  23                {name => 'city',           title => t8('City') },
  24                {name => 'zipcode',        title => t8('Zipcode')},
  25                {name => 'email',          title => t8('E-Mail') },
  26                {name => 'phone',          title => t8('Phone')  }, ]
  27 );
  28
  29 use SL::DB::VC;
  30
  31 __PACKAGE__->meta->add_relationship(
  32   additional_billing_addresses => {
  33     type         => 'one to many',
  34     class        => 'SL::DB::AdditionalBillingAddress',
  35     column_map   => { id      => 'customer_id' },
  36     manager_args => { sort_by => 'lower(additional_billing_addresses.name)' },
  37   },
  38   shipto => {
  39     type         => 'one to many',
  40     class        => 'SL::DB::Shipto',
  41     column_map   => { id      => 'trans_id' },
  42     manager_args => { sort_by => 'lower(shipto.shiptoname)' },
  43     query_args   => [ module   => 'CT' ],
  44   },
  45   contacts => {
  46     type         => 'one to many',
  47     class        => 'SL::DB::Contact',
  48     column_map   => { id      => 'cp_cv_id' },
  49     manager_args => { sort_by => 'lower(contacts.cp_name)' },
  50   },
  51 );
  52
  53 __PACKAGE__->meta->initialize;
  54
  55 __PACKAGE__->before_save('_before_save_set_customernumber');
  56
  57
  58 sub _before_save_set_customernumber {
  59   my ($self) = @_;
  60
  61   $self->create_trans_number if !defined $self->customernumber || $self->customernumber eq '';
  62   return 1;
  63 }
  64
  65 sub validate {
  66   my ($self) = @_;
  67
  68   my @errors;
  69   push @errors, $::locale->text('The customer name is missing.') if !$self->name;
  70   push @errors, $self->validate_ibans;
  71   push @errors, $self->validate_vat_id_numbers;
  72
  73   return @errors;
  74 }
  75
  76 sub short_address {
  77   my ($self) = @_;
  78
  79   return join ', ', grep { $_ } $self->street, $self->zipcode, $self->city;
  80 }
  81
  82 sub last_used_ar_chart {
  83   my ($self) = @_;
  84
  85   my $query = <<EOSQL;
  86     SELECT c.id
  87     FROM chart c
  88     JOIN acc_trans ac ON (ac.chart_id = c.id)
  89     JOIN ar a ON (a.id = ac.trans_id)
  90     WHERE (a.customer_id = ?)
  91       AND (c.category = 'I')
  92       AND (c.link !~ '_(paid|tax)')
  93       AND (a.id IN (SELECT max(a2.id) FROM ar a2 WHERE a2.customer_id = ?))
  94     ORDER BY ac.acc_trans_id ASC
  95     LIMIT 1
  96 EOSQL
  97
  98   my ($chart_id) = SL::DBUtils::selectfirst_array_query($::form, $self->db->dbh, $query, ($self->id) x 2);
  99
 100   return if !$chart_id;
 101   return SL::DB::Chart->load_cached($chart_id);
 102 }
 103
 104 sub is_customer { 1 };
 105 sub is_vendor   { 0 };
 106 sub payment_terms { goto &payment }
 107 sub number { goto &customernumber }
 108
 109 sub create_zugferd_invoices_for_this_customer {
 110   my ($self) = @_;
 111
 112   no warnings 'once';
 113   return $::instance_conf->get_create_zugferd_invoices if $self->create_zugferd_invoices == -1;
 114   return $self->create_zugferd_invoices;
 115 }
 116
 117 1;