SL/DB/DeliveryOrder.pm

   1 package SL::DB::DeliveryOrder;
   2
   3 use strict;
   4
   5 use Carp;
   6
   7 use Rose::DB::Object::Helpers ();
   8
   9 use SL::DB::MetaSetup::DeliveryOrder;
  10 use SL::DB::Manager::DeliveryOrder;
  11 use SL::DB::Helper::AttrHTML;
  12 use SL::DB::Helper::AttrSorted;
  13 use SL::DB::Helper::FlattenToForm;
  14 use SL::DB::Helper::LinkedRecords;
  15 use SL::DB::Helper::TransNumberGenerator;
  16
  17 use List::Util qw(first);
  18
  19 __PACKAGE__->meta->add_relationship(orderitems => { type         => 'one to many',
  20                                                     class        => 'SL::DB::DeliveryOrderItem',
  21                                                     column_map   => { id => 'delivery_order_id' },
  22                                                     manager_args => { with_objects => [ 'part' ] }
  23                                                   },
  24                                     custom_shipto => {
  25                                       type        => 'one to one',
  26                                       class       => 'SL::DB::Shipto',
  27                                       column_map  => { id => 'trans_id' },
  28                                       query_args  => [ module => 'DO' ],
  29                                     },
  30                                    );
  31
  32 __PACKAGE__->meta->initialize;
  33
  34 __PACKAGE__->attr_html('notes');
  35 __PACKAGE__->attr_sorted('items');
  36
  37 __PACKAGE__->before_save('_before_save_set_donumber');
  38
  39 # hooks
  40
  41 sub _before_save_set_donumber {
  42   my ($self) = @_;
  43
  44   $self->create_trans_number if !$self->donumber;
  45
  46   return 1;
  47 }
  48
  49 # methods
  50
  51 sub items { goto &orderitems; }
  52 sub add_items { goto &add_orderitems; }
  53 sub payment_terms { goto &payment; }
  54 sub record_number { goto &donumber; }
  55
  56 sub sales_order {
  57   my $self   = shift;
  58   my %params = @_;
  59
  60
  61   require SL::DB::Order;
  62   my $orders = SL::DB::Manager::Order->get_all(
  63     query => [
  64       ordnumber => $self->ordnumber,
  65       @{ $params{query} || [] },
  66     ],
  67   );
  68
  69   return first { $_->is_type('sales_order') } @{ $orders };
  70 }
  71
  72 sub type {
  73   return shift->customer_id ? 'sales_delivery_order' : 'purchase_delivery_order';
  74 }
  75
  76 sub displayable_type {
  77   my $type = shift->type;
  78
  79   return $::locale->text('Sales Delivery Order')    if $type eq 'sales_delivery_order';
  80   return $::locale->text('Purchase Delivery Order') if $type eq 'purchase_delivery_order';
  81
  82   die 'invalid type';
  83 }
  84
  85 sub displayable_name {
  86   join ' ', grep $_, map $_[0]->$_, qw(displayable_type record_number);
  87 };
  88
  89 sub displayable_state {
  90   my ($self) = @_;
  91
  92   return join '; ',
  93     ($self->closed    ? $::locale->text('closed')    : $::locale->text('open')),
  94     ($self->delivered ? $::locale->text('delivered') : $::locale->text('not delivered'));
  95 }
  96
  97 sub date {
  98   goto &transdate;
  99 }
 100
 101 sub _clone_orderitem_cvar {
 102   my ($cvar) = @_;
 103
 104   my $cloned = Rose::DB::Object::Helpers::clone_and_reset($_);
 105   $cloned->sub_module('delivery_order_items');
 106
 107   return $cloned;
 108 }
 109
 110 sub new_from {
 111   my ($class, $source, %params) = @_;
 112
 113   croak("Unsupported source object type '" . ref($source) . "'") unless ref($source) eq 'SL::DB::Order';
 114
 115   my ($item_parent_id_column, $item_parent_column);
 116
 117   if (ref($source) eq 'SL::DB::Order') {
 118     $item_parent_id_column = 'trans_id';
 119     $item_parent_column    = 'order';
 120   }
 121
 122   my %args = ( map({ ( $_ => $source->$_ ) } qw(cp_id currency_id customer_id cusordnumber delivery_term_id department_id employee_id globalproject_id intnotes language_id notes
 123                                                 ordnumber payment_id reqdate salesman_id shippingpoint shipvia taxincluded taxzone_id transaction_description vendor_id
 124                                              )),
 125                closed    => 0,
 126                is_sales  => !!$source->customer_id,
 127                delivered => 0,
 128                transdate => DateTime->today_local,
 129             );
 130
 131   # Custom shipto addresses (the ones specific to the sales/purchase
 132   # record and not to the customer/vendor) are only linked from
 133   # shipto -> delivery_orders. Meaning delivery_orders.shipto_id
 134   # will not be filled in that case. Therefore we have to return the
 135   # new shipto object as a separate object so that the caller can
 136   # save it, too.
 137   my $custom_shipto;
 138   if (!$source->shipto_id && $source->id) {
 139     $custom_shipto = $source->custom_shipto->clone($class) if $source->can('custom_shipto') && $source->custom_shipto;
 140
 141   } else {
 142     $args{shipto_id} = $source->shipto_id;
 143   }
 144
 145   my $delivery_order = $class->new(%args);
 146   $delivery_order->assign_attributes(%{ $params{attributes} }) if $params{attributes};
 147   my $items          = delete($params{items}) || $source->items_sorted;
 148   my %item_parents;
 149
 150   my @items = map {
 151     my $source_item      = $_;
 152     my $source_item_id   = $_->$item_parent_id_column;
 153     my @custom_variables = map { _clone_orderitem_cvar($_) } @{ $source_item->custom_variables };
 154
 155     $item_parents{$source_item_id} ||= $source_item->$item_parent_column;
 156     my $item_parent                  = $item_parents{$source_item_id};
 157
 158     my $current_do_item = SL::DB::DeliveryOrderItem->new(map({ ( $_ => $source_item->$_ ) }
 159                                          qw(base_qty cusordnumber description discount lastcost longdescription marge_price_factor parts_id price_factor price_factor_id
 160                                             project_id qty reqdate sellprice serialnumber transdate unit active_discount_source active_price_source
 161                                          )),
 162                                    custom_variables => \@custom_variables,
 163                                    ordnumber        => ref($item_parent) eq 'SL::DB::Order' ? $item_parent->ordnumber : $source_item->ordnumber,
 164                                  );
 165     $current_do_item->{"converted_from_orderitems_id"} = $_->{id} if ref($item_parent) eq 'SL::DB::Order';
 166     $current_do_item;
 167   } @{ $items };
 168
 169   @items = grep { $params{item_filter}->($_) } @items if $params{item_filter};
 170   @items = grep { $_->qty * 1 } @items if $params{skip_items_zero_qty};
 171   @items = grep { $_->qty >=0 } @items if $params{skip_items_negative_qty};
 172
 173   $delivery_order->items(\@items);
 174
 175   return ($delivery_order, $custom_shipto);
 176 }
 177
 178 sub customervendor {
 179   $_[0]->is_sales ? $_[0]->customer : $_[0]->vendor;
 180 }
 181
 182 sub convert_to_invoice {
 183   my ($self, %params) = @_;
 184
 185   croak("Conversion to invoices is only supported for sales records") unless $self->customer_id;
 186
 187   my $invoice;
 188   if (!$self->db->with_transaction(sub {
 189     require SL::DB::Invoice;
 190     $invoice = SL::DB::Invoice->new_from($self, %params)->post || die;
 191     $self->link_to_record($invoice);
 192     # TODO extend link_to_record for items, otherwise long-term no d.r.y.
 193     foreach my $item (@{ $invoice->items }) {
 194       foreach (qw(delivery_order_items)) {    # expand if needed (orderitems)
 195         if ($item->{"converted_from_${_}_id"}) {
 196           die unless $item->{id};
 197           RecordLinks->create_links('mode'       => 'ids',
 198                                     'from_table' => $_,
 199                                     'from_ids'   => $item->{"converted_from_${_}_id"},
 200                                     'to_table'   => 'invoice',
 201                                     'to_id'      => $item->{id},
 202           ) || die;
 203           delete $item->{"converted_from_${_}_id"};
 204         }
 205       }
 206     }
 207     $self->update_attributes(closed => 1);
 208     1;
 209   })) {
 210     return undef;
 211   }
 212
 213   return $invoice;
 214 }
 215
 216 1;
 217 __END__
 218
 219 =pod
 220
 221 =encoding utf8
 222
 223 =head1 NAME
 224
 225 SL::DB::DeliveryOrder - Rose model for delivery orders (table
 226 "delivery_orders")
 227
 228 =head1 FUNCTIONS
 229
 230 =over 4
 231
 232 =item C<date>
 233
 234 An alias for C<transdate> for compatibility with other sales/purchase models.
 235
 236 =item C<displayable_name>
 237
 238 Returns a human-readable and translated description of the delivery order, consisting of
 239 record type and number, e.g. "Verkaufslieferschein 123".
 240
 241 =item C<displayable_state>
 242
 243 Returns a human-readable description of the state regarding being
 244 closed and delivered.
 245
 246 =item C<items>
 247
 248 An alias for C<delivery_order_items> for compatibility with other
 249 sales/purchase models.
 250
 251 =item C<new_from $source, %params>
 252
 253 Creates a new C<SL::DB::DeliveryOrder> instance and copies as much
 254 information from C<$source> as possible. At the moment only instances
 255 of C<SL::DB::Order> (sales quotations, sales orders, requests for
 256 quotations and purchase orders) are supported as sources.
 257
 258 The conversion copies order items into delivery order items. Dates are copied
 259 as appropriate, e.g. the C<transdate> field will be set to the current date.
 260
 261 Returns one or two objects depending on the context. In list context
 262 the new delivery order instance and a shipto instance will be
 263 returned. In scalar instance only the delivery order instance is
 264 returned.
 265
 266 Custom shipto addresses (the ones specific to the sales/purchase
 267 record and not to the customer/vendor) are only linked from C<shipto>
 268 to C<delivery_orders>. Meaning C<delivery_orders.shipto_id> will not
 269 be filled in that case. That's why a separate shipto object is created
 270 and returned.
 271
 272 The objects returned are not saved.
 273
 274 C<%params> can include the following options:
 275
 276 =over 2
 277
 278 =item C<items>
 279
 280 An optional array reference of RDBO instances for the items to use. If
 281 missing then the method C<items_sorted> will be called on
 282 C<$source>. This option can be used to override the sorting, to
 283 exclude certain positions or to add additional ones.
 284
 285 =item C<skip_items_negative_qty>
 286
 287 If trueish then items with a negative quantity are skipped. Items with
 288 a quantity of 0 are not affected by this option.
 289
 290 =item C<skip_items_zero_qty>
 291
 292 If trueish then items with a quantity of 0 are skipped.
 293
 294 =item C<item_filter>
 295
 296 An optional code reference that is called for each item with the item
 297 as its sole parameter. Items for which the code reference returns a
 298 falsish value will be skipped.
 299
 300 =item C<attributes>
 301
 302 An optional hash reference. If it exists then it is passed to C<new>
 303 allowing the caller to set certain attributes for the new delivery
 304 order.
 305
 306 =back
 307
 308 =item C<sales_order>
 309
 310 TODO: Describe sales_order
 311
 312 =item C<type>
 313
 314 Returns a string describing this record's type: either
 315 C<sales_delivery_order> or C<purchase_delivery_order>.
 316
 317 =item C<convert_to_invoice %params>
 318
 319 Creates a new invoice with C<$self> as the basis by calling
 320 L<SL::DB::Invoice::new_from>. That invoice is posted, and C<$self> is
 321 linked to the new invoice via L<SL::DB::RecordLink>. C<$self>'s
 322 C<closed> attribute is set to C<true>, and C<$self> is saved.
 323
 324 The arguments in C<%params> are passed to L<SL::DB::Invoice::new_from>.
 325
 326 Returns the new invoice instance on success and C<undef> on
 327 failure. The whole process is run inside a transaction. On failure
 328 nothing is created or changed in the database.
 329
 330 At the moment only sales delivery orders can be converted.
 331
 332 =back
 333
 334 =head1 BUGS
 335
 336 Nothing here yet.
 337
 338 =head1 AUTHOR
 339
 340 Moritz Bunkus E<lt>m.bunkus@linet-services.deE<gt>
 341
 342 =cut