SL/DB/Helper/FlattenToForm.pm

   1 package SL::DB::Helper::FlattenToForm;
   2
   3 use strict;
   4
   5 use parent qw(Exporter);
   6 our @EXPORT = qw(flatten_to_form);
   7
   8 use List::MoreUtils qw(any);
   9
  10 use SL::CVar;
  11
  12 sub flatten_to_form {
  13   my ($self, $form, %params) = @_;
  14
  15   my $vc = $self->can('customer_id') && $self->customer_id ? 'customer' : 'vendor';
  16
  17   _copy($self, $form, '', '', 0, qw(id type taxzone_id ordnumber quonumber invnumber donumber cusordnumber taxincluded shippingpoint shipvia notes intnotes cp_id
  18                                     employee_id salesman_id closed department_id language_id payment_id delivery_customer_id delivery_vendor_id shipto_id proforma
  19                                     globalproject_id delivered transaction_description container_type accepted_by_customer invoice storno storno_id dunning_config_id
  20                                     orddate quodate reqdate gldate duedate deliverydate datepaid transdate delivery_term_id));
  21   $form->{currency} = $form->{curr} = $self->currency_id ? $self->currency->name || '' : '';
  22
  23   if (_has($self, 'transdate')) {
  24     my $transdate_idx = ref($self) eq 'SL::DB::Order'   ? ($self->quotation ? 'quodate' : 'orddate')
  25                       : ref($self) eq 'SL::DB::Invoice' ? 'invdate'
  26                       :                                   'transdate';
  27     $form->{$transdate_idx} = $self->transdate->to_lxoffice;
  28   }
  29
  30   $form->{vc} = $vc if ref($self) =~ /^SL::DB::.*Invoice/;
  31
  32   my @vc_fields          = (qw(account_number bank bank_code bic business city contact country creditlimit
  33                                department_1 department_2 discount email fax homepage iban language name
  34                                payment_terms phone street taxnumber ustid zipcode),
  35                             "${vc}number",
  36                             ($vc eq 'customer')? 'c_vendor_id': 'v_customer_id');
  37   my @vc_prefixed_fields = qw(email fax notes number phone);
  38
  39   _copy($self,                          $form, '',              '', 1, qw(amount netamount marge_total marge_percent container_remaining_weight container_remaining_volume paid));
  40   _copy($self->$vc,                     $form, '',              '', 0, @vc_fields);
  41   _copy($self->$vc,                     $form, $vc,             '', 0, @vc_prefixed_fields);
  42   _copy($self->contact,                 $form, '',              '', 0, grep { /^cp_/    } map { $_->name } SL::DB::Contact->meta->columns) if _has($self, 'cp_id');
  43   _copy($self->shipto,                  $form, '',              '', 0, grep { /^shipto/ } map { $_->name } SL::DB::Shipto->meta->columns)  if _has($self, 'shipto_id');
  44   _copy($self->globalproject,           $form, 'globalproject', '', 0, qw(number description))                                             if _has($self, 'globalproject_id');
  45   _copy($self->employee,                $form, 'employee_',     '', 0, map { $_->name } SL::DB::Employee->meta->columns)                   if _has($self, 'employee_id');
  46   _copy($self->salesman,                $form, 'salesman_',     '', 0, map { $_->name } SL::DB::Employee->meta->columns)                   if _has($self, 'salesman_id');
  47   _copy($self->acceptance_confirmed_by, $form, 'acceptance_confirmed_by_', '', 0, map { $_->name } SL::DB::Employee->meta->columns)        if _has($self, 'acceptance_confirmed_by_id');
  48
  49   $form->{employee}   = $self->employee->name          if _has($self, 'employee_id');
  50   $form->{language}   = $self->language->template_code if _has($self, 'language_id');
  51   $form->{department} = $self->department->description if _has($self, 'department_id');
  52   $form->{rowcount}   = scalar(@{ $self->items });
  53
  54   my $idx = 0;
  55   my $format_amounts = $params{format_amounts} ? 1 : 0;
  56   my $format_notnull = $params{format_amounts} ? 2 : 0;
  57   my $format_percent = $params{format_amounts} ? 3 : 0;
  58   foreach my $item (@{ $self->items_sorted }) {
  59     next if _has($item, 'assemblyitem');
  60
  61     $idx++;
  62
  63     $form->{"partsgroup_${idx}"} = $item->part->partsgroup->partsgroup if _has($item->part, 'partsgroup_id');
  64     _copy($item->part,    $form, '',        "_${idx}", 0,               qw(id partnumber weight));
  65     _copy($item->part,    $form, '',        "_${idx}", 0,               qw(listprice));
  66     _copy($item,          $form, '',        "_${idx}", 0,               qw(description project_id ship serialnumber pricegroup_id ordnumber donumber cusordnumber unit
  67                                                                            subtotal longdescription price_factor_id marge_price_factor approved_sellprice reqdate transdate));
  68     _copy($item,          $form, '',        "_${idx}", $format_amounts, qw(qty sellprice marge_total marge_percent lastcost));
  69     _copy($item,          $form, '',        "_${idx}", $format_percent, qw(discount));
  70     _copy($item->project, $form, 'project', "_${idx}", 0,               qw(number description)) if _has($item, 'project_id');
  71
  72     _copy_custom_variables($item, $form, 'ic_cvar_', "_${idx}");
  73
  74     if (ref($self) eq 'SL::DB::Invoice') {
  75       my $date                          = $item->deliverydate ? $item->deliverydate->to_lxoffice : undef;
  76       $form->{"deliverydate_oe_${idx}"} = $date;
  77       $form->{"reqdate_${idx}"}         = $date;
  78     }
  79   }
  80
  81   _copy_custom_variables($self, $form, 'vc_cvar_', '');
  82
  83   return $self;
  84 }
  85
  86 sub _has {
  87   my ($obj, $column) = @_;
  88   return $obj->can($column) && $obj->$column;
  89 }
  90
  91 sub _copy {
  92   my ($src, $form, $prefix, $postfix, $format_amounts, @columns) = @_;
  93
  94   @columns = grep { $src->can($_) } @columns;
  95
  96   map { $form->{"${prefix}${_}${postfix}"} = ref($src->$_) eq 'DateTime' ? $src->$_->to_lxoffice : $src->$_             } @columns if !$format_amounts;
  97   map { $form->{"${prefix}${_}${postfix}"} =                $::form->format_amount(\%::myconfig, $src->$_ * 1, 2)       } @columns if  $format_amounts == 1;
  98   map { $form->{"${prefix}${_}${postfix}"} = $src->$_ * 1 ? $::form->format_amount(\%::myconfig, $src->$_ * 1, 2) : 0   } @columns if  $format_amounts == 2;
  99   map { $form->{"${prefix}${_}${postfix}"} = $src->$_ * 1 ? $::form->format_amount(\%::myconfig, $src->$_ * 100, 2) : 0 } @columns if  $format_amounts == 3;
 100
 101   return $src;
 102 }
 103
 104 sub _copy_custom_variables {
 105   my ($src, $form, $prefix, $postfix) = @_;
 106
 107   my ($module, $sub_module, $trans_id) = ref($src) eq 'SL::DB::OrderItem'         ? ('IC', 'orderitems',           $src->id)
 108                                        : ref($src) eq 'SL::DB::DeliveryOrderItem' ? ('IC', 'delivery_order_items', $src->id)
 109                                        : ref($src) eq 'SL::DB::InvoiceItem'       ? ('IC', 'invoice',              $src->id)
 110                                        :                                            ('CT', undef,                  _has($src, 'customer_id') ? $src->customer_id : $src->vendor_id);
 111
 112   return unless $trans_id;
 113
 114   my $cvars = CVar->get_custom_variables(dbh        => $src->db->dbh,
 115                                          module     => $module,
 116                                          sub_module => $sub_module,
 117                                          trans_id   => $trans_id,
 118                                         );
 119   map { $form->{ $prefix . $_->{name} . $postfix } = $_->{value} } @{ $cvars };
 120
 121   return $src;
 122 }
 123
 124 1;