SL/DB/DeliveryOrder.pm

   1 package SL::DB::DeliveryOrder;
   2
   3 use strict;
   4
   5 use Carp;
   6
   7 use SL::DB::MetaSetup::DeliveryOrder;
   8 use SL::DB::Manager::DeliveryOrder;
   9 use SL::DB::Helper::FlattenToForm;
  10 use SL::DB::Helper::LinkedRecords;
  11 use SL::DB::Helper::TransNumberGenerator;
  12
  13 use List::Util qw(first);
  14
  15 __PACKAGE__->meta->add_relationship(orderitems => { type         => 'one to many',
  16                                                     class        => 'SL::DB::DeliveryOrderItem',
  17                                                     column_map   => { id => 'delivery_order_id' },
  18                                                     manager_args => { with_objects => [ 'part' ] }
  19                                                   },
  20                                    );
  21
  22 __PACKAGE__->meta->initialize;
  23
  24 __PACKAGE__->before_save('_before_save_set_donumber');
  25
  26 # hooks
  27
  28 sub _before_save_set_donumber {
  29   my ($self) = @_;
  30
  31   $self->create_trans_number if !$self->donumber;
  32
  33   return 1;
  34 }
  35
  36 # methods
  37
  38 sub items { goto &orderitems; }
  39
  40 sub items_sorted {
  41   my ($self) = @_;
  42
  43   return [ sort {$a->id <=> $b->id } @{ $self->items } ];
  44 }
  45
  46 sub sales_order {
  47   my $self   = shift;
  48   my %params = @_;
  49
  50
  51   require SL::DB::Order;
  52   my $orders = SL::DB::Manager::Order->get_all(
  53     query => [
  54       ordnumber => $self->ordnumber,
  55       @{ $params{query} || [] },
  56     ],
  57   );
  58
  59   return first { $_->is_type('sales_order') } @{ $orders };
  60 }
  61
  62 sub type {
  63   return shift->customer_id ? 'sales_delivery_order' : 'purchase_delivery_order';
  64 }
  65
  66 sub displayable_state {
  67   my ($self) = @_;
  68
  69   return join '; ',
  70     ($self->closed    ? $::locale->text('closed')    : $::locale->text('open')),
  71     ($self->delivered ? $::locale->text('delivered') : $::locale->text('not delivered'));
  72 }
  73
  74 sub date {
  75   goto &transdate;
  76 }
  77
  78 sub new_from {
  79   my ($class, $source, %params) = @_;
  80
  81   croak("Unsupported source object type '" . ref($source) . "'") unless ref($source) eq 'SL::DB::Order';
  82
  83   my $terms = $source->can('payment_id') && $source->payment_id ? $source->payment_terms->terms_netto : 0;
  84
  85   my %args = ( map({ ( $_ => $source->$_ ) } qw(cp_id currency_id customer_id cusordnumber department_id employee_id globalproject_id intnotes language_id notes
  86                                                 ordnumber reqdate salesman_id shippingpoint shipvia taxincluded taxzone_id transaction_description vendor_id
  87                                              )),
  88                closed    => 0,
  89                is_sales  => !!$source->customer_id,
  90                delivered => 0,
  91                terms     => $terms,
  92                transdate => DateTime->today_local,
  93             );
  94
  95   # Custom shipto addresses (the ones specific to the sales/purchase
  96   # record and not to the customer/vendor) are only linked from
  97   # shipto -> delivery_orders. Meaning delivery_orders.shipto_id
  98   # will not be filled in that case. Therefore we have to return the
  99   # new shipto object as a separate object so that the caller can
 100   # save it, too.
 101   my $custom_shipto;
 102   if (!$source->shipto_id && $source->id) {
 103     require SL::DB::Shipto;
 104
 105     my $old = SL::DB::Manager::Shipto->find_by(trans_id => $source->id);
 106     if ($old) {
 107       $custom_shipto = SL::DB::Shipto->new(
 108         map  { +($_ => $old->$_) }
 109         grep { !m{^ (?: itime | mtime | shipto_id | trans_id ) $}x }
 110         map  { $_->name }
 111         @{ $old->meta->columns }
 112       );
 113     }
 114
 115   } else {
 116     $args{shipto_id} = $source->shipto_id;
 117   }
 118
 119   my $delivery_order = $class->new(%args, %params);
 120
 121   my @items = map {
 122     my $source_item = $_;
 123     SL::DB::DeliveryOrderItem->new(map({ ( $_ => $source_item->$_ ) }
 124                                    qw(base_qty cusordnumber description discount lastcost longdescription marge_price_factor ordnumber parts_id price_factor price_factor_id
 125                                       project_id qty reqdate sellprice serialnumber transdate unit
 126                                    )));
 127   } @{ $source->items_sorted };
 128
 129   $delivery_order->items(\@items);
 130
 131   return ($delivery_order, $custom_shipto);
 132 }
 133
 134 1;
 135 __END__
 136
 137 =pod
 138
 139 =encoding utf8
 140
 141 =head1 NAME
 142
 143 SL::DB::DeliveryOrder - Rose model for delivery orders (table
 144 "delivery_orders")
 145
 146 =head1 FUNCTIONS
 147
 148 =over 4
 149
 150 =item C<date>
 151
 152 An alias for L</transdate> for compatibility with other sales/purchase models.
 153
 154 =item C<displayable_state>
 155
 156 Returns a human-readable description of the state regarding being
 157 closed and delivered.
 158
 159 =item C<items>
 160
 161 An alias for L</deliver_orer_items> for compatibility with other
 162 sales/purchase models.
 163
 164 =item C<items_sorted>
 165
 166 Returns the delivery order items sorted by their ID (same order they
 167 appear in the frontend delivery order masks).
 168
 169 =item C<new_from $source>
 170
 171 Creates a new C<SL::DB::DeliveryOrder> instance and copies as much
 172 information from C<$source> as possible. At the moment only instances
 173 of C<SL::DB::Order> (sales quotations, sales orders, requests for
 174 quotations and purchase orders) are supported as sources.
 175
 176 The conversion copies order items into delivery order items. Dates are copied
 177 as appropriate, e.g. the C<transdate> field will be set to the current date.
 178
 179 Returns one or two objects depending on the context. In list context
 180 the new delivery order instance and a shipto instance will be
 181 returned. In scalar instance only the delivery order instance is
 182 returned.
 183
 184 Custom shipto addresses (the ones specific to the sales/purchase
 185 record and not to the customer/vendor) are only linked from C<shipto>
 186 to C<delivery_orders>. Meaning C<delivery_orders.shipto_id> will not
 187 be filled in that case. That's why a separate shipto object is created
 188 and returned.
 189
 190 The objects returned are not saved.
 191
 192 =item C<sales_order>
 193
 194 TODO: Describe sales_order
 195
 196 =item C<type>
 197
 198 Returns a stringdescribing this record's type: either
 199 C<sales_delivery_order> or C<purchase_delivery_order>.
 200
 201 =back
 202
 203 =head1 BUGS
 204
 205 Nothing here yet.
 206
 207 =head1 AUTHOR
 208
 209 Moritz Bunkus E<lt>m.bunkus@linet-services.deE<gt>
 210
 211 =cut