SL/DB/Helper/Payment.pm

   1 package SL::DB::Helper::Payment;
   2
   3 use strict;
   4
   5 use parent qw(Exporter);
   6 our @EXPORT = qw(pay_invoice);
   7 our @EXPORT_OK = qw(skonto_date skonto_charts amount_less_skonto within_skonto_period percent_skonto reference_account reference_amount open_amount open_percent remaining_skonto_days skonto_amount check_skonto_configuration valid_skonto_amount get_payment_suggestions validate_payment_type open_sepa_transfer_amount get_payment_select_options_for_bank_transaction exchangerate forex);
   8 our %EXPORT_TAGS = (
   9   "ALL" => [@EXPORT, @EXPORT_OK],
  10 );
  11
  12 require SL::DB::Chart;
  13 use Data::Dumper;
  14 use DateTime;
  15 use SL::DATEV qw(:CONSTANTS);
  16 use SL::Locale::String qw(t8);
  17 use List::Util qw(sum);
  18 use SL::DB::Exchangerate;
  19 use SL::DB::Currency;
  20 use Carp;
  21
  22 #
  23 # Public functions not exported by default
  24 #
  25
  26 sub pay_invoice {
  27   my ($self, %params) = @_;
  28
  29   require SL::DB::Tax;
  30
  31   my $is_sales = ref($self) eq 'SL::DB::Invoice';
  32   my $mult = $is_sales ? 1 : -1;  # multiplier for getting the right sign depending on ar/ap
  33   my @new_acc_ids;
  34   my $paid_amount = 0; # the amount that will be later added to $self->paid, should be in default currency
  35
  36   # default values if not set
  37   $params{payment_type} = 'without_skonto' unless $params{payment_type};
  38   validate_payment_type($params{payment_type});
  39
  40   # check for required parameters
  41   Common::check_params(\%params, qw(chart_id transdate));
  42   if ( $params{'payment_type'} eq 'without_skonto' && abs($params{'amount'}) < 0) {
  43     croak "invalid amount for payment_type 'without_skonto': $params{'amount'}\n";
  44   }
  45
  46
  47   my $transdate_obj;
  48   if (ref($params{transdate} eq 'DateTime')) {
  49     $transdate_obj = $params{transdate};
  50   } else {
  51    $transdate_obj = $::locale->parse_date_to_object($params{transdate});
  52   };
  53   croak t8('Illegal date') unless ref $transdate_obj;
  54
  55   # check for closed period
  56   my $closedto = $::locale->parse_date_to_object($::instance_conf->get_closedto);
  57   if ( ref $closedto && $transdate_obj < $closedto ) {
  58     croak t8('Cannot post payment for a closed period!');
  59   };
  60
  61   # check for maximum number of future days
  62   if ( $::instance_conf->get_max_future_booking_interval > 0 ) {
  63     croak t8('Cannot post transaction above the maximum future booking date!') if $transdate_obj > DateTime->now->add( days => $::instance_conf->get_max_future_booking_interval );
  64   };
  65
  66   # currency is either passed or use the invoice currency if it differs from the default currency
  67   my ($exchangerate,$currency);
  68   if ($params{currency} || $params{currency_id} || $self->currency_id != $::instance_conf->get_currency_id) {
  69     if ($params{currency} || $params{currency_id} ) { # currency was specified
  70       $currency = SL::DB::Manager::Currency->find_by(name => $params{currency}) || SL::DB::Manager::Currency->find_by(id => $params{currency_id});
  71     } else { # use invoice currency
  72       $currency = SL::DB::Manager::Currency->find_by(id => $self->currency_id);
  73     };
  74     die "no currency" unless $currency;
  75     if ($currency->id == $::instance_conf->get_currency_id) {
  76       $exchangerate = 1;
  77     } else {
  78       my $rate = SL::DB::Manager::Exchangerate->find_by(currency_id => $currency->id,
  79                                                         transdate   => $transdate_obj,
  80                                                        );
  81       if ($rate) {
  82         $exchangerate = $is_sales ? $rate->buy : $rate->sell;
  83       } else {
  84         die "No exchange rate for " . $transdate_obj->to_kivitendo;
  85       };
  86     };
  87   } else { # no currency param given or currency is the same as default_currency
  88     $exchangerate = 1;
  89   };
  90
  91   # options with_skonto_pt and difference_as_skonto don't require the parameter
  92   # amount, but if amount is passed, make sure it matches the expected value
  93   if ( $params{'payment_type'} eq 'difference_as_skonto' ) {
  94     croak "amount $params{amount} doesn't match open amount " . $self->open_amount . ", diff = " . ($params{amount}-$self->open_amount) if $params{amount} && abs($self->open_amount - $params{amount} ) > 0.0000001;
  95   } elsif ( $params{'payment_type'} eq 'with_skonto_pt' ) {
  96     croak "amount $params{amount} doesn't match amount less skonto: " . $self->amount_less_skonto . "\n" if $params{amount} && abs($self->amount_less_skonto - $params{amount} ) > 0.0000001;
  97     croak "payment type with_skonto_pt can't be used if payments have already been made" if $self->paid != 0;
  98   };
  99
 100   # absolute skonto amount for invoice, use as reference sum to see if the
 101   # calculated skontos add up
 102   # only needed for payment_term "with_skonto_pt"
 103
 104   my $skonto_amount_check = $self->skonto_amount; # variable should be zero after calculating all skonto
 105   my $total_open_amount   = $self->open_amount;
 106
 107   # account where money is paid to/from: bank account or cash
 108   my $account_bank = SL::DB::Manager::Chart->find_by(id => $params{chart_id});
 109   croak "can't find bank account with id " . $params{chart_id} unless ref $account_bank;
 110
 111   my $reference_account = $self->reference_account;
 112   croak "can't find reference account (link = AR/AP) for invoice" unless ref $reference_account;
 113
 114   my $memo   = $params{memo}   // '';
 115   my $source = $params{source} // '';
 116
 117   my $rounded_params_amount = _round( $params{amount} ); # / $exchangerate);
 118   my $fx_gain_loss_amount = 0; # for fx_gain and fx_loss
 119
 120   my $db = $self->db;
 121   $db->with_transaction(sub {
 122     my $new_acc_trans;
 123
 124     # all three payment type create 1 AR/AP booking (the paid part)
 125     # difference_as_skonto creates n skonto bookings (1 for each buchungsgruppe type)
 126     # with_skonto_pt creates 1 bank booking and n skonto bookings (1 for each buchungsgruppe type)
 127     # without_skonto creates 1 bank booking
 128
 129     # as long as there is no automatic tax, payments are always booked with
 130     # taxkey 0
 131
 132     unless ( $params{payment_type} eq 'difference_as_skonto' ) {
 133       # cases with_skonto_pt and without_skonto
 134
 135       # for case with_skonto_pt we need to know the corrected amount at this
 136       # stage if we are going to use $params{amount}
 137
 138       my $pay_amount = $rounded_params_amount;
 139       $pay_amount = $self->amount_less_skonto if $params{payment_type} eq 'with_skonto_pt';
 140
 141       # bank account and AR/AP
 142       $paid_amount += $pay_amount * $exchangerate;
 143
 144       my $amount = (-1 * $pay_amount) * $mult;
 145
 146
 147       # total amount against bank, do we already know this by now?
 148       $new_acc_trans = SL::DB::AccTransaction->new(trans_id   => $self->id,
 149                                                    chart_id   => $account_bank->id,
 150                                                    chart_link => $account_bank->link,
 151                                                    amount     => $amount,
 152                                                    transdate  => $transdate_obj,
 153                                                    source     => $source,
 154                                                    memo       => $memo,
 155                                                    project_id => $params{project_id} ? $params{project_id} : undef,
 156                                                    taxkey     => 0,
 157                                                    tax_id     => SL::DB::Manager::Tax->find_by(taxkey => 0)->id);
 158       $new_acc_trans->save;
 159
 160       push @new_acc_ids, $new_acc_trans->acc_trans_id;
 161       # deal with fxtransaction
 162       if ( $self->currency_id != $::instance_conf->get_currency_id ) {
 163         my $fxamount = _round($amount - ($amount * $exchangerate));
 164         $new_acc_trans = SL::DB::AccTransaction->new(trans_id       => $self->id,
 165                                                      chart_id       => $account_bank->id,
 166                                                      chart_link     => $account_bank->link,
 167                                                      amount         => $fxamount * -1,
 168                                                      transdate      => $transdate_obj,
 169                                                      source         => $source,
 170                                                      memo           => $memo,
 171                                                      taxkey         => 0,
 172                                                      fx_transaction => 1,
 173                                                      tax_id         => SL::DB::Manager::Tax->find_by(taxkey => 0)->id);
 174         $new_acc_trans->save;
 175         push @new_acc_ids, $new_acc_trans->acc_trans_id;
 176         # if invoice exchangerate differs from exchangerate of payment
 177         # deal with fxloss and fxamount
 178         if ($self->exchangerate and $self->exchangerate != 1 and $self->exchangerate != $exchangerate) {
 179           my $fxgain_chart = SL::DB::Manager::Chart->find_by(id => $::instance_conf->get_fxgain_accno_id) || die "Can't determine fxgain chart";
 180           my $fxloss_chart = SL::DB::Manager::Chart->find_by(id => $::instance_conf->get_fxloss_accno_id) || die "Can't determine fxloss chart";
 181           my $gain_loss_amount = _round($amount * ($exchangerate - $self->exchangerate ) * -1,2);
 182           my $gain_loss_chart = $gain_loss_amount > 0 ? $fxgain_chart : $fxloss_chart;
 183           $fx_gain_loss_amount = $gain_loss_amount;
 184
 185           $new_acc_trans = SL::DB::AccTransaction->new(trans_id       => $self->id,
 186                                                        chart_id       => $gain_loss_chart->id,
 187                                                        chart_link     => $gain_loss_chart->link,
 188                                                        amount         => $gain_loss_amount,
 189                                                        transdate      => $transdate_obj,
 190                                                        source         => $source,
 191                                                        memo           => $memo,
 192                                                        taxkey         => 0,
 193                                                        fx_transaction => 0,
 194                                                        tax_id         => SL::DB::Manager::Tax->find_by(taxkey => 0)->id);
 195           $new_acc_trans->save;
 196           push @new_acc_ids, $new_acc_trans->acc_trans_id;
 197
 198         }
 199       }
 200     }
 201
 202     if ( $params{payment_type} eq 'difference_as_skonto' or $params{payment_type} eq 'with_skonto_pt' ) {
 203
 204       my $total_skonto_amount;
 205       if ( $params{payment_type} eq 'with_skonto_pt' ) {
 206         $total_skonto_amount = $self->skonto_amount;
 207       } elsif ( $params{payment_type} eq 'difference_as_skonto' ) {
 208         $total_skonto_amount = $self->open_amount;
 209       };
 210
 211       my @skonto_bookings = $self->skonto_charts($total_skonto_amount);
 212
 213       # error checking:
 214       if ( $params{payment_type} eq 'difference_as_skonto' ) {
 215         my $calculated_skonto_sum  = sum map { $_->{skonto_amount} } @skonto_bookings;
 216         croak "calculated skonto for difference_as_skonto = $calculated_skonto_sum doesn't add up open amount: " . $self->open_amount unless _round($calculated_skonto_sum) == _round($self->open_amount);
 217       };
 218
 219       my $reference_amount = $total_skonto_amount;
 220
 221       # create an acc_trans entry for each result of $self->skonto_charts
 222       foreach my $skonto_booking ( @skonto_bookings ) {
 223         next unless $skonto_booking->{'chart_id'};
 224         next unless $skonto_booking->{'skonto_amount'} != 0;
 225         my $amount = -1 * $skonto_booking->{skonto_amount};
 226         $new_acc_trans = SL::DB::AccTransaction->new(trans_id   => $self->id,
 227                                                      chart_id   => $skonto_booking->{'chart_id'},
 228                                                      chart_link => SL::DB::Manager::Chart->find_by(id => $skonto_booking->{'chart_id'})->link,
 229                                                      amount     => $amount * $mult,
 230                                                      transdate  => $transdate_obj,
 231                                                      source     => $params{source},
 232                                                      taxkey     => 0,
 233                                                      tax_id     => SL::DB::Manager::Tax->find_by(taxkey => 0)->id);
 234
 235         # the acc_trans entries are saved individually, not added to $self and then saved all at once
 236         $new_acc_trans->save;
 237         push @new_acc_ids, $new_acc_trans->acc_trans_id;
 238
 239         $reference_amount -= abs($amount);
 240         $paid_amount      += -1 * $amount * $exchangerate;
 241         $skonto_amount_check -= $skonto_booking->{'skonto_amount'};
 242       };
 243       if ( $params{payment_type} eq 'difference_as_skonto' ) {
 244           die "difference_as_skonto calculated incorrectly, sum of calculated payments doesn't add up to open amount $total_open_amount, reference_amount = $reference_amount\n" unless _round($reference_amount) == 0;
 245       }
 246     }
 247
 248     my $arap_amount = 0;
 249
 250     if ( $params{payment_type} eq 'difference_as_skonto' ) {
 251       $arap_amount = $total_open_amount;
 252     } elsif ( $params{payment_type} eq 'without_skonto' ) {
 253       $arap_amount = $rounded_params_amount;
 254     } elsif ( $params{payment_type} eq 'with_skonto_pt' ) {
 255       # this should be amount + sum(amount+skonto), but while we only allow
 256       # with_skonto_pt for completely unpaid invoices we just use the value
 257       # from the invoice
 258       $arap_amount = $total_open_amount;
 259     }
 260
 261     # regardless of payment_type there is always only exactly one arap booking
 262     # TODO: compare $arap_amount to running total
 263     my $arap_booking= SL::DB::AccTransaction->new(trans_id   => $self->id,
 264                                                   chart_id   => $reference_account->id,
 265                                                   chart_link => $reference_account->link,
 266                                                   amount     => _round($arap_amount * $mult * $exchangerate - $fx_gain_loss_amount),
 267                                                   transdate  => $transdate_obj,
 268                                                   source     => '', #$params{source},
 269                                                   taxkey     => 0,
 270                                                   tax_id     => SL::DB::Manager::Tax->find_by(taxkey => 0)->id);
 271     $arap_booking->save;
 272     push @new_acc_ids, $arap_booking->acc_trans_id;
 273
 274     $fx_gain_loss_amount *= -1 if $self->is_sales;
 275     $self->paid($self->paid + _round($paid_amount) + $fx_gain_loss_amount) if $paid_amount;
 276     $self->datepaid($transdate_obj);
 277     $self->save;
 278
 279     # make sure transactions will be reloaded the next time $self->transactions
 280     # is called, as pay_invoice saves the acc_trans objects individually rather
 281     # than adding them to the transaction relation array.
 282     $self->forget_related('transactions');
 283
 284     my $datev_check = 0;
 285     if ( $is_sales )  {
 286       if ( (  $self->invoice && $::instance_conf->get_datev_check_on_sales_invoice  ) ||
 287            ( !$self->invoice && $::instance_conf->get_datev_check_on_ar_transaction )) {
 288         $datev_check = 1;
 289       }
 290     } else {
 291       if ( (  $self->invoice && $::instance_conf->get_datev_check_on_purchase_invoice ) ||
 292            ( !$self->invoice && $::instance_conf->get_datev_check_on_ap_transaction   )) {
 293         $datev_check = 1;
 294       }
 295     }
 296
 297     if ( $datev_check ) {
 298
 299       my $datev = SL::DATEV->new(
 300         dbh        => $db->dbh,
 301         trans_id   => $self->{id},
 302       );
 303
 304       $datev->generate_datev_data;
 305
 306       if ($datev->errors) {
 307         # this exception should be caught by with_transaction, which handles the rollback
 308         die join "\n", $::locale->text('DATEV check returned errors:'), $datev->errors;
 309       }
 310     }
 311
 312     1;
 313
 314   }) || die t8('error while paying invoice #1 : ', $self->invnumber) . $db->error . "\n";
 315   return wantarray ? @new_acc_ids : 1;
 316 }
 317
 318 sub skonto_date {
 319
 320   my $self = shift;
 321
 322   my $is_sales = ref($self) eq 'SL::DB::Invoice';
 323
 324   my $skonto_date;
 325
 326   if ( $is_sales ) {
 327     return undef unless ref $self->payment_terms;
 328     return undef unless $self->payment_terms->terms_skonto > 0;
 329     $skonto_date = DateTime->from_object(object => $self->transdate)->add(days => $self->payment_terms->terms_skonto);
 330   } else {
 331     return undef unless ref $self->vendor->payment_terms;
 332     return undef unless $self->vendor->payment_terms->terms_skonto > 0;
 333     $skonto_date = DateTime->from_object(object => $self->transdate)->add(days => $self->vendor->payment_terms->terms_skonto);
 334   };
 335
 336   return $skonto_date;
 337 };
 338
 339 sub reference_account {
 340   my $self = shift;
 341
 342   my $is_sales = ref($self) eq 'SL::DB::Invoice';
 343
 344   require SL::DB::Manager::AccTransaction;
 345
 346   my $link_filter = $is_sales ? 'AR' : 'AP';
 347
 348   my $acc_trans = SL::DB::Manager::AccTransaction->find_by(
 349      trans_id   => $self->id,
 350      SL::DB::Manager::AccTransaction->chart_link_filter("$link_filter")
 351   );
 352
 353   return undef unless ref $acc_trans;
 354
 355   my $reference_account = SL::DB::Manager::Chart->find_by(id => $acc_trans->chart_id);
 356
 357   return $reference_account;
 358 };
 359
 360 sub reference_amount {
 361   my $self = shift;
 362
 363   my $is_sales = ref($self) eq 'SL::DB::Invoice';
 364
 365   require SL::DB::Manager::AccTransaction;
 366
 367   my $link_filter = $is_sales ? 'AR' : 'AP';
 368
 369   my $acc_trans = SL::DB::Manager::AccTransaction->find_by(
 370      trans_id   => $self->id,
 371      SL::DB::Manager::AccTransaction->chart_link_filter("$link_filter")
 372   );
 373
 374   return undef unless ref $acc_trans;
 375
 376   # this should be the same as $self->amount
 377   return $acc_trans->amount;
 378 };
 379
 380
 381 sub open_amount {
 382   my $self = shift;
 383
 384   # in the future maybe calculate this from acc_trans
 385
 386   # if the difference is 0.01 Cent this may end up as 0.009999999999998
 387   # numerically, so round this value when checking for cent threshold >= 0.01
 388
 389   return ($self->amount // 0) - ($self->paid // 0);
 390 };
 391
 392 sub open_percent {
 393   my $self = shift;
 394
 395   return 0 if $self->amount == 0;
 396   my $open_percent;
 397   if ( $self->open_amount < 0 ) {
 398     # overpaid, currently treated identically
 399     $open_percent = $self->open_amount * 100 / $self->amount;
 400   } else {
 401     $open_percent = $self->open_amount * 100 / $self->amount;
 402   };
 403
 404   return _round($open_percent) || 0;
 405 };
 406
 407 sub skonto_amount {
 408   my $self = shift;
 409
 410   return $self->amount - $self->amount_less_skonto;
 411 };
 412
 413 sub remaining_skonto_days {
 414   my $self = shift;
 415
 416   return undef unless ref $self->skonto_date;
 417
 418   my $dur = DateTime::Duration->new($self->skonto_date - DateTime->today);
 419   return $dur->delta_days();
 420
 421 };
 422
 423 sub percent_skonto {
 424   my $self = shift;
 425
 426   my $is_sales = ref($self) eq 'SL::DB::Invoice';
 427
 428   my $percent_skonto = 0;
 429
 430   if ( $is_sales ) {
 431     return undef unless ref $self->payment_terms;
 432     return undef unless $self->payment_terms->percent_skonto > 0;
 433     $percent_skonto = $self->payment_terms->percent_skonto;
 434   } else {
 435     return undef unless ref $self->vendor->payment_terms;
 436     return undef unless $self->vendor->payment_terms->terms_skonto > 0;
 437     $percent_skonto = $self->vendor->payment_terms->percent_skonto;
 438   };
 439
 440   return $percent_skonto;
 441 };
 442
 443 sub amount_less_skonto {
 444   # amount that has to be paid if skonto applies, always return positive rounded values
 445   # the result is rounded so we can directly compare it with the user input
 446   my $self = shift;
 447
 448   my $percent_skonto = $self->percent_skonto || 0;
 449
 450   return _round($self->amount - ( $self->amount * $percent_skonto) );
 451
 452 };
 453
 454 sub check_skonto_configuration {
 455   my $self = shift;
 456
 457   my $is_sales = ref($self) eq 'SL::DB::Invoice';
 458
 459   my $skonto_configured = 1; # default is assume skonto works
 460
 461   # my $transactions = $self->transactions;
 462   foreach my $transaction (@{ $self->transactions }) {
 463     # find all transactions with an AR_amount or AP_amount link
 464     my $tax = SL::DB::Manager::Tax->get_first( where => [taxkey => $transaction->taxkey, id => $transaction->tax_id ]);
 465     croak "no tax for taxkey " . $transaction->{taxkey} unless ref $tax;
 466
 467     $transaction->{chartlinks} = { map { $_ => 1 } split(m/:/, $transaction->chart_link) };
 468     if ( $is_sales && $transaction->{chartlinks}->{AR_amount} ) {
 469       $skonto_configured = 0 unless $tax->skonto_sales_chart_id;
 470     } elsif ( !$is_sales && $transaction->{chartlinks}->{AP_amount}) {
 471       $skonto_configured = 0 unless $tax->skonto_purchase_chart_id;
 472     };
 473   };
 474
 475   return $skonto_configured;
 476 };
 477
 478 sub open_sepa_transfer_amount {
 479   my $self = shift;
 480
 481   my ($vc, $key, $type);
 482   if ( ref($self) eq 'SL::DB::Invoice' ) {
 483     $vc   = 'customer';
 484     $key  = 'ap_id';
 485     $type = 'ar';
 486   } else {
 487     $vc   = 'vendor';
 488     $key  = 'ap_id';
 489     $type = 'ap';
 490   };
 491
 492   my $sql = qq|SELECT SUM(sei.amount) AS amount FROM sepa_export_items sei | .
 493             qq| LEFT JOIN sepa_export se ON (sei.sepa_export_id = se.id)   | .
 494             qq| WHERE $key = ? AND NOT se.closed AND (se.vc = '$vc')       |;
 495
 496   my ($open_sepa_amount) = $self->db->dbh->selectrow_array($sql, undef, $self->id);
 497
 498   return $open_sepa_amount || 0;
 499
 500 };
 501
 502
 503 sub skonto_charts {
 504   my $self = shift;
 505
 506   # TODO: use param for amount, may also want to calculate skonto_amounts by
 507   # passing percentage in the future
 508
 509   my $amount = shift || $self->skonto_amount;
 510
 511   croak "no amount passed to skonto_charts" unless abs(_round($amount)) >= 0.01;
 512
 513   # TODO: check whether there are negative values in invoice / acc_trans ... credited items
 514
 515   # don't check whether skonto applies, because user may want to override this
 516   # return undef unless $self->percent_skonto;  # for is_sales
 517   # return undef unless $self->vendor->payment_terms->percent_skonto;  # for purchase
 518
 519   my $is_sales = ref($self) eq 'SL::DB::Invoice';
 520
 521   my $mult = $is_sales ? 1 : -1;  # multiplier for getting the right sign
 522
 523   my @skonto_charts;  # resulting array with all income/expense accounts that have to be corrected
 524
 525   # calculate effective skonto (percentage) in difference_as_skonto mode
 526   # only works if there are no negative acc_trans values
 527   my $effective_skonto_rate = $amount ? $amount / $self->amount : 0;
 528
 529   # checks:
 530   my $total_skonto_amount  = 0;
 531   my $total_rounding_error = 0;
 532
 533   my $reference_ARAP_amount = 0;
 534
 535   # my $transactions = $self->transactions;
 536   foreach my $transaction (@{ $self->transactions }) {
 537     # find all transactions with an AR_amount or AP_amount link
 538     $transaction->{chartlinks} = { map { $_ => 1 } split(m/:/, $transaction->{chart_link}) };
 539     # second condition is that we can determine an automatic Skonto account for each AR_amount entry
 540
 541     if ( ( $is_sales && $transaction->{chartlinks}->{AR_amount} ) or ( !$is_sales && $transaction->{chartlinks}->{AP_amount}) ) {
 542         # $reference_ARAP_amount += $transaction->{amount} * $mult;
 543
 544         # quick hack that works around problem of non-unique tax keys in SKR04
 545         # ? use tax_id in acc_trans
 546         my $tax = SL::DB::Manager::Tax->get_first( where => [id => $transaction->{tax_id}]);
 547         croak "no tax for taxkey " . $transaction->{taxkey} unless ref $tax;
 548
 549         if ( $is_sales ) {
 550           die t8('no skonto_chart configured for taxkey #1 : #2 : #3', $transaction->{taxkey} , $tax->taxdescription , $tax->rate*100) unless ref $tax->skonto_sales_chart;
 551         } else {
 552           die t8('no skonto_chart configured for taxkey #1 : #2 : #3', $transaction->{taxkey} , $tax->taxdescription , $tax->rate*100) unless ref $tax->skonto_purchase_chart;
 553         };
 554
 555         my $skonto_amount_unrounded;
 556
 557         my $skonto_percent_abs = $self->amount ? abs($transaction->amount * (1 + $tax->rate) * 100 / $self->amount) : 0;
 558
 559         my $transaction_amount = abs($transaction->{amount} * (1 + $tax->rate));
 560         my $transaction_skonto_percent = abs($transaction_amount/$self->amount); # abs($transaction->{amount} * (1 + $tax->rate));
 561
 562
 563         $skonto_amount_unrounded   = abs($amount * $transaction_skonto_percent);
 564         my $skonto_amount_rounded  = _round($skonto_amount_unrounded);
 565         my $rounding_error         = $skonto_amount_unrounded - $skonto_amount_rounded;
 566         my $rounded_rounding_error = _round($rounding_error);
 567
 568         $total_rounding_error += $rounding_error;
 569         $total_skonto_amount  += $skonto_amount_rounded;
 570
 571         my $rec = {
 572           # skonto_percent_abs: relative part of amount + tax to the total invoice amount
 573           'skonto_percent_abs'     => $skonto_percent_abs,
 574           'chart_id'               => $is_sales ? $tax->skonto_sales_chart->id : $tax->skonto_purchase_chart->id,
 575           'skonto_amount'          => $skonto_amount_rounded,
 576           # 'rounding_error'         => $rounding_error,
 577           # 'rounded_rounding_error' => $rounded_rounding_error,
 578         };
 579
 580         push @skonto_charts, $rec;
 581       };
 582   };
 583
 584   # if the rounded sum of all rounding_errors reaches 0.01 this sum is
 585   # subtracted from the largest skonto_amount
 586   my $rounded_total_rounding_error = abs(_round($total_rounding_error));
 587
 588   if ( $rounded_total_rounding_error > 0 ) {
 589     my $highest_amount_pos = 0;
 590     my $highest_amount = 0;
 591     my $i = -1;
 592     foreach my $ref ( @skonto_charts ) {
 593       $i++;
 594       if ( $ref->{skonto_amount} > $highest_amount ) {
 595         $highest_amount     = $ref->{skonto_amount};
 596         $highest_amount_pos = $i;
 597       };
 598     };
 599     $skonto_charts[$i]->{skonto_amount} -= $rounded_total_rounding_error;
 600   };
 601
 602   return @skonto_charts;
 603 };
 604
 605
 606 sub within_skonto_period {
 607   my $self = shift;
 608   my $dateref = shift || DateTime->now->truncate( to => 'day' );
 609
 610   return undef unless ref $dateref eq 'DateTime';
 611   return 0 unless $self->skonto_date;
 612
 613   # return 1 if requested date (or today) is inside skonto period
 614   # this will also return 1 if date is before the invoice date
 615   return $dateref <= $self->skonto_date;
 616 };
 617
 618 sub valid_skonto_amount {
 619   my $self = shift;
 620   my $amount = shift || 0;
 621   my $max_skonto_percent = 0.10;
 622
 623   return 0 unless $amount > 0;
 624
 625   # does this work for other currencies?
 626   return ($self->amount*$max_skonto_percent) > $amount;
 627 };
 628
 629 sub get_payment_select_options_for_bank_transaction {
 630   my ($self, $bt_id, %params) = @_;
 631
 632
 633   # CAVEAT template code expects with_skonto_pt at position 1 for visual help
 634   my @options;
 635   if(!$self->skonto_date) {
 636     push(@options, { payment_type => 'without_skonto', display => t8('without skonto'), selected => 1 });
 637     # wrong call to presenter or not implemented? disabled option is ignored
 638     # push(@options, { payment_type => 'with_skonto_pt', display => t8('with skonto acc. to pt'), disabled => 1 });
 639     return @options;
 640   }
 641   # valid skonto date, check if skonto is preferred
 642   my $bt = SL::DB::BankTransaction->new(id => $bt_id)->load;
 643   if ($self->skonto_date && $self->within_skonto_period($bt->transdate)) {
 644     push(@options, { payment_type => 'without_skonto', display => t8('without skonto') });
 645     push(@options, { payment_type => 'with_skonto_pt', display => t8('with skonto acc. to pt'), selected => 1 });
 646   } else {
 647     push(@options, { payment_type => 'without_skonto', display => t8('without skonto') , selected => 1 });
 648     push(@options, { payment_type => 'with_skonto_pt', display => t8('with skonto acc. to pt')});
 649   }
 650   return @options;
 651 }
 652
 653 sub exchangerate {
 654   my ($self) = @_;
 655
 656   return 1 if $self->currency_id == $::instance_conf->get_currency_id;
 657
 658   die "transdate isn't a DateTime object:" . ref($self->transdate) unless ref($self->transdate) eq 'DateTime';
 659   my $rate = SL::DB::Manager::Exchangerate->find_by(currency_id => $self->currency_id,
 660                                                     transdate   => $self->transdate,
 661                                                    );
 662   return undef unless $rate;
 663
 664   return $self->is_sales ? $rate->buy : $rate->sell; # also undef if not defined
 665 };
 666
 667 sub get_payment_suggestions {
 668
 669   my ($self, %params) = @_;
 670
 671   my $open_amount = $self->open_amount;
 672   $open_amount   -= $self->open_sepa_transfer_amount if $params{sepa};
 673
 674   $self->{invoice_amount_suggestion} = $open_amount;
 675   undef $self->{payment_select_options};
 676   push(@{$self->{payment_select_options}} , { payment_type => 'without_skonto',  display => t8('without skonto') });
 677   if ( $self->within_skonto_period ) {
 678     # If there have been no payments yet suggest amount_less_skonto, otherwise the open amount
 679     if ( $open_amount &&                   # invoice amount not 0
 680          $open_amount == $self->amount &&  # no payments yet, or sum of payments and sepa export amounts is zero
 681          $self->check_skonto_configuration) {
 682       $self->{invoice_amount_suggestion} = $self->amount_less_skonto;
 683       push(@{$self->{payment_select_options}} , { payment_type => 'with_skonto_pt',  display => t8('with skonto acc. to pt') , selected => 1 });
 684     } else {
 685       if ( ( $self->valid_skonto_amount($self->open_amount) || $self->valid_skonto_amount($open_amount) ) and not $params{sepa} ) {
 686         $self->{invoice_amount_suggestion} = $open_amount;
 687         # only suggest difference_as_skonto if open_amount exactly matches skonto_amount
 688         # AND we aren't in SEPA mode
 689         my $selected = 0;
 690         $selected = 1 if _round($open_amount) == _round($self->skonto_amount);
 691         push(@{$self->{payment_select_options}} , { payment_type => 'difference_as_skonto',  display => t8('difference as skonto') , selected => $selected });
 692       };
 693     };
 694   } else {
 695     # invoice was configured with skonto, but skonto date has passed, or no skonto available
 696     $self->{invoice_amount_suggestion} = $open_amount;
 697     # difference_as_skonto doesn't make any sense for SEPA transfer, as this doesn't cause any actual payment
 698     if ( $self->valid_skonto_amount($self->open_amount) && not $params{sepa} ) {
 699       push(@{$self->{payment_select_options}} , { payment_type => 'difference_as_skonto',  display => t8('difference as skonto') , selected => 0 });
 700     };
 701   };
 702   return 1;
 703 };
 704
 705 # locales for payment type
 706 #
 707 # $main::locale->text('without_skonto')
 708 # $main::locale->text('with_skonto_pt')
 709 # $main::locale->text('difference_as_skonto')
 710 #
 711
 712 sub validate_payment_type {
 713   my $payment_type = shift;
 714
 715   my %allowed_payment_types = map { $_ => 1 } qw(without_skonto with_skonto_pt difference_as_skonto);
 716   croak "illegal payment type: $payment_type, must be one of: " . join(' ', keys %allowed_payment_types) unless $allowed_payment_types{ $payment_type };
 717
 718   return 1;
 719 }
 720
 721 sub forex {
 722   my ($self) = @_;
 723   $self->currency_id == $::instance_conf->get_currency_id ? return 0 : return 1;
 724 };
 725
 726 sub _round {
 727   my $value = shift;
 728   my $num_dec = 2;
 729   return $::form->round_amount($value, 2);
 730 }
 731
 732 1;
 733
 734 __END__
 735
 736 =pod
 737
 738 =head1 NAME
 739
 740 SL::DB::Helper::Payment  Mixin providing helper methods for paying C<Invoice>
 741                          and C<PurchaseInvoice> objects and using skonto
 742
 743 =head1 SYNOPSIS
 744
 745 In addition to actually causing a payment via pay_invoice this helper contains
 746 many methods that help in determining information about the status of the
 747 invoice, such as the remaining open amount, whether skonto applies, until which
 748 date skonto applies, the skonto amount and relative percentages, what to do
 749 with skonto, ...
 750
 751 To prevent duplicate code this was all added in this mixin rather than directly
 752 in SL::DB::Invoice and SL::DB::PurchaseInvoice.
 753
 754 =over 4
 755
 756 =item C<pay_invoice %params>
 757
 758 Create a payment booking for an existing invoice object (type ar/ap/is/ir) via
 759 a configured bank account.
 760
 761 This function deals with all the acc_trans entries and also updates paid and datepaid.
 762 The params C<transdate> and C<chart_id> are mandantory.
 763 If the default payment ('without_skonto') is used the param amount is also
 764 mandantory.
 765
 766 Transdate can either be a date object or a date string.
 767 Chart_id is the id of the payment booking chart.
 768 Amount is either a postive or negative number, but never 0.
 769
 770
 771 Example:
 772
 773   my $ap   = SL::DB::Manager::PurchaseInvoice->find_by( invnumber => '1');
 774   my $bank = SL::DB::Manager::BankAccount->find_by( name => 'Bank');
 775   $ap->pay_invoice(chart_id      => $bank->chart_id,
 776                    amount        => $ap->open_amount,
 777                    transdate     => DateTime->now->to_kivitendo,
 778                    memo          => 'foobar',
 779                    source        => 'barfoo',
 780                    payment_type  => 'without_skonto',  # default if not specified
 781                    project_id    => 25,
 782                   );
 783
 784 or with skonto:
 785   $ap->pay_invoice(chart_id      => $bank->chart_id,
 786                    amount        => $ap->amount,       # doesn't need to be specified
 787                    transdate     => DateTime->now->to_kivitendo,
 788                    memo          => 'foobar',
 789                    source        => 'barfoo',
 790                    payment_type  => 'with_skonto',
 791                   );
 792
 793 or in a certain currency:
 794   $ap->pay_invoice(chart_id      => $bank->chart_id,
 795                    amount        => 500,
 796                    currency      => 'USD',
 797                    transdate     => DateTime->now->to_kivitendo,
 798                    memo          => 'foobar',
 799                    source        => 'barfoo',
 800                    payment_type  => 'with_skonto_pt',
 801                   );
 802
 803 Allowed payment types are:
 804   without_skonto with_skonto_pt difference_as_skonto
 805
 806 The option C<payment_type> allows for a basic skonto mechanism.
 807
 808 C<without_skonto> is the default mode, "amount" is paid to the account in
 809 chart_id. This can also be used for partial payments and corrections via
 810 negative amounts.
 811
 812 C<with_skonto_pt> can't be used for partial payments. When used on unpaid
 813 invoices the whole amount is paid, with the skonto part automatically being
 814 booked according to the skonto chart configured in the tax settings for each
 815 tax key. If an amount is passed it is ignored and the actual configured skonto
 816 amount is used.
 817
 818 C<difference_as_skonto> can only be used after partial payments have been made,
 819 the whole specified amount is booked according to the skonto charts configured
 820 in the tax settings for each tax key.
 821
 822 So passing amount doesn't have any effect for the cases C<with_skonto_pt> and
 823 C<difference_as_skonto>, as all necessary values are taken from the stored
 824 invoice.
 825
 826 The skonto modes automatically calculate the relative amounts for a mix of
 827 taxes, e.g. items with 7% and 19% in one invoice. There is a helper method
 828 skonto_charts, which calculates the relative percentages according to the
 829 amounts in acc_trans (which are grouped by tax).
 830
 831 There is currently no way of excluding certain items in an invoice from having
 832 skonto applied to them.  If this feature was added to parts the calculation
 833 method of relative skonto would have to be completely rewritten using the
 834 invoice items rather than acc_trans.
 835
 836 The skonto modes also still don't automatically correct the tax, this still has
 837 to be done manually. Therefore all payments generated by pay_invoice have
 838 taxkey 0.
 839
 840 There is currently no way to directly pay an invoice via this method if the
 841 effective skonto differs from the skonto according to the payment terms
 842 configured for the invoice/vendor.
 843
 844 In this case one has to pay in two steps: first the actual paid amount via
 845 "without skonto", and then the remainder via "difference_as_skonto". The user
 846 has to there actively decide whether to accept the differing skonto.
 847
 848 Because of the way skonto_charts works the calculation doesn't work if there
 849 are negative values in acc_trans. E.g. one invoice with a positive value for
 850 19% tax and a negative value for the acc_trans line with 7%
 851
 852 Skonto doesn't/shouldn't apply if the invoice contains credited items.
 853
 854 If no amount is given the whole open amout is paid.
 855
 856 If neither currency or currency_id are given as params, the currency of the
 857 invoice is assumed to be the payment currency.
 858
 859 If successful the return value will be 1 in scalar context or in list context
 860 the two ids (acc_trans_id) of the newly created bookings.
 861 =item C<reference_account>
 862
 863 Returns a chart object which is the chart of the invoice with link AR or AP.
 864
 865 Example (1200 is the AR account for SKR04):
 866   my $invoice = invoice(invnumber => '144');
 867   $invoice->reference_account->accno
 868   # 1200
 869
 870 =item C<percent_skonto>
 871
 872 Returns the configured skonto percentage of the payment terms of an invoice,
 873 e.g. 0.02 for 2%. Payment terms come from invoice settings for ar, from vendor
 874 settings for ap.
 875
 876 =item C<amount_less_skonto>
 877
 878 If the invoice has a payment term (via ar for sales, via vendor for purchase),
 879 calculate the amount to be paid in the case of skonto.  This doesn't check,
 880 whether skonto applies (i.e. skonto doesn't wasn't exceeded), it just subtracts
 881 the configured percentage (e.g. 2%) from the total amount.
 882
 883 The returned value is rounded to two decimals.
 884
 885 =item C<skonto_date>
 886
 887 The date up to which skonto may be taken. This is calculated from the invoice
 888 date + the number of days configured in the payment terms.
 889
 890 This method can also be used to determine whether skonto applies for the
 891 invoice, as it returns undef if there is no payment term or skonto days is set
 892 to 0.
 893
 894 =item C<within_skonto_period [DATE]>
 895
 896 Returns 0 or 1.
 897
 898 Checks whether the invoice has payment terms configured, and whether the date
 899 is within the skonto max date. If no date is passed the current date is used.
 900
 901 You can also pass a dateref object as a parameter to check whether skonto
 902 applies for that date rather than the current date.
 903
 904 =item C<valid_skonto_amount>
 905
 906 Takes an amount as an argument and checks whether the amount is less than 10%
 907 of the total amount of the invoice. The value of 10% is currently hardcoded in
 908 the method. This method is currently used to check whether to offer the payment
 909 option "difference as skonto".
 910
 911 Example:
 912  if ( $invoice->valid_skonto_amount($invoice->open_amount) ) {
 913    # ... do something
 914  }
 915
 916 =item C<skonto_charts [$amount]>
 917
 918 Returns a list of chart_ids and some calculated numbers that can be used for
 919 paying the invoice with skonto. This function will automatically calculate the
 920 relative skonto amounts even if the invoice contains several types of taxes
 921 (e.g. 7% and 19%).
 922
 923 Example usage:
 924   my $invoice = SL::DB::Manager::Invoice->find_by(invnumber => '211');
 925   my @skonto_charts = $invoice->skonto_charts;
 926
 927 or with the total skonto amount as an argument:
 928   my @skonto_charts = $invoice->skonto_charts($invoice->open_amount);
 929
 930 The following values are generated for each chart:
 931
 932 =over 2
 933
 934 =item C<chart_id>
 935
 936 The chart id of the skonto amount to be booked.
 937
 938 =item C<skonto_amount>
 939
 940 The total amount to be paid to the account
 941
 942 =item C<skonto_percent>
 943
 944 The relative percentage of that skonto chart. This can be useful if the actual
 945 ekonto that is paid deviates from the granted skonto, e.g. customer effectively
 946 pays 2.6% skonto instead of 2%, and we accept this. Then we can still calculate
 947 the relative skonto amounts for different taxes based on the absolute
 948 percentages. Used for case C<difference_as_skonto>.
 949
 950 =item C<skonto_percent_abs>
 951
 952 The absolute percentage of that skonto chart in relation to the total amount.
 953 Used to calculate skonto_amount for case C<with_skonto_pt>.
 954
 955 =back
 956
 957 If the invoice contains several types of taxes then skonto_charts can be used
 958 to calculate the relative amounts.
 959
 960 Example in console of an invoice with 100 Euro at 7% and 100 Euro at 19% with
 961 tax not included:
 962
 963   my $invoice = invoice(invnumber => '144');
 964   $invoice->amount
 965   226.00000
 966   $invoice->payment_terms->percent_skonto
 967   0.02
 968   $invoice->skonto_charts
 969   pp $invoice->skonto_charts
 970   #             $VAR1 = {
 971   #               'chart_id'       => 128,
 972   #               'skonto_amount'  => '2.14',
 973   #               'skonto_percent' => '47.3451327433627'
 974   #             };
 975   #             $VAR2 = {
 976   #               'chart_id'       => 130,
 977   #               'skonto_amount'  => '2.38',
 978   #               'skonto_percent' => '52.654867256637'
 979   #             };
 980
 981 C<skonto_charts> always returns positive values (abs) for C<skonto_amount> and
 982 C<skonto_percent>.
 983
 984 C<skonto_charts> generates one entry for each acc_trans entry. ar and ap
 985 bookings only have one acc_trans entry for each taxkey (e.g. 7% and 19%).  This
 986 is because all the items are grouped according to the Buchungsgruppen mechanism
 987 and the totals are written to acc_trans.  For is and ir it is possible to have
 988 several acc_trans entries with the same tax. In this case skonto_charts
 989 generates a skonto booking for each acc_trans income/expense entry.
 990
 991 In the future this function may also be used to calculate the corrections for
 992 the income tax.
 993
 994 =item C<open_amount>
 995
 996 Unrounded total open amount of invoice (amount - paid).
 997 Doesn't take into account pending SEPA transfers.
 998
 999 =item C<open_percent>
1000
1001 Percentage of the invoice that is still unpaid, e.g. 100,00 if no payments have
1002 been made yet, 0,00 if fully paid.
1003
1004 =item C<remaining_skonto_days>
1005
1006 How many days skonto can still be taken, calculated from current day. Returns 0
1007 if current day is the max skonto date, and negative number if skonto date has
1008 already passed.
1009
1010 Returns undef if skonto is not configured for that invoice.
1011
1012 =item C<get_payment_suggestions %params>
1013
1014 Creates data intended for an L.select_tag dropdown that can be used in a
1015 template. Depending on the rules it will choose from the options
1016 without_skonto, with_skonto_pt and difference_as_skonto, and select the most
1017 likely one.
1018
1019 If the parameter "sepa" is passed, the SEPA export payments that haven't been
1020 executed yet are considered when determining the open amount of the invoice.
1021
1022 The current rules are:
1023
1024 =over 2
1025
1026 =item * without_skonto is always an option
1027
1028 =item * with_skonto_pt is only offered if there haven't been any payments yet and the current date is within the skonto period.
1029
1030 =item * difference_as_skonto is only offered if there have already been payments made and the open amount is smaller than 10% of the total amount.
1031
1032 with_skonto_pt will only be offered, if all the AR_amount/AP_amount have a
1033 taxkey with a configured skonto chart
1034
1035 =back
1036
1037 It will also fill $self->{invoice_amount_suggestion} with either the open
1038 amount, or if with_skonto_pt is selected, with amount_less_skonto, so the
1039 template can fill the input with the likely amount.
1040
1041 Example in console:
1042   my $ar = invoice( invnumber => '257');
1043   $ar->get_payment_suggestions;
1044   print $ar->{invoice_amount_suggestion} . "\n";
1045   # 97.23
1046   pp $ar->{payment_select_options}
1047   # $VAR1 = [
1048   #         {
1049   #           'display' => 'ohne Skonto',
1050   #           'payment_type' => 'without_skonto'
1051   #         },
1052   #         {
1053   #           'display' => 'mit Skonto nach ZB',
1054   #           'payment_type' => 'with_skonto_pt',
1055   #           'selected' => 1
1056   #         }
1057   #       ];
1058
1059 The resulting array $ar->{payment_select_options} can be used in a template
1060 select_tag using value_key and title_key:
1061
1062 [% L.select_tag('payment_type_' _ loop.count, invoice.payment_select_options, value_key => 'payment_type', title_key => 'display', id => 'payment_type_' _ loop.count) %]
1063
1064 It would probably make sense to have different rules for the pre-selected items
1065 for sales and purchase, and to also make these rules configurable in the
1066 defaults. E.g. when creating a SEPA bank transfer for vendor invoices a company
1067 might always want to pay quickly making use of skonto, while another company
1068 might always want to pay as late as possible.
1069
1070 =item C<get_payment_select_options_for_bank_transaction $banktransaction_id %params>
1071
1072 Make suggestion for a skonto payment type by returning an HTML blob of the options
1073 of a HTML drop-down select with the most likely option preselected.
1074
1075 This is a helper function for BankTransaction/ajax_payment_suggestion and
1076 template/webpages/bank_transactions/invoices.html
1077
1078 We are working with an existing payment, so difference_as_skonto never makes sense.
1079
1080 If skonto is not possible (skonto_date does not exists) simply return
1081 the single 'no skonto' option as a visual hint.
1082
1083 If skonto is possible (skonto_date exists), add two possibilities:
1084 without_skonto and with_skonto_pt if payment date is within skonto_date,
1085 preselect with_skonto_pt, otherwise preselect without skonto.
1086
1087 =item C<exchangerate>
1088
1089 Returns 1 immediately if the record uses the default currency.
1090
1091 Returns the exchangerate in database format for the invoice according to that
1092 invoice's transdate, returning 'buy' for sales, 'sell' for purchases.
1093
1094 If no exchangerate can be found for that day undef is returned.
1095
1096 =item C<forex>
1097
1098 Returns 1 if record uses a different currency, 0 if the default currency is used.
1099
1100 =back
1101
1102 =head1 TODO AND CAVEATS
1103
1104 =over 4
1105
1106 =item *
1107
1108 when looking at open amount, maybe consider that there may already be queued
1109 amounts in SEPA Export
1110
1111 =back
1112
1113 =head1 AUTHOR
1114
1115 G. Richardson E<lt>grichardson@kivitendo-premium.de<gt>
1116
1117 =cut