SL/DB/Helper/Payment.pm

   1 package SL::DB::Helper::Payment;
   2
   3 use strict;
   4
   5 use parent qw(Exporter);
   6 our @EXPORT = qw(pay_invoice);
   7 our @EXPORT_OK = qw(skonto_date skonto_charts amount_less_skonto within_skonto_period percent_skonto reference_account reference_amount open_amount open_percent remaining_skonto_days skonto_amount check_skonto_configuration valid_skonto_amount get_payment_suggestions validate_payment_type open_sepa_transfer_amount get_payment_select_options_for_bank_transaction exchangerate forex);
   8 our %EXPORT_TAGS = (
   9   "ALL" => [@EXPORT, @EXPORT_OK],
  10 );
  11
  12 require SL::DB::Chart;
  13 use Data::Dumper;
  14 use DateTime;
  15 use SL::DATEV qw(:CONSTANTS);
  16 use SL::Locale::String qw(t8);
  17 use List::Util qw(sum);
  18 use SL::DB::Exchangerate;
  19 use SL::DB::Currency;
  20 use Carp;
  21
  22 #
  23 # Public functions not exported by default
  24 #
  25
  26 sub pay_invoice {
  27   my ($self, %params) = @_;
  28
  29   require SL::DB::Tax;
  30
  31   my $is_sales = ref($self) eq 'SL::DB::Invoice';
  32   my $mult = $is_sales ? 1 : -1;  # multiplier for getting the right sign depending on ar/ap
  33
  34   my $paid_amount = 0; # the amount that will be later added to $self->paid, should be in default currency
  35
  36   # default values if not set
  37   $params{payment_type} = 'without_skonto' unless $params{payment_type};
  38   validate_payment_type($params{payment_type});
  39
  40   # check for required parameters
  41   Common::check_params(\%params, qw(chart_id transdate));
  42
  43   my $transdate_obj;
  44   if (ref($params{transdate} eq 'DateTime')) {
  45     $transdate_obj = $params{transdate};
  46   } else {
  47    $transdate_obj = $::locale->parse_date_to_object($params{transdate});
  48   };
  49   croak t8('Illegal date') unless ref $transdate_obj;
  50
  51   # check for closed period
  52   my $closedto = $::locale->parse_date_to_object($::instance_conf->get_closedto);
  53   if ( ref $closedto && $transdate_obj < $closedto ) {
  54     croak t8('Cannot post payment for a closed period!');
  55   };
  56
  57   # check for maximum number of future days
  58   if ( $::instance_conf->get_max_future_booking_interval > 0 ) {
  59     croak t8('Cannot post transaction above the maximum future booking date!') if $transdate_obj > DateTime->now->add( days => $::instance_conf->get_max_future_booking_interval );
  60   };
  61
  62   # currency is either passed or use the invoice currency if it differs from the default currency
  63   my ($exchangerate,$currency);
  64   if ($params{currency} || $params{currency_id} || $self->currency_id != $::instance_conf->get_currency_id) {
  65     if ($params{currency} || $params{currency_id} ) { # currency was specified
  66       $currency = SL::DB::Manager::Currency->find_by(name => $params{currency}) || SL::DB::Manager::Currency->find_by(id => $params{currency_id});
  67     } else { # use invoice currency
  68       $currency = SL::DB::Manager::Currency->find_by(id => $self->currency_id);
  69     };
  70     die "no currency" unless $currency;
  71     if ($currency->id == $::instance_conf->get_currency_id) {
  72       $exchangerate = 1;
  73     } else {
  74       my $rate = SL::DB::Manager::Exchangerate->find_by(currency_id => $currency->id,
  75                                                         transdate   => $transdate_obj,
  76                                                        );
  77       if ($rate) {
  78         $exchangerate = $is_sales ? $rate->buy : $rate->sell;
  79       } else {
  80         die "No exchange rate for " . $transdate_obj->to_kivitendo;
  81       };
  82     };
  83   } else { # no currency param given or currency is the same as default_currency
  84     $exchangerate = 1;
  85   };
  86
  87   # input checks:
  88   if ( $params{'payment_type'} eq 'without_skonto' ) {
  89     croak "invalid amount for payment_type 'without_skonto': $params{'amount'}\n" unless abs($params{'amount'}) > 0;
  90   };
  91
  92   # options with_skonto_pt and difference_as_skonto don't require the parameter
  93   # amount, but if amount is passed, make sure it matches the expected value
  94   if ( $params{'payment_type'} eq 'difference_as_skonto' ) {
  95     croak "amount $params{amount} doesn't match open amount " . $self->open_amount . ", diff = " . ($params{amount}-$self->open_amount) if $params{amount} && abs($self->open_amount - $params{amount} ) > 0.0000001;
  96   } elsif ( $params{'payment_type'} eq 'with_skonto_pt' ) {
  97     croak "amount $params{amount} doesn't match amount less skonto: " . $self->amount_less_skonto . "\n" if $params{amount} && abs($self->amount_less_skonto - $params{amount} ) > 0.0000001;
  98     croak "payment type with_skonto_pt can't be used if payments have already been made" if $self->paid != 0;
  99   };
 100
 101   # absolute skonto amount for invoice, use as reference sum to see if the
 102   # calculated skontos add up
 103   # only needed for payment_term "with_skonto_pt"
 104
 105   my $skonto_amount_check = $self->skonto_amount; # variable should be zero after calculating all skonto
 106   my $total_open_amount   = $self->open_amount;
 107
 108   # account where money is paid to/from: bank account or cash
 109   my $account_bank = SL::DB::Manager::Chart->find_by(id => $params{chart_id});
 110   croak "can't find bank account with id " . $params{chart_id} unless ref $account_bank;
 111
 112   my $reference_account = $self->reference_account;
 113   croak "can't find reference account (link = AR/AP) for invoice" unless ref $reference_account;
 114
 115   my $memo   = $params{memo}   // '';
 116   my $source = $params{source} // '';
 117
 118   my $rounded_params_amount = _round( $params{amount} ); # / $exchangerate);
 119   my $fx_gain_loss_amount = 0; # for fx_gain and fx_loss
 120
 121   my $db = $self->db;
 122   $db->with_transaction(sub {
 123     my $new_acc_trans;
 124
 125     # all three payment type create 1 AR/AP booking (the paid part)
 126     # difference_as_skonto creates n skonto bookings (1 for each tax type)
 127     # with_skonto_pt creates 1 bank booking and n skonto bookings (1 for each tax type)
 128     # without_skonto creates 1 bank booking
 129
 130     # as long as there is no automatic tax, payments are always booked with
 131     # taxkey 0
 132
 133     unless ( $params{payment_type} eq 'difference_as_skonto' ) {
 134       # cases with_skonto_pt and without_skonto
 135
 136       # for case with_skonto_pt we need to know the corrected amount at this
 137       # stage if we are going to use $params{amount}
 138
 139       my $pay_amount = $rounded_params_amount;
 140       $pay_amount = $self->amount_less_skonto if $params{payment_type} eq 'with_skonto_pt';
 141
 142       # bank account and AR/AP
 143       $paid_amount += $pay_amount * $exchangerate;
 144
 145       my $amount = (-1 * $pay_amount) * $mult;
 146
 147
 148       # total amount against bank, do we already know this by now?
 149       $new_acc_trans = SL::DB::AccTransaction->new(trans_id   => $self->id,
 150                                                    chart_id   => $account_bank->id,
 151                                                    chart_link => $account_bank->link,
 152                                                    amount     => $amount,
 153                                                    transdate  => $transdate_obj,
 154                                                    source     => $source,
 155                                                    memo       => $memo,
 156                                                    project_id => $params{project_id} ? $params{project_id} : undef,
 157                                                    taxkey     => 0,
 158                                                    tax_id     => SL::DB::Manager::Tax->find_by(taxkey => 0)->id);
 159       $new_acc_trans->save;
 160
 161       # deal with fxtransaction
 162       if ( $self->currency_id != $::instance_conf->get_currency_id ) {
 163         my $fxamount = _round($amount - ($amount * $exchangerate));
 164         $new_acc_trans = SL::DB::AccTransaction->new(trans_id       => $self->id,
 165                                                      chart_id       => $account_bank->id,
 166                                                      chart_link     => $account_bank->link,
 167                                                      amount         => $fxamount * -1,
 168                                                      transdate      => $transdate_obj,
 169                                                      source         => $source,
 170                                                      memo           => $memo,
 171                                                      taxkey         => 0,
 172                                                      fx_transaction => 1,
 173                                                      tax_id         => SL::DB::Manager::Tax->find_by(taxkey => 0)->id);
 174         $new_acc_trans->save;
 175         # if invoice exchangerate differs from exchangerate of payment
 176         # deal with fxloss and fxamount
 177         if ($self->exchangerate and $self->exchangerate != 1 and $self->exchangerate != $exchangerate) {
 178           my $fxgain_chart = SL::DB::Manager::Chart->find_by(id => $::instance_conf->get_fxgain_accno_id) || die "Can't determine fxgain chart";
 179           my $fxloss_chart = SL::DB::Manager::Chart->find_by(id => $::instance_conf->get_fxloss_accno_id) || die "Can't determine fxloss chart";
 180           my $gain_loss_amount = _round($amount * ($exchangerate - $self->exchangerate ) * -1,2);
 181           my $gain_loss_chart = $gain_loss_amount > 0 ? $fxgain_chart : $fxloss_chart;
 182           $fx_gain_loss_amount = $gain_loss_amount;
 183
 184           $new_acc_trans = SL::DB::AccTransaction->new(trans_id       => $self->id,
 185                                                        chart_id       => $gain_loss_chart->id,
 186                                                        chart_link     => $gain_loss_chart->link,
 187                                                        amount         => $gain_loss_amount,
 188                                                        transdate      => $transdate_obj,
 189                                                        source         => $source,
 190                                                        memo           => $memo,
 191                                                        taxkey         => 0,
 192                                                        fx_transaction => 0,
 193                                                        tax_id         => SL::DB::Manager::Tax->find_by(taxkey => 0)->id);
 194           $new_acc_trans->save;
 195
 196         };
 197       };
 198     };
 199
 200     if ( $params{payment_type} eq 'difference_as_skonto' or $params{payment_type} eq 'with_skonto_pt' ) {
 201
 202       my $total_skonto_amount;
 203       if ( $params{payment_type} eq 'with_skonto_pt' ) {
 204         $total_skonto_amount = $self->skonto_amount;
 205       } elsif ( $params{payment_type} eq 'difference_as_skonto' ) {
 206         $total_skonto_amount = $self->open_amount;
 207       };
 208
 209       my @skonto_bookings = $self->skonto_charts($total_skonto_amount);
 210
 211       # error checking:
 212       if ( $params{payment_type} eq 'difference_as_skonto' ) {
 213         my $calculated_skonto_sum  = sum map { $_->{skonto_amount} } @skonto_bookings;
 214         croak "calculated skonto for difference_as_skonto = $calculated_skonto_sum doesn't add up open amount: " . $self->open_amount unless _round($calculated_skonto_sum) == _round($self->open_amount);
 215       };
 216
 217       my $reference_amount = $total_skonto_amount;
 218
 219       # create an acc_trans entry for each result of $self->skonto_charts
 220       foreach my $skonto_booking ( @skonto_bookings ) {
 221         next unless $skonto_booking->{'chart_id'};
 222         next unless $skonto_booking->{'skonto_amount'} != 0;
 223         my $amount = -1 * $skonto_booking->{skonto_amount};
 224         $new_acc_trans = SL::DB::AccTransaction->new(trans_id   => $self->id,
 225                                                      chart_id   => $skonto_booking->{'chart_id'},
 226                                                      chart_link => SL::DB::Manager::Chart->find_by(id => $skonto_booking->{'chart_id'})->link,
 227                                                      amount     => $amount * $mult,
 228                                                      transdate  => $transdate_obj,
 229                                                      source     => $params{source},
 230                                                      taxkey     => 0,
 231                                                      tax_id     => SL::DB::Manager::Tax->find_by(taxkey => 0)->id);
 232
 233         # the acc_trans entries are saved individually, not added to $self and then saved all at once
 234         $new_acc_trans->save;
 235
 236         $reference_amount -= abs($amount);
 237         $paid_amount      += -1 * $amount * $exchangerate;
 238         $skonto_amount_check -= $skonto_booking->{'skonto_amount'};
 239       };
 240       if ( $params{payment_type} eq 'difference_as_skonto' ) {
 241           die "difference_as_skonto calculated incorrectly, sum of calculated payments doesn't add up to open amount $total_open_amount, reference_amount = $reference_amount\n" unless _round($reference_amount) == 0;
 242       }
 243
 244     };
 245
 246     my $arap_amount = 0;
 247
 248     if ( $params{payment_type} eq 'difference_as_skonto' ) {
 249       $arap_amount = $total_open_amount;
 250     } elsif ( $params{payment_type} eq 'without_skonto' ) {
 251       $arap_amount = $rounded_params_amount;
 252     } elsif ( $params{payment_type} eq 'with_skonto_pt' ) {
 253       # this should be amount + sum(amount+skonto), but while we only allow
 254       # with_skonto_pt for completely unpaid invoices we just use the value
 255       # from the invoice
 256       $arap_amount = $total_open_amount;
 257     };
 258
 259     # regardless of payment_type there is always only exactly one arap booking
 260     # TODO: compare $arap_amount to running total
 261     my $arap_booking= SL::DB::AccTransaction->new(trans_id   => $self->id,
 262                                                   chart_id   => $reference_account->id,
 263                                                   chart_link => $reference_account->link,
 264                                                   amount     => _round($arap_amount * $mult * $exchangerate - $fx_gain_loss_amount),
 265                                                   transdate  => $transdate_obj,
 266                                                   source     => '', #$params{source},
 267                                                   taxkey     => 0,
 268                                                   tax_id     => SL::DB::Manager::Tax->find_by(taxkey => 0)->id);
 269     $arap_booking->save;
 270
 271     $fx_gain_loss_amount *= -1 if $self->is_sales;
 272     $self->paid($self->paid + _round($paid_amount) + $fx_gain_loss_amount) if $paid_amount;
 273     $self->datepaid($transdate_obj);
 274     $self->save;
 275
 276     # make sure transactions will be reloaded the next time $self->transactions
 277     # is called, as pay_invoice saves the acc_trans objects individually rather
 278     # than adding them to the transaction relation array.
 279     $self->forget_related('transactions');
 280
 281     my $datev_check = 0;
 282     if ( $is_sales )  {
 283       if ( (  $self->invoice && $::instance_conf->get_datev_check_on_sales_invoice  ) ||
 284            ( !$self->invoice && $::instance_conf->get_datev_check_on_ar_transaction )) {
 285         $datev_check = 1;
 286       }
 287     } else {
 288       if ( (  $self->invoice && $::instance_conf->get_datev_check_on_purchase_invoice ) ||
 289            ( !$self->invoice && $::instance_conf->get_datev_check_on_ap_transaction   )) {
 290         $datev_check = 1;
 291       }
 292     }
 293
 294     if ( $datev_check ) {
 295
 296       my $datev = SL::DATEV->new(
 297         dbh        => $db->dbh,
 298         trans_id   => $self->{id},
 299       );
 300
 301       $datev->generate_datev_data;
 302
 303       if ($datev->errors) {
 304         # this exception should be caught by with_transaction, which handles the rollback
 305         die join "\n", $::locale->text('DATEV check returned errors:'), $datev->errors;
 306       }
 307     }
 308
 309     1;
 310
 311   }) || die t8('error while paying invoice #1 : ', $self->invnumber) . $db->error . "\n";
 312
 313   return 1;
 314 };
 315
 316 sub skonto_date {
 317
 318   my $self = shift;
 319
 320   my $is_sales = ref($self) eq 'SL::DB::Invoice';
 321
 322   my $skonto_date;
 323
 324   if ( $is_sales ) {
 325     return undef unless ref $self->payment_terms;
 326     return undef unless $self->payment_terms->terms_skonto > 0;
 327     $skonto_date = DateTime->from_object(object => $self->transdate)->add(days => $self->payment_terms->terms_skonto);
 328   } else {
 329     return undef unless ref $self->vendor->payment_terms;
 330     return undef unless $self->vendor->payment_terms->terms_skonto > 0;
 331     $skonto_date = DateTime->from_object(object => $self->transdate)->add(days => $self->vendor->payment_terms->terms_skonto);
 332   };
 333
 334   return $skonto_date;
 335 };
 336
 337 sub reference_account {
 338   my $self = shift;
 339
 340   my $is_sales = ref($self) eq 'SL::DB::Invoice';
 341
 342   require SL::DB::Manager::AccTransaction;
 343
 344   my $link_filter = $is_sales ? 'AR' : 'AP';
 345
 346   my $acc_trans = SL::DB::Manager::AccTransaction->find_by(
 347      trans_id   => $self->id,
 348      SL::DB::Manager::AccTransaction->chart_link_filter("$link_filter")
 349   );
 350
 351   return undef unless ref $acc_trans;
 352
 353   my $reference_account = SL::DB::Manager::Chart->find_by(id => $acc_trans->chart_id);
 354
 355   return $reference_account;
 356 };
 357
 358 sub reference_amount {
 359   my $self = shift;
 360
 361   my $is_sales = ref($self) eq 'SL::DB::Invoice';
 362
 363   require SL::DB::Manager::AccTransaction;
 364
 365   my $link_filter = $is_sales ? 'AR' : 'AP';
 366
 367   my $acc_trans = SL::DB::Manager::AccTransaction->find_by(
 368      trans_id   => $self->id,
 369      SL::DB::Manager::AccTransaction->chart_link_filter("$link_filter")
 370   );
 371
 372   return undef unless ref $acc_trans;
 373
 374   # this should be the same as $self->amount
 375   return $acc_trans->amount;
 376 };
 377
 378
 379 sub open_amount {
 380   my $self = shift;
 381
 382   # in the future maybe calculate this from acc_trans
 383
 384   # if the difference is 0.01 Cent this may end up as 0.009999999999998
 385   # numerically, so round this value when checking for cent threshold >= 0.01
 386
 387   return ($self->amount // 0) - ($self->paid // 0);
 388 };
 389
 390 sub open_percent {
 391   my $self = shift;
 392
 393   return 0 if $self->amount == 0;
 394   my $open_percent;
 395   if ( $self->open_amount < 0 ) {
 396     # overpaid, currently treated identically
 397     $open_percent = $self->open_amount * 100 / $self->amount;
 398   } else {
 399     $open_percent = $self->open_amount * 100 / $self->amount;
 400   };
 401
 402   return _round($open_percent) || 0;
 403 };
 404
 405 sub skonto_amount {
 406   my $self = shift;
 407
 408   return $self->amount - $self->amount_less_skonto;
 409 };
 410
 411 sub remaining_skonto_days {
 412   my $self = shift;
 413
 414   return undef unless ref $self->skonto_date;
 415
 416   my $dur = DateTime::Duration->new($self->skonto_date - DateTime->today);
 417   return $dur->delta_days();
 418
 419 };
 420
 421 sub percent_skonto {
 422   my $self = shift;
 423
 424   my $is_sales = ref($self) eq 'SL::DB::Invoice';
 425
 426   my $percent_skonto = 0;
 427
 428   if ( $is_sales ) {
 429     return undef unless ref $self->payment_terms;
 430     return undef unless $self->payment_terms->percent_skonto > 0;
 431     $percent_skonto = $self->payment_terms->percent_skonto;
 432   } else {
 433     return undef unless ref $self->vendor->payment_terms;
 434     return undef unless $self->vendor->payment_terms->terms_skonto > 0;
 435     $percent_skonto = $self->vendor->payment_terms->percent_skonto;
 436   };
 437
 438   return $percent_skonto;
 439 };
 440
 441 sub amount_less_skonto {
 442   # amount that has to be paid if skonto applies, always return positive rounded values
 443   # the result is rounded so we can directly compare it with the user input
 444   my $self = shift;
 445
 446   my $is_sales = ref($self) eq 'SL::DB::Invoice';
 447
 448   my $percent_skonto = $self->percent_skonto || 0;
 449
 450   return _round($self->amount - ( $self->amount * $percent_skonto) );
 451
 452 };
 453
 454 sub check_skonto_configuration {
 455   my $self = shift;
 456
 457   my $is_sales = ref($self) eq 'SL::DB::Invoice';
 458
 459   my $skonto_configured = 1; # default is assume skonto works
 460
 461   # my $transactions = $self->transactions;
 462   foreach my $transaction (@{ $self->transactions }) {
 463     # find all transactions with an AR_amount or AP_amount link
 464     my $tax = SL::DB::Manager::Tax->get_first( where => [taxkey => $transaction->taxkey, id => $transaction->tax_id ]);
 465     croak "no tax for taxkey " . $transaction->{taxkey} unless ref $tax;
 466
 467     $transaction->{chartlinks} = { map { $_ => 1 } split(m/:/, $transaction->chart_link) };
 468     if ( $is_sales && $transaction->{chartlinks}->{AR_amount} ) {
 469       $skonto_configured = 0 unless $tax->skonto_sales_chart_id;
 470     } elsif ( !$is_sales && $transaction->{chartlinks}->{AP_amount}) {
 471       $skonto_configured = 0 unless $tax->skonto_purchase_chart_id;
 472     };
 473   };
 474
 475   return $skonto_configured;
 476 };
 477
 478 sub open_sepa_transfer_amount {
 479   my $self = shift;
 480
 481   my ($vc, $key, $type);
 482   if ( ref($self) eq 'SL::DB::Invoice' ) {
 483     $vc   = 'customer';
 484     $key  = 'ap_id';
 485     $type = 'ar';
 486   } else {
 487     $vc   = 'vendor';
 488     $key  = 'ap_id';
 489     $type = 'ap';
 490   };
 491
 492   my $sql = qq|SELECT SUM(sei.amount) AS amount FROM sepa_export_items sei | .
 493             qq| LEFT JOIN sepa_export se ON (sei.sepa_export_id = se.id)   | .
 494             qq| WHERE $key = ? AND NOT se.closed AND (se.vc = '$vc')       |;
 495
 496   my ($open_sepa_amount) = $self->db->dbh->selectrow_array($sql, undef, $self->id);
 497
 498   return $open_sepa_amount || 0;
 499
 500 };
 501
 502
 503 sub skonto_charts {
 504   my $self = shift;
 505
 506   # TODO: use param for amount, may also want to calculate skonto_amounts by
 507   # passing percentage in the future
 508
 509   my $amount = shift || $self->skonto_amount;
 510
 511   croak "no amount passed to skonto_charts" unless abs(_round($amount)) >= 0.01;
 512
 513   # TODO: check whether there are negative values in invoice / acc_trans ... credited items
 514
 515   # don't check whether skonto applies, because user may want to override this
 516   # return undef unless $self->percent_skonto;  # for is_sales
 517   # return undef unless $self->vendor->payment_terms->percent_skonto;  # for purchase
 518
 519   my $is_sales = ref($self) eq 'SL::DB::Invoice';
 520
 521   my $mult = $is_sales ? 1 : -1;  # multiplier for getting the right sign
 522
 523   my @skonto_charts;  # resulting array with all income/expense accounts that have to be corrected
 524
 525   # calculate effective skonto (percentage) in difference_as_skonto mode
 526   # only works if there are no negative acc_trans values
 527   my $effective_skonto_rate = $amount ? $amount / $self->amount : 0;
 528
 529   # checks:
 530   my $total_skonto_amount  = 0;
 531   my $total_rounding_error = 0;
 532
 533   my $reference_ARAP_amount = 0;
 534
 535   # my $transactions = $self->transactions;
 536   foreach my $transaction (@{ $self->transactions }) {
 537     # find all transactions with an AR_amount or AP_amount link
 538     $transaction->{chartlinks} = { map { $_ => 1 } split(m/:/, $transaction->{chart_link}) };
 539     # second condition is that we can determine an automatic Skonto account for each AR_amount entry
 540
 541     if ( ( $is_sales && $transaction->{chartlinks}->{AR_amount} ) or ( !$is_sales && $transaction->{chartlinks}->{AP_amount}) ) {
 542         # $reference_ARAP_amount += $transaction->{amount} * $mult;
 543
 544         # quick hack that works around problem of non-unique tax keys in SKR04
 545         # ? use tax_id in acc_trans
 546         my $tax = SL::DB::Manager::Tax->get_first( where => [id => $transaction->{tax_id}]);
 547         croak "no tax for taxkey " . $transaction->{taxkey} unless ref $tax;
 548
 549         if ( $is_sales ) {
 550           die t8('no skonto_chart configured for taxkey #1 : #2 : #3', $transaction->{taxkey} , $tax->taxdescription , $tax->rate*100) unless ref $tax->skonto_sales_chart;
 551         } else {
 552           die t8('no skonto_chart configured for taxkey #1 : #2 : #3', $transaction->{taxkey} , $tax->taxdescription , $tax->rate*100) unless ref $tax->skonto_purchase_chart;
 553         };
 554
 555         my $skonto_amount_unrounded;
 556
 557         my $skonto_percent_abs = $self->amount ? abs($transaction->amount * (1 + $tax->rate) * 100 / $self->amount) : 0;
 558
 559         my $transaction_amount = abs($transaction->{amount} * (1 + $tax->rate));
 560         my $transaction_skonto_percent = abs($transaction_amount/$self->amount); # abs($transaction->{amount} * (1 + $tax->rate));
 561
 562
 563         $skonto_amount_unrounded   = abs($amount * $transaction_skonto_percent);
 564         my $skonto_amount_rounded  = _round($skonto_amount_unrounded);
 565         my $rounding_error         = $skonto_amount_unrounded - $skonto_amount_rounded;
 566         my $rounded_rounding_error = _round($rounding_error);
 567
 568         $total_rounding_error += $rounding_error;
 569         $total_skonto_amount  += $skonto_amount_rounded;
 570
 571         my $rec = {
 572           # skonto_percent_abs: relative part of amount + tax to the total invoice amount
 573           'skonto_percent_abs'     => $skonto_percent_abs,
 574           'chart_id'               => $is_sales ? $tax->skonto_sales_chart->id : $tax->skonto_purchase_chart->id,
 575           'skonto_amount'          => $skonto_amount_rounded,
 576           # 'rounding_error'         => $rounding_error,
 577           # 'rounded_rounding_error' => $rounded_rounding_error,
 578         };
 579
 580         push @skonto_charts, $rec;
 581       };
 582   };
 583
 584   # if the rounded sum of all rounding_errors reaches 0.01 this sum is
 585   # subtracted from the largest skonto_amount
 586   my $rounded_total_rounding_error = abs(_round($total_rounding_error));
 587
 588   if ( $rounded_total_rounding_error > 0 ) {
 589     my $highest_amount_pos = 0;
 590     my $highest_amount = 0;
 591     my $i = -1;
 592     foreach my $ref ( @skonto_charts ) {
 593       $i++;
 594       if ( $ref->{skonto_amount} > $highest_amount ) {
 595         $highest_amount     = $ref->{skonto_amount};
 596         $highest_amount_pos = $i;
 597       };
 598     };
 599     $skonto_charts[$i]->{skonto_amount} -= $rounded_total_rounding_error;
 600   };
 601
 602   return @skonto_charts;
 603 };
 604
 605
 606 sub within_skonto_period {
 607   my $self = shift;
 608   my $dateref = shift || DateTime->now->truncate( to => 'day' );
 609
 610   return undef unless ref $dateref eq 'DateTime';
 611   return 0 unless $self->skonto_date;
 612
 613   # return 1 if requested date (or today) is inside skonto period
 614   # this will also return 1 if date is before the invoice date
 615   return $dateref <= $self->skonto_date;
 616 };
 617
 618 sub valid_skonto_amount {
 619   my $self = shift;
 620   my $amount = shift || 0;
 621   my $max_skonto_percent = 0.10;
 622
 623   return 0 unless $amount > 0;
 624
 625   # does this work for other currencies?
 626   return ($self->amount*$max_skonto_percent) > $amount;
 627 };
 628
 629 sub get_payment_select_options_for_bank_transaction {
 630   my ($self, $bt_id, %params) = @_;
 631
 632   my $bt = SL::DB::Manager::BankTransaction->find_by( id => $bt_id );
 633   croak ("Need bt_id to get a valid bank transaction") unless $bt;
 634
 635   # user may overpay invoices and if not, this case should better be handled elsewhere
 636   #my $open_amount = $self->open_amount;
 637   #croak ("Need an open invoice") unless $open_amount;
 638
 639   my @options;
 640
 641     if ($self->skonto_date && $self->within_skonto_period($bt->transdate)) {
 642       push(@options, { payment_type => 'without_skonto', display => t8('without skonto') });
 643       push(@options, { payment_type => 'with_skonto_pt', display => t8('with skonto acc. to pt'), selected => 1 });
 644     } else {
 645       push(@options, { payment_type => 'without_skonto', display => t8('without skonto') , selected => 1 });
 646       push(@options, { payment_type => 'with_skonto_pt', display => t8('with skonto acc. to pt')});
 647     }
 648   }
 649
 650   return @options;
 651 }
 652
 653 sub exchangerate {
 654   my ($self) = @_;
 655
 656   return 1 if $self->currency_id == $::instance_conf->get_currency_id;
 657
 658   die "transdate isn't a DateTime object:" . ref($self->transdate) unless ref($self->transdate) eq 'DateTime';
 659   my $rate = SL::DB::Manager::Exchangerate->find_by(currency_id => $self->currency_id,
 660                                                     transdate   => $self->transdate,
 661                                                    );
 662   return undef unless $rate;
 663
 664   return $self->is_sales ? $rate->buy : $rate->sell; # also undef if not defined
 665 };
 666
 667 sub get_payment_suggestions {
 668
 669   my ($self, %params) = @_;
 670
 671   my $open_amount = $self->open_amount;
 672   $open_amount   -= $self->open_sepa_transfer_amount if $params{sepa};
 673
 674   $self->{invoice_amount_suggestion} = $open_amount;
 675   undef $self->{payment_select_options};
 676   push(@{$self->{payment_select_options}} , { payment_type => 'without_skonto',  display => t8('without skonto') });
 677   if ( $self->within_skonto_period ) {
 678     # If there have been no payments yet suggest amount_less_skonto, otherwise the open amount
 679     if ( $open_amount &&                   # invoice amount not 0
 680          $open_amount == $self->amount &&  # no payments yet, or sum of payments and sepa export amounts is zero
 681          $self->check_skonto_configuration) {
 682       $self->{invoice_amount_suggestion} = $self->amount_less_skonto;
 683       push(@{$self->{payment_select_options}} , { payment_type => 'with_skonto_pt',  display => t8('with skonto acc. to pt') , selected => 1 });
 684     } else {
 685       if ( ( $self->valid_skonto_amount($self->open_amount) || $self->valid_skonto_amount($open_amount) ) and not $params{sepa} ) {
 686         $self->{invoice_amount_suggestion} = $open_amount;
 687         # only suggest difference_as_skonto if open_amount exactly matches skonto_amount
 688         # AND we aren't in SEPA mode
 689         my $selected = 0;
 690         $selected = 1 if _round($open_amount) == _round($self->skonto_amount);
 691         push(@{$self->{payment_select_options}} , { payment_type => 'difference_as_skonto',  display => t8('difference as skonto') , selected => $selected });
 692       };
 693     };
 694   } else {
 695     # invoice was configured with skonto, but skonto date has passed, or no skonto available
 696     $self->{invoice_amount_suggestion} = $open_amount;
 697     # difference_as_skonto doesn't make any sense for SEPA transfer, as this doesn't cause any actual payment
 698     if ( $self->valid_skonto_amount($self->open_amount) && not $params{sepa} ) {
 699       push(@{$self->{payment_select_options}} , { payment_type => 'difference_as_skonto',  display => t8('difference as skonto') , selected => 0 });
 700     };
 701   };
 702   return 1;
 703 };
 704
 705 # locales for payment type
 706 #
 707 # $main::locale->text('without_skonto')
 708 # $main::locale->text('with_skonto_pt')
 709 # $main::locale->text('difference_as_skonto')
 710 #
 711
 712 sub validate_payment_type {
 713   my $payment_type = shift;
 714
 715   my %allowed_payment_types = map { $_ => 1 } qw(without_skonto with_skonto_pt difference_as_skonto);
 716   croak "illegal payment type: $payment_type, must be one of: " . join(' ', keys %allowed_payment_types) unless $allowed_payment_types{ $payment_type };
 717
 718   return 1;
 719 }
 720
 721 sub forex {
 722   my ($self) = @_;
 723   $self->currency_id == $::instance_conf->get_currency_id ? return 0 : return 1;
 724 };
 725
 726 sub _round {
 727   my $value = shift;
 728   my $num_dec = 2;
 729   return $::form->round_amount($value, 2);
 730 }
 731
 732 1;
 733
 734 __END__
 735
 736 =pod
 737
 738 =head1 NAME
 739
 740 SL::DB::Helper::Payment  Mixin providing helper methods for paying C<Invoice>
 741                          and C<PurchaseInvoice> objects and using skonto
 742
 743 =head1 SYNOPSIS
 744
 745 In addition to actually causing a payment via pay_invoice this helper contains
 746 many methods that help in determining information about the status of the
 747 invoice, such as the remaining open amount, whether skonto applies, until which
 748 date skonto applies, the skonto amount and relative percentages, what to do
 749 with skonto, ...
 750
 751 To prevent duplicate code this was all added in this mixin rather than directly
 752 in SL::DB::Invoice and SL::DB::PurchaseInvoice.
 753
 754 =over 4
 755
 756 =item C<pay_invoice %params>
 757
 758 Create a payment booking for an existing invoice object (type ar/ap/is/ir) via
 759 a configured bank account.
 760
 761 This function deals with all the acc_trans entries and also updates paid and datepaid.
 762
 763 Example:
 764
 765   my $ap   = SL::DB::Manager::PurchaseInvoice->find_by( invnumber => '1');
 766   my $bank = SL::DB::Manager::BankAccount->find_by( name => 'Bank');
 767   $ap->pay_invoice(chart_id      => $bank->chart_id,
 768                    amount        => $ap->open_amount,
 769                    transdate     => DateTime->now->to_kivitendo,
 770                    memo          => 'foobar',
 771                    source        => 'barfoo',
 772                    payment_type  => 'without_skonto',  # default if not specified
 773                    project_id    => 25,
 774                   );
 775
 776 or with skonto:
 777   $ap->pay_invoice(chart_id      => $bank->chart_id,
 778                    amount        => $ap->amount,       # doesn't need to be specified
 779                    transdate     => DateTime->now->to_kivitendo,
 780                    memo          => 'foobar',
 781                    source        => 'barfoo',
 782                    payment_type  => 'with_skonto',
 783                   );
 784
 785 or in a certain currency:
 786   $ap->pay_invoice(chart_id      => $bank->chart_id,
 787                    amount        => 500,
 788                    currency      => 'USD',
 789                    transdate     => DateTime->now->to_kivitendo,
 790                    memo          => 'foobar',
 791                    source        => 'barfoo',
 792                    payment_type  => 'with_skonto_pt',
 793                   );
 794
 795 Allowed payment types are:
 796   without_skonto with_skonto_pt difference_as_skonto
 797
 798 The option C<payment_type> allows for a basic skonto mechanism.
 799
 800 C<without_skonto> is the default mode, "amount" is paid to the account in
 801 chart_id. This can also be used for partial payments and corrections via
 802 negative amounts.
 803
 804 C<with_skonto_pt> can't be used for partial payments. When used on unpaid
 805 invoices the whole amount is paid, with the skonto part automatically being
 806 booked according to the skonto chart configured in the tax settings for each
 807 tax key. If an amount is passed it is ignored and the actual configured skonto
 808 amount is used.
 809
 810 C<difference_as_skonto> can only be used after partial payments have been made,
 811 the whole specified amount is booked according to the skonto charts configured
 812 in the tax settings for each tax key.
 813
 814 So passing amount doesn't have any effect for the cases C<with_skonto_pt> and
 815 C<difference_as_skonto>, as all necessary values are taken from the stored
 816 invoice.
 817
 818 The skonto modes automatically calculate the relative amounts for a mix of
 819 taxes, e.g. items with 7% and 19% in one invoice. There is a helper method
 820 skonto_charts, which calculates the relative percentages according to the
 821 amounts in acc_trans (which are grouped by tax).
 822
 823 There is currently no way of excluding certain items in an invoice from having
 824 skonto applied to them.  If this feature was added to parts the calculation
 825 method of relative skonto would have to be completely rewritten using the
 826 invoice items rather than acc_trans.
 827
 828 The skonto modes also still don't automatically correct the tax, this still has
 829 to be done manually. Therefore all payments generated by pay_invoice have
 830 taxkey 0.
 831
 832 There is currently no way to directly pay an invoice via this method if the
 833 effective skonto differs from the skonto according to the payment terms
 834 configured for the invoice/vendor.
 835
 836 In this case one has to pay in two steps: first the actual paid amount via
 837 "without skonto", and then the remainder via "difference_as_skonto". The user
 838 has to there actively decide whether to accept the differing skonto.
 839
 840 Because of the way skonto_charts works the calculation doesn't work if there
 841 are negative values in acc_trans. E.g. one invoice with a positive value for
 842 19% tax and a negative value for the acc_trans line with 7%
 843
 844 Skonto doesn't/shouldn't apply if the invoice contains credited items.
 845
 846 If no amount is given the whole open amout is paid.
 847
 848 If neither currency or currency_id are given as params, the currency of the
 849 invoice is assumed to be the payment currency.
 850
 851 =item C<reference_account>
 852
 853 Returns a chart object which is the chart of the invoice with link AR or AP.
 854
 855 Example (1200 is the AR account for SKR04):
 856   my $invoice = invoice(invnumber => '144');
 857   $invoice->reference_account->accno
 858   # 1200
 859
 860 =item C<percent_skonto>
 861
 862 Returns the configured skonto percentage of the payment terms of an invoice,
 863 e.g. 0.02 for 2%. Payment terms come from invoice settings for ar, from vendor
 864 settings for ap.
 865
 866 =item C<amount_less_skonto>
 867
 868 If the invoice has a payment term (via ar for sales, via vendor for purchase),
 869 calculate the amount to be paid in the case of skonto.  This doesn't check,
 870 whether skonto applies (i.e. skonto doesn't wasn't exceeded), it just subtracts
 871 the configured percentage (e.g. 2%) from the total amount.
 872
 873 The returned value is rounded to two decimals.
 874
 875 =item C<skonto_date>
 876
 877 The date up to which skonto may be taken. This is calculated from the invoice
 878 date + the number of days configured in the payment terms.
 879
 880 This method can also be used to determine whether skonto applies for the
 881 invoice, as it returns undef if there is no payment term or skonto days is set
 882 to 0.
 883
 884 =item C<within_skonto_period [DATE]>
 885
 886 Returns 0 or 1.
 887
 888 Checks whether the invoice has payment terms configured, and whether the date
 889 is within the skonto max date. If no date is passed the current date is used.
 890
 891 You can also pass a dateref object as a parameter to check whether skonto
 892 applies for that date rather than the current date.
 893
 894 =item C<valid_skonto_amount>
 895
 896 Takes an amount as an argument and checks whether the amount is less than 10%
 897 of the total amount of the invoice. The value of 10% is currently hardcoded in
 898 the method. This method is currently used to check whether to offer the payment
 899 option "difference as skonto".
 900
 901 Example:
 902  if ( $invoice->valid_skonto_amount($invoice->open_amount) ) {
 903    # ... do something
 904  }
 905
 906 =item C<skonto_charts [$amount]>
 907
 908 Returns a list of chart_ids and some calculated numbers that can be used for
 909 paying the invoice with skonto. This function will automatically calculate the
 910 relative skonto amounts even if the invoice contains several types of taxes
 911 (e.g. 7% and 19%).
 912
 913 Example usage:
 914   my $invoice = SL::DB::Manager::Invoice->find_by(invnumber => '211');
 915   my @skonto_charts = $invoice->skonto_charts;
 916
 917 or with the total skonto amount as an argument:
 918   my @skonto_charts = $invoice->skonto_charts($invoice->open_amount);
 919
 920 The following values are generated for each chart:
 921
 922 =over 2
 923
 924 =item C<chart_id>
 925
 926 The chart id of the skonto amount to be booked.
 927
 928 =item C<skonto_amount>
 929
 930 The total amount to be paid to the account
 931
 932 =item C<skonto_percent>
 933
 934 The relative percentage of that skonto chart. This can be useful if the actual
 935 ekonto that is paid deviates from the granted skonto, e.g. customer effectively
 936 pays 2.6% skonto instead of 2%, and we accept this. Then we can still calculate
 937 the relative skonto amounts for different taxes based on the absolute
 938 percentages. Used for case C<difference_as_skonto>.
 939
 940 =item C<skonto_percent_abs>
 941
 942 The absolute percentage of that skonto chart in relation to the total amount.
 943 Used to calculate skonto_amount for case C<with_skonto_pt>.
 944
 945 =back
 946
 947 If the invoice contains several types of taxes then skonto_charts can be used
 948 to calculate the relative amounts.
 949
 950 Example in console of an invoice with 100 Euro at 7% and 100 Euro at 19% with
 951 tax not included:
 952
 953   my $invoice = invoice(invnumber => '144');
 954   $invoice->amount
 955   226.00000
 956   $invoice->payment_terms->percent_skonto
 957   0.02
 958   $invoice->skonto_charts
 959   pp $invoice->skonto_charts
 960   #             $VAR1 = {
 961   #               'chart_id'       => 128,
 962   #               'skonto_amount'  => '2.14',
 963   #               'skonto_percent' => '47.3451327433627'
 964   #             };
 965   #             $VAR2 = {
 966   #               'chart_id'       => 130,
 967   #               'skonto_amount'  => '2.38',
 968   #               'skonto_percent' => '52.654867256637'
 969   #             };
 970
 971 C<skonto_charts> always returns positive values (abs) for C<skonto_amount> and
 972 C<skonto_percent>.
 973
 974 C<skonto_charts> generates one entry for each acc_trans entry. ar and ap
 975 bookings only have one acc_trans entry for each taxkey (e.g. 7% and 19%).  This
 976 is because all the items are grouped according to the Buchungsgruppen mechanism
 977 and the totals are written to acc_trans.  For is and ir it is possible to have
 978 several acc_trans entries with the same tax. In this case skonto_charts
 979 generates a skonto booking for each acc_trans income/expense entry.
 980
 981 In the future this function may also be used to calculate the corrections for
 982 the income tax.
 983
 984 =item C<open_amount>
 985
 986 Unrounded total open amount of invoice (amount - paid).
 987 Doesn't take into account pending SEPA transfers.
 988
 989 =item C<open_percent>
 990
 991 Percentage of the invoice that is still unpaid, e.g. 100,00 if no payments have
 992 been made yet, 0,00 if fully paid.
 993
 994 =item C<remaining_skonto_days>
 995
 996 How many days skonto can still be taken, calculated from current day. Returns 0
 997 if current day is the max skonto date, and negative number if skonto date has
 998 already passed.
 999
1000 Returns undef if skonto is not configured for that invoice.
1001
1002 =item C<get_payment_suggestions %params>
1003
1004 Creates data intended for an L.select_tag dropdown that can be used in a
1005 template. Depending on the rules it will choose from the options
1006 without_skonto, with_skonto_pt and difference_as_skonto, and select the most
1007 likely one.
1008
1009 If the parameter "sepa" is passed, the SEPA export payments that haven't been
1010 executed yet are considered when determining the open amount of the invoice.
1011
1012 The current rules are:
1013
1014 =over 2
1015
1016 =item * without_skonto is always an option
1017
1018 =item * with_skonto_pt is only offered if there haven't been any payments yet and the current date is within the skonto period.
1019
1020 =item * difference_as_skonto is only offered if there have already been payments made and the open amount is smaller than 10% of the total amount.
1021
1022 with_skonto_pt will only be offered, if all the AR_amount/AP_amount have a
1023 taxkey with a configured skonto chart
1024
1025 =back
1026
1027 It will also fill $self->{invoice_amount_suggestion} with either the open
1028 amount, or if with_skonto_pt is selected, with amount_less_skonto, so the
1029 template can fill the input with the likely amount.
1030
1031 Example in console:
1032   my $ar = invoice( invnumber => '257');
1033   $ar->get_payment_suggestions;
1034   print $ar->{invoice_amount_suggestion} . "\n";
1035   # 97.23
1036   pp $ar->{payment_select_options}
1037   # $VAR1 = [
1038   #         {
1039   #           'display' => 'ohne Skonto',
1040   #           'payment_type' => 'without_skonto'
1041   #         },
1042   #         {
1043   #           'display' => 'mit Skonto nach ZB',
1044   #           'payment_type' => 'with_skonto_pt',
1045   #           'selected' => 1
1046   #         }
1047   #       ];
1048
1049 The resulting array $ar->{payment_select_options} can be used in a template
1050 select_tag using value_key and title_key:
1051
1052 [% L.select_tag('payment_type_' _ loop.count, invoice.payment_select_options, value_key => 'payment_type', title_key => 'display', id => 'payment_type_' _ loop.count) %]
1053
1054 It would probably make sense to have different rules for the pre-selected items
1055 for sales and purchase, and to also make these rules configurable in the
1056 defaults. E.g. when creating a SEPA bank transfer for vendor invoices a company
1057 might always want to pay quickly making use of skonto, while another company
1058 might always want to pay as late as possible.
1059
1060 =item C<get_payment_select_options_for_bank_transaction $banktransaction_id %params>
1061
1062 Make suggestion for a skonto payment type by returning an HTML blob of the options
1063 of a HTML drop-down select with the most likely option preselected.
1064
1065 This is a helper function for BankTransaction/ajax_payment_suggestion.
1066
1067 We are working with an existing payment, so difference_as_skonto never makes sense.
1068
1069 If skonto is possible (skonto_date exists), add two possibilities:
1070 without_skonto and with_skonto_pt if payment date is within skonto_date,
1071 preselect with_skonto_pt, otherwise preselect without skonto.
1072
1073 =item C<exchangerate>
1074
1075 Returns 1 immediately if the record uses the default currency.
1076
1077 Returns the exchangerate in database format for the invoice according to that
1078 invoice's transdate, returning 'buy' for sales, 'sell' for purchases.
1079
1080 If no exchangerate can be found for that day undef is returned.
1081
1082 =item C<forex>
1083
1084 Returns 1 if record uses a different currency, 0 if the default currency is used.
1085
1086 =back
1087
1088 =head1 TODO AND CAVEATS
1089
1090 =over 4
1091
1092 =item *
1093
1094 when looking at open amount, maybe consider that there may already be queued
1095 amounts in SEPA Export
1096
1097 =back
1098
1099 =head1 AUTHOR
1100
1101 G. Richardson E<lt>grichardson@kivitendo-premium.de<gt>
1102
1103 =cut