SL/DB/DeliveryOrder.pm

   1 package SL::DB::DeliveryOrder;
   2
   3 use strict;
   4
   5 use Carp;
   6
   7 use Rose::DB::Object::Helpers ();
   8
   9 use SL::DB::MetaSetup::DeliveryOrder;
  10 use SL::DB::Manager::DeliveryOrder;
  11 use SL::DB::Helper::FlattenToForm;
  12 use SL::DB::Helper::LinkedRecords;
  13 use SL::DB::Helper::TransNumberGenerator;
  14
  15 use List::Util qw(first);
  16
  17 __PACKAGE__->meta->add_relationship(orderitems => { type         => 'one to many',
  18                                                     class        => 'SL::DB::DeliveryOrderItem',
  19                                                     column_map   => { id => 'delivery_order_id' },
  20                                                     manager_args => { with_objects => [ 'part' ] }
  21                                                   },
  22                                     custom_shipto => {
  23                                       type        => 'one to one',
  24                                       class       => 'SL::DB::Shipto',
  25                                       column_map  => { id => 'trans_id' },
  26                                       query_args  => [ module => 'DO' ],
  27                                     },
  28                                    );
  29
  30 __PACKAGE__->meta->initialize;
  31
  32 __PACKAGE__->before_save('_before_save_set_donumber');
  33
  34 # hooks
  35
  36 sub _before_save_set_donumber {
  37   my ($self) = @_;
  38
  39   $self->create_trans_number if !$self->donumber;
  40
  41   return 1;
  42 }
  43
  44 # methods
  45
  46 sub items { goto &orderitems; }
  47
  48 sub items_sorted {
  49   my ($self) = @_;
  50
  51   return [ sort {$a->id <=> $b->id } @{ $self->items } ];
  52 }
  53
  54 sub sales_order {
  55   my $self   = shift;
  56   my %params = @_;
  57
  58
  59   require SL::DB::Order;
  60   my $orders = SL::DB::Manager::Order->get_all(
  61     query => [
  62       ordnumber => $self->ordnumber,
  63       @{ $params{query} || [] },
  64     ],
  65   );
  66
  67   return first { $_->is_type('sales_order') } @{ $orders };
  68 }
  69
  70 sub type {
  71   return shift->customer_id ? 'sales_delivery_order' : 'purchase_delivery_order';
  72 }
  73
  74 sub displayable_state {
  75   my ($self) = @_;
  76
  77   return join '; ',
  78     ($self->closed    ? $::locale->text('closed')    : $::locale->text('open')),
  79     ($self->delivered ? $::locale->text('delivered') : $::locale->text('not delivered'));
  80 }
  81
  82 sub date {
  83   goto &transdate;
  84 }
  85
  86 sub _clone_orderitem_cvar {
  87   my ($cvar) = @_;
  88
  89   my $cloned = Rose::DB::Object::Helpers::clone_and_reset($_);
  90   $cloned->sub_module('delivery_order_items');
  91
  92   return $cloned;
  93 }
  94
  95 sub new_from {
  96   my ($class, $source, %params) = @_;
  97
  98   croak("Unsupported source object type '" . ref($source) . "'") unless ref($source) eq 'SL::DB::Order';
  99
 100   my $terms = $source->can('payment_id') && $source->payment_id ? $source->payment_terms->terms_netto : 0;
 101
 102   my %args = ( map({ ( $_ => $source->$_ ) } qw(cp_id currency_id customer_id cusordnumber department_id employee_id globalproject_id intnotes language_id notes
 103                                                 ordnumber reqdate salesman_id shippingpoint shipvia taxincluded taxzone_id transaction_description vendor_id
 104                                              )),
 105                closed    => 0,
 106                is_sales  => !!$source->customer_id,
 107                delivered => 0,
 108                terms     => $terms,
 109                transdate => DateTime->today_local,
 110             );
 111
 112   # Custom shipto addresses (the ones specific to the sales/purchase
 113   # record and not to the customer/vendor) are only linked from
 114   # shipto -> delivery_orders. Meaning delivery_orders.shipto_id
 115   # will not be filled in that case. Therefore we have to return the
 116   # new shipto object as a separate object so that the caller can
 117   # save it, too.
 118   my $custom_shipto;
 119   if (!$source->shipto_id && $source->id) {
 120     my $old = $source->custom_shipto;
 121     if ($old) {
 122       $custom_shipto = SL::DB::Shipto->new(
 123         map  { +($_ => $old->$_) }
 124         grep { !m{^ (?: itime | mtime | shipto_id | trans_id ) $}x }
 125         map  { $_->name }
 126         @{ $old->meta->columns }
 127       );
 128       $custom_shipto->module('DO');
 129     }
 130
 131   } else {
 132     $args{shipto_id} = $source->shipto_id;
 133   }
 134
 135   my $delivery_order = $class->new(%args, %{ $params{attributes} || {} });
 136
 137   my @items = map {
 138     my $source_item      = $_;
 139     my @custom_variables = map { _clone_orderitem_cvar($_) } @{ $source_item->custom_variables };
 140
 141     SL::DB::DeliveryOrderItem->new(map({ ( $_ => $source_item->$_ ) }
 142                                          qw(base_qty cusordnumber description discount lastcost longdescription marge_price_factor ordnumber parts_id price_factor price_factor_id
 143                                             project_id qty reqdate sellprice serialnumber transdate unit
 144                                          )),
 145                                    custom_variables => \@custom_variables);
 146
 147   } @{ $source->items_sorted };
 148
 149   @items = grep { $_->qty * 1 } @items if $params{skip_items_zero_qty};
 150
 151   $delivery_order->items(\@items);
 152
 153   return ($delivery_order, $custom_shipto);
 154 }
 155
 156 1;
 157 __END__
 158
 159 =pod
 160
 161 =encoding utf8
 162
 163 =head1 NAME
 164
 165 SL::DB::DeliveryOrder - Rose model for delivery orders (table
 166 "delivery_orders")
 167
 168 =head1 FUNCTIONS
 169
 170 =over 4
 171
 172 =item C<date>
 173
 174 An alias for C<transdate> for compatibility with other sales/purchase models.
 175
 176 =item C<displayable_state>
 177
 178 Returns a human-readable description of the state regarding being
 179 closed and delivered.
 180
 181 =item C<items>
 182
 183 An alias for C<deliver_orer_items> for compatibility with other
 184 sales/purchase models.
 185
 186 =item C<items_sorted>
 187
 188 Returns the delivery order items sorted by their ID (same order they
 189 appear in the frontend delivery order masks).
 190
 191 =item C<new_from $source, %params>
 192
 193 Creates a new C<SL::DB::DeliveryOrder> instance and copies as much
 194 information from C<$source> as possible. At the moment only instances
 195 of C<SL::DB::Order> (sales quotations, sales orders, requests for
 196 quotations and purchase orders) are supported as sources.
 197
 198 The conversion copies order items into delivery order items. Dates are copied
 199 as appropriate, e.g. the C<transdate> field will be set to the current date.
 200
 201 Returns one or two objects depending on the context. In list context
 202 the new delivery order instance and a shipto instance will be
 203 returned. In scalar instance only the delivery order instance is
 204 returned.
 205
 206 Custom shipto addresses (the ones specific to the sales/purchase
 207 record and not to the customer/vendor) are only linked from C<shipto>
 208 to C<delivery_orders>. Meaning C<delivery_orders.shipto_id> will not
 209 be filled in that case. That's why a separate shipto object is created
 210 and returned.
 211
 212 The objects returned are not saved.
 213
 214 C<%params> can include the following options:
 215
 216 =over 2
 217
 218 =item C<skip_items_zero_qty>
 219
 220 If trueish then items with a quantity of 0 are skipped.
 221
 222 =item C<attributes>
 223
 224 An optional hash reference. If it exists then it is passed to C<new>
 225 allowing the caller to set certain attributes for the new delivery
 226 order.
 227
 228 =back
 229
 230 =item C<sales_order>
 231
 232 TODO: Describe sales_order
 233
 234 =item C<type>
 235
 236 Returns a stringdescribing this record's type: either
 237 C<sales_delivery_order> or C<purchase_delivery_order>.
 238
 239 =back
 240
 241 =head1 BUGS
 242
 243 Nothing here yet.
 244
 245 =head1 AUTHOR
 246
 247 Moritz Bunkus E<lt>m.bunkus@linet-services.deE<gt>
 248
 249 =cut