SL/DB/DeliveryOrder.pm

   1 package SL::DB::DeliveryOrder;
   2
   3 use strict;
   4
   5 use Carp;
   6
   7 use Rose::DB::Object::Helpers ();
   8
   9 use SL::DB::MetaSetup::DeliveryOrder;
  10 use SL::DB::Manager::DeliveryOrder;
  11 use SL::DB::Helper::AttrHTML;
  12 use SL::DB::Helper::AttrSorted;
  13 use SL::DB::Helper::FlattenToForm;
  14 use SL::DB::Helper::LinkedRecords;
  15 use SL::DB::Helper::TransNumberGenerator;
  16
  17 use SL::DB::Part;
  18 use SL::DB::Unit;
  19
  20 use SL::Helper::Number qw(_format_total _round_total);
  21
  22 use List::Util qw(first);
  23 use List::MoreUtils qw(any pairwise);
  24 use Math::Round qw(nhimult);
  25
  26 __PACKAGE__->meta->add_relationship(orderitems => { type         => 'one to many',
  27                                                     class        => 'SL::DB::DeliveryOrderItem',
  28                                                     column_map   => { id => 'delivery_order_id' },
  29                                                     manager_args => { with_objects => [ 'part' ] }
  30                                                   },
  31                                     custom_shipto => {
  32                                       type        => 'one to one',
  33                                       class       => 'SL::DB::Shipto',
  34                                       column_map  => { id => 'trans_id' },
  35                                       query_args  => [ module => 'DO' ],
  36                                     },
  37                                    );
  38
  39 __PACKAGE__->meta->initialize;
  40
  41 __PACKAGE__->attr_html('notes');
  42 __PACKAGE__->attr_sorted('items');
  43
  44 __PACKAGE__->before_save('_before_save_set_donumber');
  45
  46 # hooks
  47
  48 sub _before_save_set_donumber {
  49   my ($self) = @_;
  50
  51   $self->create_trans_number if !$self->donumber;
  52
  53   return 1;
  54 }
  55
  56 # methods
  57
  58 sub items { goto &orderitems; }
  59 sub add_items { goto &add_orderitems; }
  60 sub payment_terms { goto &payment; }
  61 sub record_number { goto &donumber; }
  62
  63 sub sales_order {
  64   my $self   = shift;
  65   my %params = @_;
  66
  67
  68   require SL::DB::Order;
  69   my $orders = SL::DB::Manager::Order->get_all(
  70     query => [
  71       ordnumber => $self->ordnumber,
  72       @{ $params{query} || [] },
  73     ],
  74   );
  75
  76   return first { $_->is_type('sales_order') } @{ $orders };
  77 }
  78
  79 sub type {
  80   return shift->customer_id ? 'sales_delivery_order' : 'purchase_delivery_order';
  81 }
  82
  83 sub displayable_type {
  84   my $type = shift->type;
  85
  86   return $::locale->text('Sales Delivery Order')    if $type eq 'sales_delivery_order';
  87   return $::locale->text('Purchase Delivery Order') if $type eq 'purchase_delivery_order';
  88
  89   die 'invalid type';
  90 }
  91
  92 sub displayable_name {
  93   join ' ', grep $_, map $_[0]->$_, qw(displayable_type record_number);
  94 };
  95
  96 sub displayable_state {
  97   my ($self) = @_;
  98
  99   return join '; ',
 100     ($self->closed    ? $::locale->text('closed')    : $::locale->text('open')),
 101     ($self->delivered ? $::locale->text('delivered') : $::locale->text('not delivered'));
 102 }
 103
 104 sub date {
 105   goto &transdate;
 106 }
 107
 108 sub _clone_orderitem_cvar {
 109   my ($cvar) = @_;
 110
 111   my $cloned = $_->clone_and_reset;
 112   $cloned->sub_module('delivery_order_items');
 113
 114   return $cloned;
 115 }
 116
 117 sub new_from {
 118   my ($class, $source, %params) = @_;
 119
 120   croak("Unsupported source object type '" . ref($source) . "'") unless ref($source) eq 'SL::DB::Order';
 121
 122   my ($item_parent_id_column, $item_parent_column);
 123
 124   if (ref($source) eq 'SL::DB::Order') {
 125     $item_parent_id_column = 'trans_id';
 126     $item_parent_column    = 'order';
 127   }
 128
 129   my %args = ( map({ ( $_ => $source->$_ ) } qw(cp_id currency_id customer_id cusordnumber delivery_term_id department_id employee_id globalproject_id intnotes language_id notes
 130                                                 ordnumber payment_id reqdate salesman_id shippingpoint shipvia taxincluded taxzone_id transaction_description vendor_id
 131                                              )),
 132                closed    => 0,
 133                is_sales  => !!$source->customer_id,
 134                delivered => 0,
 135                transdate => DateTime->today_local,
 136             );
 137
 138   # Custom shipto addresses (the ones specific to the sales/purchase
 139   # record and not to the customer/vendor) are only linked from
 140   # shipto → delivery_orders. Meaning delivery_orders.shipto_id
 141   # will not be filled in that case.
 142   if (!$source->shipto_id && $source->id) {
 143     $args{custom_shipto} = $source->custom_shipto->clone($class) if $source->can('custom_shipto') && $source->custom_shipto;
 144
 145   } else {
 146     $args{shipto_id} = $source->shipto_id;
 147   }
 148
 149   my $delivery_order = $class->new(%args);
 150   $delivery_order->assign_attributes(%{ $params{attributes} }) if $params{attributes};
 151   my $items          = delete($params{items}) || $source->items_sorted;
 152   my %item_parents;
 153
 154   my @items = map {
 155     my $source_item      = $_;
 156     my $source_item_id   = $_->$item_parent_id_column;
 157     my @custom_variables = map { _clone_orderitem_cvar($_) } @{ $source_item->custom_variables };
 158
 159     $item_parents{$source_item_id} ||= $source_item->$item_parent_column;
 160     my $item_parent                  = $item_parents{$source_item_id};
 161
 162     my $current_do_item = SL::DB::DeliveryOrderItem->new(map({ ( $_ => $source_item->$_ ) }
 163                                          qw(base_qty cusordnumber description discount lastcost longdescription marge_price_factor parts_id price_factor price_factor_id
 164                                             project_id qty reqdate sellprice serialnumber transdate unit active_discount_source active_price_source
 165                                          )),
 166                                    custom_variables => \@custom_variables,
 167                                    ordnumber        => ref($item_parent) eq 'SL::DB::Order' ? $item_parent->ordnumber : $source_item->ordnumber,
 168                                  );
 169     $current_do_item->{"converted_from_orderitems_id"} = $_->{id} if ref($item_parent) eq 'SL::DB::Order';
 170     $current_do_item;
 171   } @{ $items };
 172
 173   @items = grep { $params{item_filter}->($_) } @items if $params{item_filter};
 174   @items = grep { $_->qty * 1 } @items if $params{skip_items_zero_qty};
 175   @items = grep { $_->qty >=0 } @items if $params{skip_items_negative_qty};
 176
 177   $delivery_order->items(\@items);
 178
 179   return $delivery_order;
 180 }
 181
 182 sub new_from_time_recordings {
 183   my ($class, $sources, %params) = @_;
 184
 185   croak("Unsupported object type in sources")                                      if any { ref($_) ne 'SL::DB::TimeRecording' }            @$sources;
 186   croak("Cannot create delivery order from source records of different customers") if any { $_->customer_id != $sources->[0]->customer_id } @$sources;
 187
 188   # - one item per part (article)
 189   # - qty is sum of duration
 190   # - description goes to item longdescription
 191   #  - ordered and summed by date
 192   #  - each description goes to an ordered list
 193   #  - (as time recording descriptions are formatted text by now, use stripped text)
 194   #  - merge same descriptions (todo)
 195   #
 196
 197   my $default_part_id = $params{default_part_id}    ? $params{default_part_id}
 198                       : $params{default_partnumber} ? SL::DB::Manager::Part->find_by(partnumber => $params{default_partnumber})->id
 199                       : undef;
 200
 201   # check parts and collect entries
 202   my %part_by_part_id;
 203   my $entries;
 204   foreach my $source (@$sources) {
 205     my $part_id  = $source->part_id ? $source->part_id
 206                  : $default_part_id ? $default_part_id
 207                  : undef;
 208
 209     die 'article not found for entry "' . $source->displayable_times . '"' if !$part_id;
 210
 211     if (!$part_by_part_id{$part_id}) {
 212       $part_by_part_id{$part_id} = SL::DB::Part->new(id => $part_id)->load;
 213       die 'article unit must be time based for entry "' . $source->displayable_times . '"' if !$part_by_part_id{$part_id}->unit_obj->is_time_based;
 214     }
 215
 216     my $date = $source->date->to_kivitendo;
 217     $entries->{$part_id}->{$date}->{duration} += $params{rounding}
 218                                                ? nhimult(0.25, ($source->duration_in_hours))
 219                                                : _round_total($source->duration_in_hours);
 220     # add content if not already in description
 221     my $new_description = '' . $source->description_as_stripped_html;
 222     $entries->{$part_id}->{$date}->{content} ||= '';
 223     $entries->{$part_id}->{$date}->{content}  .= '<li>' . $new_description . '</li>'
 224       unless $entries->{$part_id}->{$date}->{content} =~ m/\Q$new_description/;
 225
 226     $entries->{$part_id}->{$date}->{date_obj}  = $source->start_time || $source->date; # for sorting
 227   }
 228
 229   my @items;
 230
 231   my $h_unit = SL::DB::Manager::Unit->find_h_unit;
 232
 233   my @keys = sort { $part_by_part_id{$a}->partnumber cmp $part_by_part_id{$b}->partnumber } keys %$entries;
 234   foreach my $key (@keys) {
 235     my $qty = 0;
 236     my $longdescription = '';
 237
 238     my @dates = sort { $entries->{$key}->{$a}->{date_obj} <=> $entries->{$key}->{$b}->{date_obj} } keys %{$entries->{$key}};
 239     foreach my $date (@dates) {
 240       my $entry = $entries->{$key}->{$date};
 241
 242       $qty             += $entry->{duration};
 243       $longdescription .= $date . ' <strong>' . _format_total($entry->{duration}) . ' h</strong>';
 244       $longdescription .= '<ul>';
 245       $longdescription .= $entry->{content};
 246       $longdescription .= '</ul>';
 247     }
 248
 249     my $item = SL::DB::DeliveryOrderItem->new(
 250       parts_id        => $part_by_part_id{$key}->id,
 251       description     => $part_by_part_id{$key}->description,
 252       qty             => $qty,
 253       base_qty        => $h_unit->convert_to($qty, $part_by_part_id{$key}->unit_obj),
 254       unit_obj        => $h_unit,
 255       sellprice       => $part_by_part_id{$key}->sellprice, # Todo: use price rules to get sellprice
 256       longdescription => $longdescription,
 257     );
 258
 259     push @items, $item;
 260   }
 261
 262   my $delivery_order;
 263
 264   if ($params{related_order}) {
 265     # collect suitable items in related order
 266     my @items_to_use;
 267     my @new_attributes;
 268     foreach my $item (@items) {
 269       my $item_to_use = first {$item->parts_id == $_->parts_id} @{ $params{related_order}->items_sorted };
 270
 271       die "no suitable item found in related order" if !$item_to_use;
 272
 273       my %new_attributes;
 274       $new_attributes{$_} = $item->$_ for qw(qty base_qty unit_obj longdescription);
 275       push @items_to_use,   $item_to_use;
 276       push @new_attributes, \%new_attributes;
 277     }
 278
 279     $delivery_order = $class->new_from($params{related_order}, items => \@items_to_use, %params);
 280     pairwise { $a->assign_attributes( %$b) } @{$delivery_order->items}, @new_attributes;
 281
 282   } else {
 283     my %args = (
 284       is_sales    => 1,
 285       delivered   => 0,
 286       customer_id => $sources->[0]->customer_id,
 287       taxzone_id  => $sources->[0]->customer->taxzone_id,
 288       currency_id => $sources->[0]->customer->currency_id,
 289       employee_id => SL::DB::Manager::Employee->current->id,
 290       salesman_id => SL::DB::Manager::Employee->current->id,
 291       items       => \@items,
 292     );
 293     $delivery_order = $class->new(%args);
 294     $delivery_order->assign_attributes(%{ $params{attributes} }) if $params{attributes};
 295   }
 296
 297   return $delivery_order;
 298 }
 299
 300 sub customervendor {
 301   $_[0]->is_sales ? $_[0]->customer : $_[0]->vendor;
 302 }
 303
 304 sub convert_to_invoice {
 305   my ($self, %params) = @_;
 306
 307   croak("Conversion to invoices is only supported for sales records") unless $self->customer_id;
 308
 309   my $invoice;
 310   if (!$self->db->with_transaction(sub {
 311     require SL::DB::Invoice;
 312     $invoice = SL::DB::Invoice->new_from($self, %params)->post || die;
 313     $self->link_to_record($invoice);
 314     # TODO extend link_to_record for items, otherwise long-term no d.r.y.
 315     foreach my $item (@{ $invoice->items }) {
 316       foreach (qw(delivery_order_items)) {    # expand if needed (orderitems)
 317         if ($item->{"converted_from_${_}_id"}) {
 318           die unless $item->{id};
 319           RecordLinks->create_links('mode'       => 'ids',
 320                                     'from_table' => $_,
 321                                     'from_ids'   => $item->{"converted_from_${_}_id"},
 322                                     'to_table'   => 'invoice',
 323                                     'to_id'      => $item->{id},
 324           ) || die;
 325           delete $item->{"converted_from_${_}_id"};
 326         }
 327       }
 328     }
 329     $self->update_attributes(closed => 1);
 330     1;
 331   })) {
 332     return undef;
 333   }
 334
 335   return $invoice;
 336 }
 337
 338 sub digest {
 339   my ($self) = @_;
 340
 341   sprintf "%s %s (%s)",
 342     $self->donumber,
 343     $self->customervendor->name,
 344     $self->date->to_kivitendo;
 345 }
 346
 347 1;
 348 __END__
 349
 350 =pod
 351
 352 =encoding utf8
 353
 354 =head1 NAME
 355
 356 SL::DB::DeliveryOrder - Rose model for delivery orders (table
 357 "delivery_orders")
 358
 359 =head1 FUNCTIONS
 360
 361 =over 4
 362
 363 =item C<date>
 364
 365 An alias for C<transdate> for compatibility with other sales/purchase models.
 366
 367 =item C<displayable_name>
 368
 369 Returns a human-readable and translated description of the delivery order, consisting of
 370 record type and number, e.g. "Verkaufslieferschein 123".
 371
 372 =item C<displayable_state>
 373
 374 Returns a human-readable description of the state regarding being
 375 closed and delivered.
 376
 377 =item C<items>
 378
 379 An alias for C<delivery_order_items> for compatibility with other
 380 sales/purchase models.
 381
 382 =item C<new_from $source, %params>
 383
 384 Creates a new C<SL::DB::DeliveryOrder> instance and copies as much
 385 information from C<$source> as possible. At the moment only instances
 386 of C<SL::DB::Order> (sales quotations, sales orders, requests for
 387 quotations and purchase orders) are supported as sources.
 388
 389 The conversion copies order items into delivery order items. Dates are copied
 390 as appropriate, e.g. the C<transdate> field will be set to the current date.
 391
 392 Returns the new delivery order instance. The object returned is not
 393 saved.
 394
 395 C<%params> can include the following options:
 396
 397 =over 2
 398
 399 =item C<items>
 400
 401 An optional array reference of RDBO instances for the items to use. If
 402 missing then the method C<items_sorted> will be called on
 403 C<$source>. This option can be used to override the sorting, to
 404 exclude certain positions or to add additional ones.
 405
 406 =item C<skip_items_negative_qty>
 407
 408 If trueish then items with a negative quantity are skipped. Items with
 409 a quantity of 0 are not affected by this option.
 410
 411 =item C<skip_items_zero_qty>
 412
 413 If trueish then items with a quantity of 0 are skipped.
 414
 415 =item C<item_filter>
 416
 417 An optional code reference that is called for each item with the item
 418 as its sole parameter. Items for which the code reference returns a
 419 falsish value will be skipped.
 420
 421 =item C<attributes>
 422
 423 An optional hash reference. If it exists then it is passed to C<new>
 424 allowing the caller to set certain attributes for the new delivery
 425 order.
 426
 427 =back
 428
 429 =item C<new_from_time_recordings $sources, %params>
 430
 431 Creates a new C<SL::DB::DeliveryOrder> instance from the time recordings
 432 given as C<$sources>. All time recording entries must belong to the same
 433 customer. Time recordings are sorted by article and date. For each article
 434 a new delivery order item is created. If no article is associated with an
 435 entry, a default article will be used (hard coded).
 436 Entries of the same date (for each article) are summed together and form a
 437 list entry in the long description of the item.
 438
 439 The created delivery order object will be returnd but not saved.
 440
 441 C<$sources> must be an array reference of C<SL::DB::TimeRecording> instances.
 442
 443 C<%params> can include the following options:
 444
 445 =over 2
 446
 447 =item C<attributes>
 448
 449 An optional hash reference. If it exists then it is used to set
 450 attributes of the newly created delivery order object.
 451
 452 =back
 453
 454 =item C<sales_order>
 455
 456 TODO: Describe sales_order
 457
 458 =item C<type>
 459
 460 Returns a string describing this record's type: either
 461 C<sales_delivery_order> or C<purchase_delivery_order>.
 462
 463 =item C<convert_to_invoice %params>
 464
 465 Creates a new invoice with C<$self> as the basis by calling
 466 L<SL::DB::Invoice::new_from>. That invoice is posted, and C<$self> is
 467 linked to the new invoice via L<SL::DB::RecordLink>. C<$self>'s
 468 C<closed> attribute is set to C<true>, and C<$self> is saved.
 469
 470 The arguments in C<%params> are passed to L<SL::DB::Invoice::new_from>.
 471
 472 Returns the new invoice instance on success and C<undef> on
 473 failure. The whole process is run inside a transaction. On failure
 474 nothing is created or changed in the database.
 475
 476 At the moment only sales delivery orders can be converted.
 477
 478 =back
 479
 480 =head1 BUGS
 481
 482 Nothing here yet.
 483
 484 =head1 AUTHOR
 485
 486 Moritz Bunkus E<lt>m.bunkus@linet-services.deE<gt>
 487
 488 =cut