SL/DB/DeliveryOrder.pm

   1 package SL::DB::DeliveryOrder;
   2
   3 use strict;
   4
   5 use Carp;
   6
   7 use SL::DB::MetaSetup::DeliveryOrder;
   8 use SL::DB::Manager::DeliveryOrder;
   9 use SL::DB::Helper::LinkedRecords;
  10 use SL::DB::Helper::TransNumberGenerator;
  11
  12 use List::Util qw(first);
  13
  14 __PACKAGE__->meta->add_relationship(orderitems => { type         => 'one to many',
  15                                                     class        => 'SL::DB::DeliveryOrderItem',
  16                                                     column_map   => { id => 'delivery_order_id' },
  17                                                     manager_args => { with_objects => [ 'part' ] }
  18                                                   },
  19                                    );
  20
  21 __PACKAGE__->meta->initialize;
  22
  23 __PACKAGE__->before_save('_before_save_set_donumber');
  24
  25 # hooks
  26
  27 sub _before_save_set_donumber {
  28   my ($self) = @_;
  29
  30   $self->create_trans_number if !$self->donumber;
  31
  32   return 1;
  33 }
  34
  35 # methods
  36
  37 sub items { goto &orderitems; }
  38
  39 sub items_sorted {
  40   my ($self) = @_;
  41
  42   return [ sort {$a->id <=> $b->id } @{ $self->items } ];
  43 }
  44
  45 sub sales_order {
  46   my $self   = shift;
  47   my %params = @_;
  48
  49
  50   require SL::DB::Order;
  51   my $orders = SL::DB::Manager::Order->get_all(
  52     query => [
  53       ordnumber => $self->ordnumber,
  54       @{ $params{query} || [] },
  55     ],
  56   );
  57
  58   return first { $_->is_type('sales_order') } @{ $orders };
  59 }
  60
  61 sub type {
  62   return shift->customer_id ? 'sales_delivery_order' : 'purchase_delivery_order';
  63 }
  64
  65 sub displayable_state {
  66   my ($self) = @_;
  67
  68   return join '; ',
  69     ($self->closed    ? $::locale->text('closed')    : $::locale->text('open')),
  70     ($self->delivered ? $::locale->text('delivered') : $::locale->text('not delivered'));
  71 }
  72
  73 sub date {
  74   goto &transdate;
  75 }
  76
  77 sub new_from {
  78   my ($class, $source, %params) = @_;
  79
  80   croak("Unsupported source object type '" . ref($source) . "'") unless ref($source) eq 'SL::DB::Order';
  81
  82   my $terms = $source->can('payment_id') && $source->payment_id ? $source->payment_terms->terms_netto : 0;
  83
  84   my %args = ( map({ ( $_ => $source->$_ ) } qw(cp_id currency_id customer_id cusordnumber department_id employee_id globalproject_id intnotes language_id notes
  85                                                 ordnumber reqdate salesman_id shippingpoint shipvia taxincluded taxzone_id transaction_description vendor_id
  86                                              )),
  87                closed    => 0,
  88                is_sales  => !!$source->customer_id,
  89                delivered => 0,
  90                terms     => $terms,
  91                transdate => DateTime->today_local,
  92             );
  93
  94   # Custom shipto addresses (the ones specific to the sales/purchase
  95   # record and not to the customer/vendor) are only linked from
  96   # shipto -> delivery_orders. Meaning delivery_orders.shipto_id
  97   # will not be filled in that case. Therefore we have to return the
  98   # new shipto object as a separate object so that the caller can
  99   # save it, too.
 100   my $custom_shipto;
 101   if (!$source->shipto_id && $source->id) {
 102     require SL::DB::Shipto;
 103
 104     my $old = SL::DB::Manager::Shipto->find_by(trans_id => $source->id);
 105     if ($old) {
 106       $custom_shipto = SL::DB::Shipto->new(
 107         map  { +($_ => $old->$_) }
 108         grep { !m{^ (?: itime | mtime | shipto_id | trans_id ) $}x }
 109         map  { $_->name }
 110         @{ $old->meta->columns }
 111       );
 112     }
 113
 114   } else {
 115     $args{shipto_id} = $source->shipto_id;
 116   }
 117
 118   my $delivery_order = $class->new(%args, %params);
 119
 120   my @items = map {
 121     my $source_item = $_;
 122     SL::DB::DeliveryOrderItem->new(map({ ( $_ => $source_item->$_ ) }
 123                                    qw(base_qty cusordnumber description discount lastcost longdescription marge_price_factor ordnumber parts_id price_factor price_factor_id
 124                                       project_id qty reqdate sellprice serialnumber transdate unit
 125                                    )));
 126   } @{ $source->items_sorted };
 127
 128   $delivery_order->items(\@items);
 129
 130   return ($delivery_order, $custom_shipto);
 131 }
 132
 133 1;
 134 __END__
 135
 136 =pod
 137
 138 =encoding utf8
 139
 140 =head1 NAME
 141
 142 SL::DB::DeliveryOrder - Rose model for delivery orders (table
 143 "delivery_orders")
 144
 145 =head1 FUNCTIONS
 146
 147 =over 4
 148
 149 =item C<date>
 150
 151 An alias for L</transdate> for compatibility with other sales/purchase models.
 152
 153 =item C<displayable_state>
 154
 155 Returns a human-readable description of the state regarding being
 156 closed and delivered.
 157
 158 =item C<items>
 159
 160 An alias for L</deliver_orer_items> for compatibility with other
 161 sales/purchase models.
 162
 163 =item C<items_sorted>
 164
 165 Returns the delivery order items sorted by their ID (same order they
 166 appear in the frontend delivery order masks).
 167
 168 =item C<new_from $source>
 169
 170 Creates a new C<SL::DB::DeliveryOrder> instance and copies as much
 171 information from C<$source> as possible. At the moment only instances
 172 of C<SL::DB::Order> (sales quotations, sales orders, requests for
 173 quotations and purchase orders) are supported as sources.
 174
 175 The conversion copies order items into delivery order items. Dates are copied
 176 as appropriate, e.g. the C<transdate> field will be set to the current date.
 177
 178 Returns one or two objects depending on the context. In list context
 179 the new delivery order instance and a shipto instance will be
 180 returned. In scalar instance only the delivery order instance is
 181 returned.
 182
 183 Custom shipto addresses (the ones specific to the sales/purchase
 184 record and not to the customer/vendor) are only linked from C<shipto>
 185 to C<delivery_orders>. Meaning C<delivery_orders.shipto_id> will not
 186 be filled in that case. That's why a separate shipto object is created
 187 and returned.
 188
 189 The objects returned are not saved.
 190
 191 =item C<sales_order>
 192
 193 TODO: Describe sales_order
 194
 195 =item C<type>
 196
 197 Returns a stringdescribing this record's type: either
 198 C<sales_delivery_order> or C<purchase_delivery_order>.
 199
 200 =back
 201
 202 =head1 BUGS
 203
 204 Nothing here yet.
 205
 206 =head1 AUTHOR
 207
 208 Moritz Bunkus E<lt>m.bunkus@linet-services.deE<gt>
 209
 210 =cut