SL/DB/DeliveryOrder.pm

   1 package SL::DB::DeliveryOrder;
   2
   3 use strict;
   4
   5 use Carp;
   6
   7 use Rose::DB::Object::Helpers ();
   8
   9 use SL::DB::MetaSetup::DeliveryOrder;
  10 use SL::DB::Manager::DeliveryOrder;
  11 use SL::DB::Helper::AttrHTML;
  12 use SL::DB::Helper::AttrSorted;
  13 use SL::DB::Helper::FlattenToForm;
  14 use SL::DB::Helper::LinkedRecords;
  15 use SL::DB::Helper::TransNumberGenerator;
  16
  17 use List::Util qw(first);
  18
  19 __PACKAGE__->meta->add_relationship(orderitems => { type         => 'one to many',
  20                                                     class        => 'SL::DB::DeliveryOrderItem',
  21                                                     column_map   => { id => 'delivery_order_id' },
  22                                                     manager_args => { with_objects => [ 'part' ] }
  23                                                   },
  24                                     custom_shipto => {
  25                                       type        => 'one to one',
  26                                       class       => 'SL::DB::Shipto',
  27                                       column_map  => { id => 'trans_id' },
  28                                       query_args  => [ module => 'DO' ],
  29                                     },
  30                                    );
  31
  32 __PACKAGE__->meta->initialize;
  33
  34 __PACKAGE__->attr_html('notes');
  35 __PACKAGE__->attr_sorted('items');
  36
  37 __PACKAGE__->before_save('_before_save_set_donumber');
  38
  39 # hooks
  40
  41 sub _before_save_set_donumber {
  42   my ($self) = @_;
  43
  44   $self->create_trans_number if !$self->donumber;
  45
  46   return 1;
  47 }
  48
  49 # methods
  50
  51 sub items { goto &orderitems; }
  52 sub add_items { goto &add_orderitems; }
  53 sub payment_terms { goto &payment; }
  54 sub record_number { goto &donumber; }
  55
  56 sub sales_order {
  57   my $self   = shift;
  58   my %params = @_;
  59
  60
  61   require SL::DB::Order;
  62   my $orders = SL::DB::Manager::Order->get_all(
  63     query => [
  64       ordnumber => $self->ordnumber,
  65       @{ $params{query} || [] },
  66     ],
  67   );
  68
  69   return first { $_->is_type('sales_order') } @{ $orders };
  70 }
  71
  72 sub type {
  73   return shift->customer_id ? 'sales_delivery_order' : 'purchase_delivery_order';
  74 }
  75
  76 sub displayable_type {
  77   my $type = shift->type;
  78
  79   return $::locale->text('Sales Delivery Order')    if $type eq 'sales_delivery_order';
  80   return $::locale->text('Purchase Delivery Order') if $type eq 'purchase_delivery_order';
  81
  82   die 'invalid type';
  83 }
  84
  85
  86 sub displayable_state {
  87   my ($self) = @_;
  88
  89   return join '; ',
  90     ($self->closed    ? $::locale->text('closed')    : $::locale->text('open')),
  91     ($self->delivered ? $::locale->text('delivered') : $::locale->text('not delivered'));
  92 }
  93
  94 sub date {
  95   goto &transdate;
  96 }
  97
  98 sub _clone_orderitem_cvar {
  99   my ($cvar) = @_;
 100
 101   my $cloned = Rose::DB::Object::Helpers::clone_and_reset($_);
 102   $cloned->sub_module('delivery_order_items');
 103
 104   return $cloned;
 105 }
 106
 107 sub new_from {
 108   my ($class, $source, %params) = @_;
 109
 110   croak("Unsupported source object type '" . ref($source) . "'") unless ref($source) eq 'SL::DB::Order';
 111
 112   my ($item_parent_id_column, $item_parent_column);
 113
 114   if (ref($source) eq 'SL::DB::Order') {
 115     $item_parent_id_column = 'trans_id';
 116     $item_parent_column    = 'order';
 117   }
 118
 119   my %args = ( map({ ( $_ => $source->$_ ) } qw(cp_id currency_id customer_id cusordnumber department_id employee_id globalproject_id intnotes language_id notes
 120                                                 ordnumber payment_id reqdate salesman_id shippingpoint shipvia taxincluded taxzone_id transaction_description vendor_id
 121                                              )),
 122                closed    => 0,
 123                is_sales  => !!$source->customer_id,
 124                delivered => 0,
 125                transdate => DateTime->today_local,
 126             );
 127
 128   # Custom shipto addresses (the ones specific to the sales/purchase
 129   # record and not to the customer/vendor) are only linked from
 130   # shipto -> delivery_orders. Meaning delivery_orders.shipto_id
 131   # will not be filled in that case. Therefore we have to return the
 132   # new shipto object as a separate object so that the caller can
 133   # save it, too.
 134   my $custom_shipto;
 135   if (!$source->shipto_id && $source->id) {
 136     my $old = $source->custom_shipto;
 137     if ($old) {
 138       $custom_shipto = SL::DB::Shipto->new(
 139         map  { +($_ => $old->$_) }
 140         grep { !m{^ (?: itime | mtime | shipto_id | trans_id ) $}x }
 141         map  { $_->name }
 142         @{ $old->meta->columns }
 143       );
 144       $custom_shipto->module('DO');
 145     }
 146
 147   } else {
 148     $args{shipto_id} = $source->shipto_id;
 149   }
 150
 151   my $delivery_order = $class->new(%args);
 152   $delivery_order->assign_attributes(%{ $params{attributes} }) if $params{attributes};
 153   my $items          = delete($params{items}) || $source->items_sorted;
 154   my %item_parents;
 155
 156   my @items = map {
 157     my $source_item      = $_;
 158     my $source_item_id   = $_->$item_parent_id_column;
 159     my @custom_variables = map { _clone_orderitem_cvar($_) } @{ $source_item->custom_variables };
 160
 161     $item_parents{$source_item_id} ||= $source_item->$item_parent_column;
 162     my $item_parent                  = $item_parents{$source_item_id};
 163
 164     SL::DB::DeliveryOrderItem->new(map({ ( $_ => $source_item->$_ ) }
 165                                          qw(base_qty cusordnumber description discount lastcost longdescription marge_price_factor parts_id price_factor price_factor_id
 166                                             project_id qty reqdate sellprice serialnumber transdate unit active_discount_source active_price_source
 167                                          )),
 168                                    custom_variables => \@custom_variables,
 169                                    ordnumber        => ref($item_parent) eq 'SL::DB::Order' ? $item_parent->ordnumber : $source_item->ordnumber,
 170                                  );
 171
 172   } @{ $items };
 173
 174   @items = grep { $params{item_filter}->($_) } @items if $params{item_filter};
 175   @items = grep { $_->qty * 1 } @items if $params{skip_items_zero_qty};
 176   @items = grep { $_->qty >=0 } @items if $params{skip_items_negative_qty};
 177
 178   $delivery_order->items(\@items);
 179
 180   return ($delivery_order, $custom_shipto);
 181 }
 182
 183 sub customervendor {
 184   $_[0]->is_sales ? $_[0]->customer : $_[0]->vendor;
 185 }
 186
 187 1;
 188 __END__
 189
 190 =pod
 191
 192 =encoding utf8
 193
 194 =head1 NAME
 195
 196 SL::DB::DeliveryOrder - Rose model for delivery orders (table
 197 "delivery_orders")
 198
 199 =head1 FUNCTIONS
 200
 201 =over 4
 202
 203 =item C<date>
 204
 205 An alias for C<transdate> for compatibility with other sales/purchase models.
 206
 207 =item C<displayable_state>
 208
 209 Returns a human-readable description of the state regarding being
 210 closed and delivered.
 211
 212 =item C<items>
 213
 214 An alias for C<deliver_orer_items> for compatibility with other
 215 sales/purchase models.
 216
 217 =item C<new_from $source, %params>
 218
 219 Creates a new C<SL::DB::DeliveryOrder> instance and copies as much
 220 information from C<$source> as possible. At the moment only instances
 221 of C<SL::DB::Order> (sales quotations, sales orders, requests for
 222 quotations and purchase orders) are supported as sources.
 223
 224 The conversion copies order items into delivery order items. Dates are copied
 225 as appropriate, e.g. the C<transdate> field will be set to the current date.
 226
 227 Returns one or two objects depending on the context. In list context
 228 the new delivery order instance and a shipto instance will be
 229 returned. In scalar instance only the delivery order instance is
 230 returned.
 231
 232 Custom shipto addresses (the ones specific to the sales/purchase
 233 record and not to the customer/vendor) are only linked from C<shipto>
 234 to C<delivery_orders>. Meaning C<delivery_orders.shipto_id> will not
 235 be filled in that case. That's why a separate shipto object is created
 236 and returned.
 237
 238 The objects returned are not saved.
 239
 240 C<%params> can include the following options:
 241
 242 =over 2
 243
 244 =item C<items>
 245
 246 An optional array reference of RDBO instances for the items to use. If
 247 missing then the method C<items_sorted> will be called on
 248 C<$source>. This option can be used to override the sorting, to
 249 exclude certain positions or to add additional ones.
 250
 251 =item C<skip_items_negative_qty>
 252
 253 If trueish then items with a negative quantity are skipped. Items with
 254 a quantity of 0 are not affected by this option.
 255
 256 =item C<skip_items_zero_qty>
 257
 258 If trueish then items with a quantity of 0 are skipped.
 259
 260 =item C<item_filter>
 261
 262 An optional code reference that is called for each item with the item
 263 as its sole parameter. Items for which the code reference returns a
 264 falsish value will be skipped.
 265
 266 =item C<attributes>
 267
 268 An optional hash reference. If it exists then it is passed to C<new>
 269 allowing the caller to set certain attributes for the new delivery
 270 order.
 271
 272 =back
 273
 274 =item C<sales_order>
 275
 276 TODO: Describe sales_order
 277
 278 =item C<type>
 279
 280 Returns a stringdescribing this record's type: either
 281 C<sales_delivery_order> or C<purchase_delivery_order>.
 282
 283 =back
 284
 285 =head1 BUGS
 286
 287 Nothing here yet.
 288
 289 =head1 AUTHOR
 290
 291 Moritz Bunkus E<lt>m.bunkus@linet-services.deE<gt>
 292
 293 =cut