SL/DB/DeliveryOrder.pm

   1 package SL::DB::DeliveryOrder;
   2
   3 use strict;
   4
   5 use Carp;
   6
   7 use Rose::DB::Object::Helpers ();
   8
   9 use SL::DB::MetaSetup::DeliveryOrder;
  10 use SL::DB::Manager::DeliveryOrder;
  11 use SL::DB::Helper::FlattenToForm;
  12 use SL::DB::Helper::LinkedRecords;
  13 use SL::DB::Helper::TransNumberGenerator;
  14
  15 use List::Util qw(first);
  16
  17 __PACKAGE__->meta->add_relationship(orderitems => { type         => 'one to many',
  18                                                     class        => 'SL::DB::DeliveryOrderItem',
  19                                                     column_map   => { id => 'delivery_order_id' },
  20                                                     manager_args => { with_objects => [ 'part' ] }
  21                                                   },
  22                                     custom_shipto => {
  23                                       type        => 'one to one',
  24                                       class       => 'SL::DB::Shipto',
  25                                       column_map  => { id => 'trans_id' },
  26                                       query_args  => [ module => 'DO' ],
  27                                     },
  28                                    );
  29
  30 __PACKAGE__->meta->initialize;
  31
  32 __PACKAGE__->before_save('_before_save_set_donumber');
  33
  34 # hooks
  35
  36 sub _before_save_set_donumber {
  37   my ($self) = @_;
  38
  39   $self->create_trans_number if !$self->donumber;
  40
  41   return 1;
  42 }
  43
  44 # methods
  45
  46 sub items { goto &orderitems; }
  47
  48 sub items_sorted {
  49   my ($self) = @_;
  50
  51   return [ sort {$a->id <=> $b->id } @{ $self->items } ];
  52 }
  53
  54 sub sales_order {
  55   my $self   = shift;
  56   my %params = @_;
  57
  58
  59   require SL::DB::Order;
  60   my $orders = SL::DB::Manager::Order->get_all(
  61     query => [
  62       ordnumber => $self->ordnumber,
  63       @{ $params{query} || [] },
  64     ],
  65   );
  66
  67   return first { $_->is_type('sales_order') } @{ $orders };
  68 }
  69
  70 sub type {
  71   return shift->customer_id ? 'sales_delivery_order' : 'purchase_delivery_order';
  72 }
  73
  74 sub displayable_state {
  75   my ($self) = @_;
  76
  77   return join '; ',
  78     ($self->closed    ? $::locale->text('closed')    : $::locale->text('open')),
  79     ($self->delivered ? $::locale->text('delivered') : $::locale->text('not delivered'));
  80 }
  81
  82 sub date {
  83   goto &transdate;
  84 }
  85
  86 sub _clone_orderitem_cvar {
  87   my ($cvar) = @_;
  88
  89   my $cloned = Rose::DB::Object::Helpers::clone_and_reset($_);
  90   $cloned->sub_module('delivery_order_items');
  91
  92   return $cloned;
  93 }
  94
  95 sub new_from {
  96   my ($class, $source, %params) = @_;
  97
  98   croak("Unsupported source object type '" . ref($source) . "'") unless ref($source) eq 'SL::DB::Order';
  99
 100   my $terms = $source->can('payment_id') && $source->payment_id ? $source->payment_terms->terms_netto : 0;
 101
 102   my %args = ( map({ ( $_ => $source->$_ ) } qw(cp_id currency_id customer_id cusordnumber department_id employee_id globalproject_id intnotes language_id notes
 103                                                 ordnumber reqdate salesman_id shippingpoint shipvia taxincluded taxzone_id transaction_description vendor_id
 104                                              )),
 105                closed    => 0,
 106                is_sales  => !!$source->customer_id,
 107                delivered => 0,
 108                terms     => $terms,
 109                transdate => DateTime->today_local,
 110             );
 111
 112   # Custom shipto addresses (the ones specific to the sales/purchase
 113   # record and not to the customer/vendor) are only linked from
 114   # shipto -> delivery_orders. Meaning delivery_orders.shipto_id
 115   # will not be filled in that case. Therefore we have to return the
 116   # new shipto object as a separate object so that the caller can
 117   # save it, too.
 118   my $custom_shipto;
 119   if (!$source->shipto_id && $source->id) {
 120     my $old = $source->custom_shipto;
 121     if ($old) {
 122       $custom_shipto = SL::DB::Shipto->new(
 123         map  { +($_ => $old->$_) }
 124         grep { !m{^ (?: itime | mtime | shipto_id | trans_id ) $}x }
 125         map  { $_->name }
 126         @{ $old->meta->columns }
 127       );
 128       $custom_shipto->module('DO');
 129     }
 130
 131   } else {
 132     $args{shipto_id} = $source->shipto_id;
 133   }
 134
 135   my $delivery_order = $class->new(%args, %{ $params{attributes} || {} });
 136   my $items          = delete($params{items}) || $source->items_sorted;
 137
 138   my @items = map {
 139     my $source_item      = $_;
 140     my @custom_variables = map { _clone_orderitem_cvar($_) } @{ $source_item->custom_variables };
 141
 142     SL::DB::DeliveryOrderItem->new(map({ ( $_ => $source_item->$_ ) }
 143                                          qw(base_qty cusordnumber description discount lastcost longdescription marge_price_factor ordnumber parts_id price_factor price_factor_id
 144                                             project_id qty reqdate sellprice serialnumber transdate unit
 145                                          )),
 146                                    custom_variables => \@custom_variables);
 147
 148   } @{ $items };
 149
 150   @items = grep { $_->qty * 1 } @items if $params{skip_items_zero_qty};
 151
 152   $delivery_order->items(\@items);
 153
 154   return ($delivery_order, $custom_shipto);
 155 }
 156
 157 1;
 158 __END__
 159
 160 =pod
 161
 162 =encoding utf8
 163
 164 =head1 NAME
 165
 166 SL::DB::DeliveryOrder - Rose model for delivery orders (table
 167 "delivery_orders")
 168
 169 =head1 FUNCTIONS
 170
 171 =over 4
 172
 173 =item C<date>
 174
 175 An alias for C<transdate> for compatibility with other sales/purchase models.
 176
 177 =item C<displayable_state>
 178
 179 Returns a human-readable description of the state regarding being
 180 closed and delivered.
 181
 182 =item C<items>
 183
 184 An alias for C<deliver_orer_items> for compatibility with other
 185 sales/purchase models.
 186
 187 =item C<items_sorted>
 188
 189 Returns the delivery order items sorted by their ID (same order they
 190 appear in the frontend delivery order masks).
 191
 192 =item C<new_from $source, %params>
 193
 194 Creates a new C<SL::DB::DeliveryOrder> instance and copies as much
 195 information from C<$source> as possible. At the moment only instances
 196 of C<SL::DB::Order> (sales quotations, sales orders, requests for
 197 quotations and purchase orders) are supported as sources.
 198
 199 The conversion copies order items into delivery order items. Dates are copied
 200 as appropriate, e.g. the C<transdate> field will be set to the current date.
 201
 202 Returns one or two objects depending on the context. In list context
 203 the new delivery order instance and a shipto instance will be
 204 returned. In scalar instance only the delivery order instance is
 205 returned.
 206
 207 Custom shipto addresses (the ones specific to the sales/purchase
 208 record and not to the customer/vendor) are only linked from C<shipto>
 209 to C<delivery_orders>. Meaning C<delivery_orders.shipto_id> will not
 210 be filled in that case. That's why a separate shipto object is created
 211 and returned.
 212
 213 The objects returned are not saved.
 214
 215 C<%params> can include the following options:
 216
 217 =over 2
 218
 219 =item C<items>
 220
 221 An optional array reference of RDBO instances for the items to use. If
 222 missing then the method C<items_sorted> will be called on
 223 C<$source>. This option can be used to override the sorting, to
 224 exclude certain positions or to add additional ones.
 225
 226 =item C<skip_items_zero_qty>
 227
 228 If trueish then items with a quantity of 0 are skipped.
 229
 230 =item C<attributes>
 231
 232 An optional hash reference. If it exists then it is passed to C<new>
 233 allowing the caller to set certain attributes for the new delivery
 234 order.
 235
 236 =back
 237
 238 =item C<sales_order>
 239
 240 TODO: Describe sales_order
 241
 242 =item C<type>
 243
 244 Returns a stringdescribing this record's type: either
 245 C<sales_delivery_order> or C<purchase_delivery_order>.
 246
 247 =back
 248
 249 =head1 BUGS
 250
 251 Nothing here yet.
 252
 253 =head1 AUTHOR
 254
 255 Moritz Bunkus E<lt>m.bunkus@linet-services.deE<gt>
 256
 257 =cut