SL/DB/Helper/FlattenToForm.pm

   1 package SL::DB::Helper::FlattenToForm;
   2
   3 use strict;
   4
   5 use parent qw(Exporter);
   6 our @EXPORT = qw(flatten_to_form);
   7
   8 use List::MoreUtils qw(uniq any);
   9
  10 sub flatten_to_form {
  11   my ($self, $form, %params) = @_;
  12
  13   my $vc = $self->can('customer_id') && $self->customer_id ? 'customer' : 'vendor';
  14
  15   _copy($self, $form, '', '', 0, qw(id type taxzone_id ordnumber quonumber invnumber donumber cusordnumber taxincluded shippingpoint shipvia notes intnotes cp_id
  16                                     employee_id salesman_id closed department_id language_id payment_id delivery_customer_id delivery_vendor_id shipto_id proforma
  17                                     globalproject_id delivered transaction_description container_type accepted_by_customer invoice storno storno_id dunning_config_id
  18                                     orddate quodate reqdate gldate duedate deliverydate datepaid transdate delivery_term_id));
  19   $form->{currency} = $form->{curr} = $self->currency_id ? $self->currency->name || '' : '';
  20
  21   if ( $vc eq 'customer' ) {
  22     $form->{customer_id} = $self->customer_id;
  23   } else {
  24     $form->{vendor_id} = $self->vendor_id;
  25   };
  26
  27   if (_has($self, 'transdate')) {
  28     my $transdate_idx = ref($self) eq 'SL::DB::Order'   ? ($self->quotation ? 'quodate' : 'orddate')
  29                       : ref($self) eq 'SL::DB::Invoice' ? 'invdate'
  30                       :                                   'transdate';
  31     $form->{$transdate_idx} = $self->transdate->to_lxoffice;
  32   }
  33
  34   $form->{vc} = $vc if ref($self) =~ m{^SL::DB::(?:.*Invoice|Order)};
  35
  36   my @vc_fields          = (qw(account_number bank bank_code bic business city contact country creditlimit
  37                                department_1 department_2 discount email fax gln homepage iban language name
  38                                phone street taxnumber ustid zipcode),
  39                             "${vc}number",
  40                             ($vc eq 'customer')? 'c_vendor_id': 'v_customer_id');
  41   my @vc_prefixed_fields = qw(email fax notes number phone);
  42
  43   _copy($self,                          $form, '',              '', 1, qw(amount netamount marge_total marge_percent container_remaining_weight container_remaining_volume paid));
  44   _copy($self->$vc,                     $form, '',              '', 0, @vc_fields);
  45   _copy($self->$vc,                     $form, $vc,             '', 0, @vc_prefixed_fields);
  46   _copy($self->contact,                 $form, '',              '', 0, grep { /^cp_/    } map { $_->name } SL::DB::Contact->meta->columns) if _has($self, 'cp_id');
  47   _copy($self->shipto,                  $form, '',              '', 0, grep { /^shipto/ } map { $_->name } SL::DB::Shipto->meta->columns)  if _has($self, 'shipto_id');
  48   _copy($self->globalproject,           $form, 'globalproject', '', 0, qw(number description))                                             if _has($self, 'globalproject_id');
  49   _copy($self->employee,                $form, 'employee_',     '', 0, map { $_->name } SL::DB::Employee->meta->columns)                   if _has($self, 'employee_id');
  50   _copy($self->salesman,                $form, 'salesman_',     '', 0, map { $_->name } SL::DB::Employee->meta->columns)                   if _has($self, 'salesman_id');
  51   _copy($self->acceptance_confirmed_by, $form, 'acceptance_confirmed_by_', '', 0, map { $_->name } SL::DB::Employee->meta->columns)        if _has($self, 'acceptance_confirmed_by_id');
  52
  53   $form->{employee}   = $self->employee->name          if _has($self, 'employee_id');
  54   $form->{language}   = $self->language->template_code if _has($self, 'language_id');
  55   $form->{department} = $self->department->description if _has($self, 'department_id');
  56   $form->{business}   = $self->$vc->business->description if _has($self->$vc, 'business_id');
  57   $form->{rowcount}   = scalar(@{ $self->items });
  58
  59   my $items_name = ref($self) eq 'SL::DB::Order'         ? 'orderitems'
  60                  : ref($self) eq 'SL::DB::DeliveryOrder' ? 'delivery_order_items'
  61                  : ref($self) eq 'SL::DB::Invoice'       ? 'invoice'
  62                  : '';
  63
  64   my %cvar_validity = _determine_cvar_validity($self, $vc);
  65
  66   my $idx = 0;
  67   my $format_amounts = $params{format_amounts} ? 1 : 0;
  68   my $format_notnull = $params{format_amounts} ? 2 : 0;
  69   my $format_percent = $params{format_amounts} ? 3 : 0;
  70   my $format_noround = $params{format_amounts} ? 4 : 0;
  71   foreach my $item (@{ $self->items_sorted }) {
  72     next if _has($item, 'assemblyitem');
  73
  74     $idx++;
  75
  76     $form->{"partsgroup_${idx}"} = $item->part->partsgroup->partsgroup if _has($item->part, 'partsgroup_id');
  77     _copy($item,          $form, "${items_name}_", "_${idx}", 0,               qw(id)) if $items_name;
  78     _copy($item->part,    $form, '',               "_${idx}", 0,               qw(id partnumber weight assembly));
  79     _copy($item->part,    $form, '',               "_${idx}", 0,               qw(listprice));
  80     _copy($item,          $form, '',               "_${idx}", 0,               qw(description project_id ship serialnumber pricegroup_id ordnumber donumber cusordnumber unit
  81                                                                                   subtotal longdescription price_factor_id marge_price_factor approved_sellprice reqdate transdate
  82                                                                                   active_price_source active_discount_source));
  83     _copy($item,          $form, '',              "_${idx}", $format_noround, qw(qty sellprice));
  84     _copy($item,          $form, '',              "_${idx}", $format_amounts, qw(marge_total marge_percent lastcost));
  85     _copy($item,          $form, '',              "_${idx}", $format_percent, qw(discount));
  86     _copy($item->project, $form, 'project',       "_${idx}", 0,               qw(number description)) if _has($item, 'project_id');
  87
  88     _copy_custom_variables($item, $form, 'ic_cvar_', "_${idx}", $cvar_validity{items}->{ $item->parts_id });
  89
  90     if (ref($self) eq 'SL::DB::Invoice') {
  91       my $date                          = $item->deliverydate ? $item->deliverydate->to_lxoffice : undef;
  92       $form->{"deliverydate_oe_${idx}"} = $date;
  93       $form->{"reqdate_${idx}"}         = $date;
  94     }
  95   }
  96
  97   _copy_custom_variables($self, $form, 'vc_cvar_', '', $cvar_validity{vc});
  98
  99   return $self;
 100 }
 101
 102 sub _has {
 103   my ($obj, $column) = @_;
 104   return $obj->can($column) && $obj->$column;
 105 }
 106
 107 sub _copy {
 108   my ($src, $form, $prefix, $postfix, $format_amounts, @columns) = @_;
 109
 110   @columns = grep { $src->can($_) } @columns;
 111
 112   map { $form->{"${prefix}${_}${postfix}"} = ref($src->$_) eq 'DateTime' ? $src->$_->to_lxoffice : $src->$_             } @columns if !$format_amounts;
 113   map { $form->{"${prefix}${_}${postfix}"} =                $::form->format_amount(\%::myconfig, $src->$_ * 1,   2)     } @columns if  $format_amounts == 1;
 114   map { $form->{"${prefix}${_}${postfix}"} = $src->$_ * 1 ? $::form->format_amount(\%::myconfig, $src->$_ * 1,   2) : 0 } @columns if  $format_amounts == 2;
 115   map { $form->{"${prefix}${_}${postfix}"} = $src->$_ * 1 ? $::form->format_amount(\%::myconfig, $src->$_ * 100, 2) : 0 } @columns if  $format_amounts == 3;
 116   map { $form->{"${prefix}${_}${postfix}"} = $src->$_ * 1 ? $::form->format_amount(\%::myconfig, $src->$_ * 1,  -2) : 0 } @columns if  $format_amounts == 4;
 117
 118   return $src;
 119 }
 120
 121 sub _copy_custom_variables {
 122   my ($src, $form, $prefix, $postfix, $cvar_validity) = @_;
 123
 124   my $obj = (any { ref($src) eq $_ } qw(SL::DB::OrderItem SL::DB::DeliveryOrderItem SL::DB::InvoiceItem))
 125           ? $src
 126           : $src->customervendor;
 127
 128   foreach my $cvar (@{ $obj->cvars_by_config }) {
 129     next if $cvar_validity && !$cvar_validity->{ $cvar->config_id };
 130
 131     my $value = ($cvar->config->type =~ m{^(?:bool|customer|vendor|part)$})
 132               ? $cvar->value
 133               : $cvar->value_as_text;
 134
 135     $form->{ $prefix . $cvar->config->name . $postfix } = $value;
 136   }
 137
 138   return $src;
 139 }
 140
 141 sub _determine_cvar_validity {
 142   my ($self, $vc) = @_;
 143
 144   my @part_ids    = uniq map { $_->parts_id } @{ $self->items };
 145   my @parts       = map { SL::DB::Part->new(id => $_)->load } @part_ids;
 146
 147   my %item_cvar_validity;
 148   foreach my $part (@parts) {
 149     $item_cvar_validity{ $part->id } = { map { ($_->config_id => $_->is_valid) } @{ $part->cvars_by_config } };
 150   }
 151
 152   my %vc_cvar_validity = map { ($_->config_id => $_->is_valid) } @{ $self->$vc->cvars_by_config };
 153
 154   return (
 155     items => \%item_cvar_validity,
 156     vc    => \%vc_cvar_validity,
 157   );
 158 }
 159
 160 1;